Marker.qml Example File

  /****************************************************************************
  **
  ** Copyright (C) 2015 The Qt Company Ltd.
  ** Contact: http://www.qt.io/licensing/
  **
  ** This file is part of the examples of the Qt Toolkit.
  **
  ** $QT_BEGIN_LICENSE:BSD$
  ** You may use this file under the terms of the BSD license as follows:
  **
  ** "Redistribution and use in source and binary forms, with or without
  ** modification, are permitted provided that the following conditions are
  ** met:
  **   * Redistributions of source code must retain the above copyright
  **     notice, this list of conditions and the following disclaimer.
  **   * Redistributions in binary form must reproduce the above copyright
  **     notice, this list of conditions and the following disclaimer in
  **     the documentation and/or other materials provided with the
  **     distribution.
  **   * Neither the name of The Qt Company Ltd nor the names of its
  **     contributors may be used to endorse or promote products derived
  **     from this software without specific prior written permission.
  **
  **
  ** THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
  ** "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
  ** LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
  ** A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
  ** OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
  ** SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
  ** LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
  ** DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
  ** THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
  ** (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
  ** OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE."
  **
  ** $QT_END_LICENSE$
  **
  ****************************************************************************/

  import QtQuick 2.5;
  import QtLocation 5.6

  MapQuickItem {
      id: marker
      property alias lastMouseX: markerMouseArea.lastX
      property alias lastMouseY: markerMouseArea.lastY

      anchorPoint.x: image.width/4
      anchorPoint.y: image.height

      sourceItem: Image {
          id: image
          source: "../resources/marker.png"
          opacity: markerMouseArea.pressed ? 0.6 : 1.0
          MouseArea  {
              id: markerMouseArea
              property int pressX : -1
              property int pressY : -1
              property int jitterThreshold : 10
              property int lastX: -1
              property int lastY: -1
              anchors.fill: parent
              hoverEnabled : false
              drag.target: marker
              preventStealing: true

              onPressed : {
                  map.pressX = mouse.x
                  map.pressY = mouse.y
                  map.currentMarker = -1
                  for (var i = 0; i< map.markers.length; i++){
                      if (marker == map.markers[i]){
                          map.currentMarker = i
                          break
                      }
                  }
              }

              onPressAndHold:{
                  if (Math.abs(map.pressX - mouse.x ) < map.jitterThreshold
                          && Math.abs(map.pressY - mouse.y ) < map.jitterThreshold) {
                      var p = map.fromCoordinate(marker.coordinate)
                      lastX = p.x
                      lastY = p.y
                      map.showMarkerMenu(marker.coordinate)
                  }
              }
          }

          Text{
              id: number
              y: image.height/10
              width: image.width
              color: "white"
              font.bold: true
              font.pixelSize: 14
              horizontalAlignment: Text.AlignHCenter
              Component.onCompleted: {
                  text = map.markerCounter
              }
          }

      }

      Component.onCompleted: coordinate = map.toCoordinate(Qt.point(markerMouseArea.mouseX,
                                                                    markerMouseArea.mouseY));
  }