Files
*****

In Emacs, you can find, create, view, save, and otherwise work with files and file directories.  This chapter describes most of the file-related functions of Emacs Lisp, but a few others are described in Buffers, and those related to backups and auto-saving are described in Backups and Auto-Saving.

Many of the file functions take one or more arguments that are file names.  A file name is actually a string.  Most of these functions expand file name arguments using expand-file-name, so that ~ is handled correctly, as are relative file names (including ../).  These functions don't recognize environment variable substitutions such as $HOME.  See File Name Expansion.

Visiting Files
==============

Visiting a file means reading a file into a buffer.  Once this is done, we say that the buffer is visiting that file, and call the file ``the visited file'' of the buffer.

A file and a buffer are two different things.  A file is information recorded permanently in the computer (unless you delete it).  A buffer, on the other hand, is information inside of Emacs that will vanish at the end of the editing session (or when you kill the buffer).  Usually, a buffer contains information that you have copied from a file; then we say the buffer is visiting that file.  The copy in the buffer is what you modify with editing commands.  Such changes to the buffer do not change the file; therefore, to make the changes permanent, you must save the buffer, which means copying the altered buffer contents back into the file.

In spite of the distinction between files and buffers, people often refer to a file when they mean a buffer and vice-versa.  Indeed, we say, ``I am editing a file,'' rather than, ``I am editing a buffer that I will soon save as a file of the same name.''  Humans do not usually need to make the distinction explicit.  When dealing with a computer program, however, it is good to keep the distinction in mind.

Functions for Visiting Files
----------------------------

This section describes the functions normally used to visit files. For historical reasons, these functions have names starting with find- rather than visit-.  See Buffer File Name, for functions and variables that access the visited file name of a buffer or that find an existing buffer by its visited file name.

In a Lisp program, if you want to look at the contents of a file but not alter it, the fastest way is to use insert-file-contents in a temporary buffer.  Visiting the file is not necessary and takes longer. See Reading from Files.

 -- Command: find-file filename
     This command selects a buffer visiting the file FILENAME, using an existing buffer if there is one, and otherwise creating a new buffer and reading the file into it.  It also returns that buffer.

     The body of the find-file function is very simple and looks like this:

          (switch-to-buffer (find-file-noselect filename))

     (See switch-to-buffer in Displaying Buffers.)

     When find-file is called interactively, it prompts for FILENAME in the minibuffer.

 -- Function: find-file-noselect filename
     This function is the guts of all the file-visiting functions.  It finds or creates a buffer visiting the file FILENAME, and returns it. It uses an existing buffer if there is one, and otherwise creates a new buffer and reads the file into it.  You may make the buffer current or display it in a window if you wish, but this function does not do so.

     When find-file-noselect uses an existing buffer, it first verifies that the file has not changed since it was last visited or saved in that buffer.  If the file has changed, then this function asks the user whether to reread the changed file.  If the user says yes, any changes previously made in the buffer are lost.

     If find-file-noselect needs to create a buffer, and there is no file named FILENAME, it displays the message New file in the echo area, and leaves the buffer empty.

     The find-file-noselect function calls after-find-file after reading the file (see Subroutines of Visiting).  That function sets the buffer major mode, parses local variables, warns the user if there exists an auto-save file more recent than the file just visited, and finishes by running the functions in find-file-hooks.

     The find-file-noselect function returns the buffer that is visiting the file FILENAME.

          (find-file-noselect "/etc/fstab")
               => #<buffer fstab>

 -- Command: find-file-other-window filename
     This command selects a buffer visiting the file FILENAME, but does so in a window other than the selected window.  It may use another existing window or split a window; see Displaying Buffers.

     When this command is called interactively, it prompts for FILENAME.

 -- Command: find-file-read-only filename
     This command selects a buffer visiting the file FILENAME, like find-file, but it marks the buffer as read-only.  See Read Only Buffers, for related functions and variables.

     When this command is called interactively, it prompts for FILENAME.

 -- Command: view-file filename
     This command visits FILENAME in View mode, and displays it in a recursive edit, returning to the previous buffer when done.  View mode is a mode that allows you to skim rapidly through the file but does not let you modify it.  Entering View mode runs the normal hook view-mode-hook.  See Hooks.

     When view-file is called interactively, it prompts for FILENAME.

 -- Variable: find-file-hooks
     The value of this variable is a list of functions to be called after a file is visited.  The file's local-variables specification (if any) will have been processed before the hooks are run.  The buffer visiting the file is current when the hook functions are run.

     This variable works just like a normal hook, but we think that renaming it would not be advisable.

 -- Variable: find-file-not-found-hooks
     The value of this variable is a list of functions to be called when find-file or find-file-noselect is passed a nonexistent file name.  find-file-noselect calls these functions as soon as it detects a nonexistent file.  It calls them in the order of the list, until one of them returns non-nil.  buffer-file-name is already set up.

     This is not a normal hook because the values of the functions are used and they may not all be called.

Subroutines of Visiting
-----------------------

The find-file-noselect function uses the create-file-buffer and after-find-file functions as subroutines.  Sometimes it is useful to call them directly.

 -- Function: create-file-buffer filename
     This function creates a suitably named buffer for visiting FILENAME, and returns it.  It uses FILENAME (sans directory) as the name if that name is free; otherwise, it appends a string such as <2> to get an unused name.  See also Creating Buffers.

     Please note: create-file-buffer does not associate the new buffer with a file and does not select the buffer. It also does not use the default major mode.

          (create-file-buffer "foo")
               => #<buffer foo>

          (create-file-buffer "foo")
               => #<buffer foo<2>>

          (create-file-buffer "foo")
               => #<buffer foo<3>>

     This function is used by find-file-noselect. It uses generate-new-buffer (see Creating Buffers).

 -- Function: after-find-file &optional error warn
     This function sets the buffer major mode, and parses local variables (see Auto Major Mode).  It is called by find-file-noselect and by the default revert function (see Reverting).

     If reading the file got an error because the file does not exist, but its directory does exist, the caller should pass a non-nil value for ERROR.  In that case, after-find-file issues a warning: (New File).  For more serious errors, the caller should usually not call after-find-file.

     If WARN is non-nil, then this function issues a warning if an auto-save file exists and is more recent than the visited file.

     The last thing after-find-file does is call all the functions in find-file-hooks.

Saving Buffers
==============

When you edit a file in Emacs, you are actually working on a buffer that is visiting that file---that is, the contents of the file are copied into the buffer and the copy is what you edit.  Changes to the buffer do not change the file until you save the buffer, which means copying the contents of the buffer into the file.

 -- Command: save-buffer &optional backup-option
     This function saves the contents of the current buffer in its visited file if the buffer has been modified since it was last visited or saved. Otherwise it does nothing.

     save-buffer is responsible for making backup files.  Normally, BACKUP-OPTION is nil, and save-buffer makes a backup file only if this is the first save since visiting the file.  Other values for BACKUP-OPTION request the making of backup files in other circumstances:

       * With an argument of 4 or 64, reflecting 1 or 3 C-u's, the save-buffer function marks this version of the file to be backed up when the buffer is next saved.

       * With an argument of 16 or 64, reflecting 2 or 3 C-u's, the save-buffer function unconditionally backs up the previous version of the file before saving it.

 -- Command: save-some-buffers &optional save-silently-p exiting
     This command saves some modified file-visiting buffers.  Normally it asks the user about each buffer.  But if SAVE-SILENTLY-P is non-nil, it saves all the file-visiting buffers without querying the user.

     The optional EXITING argument, if non-nil, requests this function to offer also to save certain other buffers that are not visiting files.  These are buffers that have a non-nil local value of buffer-offer-save.  (A user who says yes to saving one of these is asked to specify a file name to use.)  The save-buffers-kill-emacs function passes a non-nil value for this argument.

 -- Variable: buffer-offer-save
     When this variable is non-nil in a buffer, Emacs offers to save the buffer on exit even if the buffer is not visiting a file.  The variable is automatically local in all buffers.  Normally, Mail mode (used for editing outgoing mail) sets this to t.

 -- Command: write-file filename
     This function writes the current buffer into file FILENAME, makes the buffer visit that file, and marks it not modified.  Then it renames the buffer based on FILENAME, appending a string like <2> if necessary to make a unique buffer name.  It does most of this work by calling set-visited-file-name and save-buffer.

Saving a buffer runs several hooks.  It also performs format conversion (see Format Conversion), and may save text properties in ``annotations'' (see Saving Properties).

 -- Variable: write-file-hooks
     The value of this variable is a list of functions to be called before writing out a buffer to its visited file.  If one of them returns non-nil, the file is considered already written and the rest of the functions are not called, nor is the usual code for writing the file executed.

     If a function in write-file-hooks returns non-nil, it is responsible for making a backup file (if that is appropriate). To do so, execute the following code:

          (or buffer-backed-up (backup-buffer))

     You might wish to save the file modes value returned by backup-buffer and use that to set the mode bits of the file that you write.  This is what save-buffer normally does.

     Even though this is not a normal hook, you can use add-hook and remove-hook to manipulate the list.  See Hooks.

 -- Variable: local-write-file-hooks
     This works just like write-file-hooks, but it is intended to be made local to particular buffers.  It's not a good idea to make write-file-hooks local to a buffer---use this variable instead.

     The variable is marked as a permanent local, so that changing the major mode does not alter a buffer-local value.  This is convenient for packages that read ``file'' contents in special ways, and set up hooks to save the data in a corresponding way.

 -- Variable: write-contents-hooks
     This works just like write-file-hooks, but it is intended for hooks that pertain to the contents of the file, as opposed to hooks that pertain to where the file came from.  Such hooks are usually set up by major modes, as buffer-local bindings for this variable.

     This variable automatically becomes buffer-local whenever it is set; switching to a new major mode always resets this variable.  When you use add-hooks to add an element to this hook, you should not specify a non-nil LOCAL argument, since this variable is used only locally.

 -- Variable: after-save-hook
     This normal hook runs after a buffer has been saved in its visited file.

 -- Variable: file-precious-flag
     If this variable is non-nil, then save-buffer protects against I/O errors while saving by writing the new file to a temporary name instead of the name it is supposed to have, and then renaming it to the intended name after it is clear there are no errors.  This procedure prevents problems such as a lack of disk space from resulting in an invalid file.

     As a side effect, backups are necessarily made by copying.  See Rename or Copy.  Yet, at the same time, saving a precious file always breaks all hard links between the file you save and other file names.

     Some modes set this variable non-nil locally in particular buffers.

 -- User Option: require-final-newline
     This variable determines whether files may be written out that do not end with a newline.  If the value of the variable is t, then save-buffer silently adds a newline at the end of the file whenever the buffer being saved does not already end in one. If the value of the variable is non-nil, but not t, then save-buffer asks the user whether to add a newline each time the case arises.

     If the value of the variable is nil, then save-buffer doesn't add newlines at all.  nil is the default value, but a few major modes set it to t in particular buffers.

 -- Command: set-visited-file-name filename &optional no-query
     This function changes the visited file name of the current buffer to FILENAME.  It also renames the buffer based on FILENAME, appending a string like <2> if necessary to make a unique buffer name.  It marks the buffer as modified,a since the contents do not (as far as Emacs knows) match the actual file's contents.

     If the specified file already exists, set-visited-file-name asks for confirmation unless NO-QUERY is non-nil.

Reading from Files
==================

You can copy a file from the disk and insert it into a buffer using the insert-file-contents function.  Don't use the user-level command insert-file in a Lisp program, as that sets the mark.

 -- Function: insert-file-contents filename &optional visit beg end replace
     This function inserts the contents of file FILENAME into the current buffer after point.  It returns a list of the absolute file name and the length of the data inserted.  An error is signaled if FILENAME is not the name of a file that can be read.

     The function insert-file-contents checks the file contents against the defined file formats, and converts the file contents if appropriate.  See Format Conversion.  It also calls the functions in the list after-insert-file-functions; see Saving Properties.

     If VISIT is non-nil, this function additionally marks the buffer as unmodified and sets up various fields in the buffer so that it is visiting the file FILENAME: these include the buffer's visited file name and its last save file modtime.  This feature is used by find-file-noselect and you probably should not use it yourself.

     If BEG and END are non-nil, they should be integers specifying the portion of the file to insert.  In this case, VISIT must be nil.  For example,

          (insert-file-contents filename nil 0 500)

     inserts the first 500 characters of a file.

     If the argument REPLACE is non-nil, it means to replace the contents of the buffer (actually, just the accessible portion) with the contents of the file.  This is better than simply deleting the buffer contents and inserting the whole file, because (1) it preserves some marker positions and (2) it puts less data in the undo list.

If you want to pass a file name to another process so that another program can read the file, use the function file-local-copy; see Magic File Names.

Writing to Files
================

You can write the contents of a buffer, or part of a buffer, directly to a file on disk using the append-to-file and write-region functions.  Don't use these functions to write to files that are being visited; that could cause confusion in the mechanisms for visiting.

 -- Command: append-to-file start end filename
     This function appends the contents of the region delimited by START and END in the current buffer to the end of file FILENAME.  If that file does not exist, it is created.  This function returns nil.

     An error is signaled if FILENAME specifies a nonwritable file, or a nonexistent file in a directory where files cannot be created.

 -- Command: write-region start end filename &optional append visit
     This function writes the region delimited by START and END in the current buffer into the file specified by FILENAME.

     If START is a string, then write-region writes or appends that string, rather than text from the buffer.

     If APPEND is non-nil, then the specified text is appended to the existing file contents (if any).

     If VISIT is t, then Emacs establishes an association between the buffer and the file: the buffer is then visiting that file. It also sets the last file modification time for the current buffer to FILENAME's modtime, and marks the buffer as not modified.  This feature is used by save-buffer, but you probably should not use it yourself.

     If VISIT is a string, it specifies the file name to visit.  This way, you can write the data to one file (FILENAME) while recording the buffer as visiting another file (VISIT).  The argument VISIT is used in the echo area message and also for file locking; VISIT is stored in buffer-file-name.  This feature is used to implement file-precious-flag; don't use it yourself unless you really know what you're doing.

     The function write-region converts the data which it writes to the appropriate file formats specified by buffer-file-format. See Format Conversion.  It also calls the functions in the list write-region-annotate-functions; see Saving Properties.

     Normally, write-region displays a message Wrote file FILENAME in the echo area.  If VISIT is neither t nor nil nor a string, then this message is inhibited.  This feature is useful for programs that use files for internal purposes, files that the user does not need to know about.

File Locks
==========

When two users edit the same file at the same time, they are likely to interfere with each other.  Emacs tries to prevent this situation from arising by recording a file lock when a file is being modified. Emacs can then detect the first attempt to modify a buffer visiting a file that is locked by another Emacs job, and ask the user what to do.

File locks do not work properly when multiple machines can share file systems, such as with NFS.  Perhaps a better file locking system will be implemented in the future.  When file locks do not work, it is possible for two users to make changes simultaneously, but Emacs can still warn the user who saves second.  Also, the detection of modification of a buffer visiting a file changed on disk catches some cases of simultaneous editing; see Modification Time.

 -- Function: file-locked-p filename
     This function returns nil if the file FILENAME is not locked by this Emacs process.  It returns t if it is locked by this Emacs, and it returns the name of the user who has locked it if it is locked by someone else.

          (file-locked-p "foo")
               => nil

 -- Function: lock-buffer &optional filename
     This function locks the file FILENAME, if the current buffer is modified.  The argument FILENAME defaults to the current buffer's visited file.  Nothing is done if the current buffer is not visiting a file, or is not modified.

 -- Function: unlock-buffer
     This function unlocks the file being visited in the current buffer, if the buffer is modified.  If the buffer is not modified, then the file should not be locked, so this function does nothing.  It also does nothing if the current buffer is not visiting a file.

 -- Function: ask-user-about-lock file other-user
     This function is called when the user tries to modify FILE, but it is locked by another user named OTHER-USER.  The value it returns determines what happens next:

       * A value of t says to grab the lock on the file.  Then this user may edit the file and OTHER-USER loses the lock.

       * A value of nil says to ignore the lock and let this user edit the file anyway.

       * This function may instead signal a file-locked error, in which case the change that the user was about to make does not take place.

          The error message for this error looks like this:

               error--> File is locked: FILE OTHER-USER

          where file is the name of the file and OTHER-USER is the name of the user who has locked the file.

     The default definition of this function asks the user to choose what to do.  If you wish, you can replace the ask-user-about-lock function with your own version that decides in another way.  The code for its usual definition is in userlock.el.

Information about Files
=======================

The functions described in this section all operate on strings that designate file names.  All the functions have names that begin with the word file.  These functions all return information about actual files or directories, so their arguments must all exist as actual files or directories unless otherwise noted.

Testing Accessibility
---------------------

These functions test for permission to access a file in specific ways.

 -- Function: file-exists-p filename
     This function returns t if a file named FILENAME appears to exist.  This does not mean you can necessarily read the file, only that you can find out its attributes.  (On Unix, this is true if the file exists and you have execute permission on the containing directories, regardless of the protection of the file itself.)

     If the file does not exist, or if fascist access control policies prevent you from finding the attributes of the file, this function returns nil.

 -- Function: file-readable-p filename
     This function returns t if a file named FILENAME exists and you can read it.  It returns nil otherwise.

          (file-readable-p "files.texi")
               => t

          (file-exists-p "/usr/spool/mqueue")
               => t

          (file-readable-p "/usr/spool/mqueue")
               => nil

 -- Function: file-executable-p filename
     This function returns t if a file named FILENAME exists and you can execute it.  It returns nil otherwise.  If the file is a directory, execute permission means you can check the existence and attributes of files inside the directory, and open those files if their modes permit.

 -- Function: file-writable-p filename
     This function returns t if the file FILENAME can be written or created by you, and nil otherwise.  A file is writable if the file exists and you can write it.  It is creatable if it does not exist, but the specified directory does exist and you can write in that directory.

     In the third example below, foo is not writable because the parent directory does not exist, even though the user could create such a directory.

          (file-writable-p "~/foo")
               => t

          (file-writable-p "/foo")
               => nil

          (file-writable-p "~/no-such-dir/foo")
               => nil

 -- Function: file-accessible-directory-p dirname
     This function returns t if you have permission to open existing files in the directory whose name as a file is DIRNAME; otherwise (or if there is no such directory), it returns nil.  The value of DIRNAME may be either a directory name or the file name of a directory.

     Example: after the following,

          (file-accessible-directory-p "/foo")
               => nil

     we can deduce that any attempt to read a file in /foo/ will give an error.

 -- Function: file-ownership-preserved-p filename
     This function returns t if deleting the file FILENAME and then creating it anew would keep the file's owner unchanged.

 -- Function: file-newer-than-file-p filename1 filename2
     This function returns t if the file FILENAME1 is newer than file FILENAME2.  If FILENAME1 does not exist, it returns nil.  If FILENAME2 does not exist, it returns t.

     In the following example, assume that the file aug-19 was written on the 19th, aug-20 was written on the 20th, and the file no-file doesn't exist at all.

          (file-newer-than-file-p "aug-19" "aug-20")
               => nil

          (file-newer-than-file-p "aug-20" "aug-19")
               => t

          (file-newer-than-file-p "aug-19" "no-file")
               => t

          (file-newer-than-file-p "no-file" "aug-19")
               => nil

     You can use file-attributes to get a file's last modification time as a list of two numbers.  See File Attributes.

Distinguishing Kinds of Files
-----------------------------

This section describes how to distinguish various kinds of files, such as directories, symbolic links, and ordinary files.

 -- Function: file-symlink-p filename
     If the file FILENAME is a symbolic link, the file-symlink-p function returns the file name to which it is linked.  This may be the name of a text file, a directory, or even another symbolic link, or it may be a nonexistent file name.

     If the file FILENAME is not a symbolic link (or there is no such file), file-symlink-p returns nil.

          (file-symlink-p "foo")
               => nil

          (file-symlink-p "sym-link")
               => "foo"

          (file-symlink-p "sym-link2")
               => "sym-link"

          (file-symlink-p "/bin")
               => "/pub/bin"

 -- Function: file-directory-p filename
     This function returns t if FILENAME is the name of an existing directory, nil otherwise.

          (file-directory-p "~rms")
               => t

          (file-directory-p "~rms/lewis/files.texi")
               => nil

          (file-directory-p "~rms/lewis/no-such-file")
               => nil

          (file-directory-p "$HOME")
               => nil

          (file-directory-p
           (substitute-in-file-name "$HOME"))
               => t

 -- Function: file-regular-p filename
     This function returns t if the file FILENAME exists and is a regular file (not a directory, symbolic link, named pipe, terminal, or other I/O device).

Truenames
---------

The truename of a file is the name that you get by following symbolic links until none remain, then expanding to get rid of . and .. as components.  Strictly speaking, a file need not have a unique truename; the number of distinct truenames a file has is equal to the number of hard links to the file.  However, truenames are useful because they eliminate symbolic links as a cause of name variation.

 -- Function: file-truename filename
     The function file-truename returns the true name of the file FILENAME.  This is the name that you get by following symbolic links until none remain.  The argument must be an absolute file name.

See Buffer File Name, for related information.

Other Information about Files
-----------------------------

This section describes the functions for getting detailed information about a file, other than its contents.  This information includes the mode bits that control access permission, the owner and group numbers, the number of names, the inode number, the size, and the times of access and modification.

 -- Function: file-modes filename
     This function returns the mode bits of FILENAME, as an integer. The mode bits are also called the file permissions, and they specify access control in the usual Unix fashion.  If the low-order bit is 1, then the file is executable by all users, if the second-lowest-order bit is 1, then the file is writable by all users, etc.

     The highest value returnable is 4095 (7777 octal), meaning that everyone has read, write, and execute permission, that the SUID bit is set for both others and group, and that the sticky bit is set.

          (file-modes "~/junk/diffs")
               => 492               ; Decimal integer.

          (format "%o" 492)
               => "754"             ; Convert to octal.

          (set-file-modes "~/junk/diffs" 438)
               => nil

          (format "%o" 438)
               => "666"             ; Convert to octal.

          % ls -l diffs
            -rw-rw-rw-  1 lewis 0 3063 Oct 30 16:00 diffs

 -- Function: file-nlinks filename
     This functions returns the number of names (i.e., hard links) that file FILENAME has.  If the file does not exist, then this function returns nil.  Note that symbolic links have no effect on this function, because they are not considered to be names of the files they link to.

          % ls -l foo*
          -rw-rw-rw-  2 rms       4 Aug 19 01:27 foo
          -rw-rw-rw-  2 rms       4 Aug 19 01:27 foo1

          (file-nlinks "foo")
               => 2

          (file-nlinks "doesnt-exist")
               => nil

 -- Function: file-attributes filename
     This function returns a list of attributes of file FILENAME.  If the specified file cannot be opened, it returns nil.

     The elements of the list, in order, are:

      0. t for a directory, a string for a symbolic link (the name linked to), or nil for a text file.

      1. The number of names the file has.  Alternate names, also known as hard links, can be created by using the add-name-to-file function (see Changing File Attributes).

      2. The file's UID.

      3. The file's GID.

      4. The time of last access, as a list of two integers. The first integer has the high-order 16 bits of time, the second has the low 16 bits.  (This is similar to the value of current-time; see Time of Day.)

      5. The time of last modification as a list of two integers (as above).

      6. The time of last status change as a list of two integers (as above).

      7. The size of the file in bytes.

      8. The file's modes, as a string of ten letters or dashes, as in ls -l.

      9. t if the file's GID would change if file were deleted and recreated; nil otherwise.

      10. The file's inode number.

      11. The file system number of the file system that the file is in.  This element and the file's inode number together give enough information to distinguish any two files on the system---no two files can have the same values for both of these numbers.

     For example, here are the file attributes for files.texi:

          (file-attributes "files.texi")
               =>  (nil
                    1
                    2235
                    75
                    (8489 20284)
                    (8489 20284)
                    (8489 20285)
                    14906
                    "-rw-rw-rw-"
                    nil
                    129500
                    -32252)

     and here is how the result is interpreted:

     nil
          is neither a directory nor a symbolic link.

     1
          has only one name (the name files.texi in the current default directory).

     2235
          is owned by the user with UID 2235.

     75
          is in the group with GID 75.

     (8489 20284)
          was last accessed on Aug 19 00:09.

     (8489 20284)
          was last modified on Aug 19 00:09.

     (8489 20285)
          last had its inode changed on Aug 19 00:09.

     14906
          is 14906 characters long.

     "-rw-rw-rw-"
          has a mode of read and write access for the owner, group, and world.

     nil
          would retain the same GID if it were recreated.

     129500
          has an inode number of 129500.

     -32252
          is on file system number -32252.

Changing File Names and Attributes
==================================

The functions in this section rename, copy, delete, link, and set the modes of files.

In the functions that have an argument NEWNAME, if a file by the name of NEWNAME already exists, the actions taken depend on the value of the argument OK-IF-ALREADY-EXISTS:

  * Signal a file-already-exists error if OK-IF-ALREADY-EXISTS is nil.

  * Request confirmation if OK-IF-ALREADY-EXISTS is a number.

  * Replace the old file without confirmation if OK-IF-ALREADY-EXISTS is any other value.

 -- Function: add-name-to-file oldname newname &optional ok-if-already-exists
     This function gives the file named OLDNAME the additional name NEWNAME.  This means that NEWNAME becomes a new ``hard link'' to OLDNAME.

     In the first part of the following example, we list two files, foo and foo3.

          % ls -l fo*
          -rw-rw-rw-  1 rms       29 Aug 18 20:32 foo
          -rw-rw-rw-  1 rms       24 Aug 18 20:31 foo3

     Now we create a hard link, by calling add-name-to-file, then list the files again.  This shows two names for one file, foo and foo2.

          (add-name-to-file "~/lewis/foo1" "~/lewis/foo2")
               => nil

          % ls -l fo*
          -rw-rw-rw-  2 rms       29 Aug 18 20:32 foo
          -rw-rw-rw-  2 rms       29 Aug 18 20:32 foo2
          -rw-rw-rw-  1 rms       24 Aug 18 20:31 foo3

     Finally, we evaluate the following:

          (add-name-to-file "~/lewis/foo" "~/lewis/foo3" t)

     and list the files again.  Now there are three names for one file: foo, foo2, and foo3.  The old contents of foo3 are lost.

          (add-name-to-file "~/lewis/foo1" "~/lewis/foo3")
               => nil

          % ls -l fo*
          -rw-rw-rw-  3 rms       29 Aug 18 20:32 foo
          -rw-rw-rw-  3 rms       29 Aug 18 20:32 foo2
          -rw-rw-rw-  3 rms       29 Aug 18 20:32 foo3

     This function is meaningless on VMS, where multiple names for one file are not allowed.

     See also file-nlinks in File Attributes.

 -- Command: rename-file filename newname &optional ok-if-already-exists
     This command renames the file FILENAME as NEWNAME.

     If FILENAME has additional names aside from FILENAME, it continues to have those names.  In fact, adding the name NEWNAME with add-name-to-file and then deleting FILENAME has the same effect as renaming, aside from momentary intermediate states.

     In an interactive call, this function prompts for FILENAME and NEWNAME in the minibuffer; also, it requests confirmation if NEWNAME already exists.

 -- Command: copy-file oldname newname &optional ok-if-exists time
     This command copies the file OLDNAME to NEWNAME.  An error is signaled if OLDNAME does not exist.

     If TIME is non-nil, then this functions gives the new file the same last-modified time that the old one has.  (This works on only some operating systems.)

     In an interactive call, this function prompts for FILENAME and NEWNAME in the minibuffer; also, it requests confirmation if NEWNAME already exists.

 -- Command: delete-file filename
     This command deletes the file FILENAME, like the shell command rm FILENAME.  If the file has multiple names, it continues to exist under the other names.

     A suitable kind of file-error error is signaled if the file does not exist, or is not deletable.  (On Unix, a file is deletable if its directory is writable.)

     See also delete-directory in Create/Delete Dirs.

 -- Command: make-symbolic-link filename newname &optional ok-if-exists
     This command makes a symbolic link to FILENAME, named NEWNAME.  This is like the shell command ln -s FILENAME NEWNAME.

     In an interactive call, this function prompts for FILENAME and NEWNAME in the minibuffer; also, it requests confirmation if NEWNAME already exists.

 -- Function: define-logical-name varname string
     This function defines the logical name NAME to have the value STRING.  It is available only on VMS.

 -- Function: set-file-modes filename mode
     This function sets mode bits of FILENAME to MODE (which must be an integer).  Only the low 12 bits of MODE are used.

 -- Function: set-default-file-modes mode
     This function sets the default file protection for new files created by Emacs and its subprocesses.  Every file created with Emacs initially has this protection.  On Unix, the default protection is the bitwise complement of the ``umask'' value.

     The argument MODE must be an integer.  Only the low 9 bits of MODE are used.

     Saving a modified version of an existing file does not count as creating the file; it does not change the file's mode, and does not use the default file protection.

 -- Function: default-file-modes
     This function returns the current default protection value.

On MS-DOS, there is no such thing as an ``executable'' file mode bit. So Emacs considers a file executable if its name ends in .com, .bat or .exe.  This is reflected in the values returned by file-modes and file-attributes.

File Names
==========

Files are generally referred to by their names, in Emacs as elsewhere. File names in Emacs are represented as strings.  The functions that operate on a file all expect a file name argument.

In addition to operating on files themselves, Emacs Lisp programs often need to operate on the names; i.e., to take them apart and to use part of a name to construct related file names.  This section describes how to manipulate file names.

The functions in this section do not actually access files, so they can operate on file names that do not refer to an existing file or directory.

On VMS, all these functions understand both VMS file-name syntax and Unix syntax.  This is so that all the standard Lisp libraries can specify file names in Unix syntax and work properly on VMS without change.  On MS-DOS, these functions understand MS-DOS file-name syntax as well as Unix syntax.

File Name Components
--------------------

The operating system groups files into directories.  To specify a file, you must specify the directory and the file's name within that directory.  Therefore, Emacs considers a file name as having two main parts: the directory name part, and the nondirectory part (or file name within the directory).  Either part may be empty. Concatenating these two parts reproduces the original file name.

On Unix, the directory part is everything up to and including the last slash; the nondirectory part is the rest.  The rules in VMS syntax are complicated.

For some purposes, the nondirectory part is further subdivided into the name proper and the version number.  On Unix, only backup files have version numbers in their names; on VMS, every file has a version number, but most of the time the file name actually used in Emacs omits the version number.  Version numbers are found mostly in directory lists.

 -- Function: file-name-directory filename
     This function returns the directory part of FILENAME (or nil if FILENAME does not include a directory part).  On Unix, the function returns a string ending in a slash.  On VMS, it returns a string ending in one of the three characters :, ], or >.

          (file-name-directory "lewis/foo")  ; Unix example
               => "lewis/"

          (file-name-directory "foo")        ; Unix example
               => nil

          (file-name-directory "[X]FOO.TMP") ; VMS example
               => "[X]"

 -- Function: file-name-nondirectory filename
     This function returns the nondirectory part of FILENAME.

          (file-name-nondirectory "lewis/foo")
               => "foo"

          (file-name-nondirectory "foo")
               => "foo"

          ;; The following example is accurate only on VMS.
          (file-name-nondirectory "[X]FOO.TMP")
               => "FOO.TMP"

 -- Function: file-name-sans-versions filename
     This function returns FILENAME without any file version numbers, backup version numbers, or trailing tildes.

          (file-name-sans-versions "~rms/foo.~1~")
               => "~rms/foo"

          (file-name-sans-versions "~rms/foo~")
               => "~rms/foo"

          (file-name-sans-versions "~rms/foo")
               => "~rms/foo"

          ;; The following example applies to VMS only.
          (file-name-sans-versions "foo;23")
               => "foo"

 -- Function: file-name-sans-extension filename
     This function returns FILENAME minus its ``extension,'' if any. The extension, in a file name, is the part that starts with the last . in the last name component.  For example,

          (file-name-sans-extension "foo.lose.c")
               => "foo.lose"
          (file-name-sans-extension "big.hack/foo")
               => "big.hack/foo"

Directory Names
---------------

A directory name is the name of a directory.  A directory is a kind of file, and it has a file name, which is related to the directory name but not identical to it.  (This is not quite the same as the usual Unix terminology.)  These two different names for the same entity are related by a syntactic transformation.  On Unix, this is simple: a directory name ends in a slash, whereas the directory's name as a file lacks that slash.  On VMS, the relationship is more complicated.

The difference between a directory name and its name as a file is subtle but crucial.  When an Emacs variable or function argument is described as being a directory name, a file name of a directory is not acceptable.

The following two functions convert between directory names and file names.  They do nothing special with environment variable substitutions such as $HOME, and the constructs ~, and ...

 -- Function: file-name-as-directory filename
     This function returns a string representing FILENAME in a form that the operating system will interpret as the name of a directory.  In Unix, this means appending a slash to the string.  On VMS, the function converts a string of the form [X]Y.DIR.1 to the form [X.Y].

          (file-name-as-directory "~rms/lewis")
               => "~rms/lewis/"

 -- Function: directory-file-name dirname
     This function returns a string representing DIRNAME in a form that the operating system will interpret as the name of a file.  On Unix, this means removing a final slash from the string.  On VMS, the function converts a string of the form [X.Y] to [X]Y.DIR.1.

          (directory-file-name "~lewis/")
               => "~lewis"

Directory name abbreviations are useful for directories that are normally accessed through symbolic links.  Sometimes the users recognize primarily the link's name as ``the name'' of the directory, and find it annoying to see the directory's ``real'' name.  If you define the link name as an abbreviation for the ``real'' name, Emacs shows users the abbreviation instead.

 -- Variable: directory-abbrev-alist
     The variable directory-abbrev-alist contains an alist of abbreviations to use for file directories.  Each element has the form (FROM . TO), and says to replace FROM with TO when it appears in a directory name.  The FROM string is actually a regular expression; it should always start with ^. The function abbreviate-file-name performs these substitutions.

     You can set this variable in site-init.el to describe the abbreviations appropriate for your site.

     Here's an example, from a system on which file system /home/fsf and so on are normally accessed through symbolic links named /fsf and so on.

          (("^/home/fsf" . "/fsf")
           ("^/home/gp" . "/gp")
           ("^/home/gd" . "/gd"))

To convert a directory name to its abbreviation, use this function:

 -- Function: abbreviate-file-name dirname
     This function applies abbreviations from directory-abbrev-alist to its argument, and substitutes ~ for the user's home directory.

Absolute and Relative File Names
--------------------------------

All the directories in the file system form a tree starting at the root directory.  A file name can specify all the directory names starting from the root of the tree; then it is called an absolute file name.  Or it can specify the position of the file in the tree relative to a default directory; then it is called a relative file name.  On Unix, an absolute file name starts with a slash or a tilde (~), and a relative one does not.  The rules on VMS are complicated.

 -- Function: file-name-absolute-p filename
     This function returns t if file FILENAME is an absolute file name, nil otherwise.  On VMS, this function understands both Unix syntax and VMS syntax.

          (file-name-absolute-p "~rms/foo")
               => t

          (file-name-absolute-p "rms/foo")
               => nil

          (file-name-absolute-p "/user/rms/foo")
               => t

Functions that Expand Filenames
-------------------------------

Expansion of a file name means converting a relative file name to an absolute one.  Since this is done relative to a default directory, you must specify the default directory name as well as the file name to be expanded.  Expansion also simplifies file names by eliminating redundancies such as ./ and NAME/../.

 -- Function: expand-file-name filename &optional directory
     This function converts FILENAME to an absolute file name.  If DIRECTORY is supplied, it is the directory to start with if FILENAME is relative.  (The value of DIRECTORY should itself be an absolute directory name; it may start with ~.) Otherwise, the current buffer's value of default-directory is used.  For example:

          (expand-file-name "foo")
               => "/xcssun/users/rms/lewis/foo"

          (expand-file-name "../foo")
               => "/xcssun/users/rms/foo"

          (expand-file-name "foo" "/usr/spool/")
               => "/usr/spool/foo"

          (expand-file-name "$HOME/foo")
               => "/xcssun/users/rms/lewis/$HOME/foo"

     Filenames containing . or .. are simplified to their canonical form:

          (expand-file-name "bar/../foo")
               => "/xcssun/users/rms/lewis/foo"

     ~/ is expanded into the user's home directory.  A / or ~ following a / is taken to be the start of an absolute file name that overrides what precedes it, so everything before that / or ~ is deleted.  For example:

          (expand-file-name
           "/a1/gnu//usr/local/lib/emacs/etc/MACHINES")
               => "/usr/local/lib/emacs/etc/MACHINES"

          (expand-file-name "/a1/gnu/~/foo")
               => "/xcssun/users/rms/foo"

     In both cases, /a1/gnu/ is discarded because an absolute file name follows it.

     Note that expand-file-name does not expand environment variables; only substitute-in-file-name does that.

 -- Function: file-relative-name filename directory
     This function does the inverse of expansion---it tries to return a relative name that is equivalent to FILENAME when interpreted relative to DIRECTORY.  (If such a relative name would be longer than the absolute name, it returns the absolute name instead.)

          (file-relative-name "/foo/bar" "/foo/")
               => "bar")
          (file-relative-name "/foo/bar" "/hack/")
               => "/foo/bar")

 -- Variable: default-directory
     The value of this buffer-local variable is the default directory for the current buffer.  It should be an absolute directory name; it may start with ~.  This variable is local in every buffer.

     expand-file-name uses the default directory when its second argument is nil.

     On Unix systems, the value is always a string ending with a slash.

          default-directory
               => "/user/lewis/manual/"

 -- Function: substitute-in-file-name filename
     This function replaces environment variables references in FILENAME with the environment variable values.  Following standard Unix shell syntax, $ is the prefix to substitute an environment variable value.

     The environment variable name is the series of alphanumeric characters (including underscores) that follow the $.  If the character following the $ is a {, then the variable name is everything up to the matching }.

     Here we assume that the environment variable HOME, which holds the user's home directory name, has value /xcssun/users/rms.

          (substitute-in-file-name "$HOME/foo")
               => "/xcssun/users/rms/foo"

     If a ~ or a / appears following a /, after substitution, everything before the following / is discarded:

          (substitute-in-file-name "bar/~/foo")
               => "~/foo"

          (substitute-in-file-name "/usr/local/$HOME/foo")
               => "/xcssun/users/rms/foo"

     On VMS, $ substitution is not done, so this function does nothing on VMS except discard superfluous initial components as shown above.

Generating Unique File Names
----------------------------

Some programs need to write temporary files.  Here is the usual way to construct a name for such a file:

     (make-temp-name (concat "/tmp/" NAME-OF-APPLICATION))

Here we use the directory /tmp/ because that is the standard place on Unix for temporary files.  The job of make-temp-name is to prevent two different users or two different jobs from trying to use the same name.

 -- Function: make-temp-name string
     This function generates string that can be used as a unique name.  The name starts with STRING, and ends with a number that is different in each Emacs job.

          (make-temp-name "/tmp/foo")
               => "/tmp/foo021304"

     To prevent conflicts among different libraries running in the same Emacs, each Lisp program that uses make-temp-name should have its own STRING.  The number added to the end of the name distinguishes between the same application running in different Emacs jobs.

File Name Completion
--------------------

This section describes low-level subroutines for completing a file name.  For other completion functions, see Completion.

 -- Function: file-name-all-completions partial-filename directory
     This function returns a list of all possible completions for a file whose name starts with PARTIAL-FILENAME in directory DIRECTORY.  The order of the completions is the order of the files in the directory, which is unpredictable and conveys no useful information.

     The argument PARTIAL-FILENAME must be a file name containing no directory part and no slash.  The current buffer's default directory is prepended to DIRECTORY, if DIRECTORY is not absolute.

     In the following example, suppose that ~rms/lewis is the current default directory, and has five files whose names begin with f: foo, file~, file.c, file.c.~1~, and file.c.~2~.

          (file-name-all-completions "f" "")
               => ("foo" "file~" "file.c.~2~"
                          "file.c.~1~" "file.c")

          (file-name-all-completions "fo" "")
               => ("foo")

 -- Function: file-name-completion filename directory
     This function completes the file name FILENAME in directory DIRECTORY.  It returns the longest prefix common to all file names in directory DIRECTORY that start with FILENAME.

     If only one match exists and FILENAME matches it exactly, the function returns t.  The function returns nil if directory DIRECTORY contains no name starting with FILENAME.

     In the following example, suppose that the current default directory has five files whose names begin with f: foo, file~, file.c, file.c.~1~, and file.c.~2~.

          (file-name-completion "fi" "")
               => "file"

          (file-name-completion "file.c.~1" "")
               => "file.c.~1~"

          (file-name-completion "file.c.~1~" "")
               => t

          (file-name-completion "file.c.~3" "")
               => nil

 -- User Option: completion-ignored-extensions
     file-name-completion usually ignores file names that end in any string in this list.  It does not ignore them when all the possible completions end in one of these suffixes or when a buffer showing all possible completions is displayed.

     A typical value might look like this:

          completion-ignored-extensions
               => (".o" ".elc" "~" ".dvi")

Standard File Names
-------------------

Most of the file names used in Lisp programs are entered by the user. But occasionally a Lisp program needs to specify a standard file name for a particular use---typically, to hold customization information about each user.  For example, abbrev definitions are stored (by default) in the file ~/.abbrev_defs; the completion package stores completions in the file ~/.completions.  These are two of the many standard file names used by parts of Emacs for certain purposes.

Various operating systems have their own conventions for valid file names and for which file names to use for user profile data.  A Lisp program which reads a file using a standard file name ought to use, on each type of system, a file name suitable for that system.  The function convert-standard-filename makes this easy to do.

 -- Function: convert-standard-filename filename
     This function alters the file name FILENAME to fit the conventions of the operating system in use, and returns the result as a new string.

The recommended way to specify a standard file name in a Lisp program is to choose a name which fits the conventions of GNU and Unix systems, usually with a nondirectory part that starts with a period, and pass it to convert-standard-filename instead of using it directly.  Here is an example from the completion package:

     (defvar save-completions-file-name
             (convert-standard-filename "~/.completions")
       "*The file name to save completions to.")

On GNU and Unix systems, and on some other systems as well, convert-standard-filename returns its argument unchanged.  On some other systems, it alters the name to fit the systems's conventions.

For example, on MS-DOS the alterations made by this function include converting a leading .  to _, converting a _ in the middle of the name to . if there is no other ., inserting a . after eight characters if there is none, and truncating to three characters after the ..  (It makes other changes as well.) Thus, .abbrev_defs becomes _abbrev.def, and .completions becomes _complet.ion.

Contents of Directories
=======================

A directory is a kind of file that contains other files entered under various names.  Directories are a feature of the file system.

Emacs can list the names of the files in a directory as a Lisp list, or display the names in a buffer using the ls shell command.  In the latter case, it can optionally display information about each file, depending on the options passed to the ls command.

 -- Function: directory-files directory &optional full-name match-regexp nosort
     This function returns a list of the names of the files in the directory DIRECTORY.  By default, the list is in alphabetical order.

     If FULL-NAME is non-nil, the function returns the files' absolute file names.  Otherwise, it returns the names relative to the specified directory.

     If MATCH-REGEXP is non-nil, this function returns only those file names that contain a match for that regular expression---the other file names are excluded from the list.

     If NOSORT is non-nil, directory-files does not sort the list, so you get the file names in no particular order.  Use this if you want the utmost possible speed and don't care what order the files are processed in.  If the order of processing is visible to the user, then the user will probably be happier if you do sort the names.

          (directory-files "~lewis")
               => ("#foo#" "#foo.el#" "." ".."
                   "dired-mods.el" "files.texi"
                   "files.texi.~1~")

     An error is signaled if DIRECTORY is not the name of a directory that can be read.

 -- Function: file-name-all-versions file dirname
     This function returns a list of all versions of the file named FILE in directory DIRNAME.

 -- Function: insert-directory file switches &optional wildcard full-directory-p
     This function inserts (in the current buffer) a directory listing for directory FILE, formatted with ls according to SWITCHES.  It leaves point after the inserted text.

     The argument FILE may be either a directory name or a file specification including wildcard characters.  If WILDCARD is non-nil, that means treat FILE as a file specification with wildcards.

     If FULL-DIRECTORY-P is non-nil, that means FILE is a directory and switches do not contain -d, so that the listing should show the full contents of the directory.  (The -d option to ls says to describe a directory itself rather than its contents.)

     This function works by running a directory listing program whose name is in the variable insert-directory-program.  If WILDCARD is non-nil, it also runs the shell specified by shell-file-name, to expand the wildcards.

 -- Variable: insert-directory-program
     This variable's value is the program to run to generate a directory listing for the function insert-directory.

Creating and Deleting Directories
=================================

Most Emacs Lisp file-manipulation functions get errors when used on files that are directories.  For example, you cannot delete a directory with delete-file.  These special functions exist to create and delete directories.

 -- Function: make-directory dirname
     This function creates a directory named DIRNAME.

 -- Function: delete-directory dirname
     This function deletes the directory named DIRNAME.  The function delete-file does not work for files that are directories; you must use delete-directory for them.  If the directory contains any files, delete-directory signals an error.

Making Certain File Names ``Magic''
===================================

You can implement special handling for certain file names.  This is called making those names magic.  You must supply a regular expression to define the class of names (all those that match the regular expression), plus a handler that implements all the primitive Emacs file operations for file names that do match.

The variable file-name-handler-alist holds a list of handlers, together with regular expressions that determine when to apply each handler.  Each element has this form:

     (REGEXP . HANDLER)

All the Emacs primitives for file access and file name transformation check the given file name against file-name-handler-alist.  If the file name matches REGEXP, the primitives handle that file by calling HANDLER.

The first argument given to HANDLER is the name of the primitive; the remaining arguments are the arguments that were passed to that operation.  (The first of these arguments is typically the file name itself.)  For example, if you do this:

     (file-exists-p FILENAME)

and FILENAME has handler HANDLER, then HANDLER is called like this:

     (funcall HANDLER 'file-exists-p FILENAME)

Here are the operations that a magic file name handler gets to handle:

add-name-to-file, copy-file, delete-directory, delete-file,

diff-latest-backup-file, directory-file-name, directory-files,

dired-call-process, dired-compress-file, dired-uncache, expand-file-name,

file-accessible-directory-p, file-attributes, file-directory-p,

file-executable-p, file-exists-p, file-local-copy, file-modes, file-name-all-completions, file-name-as-directory, file-name-completion,

file-name-directory, file-name-nondirectory, file-name-sans-versions, file-newer-than-file-p, file-ownership-preserved-p, file-readable-p, file-regular-p, file-symlink-p, file-truename, file-writable-p, find-backup-file-name, get-file-buffer, insert-directory,

insert-file-contents, load, make-directory, make-symbolic-link, rename-file, set-file-modes, set-visited-file-modtime, shell-command. unhandled-file-name-directory,

vc-registered, verify-visited-file-modtime, write-region.

Handlers for insert-file-contents typically need to clear the buffer's modified flag, with (set-buffer-modified-p nil), if the VISIT argument is non-nil.  This also has the effect of unlocking the buffer if it is locked.

The handler function must handle all of the above operations, and possibly others to be added in the future.  It need not implement all these operations itself---when it has nothing special to do for a certain operation, it can reinvoke the primitive, to handle the operation ``in the usual way''.  It should always reinvoke the primitive for an operation it does not recognize.  Here's one way to do this:

     (defun my-file-handler (operation &rest args)
       ;; First check for the specific operations
       ;; that we have special handling for.
       (cond ((eq operation 'insert-file-contents) ...)
             ((eq operation 'write-region) ...)
             ...
             ;; Handle any operation we don't know about.
             (t (let ((inhibit-file-name-handlers
                      (cons 'my-file-handler
                            (and (eq inhibit-file-name-operation operation)
                                 inhibit-file-name-handlers)))
                     (inhibit-file-name-operation operation))
                  (apply operation args)))))

When a handler function decides to call the ordinary Emacs primitive for the operation at hand, it needs to prevent the primitive from calling the same handler once again, thus leading to an infinite recursion.  The example above shows how to do this, with the variables inhibit-file-name-handlers and inhibit-file-name-operation.  Be careful to use them exactly as shown above; the details are crucial for proper behavior in the case of multiple handlers, and for operations that have two file names that may each have handlers.

 -- Variable: inhibit-file-name-handlers
     This variable holds a list of handlers whose use is presently inhibited for a certain operation.

 -- Variable: inhibit-file-name-operation
     The operation for which certain handlers are presently inhibited.

 -- Function: find-file-name-handler file operation
     This function returns the handler function for file name FILE, or nil if there is none.  The argument OPERATION should be the operation to be performed on the file---the value you will pass to the handler as its first argument when you call it.  The operation is needed for comparison with inhibit-file-name-operation.

 -- Function: file-local-copy filename
     This function copies file FILENAME to an ordinary non-magic file, if it isn't one already.

     If FILENAME specifies a ``magic'' file name, which programs outside Emacs cannot directly read or write, this copies the contents to an ordinary file and returns that file's name.

     If FILENAME is an ordinary file name, not magic, then this function does nothing and returns nil.

 -- Function: unhandled-file-name-directory filename
     This function returns the name of a directory that is not magic. It uses the directory part of FILENAME if that is not magic. Otherwise, it asks the handler what to do.

     This is useful for running a subprocess; every subprocess must have a non-magic directory to serve as its current directory, and this function is a good way to come up with one.

File Format Conversion
======================

The variable format-alist defines a list of file formats, which describe textual representations used in files for the data (text, text-properties, and possibly other information) in an Emacs buffer. Emacs performs format conversion if appropriate when reading and writing files.

 -- Variable: format-alist
     This list contains one format definition for each defined file format.

Each format definition is a list of this form:

     (NAME DOC-STRING REGEXP FROM-FN TO-FN MODIFY MODE-FN)

Here is what the elements in a format definition mean:

name
     The name of this format.

doc-string
     A documentation string for the format.

regexp
     A regular expression which is used to recognize files represented in this format.

from-fn
     A function to call to decode data in this format (to convert file data into the usual Emacs data representation).

     The FROM-FN is called with two args, BEGIN and END, which specify the part of the buffer it should convert.  It should convert the text by editing it in place.  Since this can change the length of the text, FROM-FN should return the modified end position.

     One responsibility of FROM-FN is to make sure that the beginning of the file no longer matches REGEXP.  Otherwise it is likely to get called again.

to-fn
     A function to call to encode data in this format (to convert the usual Emacs data representation into this format).

     The TO-FN is called with two args, BEGIN and END, which specify the part of the buffer it should convert.  There are two ways it can do the conversion:

       * By editing the buffer in place.  In this case, TO-FN should return the end-position of the range of text, as modified.

       * By returning a list of annotations.  This is a list of elements of the form (POSITION . STRING), where POSITION is an integer specifying the relative position in the text to be written, and STRING is the annotation to add there.  The list must be sorted in order of position when TO-FN returns it.

          When write-region actually writes the text from the buffer to the file, it intermixes the specified annotations at the corresponding positions.  All this takes place without modifying the buffer.

modify
     A flag, t if the encoding function modifies the buffer, and nil if it works by returning a list of annotations.

mode
     A mode function to call after visiting a file converted from this format.

The function insert-file-contents automatically recognizes file formats when it reads the specified file.  It checks the text of the beginning of the file against the regular expressions of the format definitions, and if it finds a match, it calls the decoding function for that format.  Then it checks all the known formats over again. It keeps checking them until none of them is applicable.

Visiting a file, with find-file-noselect or the commands that use it, performs conversion likewise (because it calls insert-file-contents); it also calls the mode function for each format that it decodes.  It stores a list of the format names in the buffer-local variable buffer-file-format.

 -- Variable: buffer-file-format
     This variable states the format of the visited file.  More precisely, this is a list of the file format names that were decoded in the course of visiting the current buffer's file.  It is always local in all buffers.

When write-region writes data into a file, it first calls the encoding functions for the formats listed in buffer-file-format, in the order of appearance in the list.

 -- Function: format-write-file file format
     This command writes the current buffer contents into the file FILE in format FORMAT, and makes that format the default for future saves of the buffer.  The argument FORMAT is a list of format names.

 -- Function: format-find-file file format
     This command finds the file FILE, converting it according to format FORMAT.  It also makes FORMAT the default if the buffer is saved later.

     The argument FORMAT is a list of format names.  If FORMAT is nil, no conversion takes place.  Interactively, typing just RET for FORMAT specifies nil.

 -- Function: format-insert-file file format %optional beg end
     This command inserts the contents of file FILE, converting it according to format FORMAT.  If BEG and END are non-nil, they specify which part of the file to read, as in insert-file-contents (see Reading from Files).

     The return value is like what insert-file-contents returns: a list of the absolute file name and the length of the data inserted (after conversion).

     The argument FORMAT is a list of format names.  If FORMAT is nil, no conversion takes place.  Interactively, typing just RET for FORMAT specifies nil.

 -- Variable: auto-save-file-format
     This variable specifies the format to use for auto-saving.  Its value is a list of format names, just like the value of buffer-file-format; but it is used instead of buffer-file-format for writing auto-save files.  This variable is always local in all buffers.

Files and MS-DOS
================

Emacs on MS-DOS and on Windows NT or 95 makes a distinction between text files and binary files.  This is necessary because ordinary text files on MS-DOS use a two character sequence between lines: carriage-return and linefeed (CRLF).  Emacs expects just a newline character (a linefeed) between lines.  When Emacs reads or writes a text file on MS-DOS, it needs to convert the line separators.  This means it needs to know which files are text files and which are binary.  It makes this decision when visiting a file, and records the decision in the variable buffer-file-type for use when the file is saved.

See MS-DOS Subprocesses, for a related feature for subprocesses.

 -- Variable: buffer-file-type
     This variable, automatically local in each buffer, records the file type of the buffer's visited file.  The value is nil for text, t for binary.

 -- Function: find-buffer-file-type filename
     This function determines whether file FILENAME is a text file or a binary file.  It returns nil for text, t for binary.

 -- User Option: file-name-buffer-file-type-alist
     This variable holds an alist for distinguishing text files from binary files.  Each element has the form (REGEXP . TYPE), where REGEXP is matched against the file name, and TYPE may be is nil for text, t for binary, or a function to call to compute which.  If it is a function, then it is called with a single argument (the file name) and should return t or nil.

 -- User Option: default-buffer-file-type
     This variable specifies the default file type for files whose names don't indicate anything in particular.  Its value should be nil for text, or t for binary.

 -- Command: find-file-text filename
     Like find-file, but treat the file as text regardless of its name.

 -- Command: find-file-binary filename
     Like find-file, but treat the file as binary regardless of its name.