# See the file LICENSE for redistribution information.
#
# Copyright (c) 1996, 1997, 1998, 1999
#	Sleepycat Software.  All rights reserved.
#
#	@(#)test013.tcl	11.10 (Sleepycat) 9/24/99
#
# DB Test 13 {access method}
#
# 1. Insert 10000 keys and retrieve them (equal key/data pairs).
# 2. Attempt to overwrite keys with NO_OVERWRITE set (expect error).
# 3. Actually overwrite each one with its datum reversed.
#
# No partial testing here.
proc test013 { method {nentries 10000} args } {
	global errorCode
	global errorInfo
	global fixed_pad
	global fixed_len

	source ./include.tcl

 	set args [convert_args $method $args]
	set omethod [convert_method $method]

	puts "Test013: $method ($args) $nentries equal key/data pairs, put test"

	# Create the database and open the dictionary
	set testfile $testdir/test013.db
	set t1 $testdir/t1
	set t2 $testdir/t2
	set t3 $testdir/t3
	cleanup $testdir

	set db [eval {berkdb \
	    open -create -truncate -mode 0644} $args {$omethod $testfile}]
	error_check_good dbopen [is_valid_db $db] TRUE

	set did [open $dict]

	set pflags ""
	set gflags ""
	set txn ""
	set count 0

	if { [is_record_based $method] == 1 } {
		set checkfunc test013_recno.check
		append gflags " -recno"
		global kvals
	} else {
		set checkfunc test013.check
	}
	puts "\tTest013.a: put/get loop"
	# Here is the loop where we put and get each key/data pair
	while { [gets $did str] != -1 && $count < $nentries } {
		if { [is_record_based $method] == 1 } {
			set key [expr $count + 1]
			set kvals($key) [pad_data $method $str]
		} else {
			set key $str
		}
		set ret [eval {$db put} \
		    $txn $pflags {$key [chop_data $method $str]}]
		error_check_good put $ret 0

		set ret [eval {$db get} $gflags $txn {$key}]
		error_check_good \
		    get $ret [list [list $key [pad_data $method $str]]]
		incr count
	}
	close $did

	# Now we will try to overwrite each datum, but set the
	# NOOVERWRITE flag.
	puts "\tTest013.b: overwrite values with NOOVERWRITE flag."
	set did [open $dict]
	set count 0
	while { [gets $did str] != -1 && $count < $nentries } {
		if { [is_record_based $method] == 1 } {
			set key [expr $count + 1]
		} else {
			set key $str
		}

		set ret [eval {$db put} $txn $pflags \
		    {-nooverwrite $key [chop_data $method $str]}]
		error_check_good put [is_substr $ret "DB_KEYEXIST"] 1

		# Value should be unchanged.
		set ret [eval {$db get} $txn $gflags {$key}]
		error_check_good \
		    get $ret [list [list $key [pad_data $method $str]]]
		incr count
	}
	close $did

	# Now we will replace each item with its datum capitalized.
	puts "\tTest013.c: overwrite values with capitalized datum"
	set did [open $dict]
	set count 0
	while { [gets $did str] != -1 && $count < $nentries } {
		if { [is_record_based $method] == 1 } {
			set key [expr $count + 1]
		} else {
			set key $str
		}
		set rstr [string toupper $str]
		set r [eval {$db put} \
		    $txn $pflags {$key [chop_data $method $rstr]}]
		error_check_good put $r 0

		# Value should be changed.
		set ret [eval {$db get} $txn $gflags {$key}]
		error_check_good \
		    get $ret [list [list $key [pad_data $method $rstr]]]
		incr count
	}
	close $did

	# Now make sure that everything looks OK
	puts "\tTest013.d: check entire file contents"
	dump_file $db $txn $t1 $checkfunc
	error_check_good db_close [$db close] 0

	# Now compare the keys to see if they match the dictionary (or ints)
	if { [is_record_based $method] == 1 } {
		set oid [open $t2 w]
		for {set i 1} {$i <= $nentries} {incr i} {
			puts $oid $i
		}
		close $oid
		exec $MV $t1 $t3
	} else {
		set q q
		exec $SED $nentries$q $dict > $t3
		exec $SORT $t3 > $t2
		exec $SORT $t1 > $t3
	}

	error_check_good \
	    Test013:diff($t3,$t2) [catch { exec $CMP $t3 $t2 } res] 0

	puts "\tTest013.e: close, open, and dump file"
	# Now, reopen the file and run the last test again.
	open_and_dump_file $testfile NULL $txn $t1 $checkfunc \
	    dump_file_direction "-first" "-next"

	if { [is_record_based $method] == 0 } {
		exec $SORT $t1 > $t3
	}

	error_check_good \
	    Test013:diff($t3,$t2) [catch { exec $CMP $t3 $t2 } res] 0

	# Now, reopen the file and run the last test again in the
	# reverse direction.
	puts "\tTest013.f: close, open, and dump file in reverse direction"
	open_and_dump_file $testfile NULL $txn $t1 $checkfunc \
   	    dump_file_direction "-last" "-prev"

	if { [is_record_based $method] == 0 } {
		exec $SORT $t1 > $t3
	}

	error_check_good \
	    Test013:diff($t3,$t2) [catch { exec $CMP $t3 $t2 } res] 0
}

# Check function for test013; keys and data are identical
proc test013.check { key data } {
	error_check_good \
	    "key/data mismatch for $key" $data [string toupper $key]
}

proc test013_recno.check { key data } {
	global dict
	global kvals

	error_check_good key"$key"_exists [info exists kvals($key)] 1
	error_check_good \
	    "data mismatch for $key" $data [string toupper $kvals($key)]
}