AC_INIT(logview)

AM_CONFIG_HEADER(config.h)
AM_INIT_AUTOMAKE(gnome-admin, 1.0.1)
AM_MAINTAINER_MODE

AM_ACLOCAL_INCLUDE(macros)
GNOME_INIT

AC_ISC_POSIX
AC_PROG_CC
AC_PROG_CPP
AC_STDC_HEADERS
AC_ARG_PROGRAM
AM_PROG_LIBTOOL

GNOME_X_CHECKS
GNOME_CHECK_OBJC
GNOME_INIT_OBJC

ALL_LINGUAS="ca de es fr ga it ko no pt sv"
AM_GNOME_GETTEXT

dnl Checks for header files.
AC_HEADER_STDC

dnl Checks for typedefs, structures, and compiler characteristics.
AC_C_CONST
AC_C_INLINE
AC_HEADER_TIME

AC_CHECK_HEADERS(dlfcn.h dl.h)
AC_CHECK_LIB(dl, dlopen, DL_LIB="-ldl",[
AC_CHECK_LIB(dld, shl_load, DL_LIB="-ldld",[
AC_CHECK_FUNCS(dlopen, DL_LIB="",
AC_MSG_ERROR(Dynamic linking is not available on this platform.  Some
apps, like panel, will not run properly.))
])])
AC_SUBST(DL_LIB)

AC_SUBST(CFLAGS)
AC_SUBST(CPPFLAGS)
AC_SUBST(LDFLAGS)


dnl For logview
withval=""

AC_ARG_WITH(messages,
[      --with-messages=<filename>   specify messages log file],[
if test x$withval != x; then
   AC_MSG_RESULT("Setting messages logfile as specified $withval.")
   AC_DEFINE(PATH_MESSAGES, $withval)
fi])

if test x$withval = x; then
AC_MSG_CHECKING([for /var/adm/messages])
if test -f /var/adm/messages; then
  AC_MSG_RESULT([found])
  AC_DEFINE(PATH_MESSAGES, "/var/adm/messages")
else
  AC_MSG_RESULT([not found])
  AC_MSG_CHECKING([for /var/log/messages])
  if test -f /var/log/messages; then
    AC_MSG_RESULT([found])
    AC_DEFINE(PATH_MESSAGES, "/var/log/messages")
  else
    AC_MSG_RESULT([not found])
    AC_MSG_ERROR([Cannot find messages log file, you should specify one in --with-messages=<filename>.])
  fi
fi
fi

#check for for inet_aton.
AC_CHECK_FUNC(inet_aton,,[AC_CHECK_LIB(resolv,inet_aton,RES_LIBS="-lresolv")])
AC_SUBST(RES_LIBS)


AC_OUTPUT([
Makefile
gnome-admin.spec
macros/Makefile
po/Makefile.in
gulp/Makefile
logview/Makefile
intl/Makefile
stamp.h],[sed -e "/POTFILES =/r po/POTFILES" po/Makefile.in > po/Makefile])