dnl withenable.ac: --with and --enable options.

AC_ARG_WITH(maketextex-default,
[  --with-maketextex-default  run MakeTeXTeX if TeX source missing],
  withval=yes, withval=no)
if test "$withval" = yes; then
  AC_DEFINE(MAKE_TEX_TEX_BY_DEFAULT)
fi

AC_ARG_WITH(editor, changequote(`,')dnl
`  --with-editor=CMD       invoke CMD from the e option [vi +%d %s]',
changequote([,])dnl
  AC_DEFINE_UNQUOTED(EDITOR, $with_editor)
)

AC_ARG_ENABLE(ipc,
[  --enable-ipc            enable TeX's --ipc option, i.e., pipe to a program],
  AC_DEFINE(IPC)
  # -lsocket is needed on Solaris, at least.  Maybe -lnsl on SCO, too?
  # See ac_path_xtra.
  AC_CHECK_FUNC(connect)
  if test $ac_cv_func_connect = no; then
    AC_CHECK_LIB(socket, connect, socketlibs="-lsocket $socketlibs")
  fi
)
AC_SUBST(socketlibs)

AC_ARG_ENABLE(auto-core,
[  --enable-auto-core      cause TeX&MF to dump core given a certain filename],
  AC_DEFINE(FUNNY_CORE_DUMP))

AC_ARG_ENABLE(dump-noshare,
[  --disable-dump-share    make fmt/base/mem files architecture-dependent],
if test "$enableval" = no; then
  AC_DEFINE(NO_DUMP_SHARE)
fi
)

# Window system support for Metafont.
AC_ARG_WITH(hp2627win,
  [  --with-hp2627win        include HP 2627 window support in Metafont],
  AC_DEFINE(HP2627WIN))
AC_ARG_WITH(mftalkwin,
  [  --with-mftalkwin        include mftalk (generic server) window support],
  AC_DEFINE(NEXTWIN))
AC_ARG_WITH(nextwin,
  [  --with-nextwin          include NeXT window support],
  AC_DEFINE(NEXTWIN))
AC_ARG_WITH(regiswin,
  [  --with-regiswin         include Regis window support],
  AC_DEFINE(REGISWIN))
AC_ARG_WITH(suntoolswin,
  [  --with-suntoolswin      include old Suntools window support (this is not X)],
  wlibs="-lsuntool -lsunwindow -lpixrect $wlibs"
  AC_DEFINE(SUNWIN))
AC_ARG_WITH(tektronixwin,
  [  --with-tektronixwin     include Tektronix window support],
  AC_DEFINE(TEKTRONIXWIN))
AC_ARG_WITH(unitermwin,
  [  --with-unitermwin       include Uniterm window support],
  AC_DEFINE(UNITERMWIN))

sinclude(../kpathsea/xt.ac)dnl for web2c/configure
sinclude(kpathsea/xt.ac)dnl for top-level configure

AC_ARG_WITH(x11win,
  [  --with-x11win           same as --with-x],
  with_x="$withval")
AC_ARG_WITH(x11,
  [  --with-x11              same as --with-x],
  with_x="$withval")