g  =  {-(1 - γ^2*r^2), 
          1/(1 - γ^2*r^2), r^2, r^2*Sin[θ]^2}*
        IdentityMatrix[4]

ginverse  =  {-1/(1 - γ^2*r^2), (1 - γ^2*
                r^2), 1/r^2, 
          1/(r^2*Sin[θ]^2)}*IdentityMatrix[
          4]

X  =  {t, 
        r, θ, ϕ}

dg  =  Outer[D, g, X]

lowerconnection  = (dg + 
            Transpose[dg, {1, 3, 2}] - Transpose[dg, {2, 3, 1}])/
        2

connection  =  
      ginverse  .  lowerconnection

riemann  =  
      Transpose[Outer[D, connection, X], {1, 2, 4, 3}] - 
        Transpose[Outer[D, connection, X], {1, 2, 3, 4}] + 
        Transpose[connection . connection, {1, 3, 2, 4}] - 
        Transpose[connection . connection, {1, 4, 2, 3}]

ricci  =  
      Tr[Transpose[riemann, {1, 3, 2, 4}], Plus, 2]

R  =  Simplify[Tr[ginverse . ricci]]

einstein  =  
      Simplify[ricci  -  (1/2)*g*R]

MatrixForm[
      Simplify[ginverse . einstein]]

The above matrix represents G^mu_nu in the {t,r,θ,ϕ} basis.