<html><head><meta name="color-scheme" content="light dark"></head><body><pre style="word-wrap: break-word; white-space: pre-wrap;">package CGI;
require 5.004;

# See the bottom of this file for the POD documentation.  Search for the
# string '=head'.

# You can run this file through either pod2man or pod2html to produce pretty
# documentation in manual or html file format (these utilities are part of the
# Perl 5 distribution).

# Copyright 1995-1998 Lincoln D. Stein.  All rights reserved.
# It may be used and modified freely, but I do request that this copyright
# notice remain attached to the file.  You may modify this module as you 
# wish, but if you redistribute a modified version, please attach a note
# listing the modifications you have made.

# The most recent version and complete docs are available at:
#   http://stein.cshl.org/WWW/software/CGI/

$CGI::revision = '$Id: CGI.pm,v 1.5 1998/12/06 10:19:48 lstein Exp $';
$CGI::VERSION='2.46';

# HARD-CODED LOCATION FOR FILE UPLOAD TEMPORARY FILES.
# UNCOMMENT THIS ONLY IF YOU KNOW WHAT YOU'RE DOING.
# $TempFile::TMPDIRECTORY = '/usr/tmp';

# &gt;&gt;&gt;&gt;&gt; Here are some globals that you might want to adjust &lt;&lt;&lt;&lt;&lt;&lt;
sub initialize_globals {
    # Set this to 1 to enable copious autoloader debugging messages
    $AUTOLOAD_DEBUG = 0;

    # Change this to the preferred DTD to print in start_html()
    # or use default_dtd('text of DTD to use');
    $DEFAULT_DTD = '-//IETF//DTD HTML//EN';

    # Set this to 1 to enable NPH scripts
    # or: 
    #    1) use CGI qw(-nph)
    #    2) $CGI::nph(1)
    #    3) print header(-nph=&gt;1)
    $NPH = 0;

    # Set this to 1 to disable debugging from the
    # command line
    $NO_DEBUG = 0;

    # Set this to 1 to make the temporary files created
    # during file uploads safe from prying eyes
    # or do...
    #    1) use CGI qw(:private_tempfiles)
    #    2) $CGI::private_tempfiles(1);
    $PRIVATE_TEMPFILES = 0;

    # Set this to a positive value to limit the size of a POSTing
    # to a certain number of bytes:
    $POST_MAX = -1;

    # Change this to 1 to disable uploads entirely:
    $DISABLE_UPLOADS = 0;

    # Change this to 1 to suppress redundant HTTP headers
    $HEADERS_ONCE = 0;

    # separate the name=value pairs by semicolons rather than ampersands
    $USE_PARAM_SEMICOLONS = 0;

    # Other globals that you shouldn't worry about.
    undef $Q;
    $BEEN_THERE = 0;
    undef @QUERY_PARAM;
    undef %EXPORT;

    # prevent complaints by mod_perl
    1;
}

# ------------------ START OF THE LIBRARY ------------

# make mod_perlhappy
initialize_globals();

# FIGURE OUT THE OS WE'RE RUNNING UNDER
# Some systems support the $^O variable.  If not
# available then require() the Config library
unless ($OS) {
    unless ($OS = $^O) {
	require Config;
	$OS = $Config::Config{'osname'};
    }
}
if ($OS=~/Win/i) {
    $OS = 'WINDOWS';
} elsif ($OS=~/vms/i) {
    $OS = 'VMS';
} elsif ($OS=~/^MacOS$/i) {
    $OS = 'MACINTOSH';
} elsif ($OS=~/os2/i) {
    $OS = 'OS2';
} else {
    $OS = 'UNIX';
}

# Some OS logic.  Binary mode enabled on DOS, NT and VMS
$needs_binmode = $OS=~/^(WINDOWS|VMS|OS2)/;

# This is the default class for the CGI object to use when all else fails.
$DefaultClass = 'CGI' unless defined $CGI::DefaultClass;

# This is where to look for autoloaded routines.
$AutoloadClass = $DefaultClass unless defined $CGI::AutoloadClass;

# The path separator is a slash, backslash or semicolon, depending
# on the paltform.
$SL = {
    UNIX=&gt;'/', OS2=&gt;'\\', WINDOWS=&gt;'\\', MACINTOSH=&gt;':', VMS=&gt;'/'
    }-&gt;{$OS};

# This no longer seems to be necessary
# Turn on NPH scripts by default when running under IIS server!
# $NPH++ if defined($ENV{'SERVER_SOFTWARE'}) &amp;&amp; $ENV{'SERVER_SOFTWARE'}=~/IIS/;
$IIS++ if defined($ENV{'SERVER_SOFTWARE'}) &amp;&amp; $ENV{'SERVER_SOFTWARE'}=~/IIS/;

# Turn on special checking for Doug MacEachern's modperl
if (exists $ENV{'GATEWAY_INTERFACE'} 
    &amp;&amp; 
    ($MOD_PERL = $ENV{'GATEWAY_INTERFACE'} =~ /^CGI-Perl/))
{
    $| = 1;
    require Apache;
}
# Turn on special checking for ActiveState's PerlEx
$PERLEX++ if defined($ENV{'GATEWAY_INTERFACE'}) &amp;&amp; $ENV{'GATEWAY_INTERFACE'} =~ /^CGI-PerlEx/;

# Define the CRLF sequence.  I can't use a simple "\r\n" because the meaning
# of "\n" is different on different OS's (sometimes it generates CRLF, sometimes LF
# and sometimes CR).  The most popular VMS web server
# doesn't accept CRLF -- instead it wants a LR.  EBCDIC machines don't
# use ASCII, so \015\012 means something different.  I find this all 
# really annoying.
$EBCDIC = "\t" ne "\011";
if ($OS eq 'VMS') {
    $CRLF = "\n";
} elsif ($EBCDIC) {
    $CRLF= "\r\n";
} else {
    $CRLF = "\015\012";
}

if ($needs_binmode) {
    $CGI::DefaultClass-&gt;binmode(main::STDOUT);
    $CGI::DefaultClass-&gt;binmode(main::STDIN);
    $CGI::DefaultClass-&gt;binmode(main::STDERR);
}

%EXPORT_TAGS = (
		':html2'=&gt;['h1'..'h6',qw/p br hr ol ul li dl dt dd menu code var strong em
			   tt u i b blockquote pre img a address cite samp dfn html head
			   base body Link nextid title meta kbd start_html end_html
			   input Select option comment/],
		':html3'=&gt;[qw/div table caption th td TR Tr sup Sub strike applet Param 
			   embed basefont style span layer ilayer font frameset frame script small big/],
		':netscape'=&gt;[qw/blink fontsize center/],
		':form'=&gt;[qw/textfield textarea filefield password_field hidden checkbox checkbox_group 
			  submit reset defaults radio_group popup_menu button autoEscape
			  scrolling_list image_button start_form end_form startform endform
			  start_multipart_form end_multipart_form isindex tmpFileName uploadInfo URL_ENCODED MULTIPART/],
		':cgi'=&gt;[qw/param path_info path_translated url self_url script_name cookie Dump
			 raw_cookie request_method query_string Accept user_agent remote_host 
			 remote_addr referer server_name server_software server_port server_protocol
			 virtual_host remote_ident auth_type http use_named_parameters 
			 save_parameters restore_parameters param_fetch
			 remote_user user_name header redirect import_names put Delete Delete_all url_param/],
		':ssl' =&gt; [qw/https/],
		':imagemap' =&gt; [qw/Area Map/],
		':cgi-lib' =&gt; [qw/ReadParse PrintHeader HtmlTop HtmlBot SplitParam/],
		':html' =&gt; [qw/:html2 :html3 :netscape/],
		':standard' =&gt; [qw/:html2 :html3 :form :cgi/],
		':push' =&gt; [qw/multipart_init multipart_start multipart_end/],
		':all' =&gt; [qw/:html2 :html3 :netscape :form :cgi :internal/]
		);

# to import symbols into caller
sub import {
    my $self = shift;

# This causes modules to clash.  
#    undef %EXPORT_OK;
#    undef %EXPORT;

    $self-&gt;_setup_symbols(@_);
    my ($callpack, $callfile, $callline) = caller;

    # To allow overriding, search through the packages
    # Till we find one in which the correct subroutine is defined.
    my @packages = ($self,@{"$self\:\:ISA"});
    foreach $sym (keys %EXPORT) {
	my $pck;
	my $def = ${"$self\:\:AutoloadClass"} || $DefaultClass;
	foreach $pck (@packages) {
	    if (defined(&amp;{"$pck\:\:$sym"})) {
		$def = $pck;
		last;
	    }
	}
	*{"${callpack}::$sym"} = \&amp;{"$def\:\:$sym"};
    }
}

sub compile {
    my $pack = shift;
    $pack-&gt;_setup_symbols('-compile',@_);
}

sub expand_tags {
    my($tag) = @_;
    return ("start_$1","end_$1") if $tag=~/^(?:\*|start_|end_)(.+)/;
    my(@r);
    return ($tag) unless $EXPORT_TAGS{$tag};
    foreach (@{$EXPORT_TAGS{$tag}}) {
	push(@r,&amp;expand_tags($_));
    }
    return @r;
}

#### Method: new
# The new routine.  This will check the current environment
# for an existing query string, and initialize itself, if so.
####
sub new {
    my($class,$initializer) = @_;
    my $self = {};
    bless $self,ref $class || $class || $DefaultClass;
    if ($MOD_PERL) {
	Apache-&gt;request-&gt;register_cleanup(\&amp;CGI::_reset_globals);
	undef $NPH;
    }
    $self-&gt;_reset_globals if $PERLEX;
    $self-&gt;init($initializer);
    return $self;
}

# We provide a DESTROY method so that the autoloader
# doesn't bother trying to find it.
sub DESTROY { }

#### Method: param
# Returns the value(s)of a named parameter.
# If invoked in a list context, returns the
# entire list.  Otherwise returns the first
# member of the list.
# If name is not provided, return a list of all
# the known parameters names available.
# If more than one argument is provided, the
# second and subsequent arguments are used to
# set the value of the parameter.
####
sub param {
    my($self,@p) = self_or_default(@_);
    return $self-&gt;all_parameters unless @p;
    my($name,$value,@other);

    # For compatibility between old calling style and use_named_parameters() style, 
    # we have to special case for a single parameter present.
    if (@p &gt; 1) {
	($name,$value,@other) = $self-&gt;rearrange([NAME,[DEFAULT,VALUE,VALUES]],@p);
	my(@values);

	if (substr($p[0],0,1) eq '-' || $self-&gt;use_named_parameters) {
	    @values = defined($value) ? (ref($value) &amp;&amp; ref($value) eq 'ARRAY' ? @{$value} : $value) : ();
	} else {
	    foreach ($value,@other) {
		push(@values,$_) if defined($_);
	    }
	}
	# If values is provided, then we set it.
	if (@values) {
	    $self-&gt;add_parameter($name);
	    $self-&gt;{$name}=[@values];
	}
    } else {
	$name = $p[0];
    }

    return unless defined($name) &amp;&amp; $self-&gt;{$name};
    return wantarray ? @{$self-&gt;{$name}} : $self-&gt;{$name}-&gt;[0];
}

sub self_or_default {
    return @_ if defined($_[0]) &amp;&amp; (!ref($_[0])) &amp;&amp;($_[0] eq 'CGI');
    unless (defined($_[0]) &amp;&amp; 
	    (ref($_[0]) eq 'CGI' || UNIVERSAL::isa($_[0],'CGI')) # slightly optimized for common case
	    ) {
	$Q = $CGI::DefaultClass-&gt;new unless defined($Q);
	unshift(@_,$Q);
    }
    return @_;
}

sub self_or_CGI {
    local $^W=0;                # prevent a warning
    if (defined($_[0]) &amp;&amp;
	(substr(ref($_[0]),0,3) eq 'CGI' 
	 || UNIVERSAL::isa($_[0],'CGI'))) {
	return @_;
    } else {
	return ($DefaultClass,@_);
    }
}

########################################
# THESE METHODS ARE MORE OR LESS PRIVATE
# GO TO THE __DATA__ SECTION TO SEE MORE
# PUBLIC METHODS
########################################

# Initialize the query object from the environment.
# If a parameter list is found, this object will be set
# to an associative array in which parameter names are keys
# and the values are stored as lists
# If a keyword list is found, this method creates a bogus
# parameter list with the single parameter 'keywords'.

sub init {
    my($self,$initializer) = @_;
    my($query_string,$meth,$content_length,$fh,@lines) = ('','','','');
    local($/) = "\n";

    # if we get called more than once, we want to initialize
    # ourselves from the original query (which may be gone
    # if it was read from STDIN originally.)
    if (defined(@QUERY_PARAM) &amp;&amp; !defined($initializer)) {
	foreach (@QUERY_PARAM) {
	    $self-&gt;param('-name'=&gt;$_,'-value'=&gt;$QUERY_PARAM{$_});
	}
	return;
    }

    $meth=$ENV{'REQUEST_METHOD'} if defined($ENV{'REQUEST_METHOD'});
    $content_length = defined($ENV{'CONTENT_LENGTH'}) ? $ENV{'CONTENT_LENGTH'} : 0;
    die "Client attempted to POST $content_length bytes, but POSTs are limited to $POST_MAX"
	if ($POST_MAX &gt; 0) &amp;&amp; ($content_length &gt; $POST_MAX);
    $fh = to_filehandle($initializer) if $initializer;

  METHOD: {

      # Process multipart postings, but only if the initializer is
      # not defined.
      if ($meth eq 'POST'
	  &amp;&amp; defined($ENV{'CONTENT_TYPE'})
	  &amp;&amp; $ENV{'CONTENT_TYPE'}=~m|^multipart/form-data|
	  &amp;&amp; !defined($initializer)
	  ) {
	  my($boundary) = $ENV{'CONTENT_TYPE'} =~ /boundary=\"?([^\";,]+)\"?/;
	  $self-&gt;read_multipart($boundary,$content_length);
	  last METHOD;
      } 

      # If initializer is defined, then read parameters
      # from it.
      if (defined($initializer)) {
	  if (UNIVERSAL::isa($initializer,'CGI')) {
	      $query_string = $initializer-&gt;query_string;
	      last METHOD;
	  }
	  if (ref($initializer) &amp;&amp; ref($initializer) eq 'HASH') {
	      foreach (keys %$initializer) {
		  $self-&gt;param('-name'=&gt;$_,'-value'=&gt;$initializer-&gt;{$_});
	      }
	      last METHOD;
	  }
	  
	  if (defined($fh) &amp;&amp; ($fh ne '')) {
	      while (&lt;$fh&gt;) {
		  chomp;
		  last if /^=/;
		  push(@lines,$_);
	      }
	      # massage back into standard format
	      if ("@lines" =~ /=/) {
		  $query_string=join("&amp;",@lines);
	      } else {
		  $query_string=join("+",@lines);
	      }
	      last METHOD;
	  }

	  # last chance -- treat it as a string
	  $initializer = $$initializer if ref($initializer) eq 'SCALAR';
	  $query_string = $initializer;

	  last METHOD;
      }

      # If method is GET or HEAD, fetch the query from
      # the environment.
      if ($meth=~/^(GET|HEAD)$/) {
	  $query_string = $ENV{'QUERY_STRING'} if defined $ENV{'QUERY_STRING'};
	  last METHOD;
      }

      if ($meth eq 'POST') {
	  $self-&gt;read_from_client(\*STDIN,\$query_string,$content_length,0)
	      if $content_length &gt; 0;
	  # Some people want to have their cake and eat it too!
	  # Uncomment this line to have the contents of the query string
	  # APPENDED to the POST data.
	  # $query_string .= (length($query_string) ? '&amp;' : '') . $ENV{'QUERY_STRING'} if defined $ENV{'QUERY_STRING'};
	  last METHOD;
      }

      # If $meth is not of GET, POST or HEAD, assume we're being debugged offline.
      # Check the command line and then the standard input for data.
      # We use the shellwords package in order to behave the way that
      # UN*X programmers expect.
      $query_string = read_from_cmdline() unless $NO_DEBUG;
  }

    # We now have the query string in hand.  We do slightly
    # different things for keyword lists and parameter lists.
    if ($query_string ne '') {
	if ($query_string =~ /=/) {
	    $self-&gt;parse_params($query_string);
	} else {
	    $self-&gt;add_parameter('keywords');
	    $self-&gt;{'keywords'} = [$self-&gt;parse_keywordlist($query_string)];
	}
    }

    # Special case.  Erase everything if there is a field named
    # .defaults.
    if ($self-&gt;param('.defaults')) {
	undef %{$self};
    }

    # Associative array containing our defined fieldnames
    $self-&gt;{'.fieldnames'} = {};
    foreach ($self-&gt;param('.cgifields')) {
	$self-&gt;{'.fieldnames'}-&gt;{$_}++;
    }
    
    # Clear out our default submission button flag if present
    $self-&gt;delete('.submit');
    $self-&gt;delete('.cgifields');
    $self-&gt;save_request unless $initializer;
}

# FUNCTIONS TO OVERRIDE:
# Turn a string into a filehandle
sub to_filehandle {
    my $thingy = shift;
    return undef unless $thingy;
    return $thingy if UNIVERSAL::isa($thingy,'GLOB');
    return $thingy if UNIVERSAL::isa($thingy,'FileHandle');
    if (!ref($thingy)) {
	my $caller = 1;
	while (my $package = caller($caller++)) {
	    my($tmp) = $thingy=~/[\':]/ ? $thingy : "$package\:\:$thingy"; 
	    return $tmp if defined(fileno($tmp));
	}
    }
    return undef;
}

# send output to the browser
sub put {
    my($self,@p) = self_or_default(@_);
    $self-&gt;print(@p);
}

# print to standard output (for overriding in mod_perl)
sub print {
    shift;
    CORE::print(@_);
}

# unescape URL-encoded data
sub unescape {
    shift() if ref($_[0]);
    my $todecode = shift;
    return undef unless defined($todecode);
    $todecode =~ tr/+/ /;       # pluses become spaces
    $todecode =~ s/%([0-9a-fA-F]{2})/pack("c",hex($1))/ge;
    return $todecode;
}

# URL-encode data
sub escape {
    shift() if ref($_[0]) || $_[0] eq $DefaultClass;
    my $toencode = shift;
    return undef unless defined($toencode);
    $toencode=~s/([^a-zA-Z0-9_.-])/uc sprintf("%%%02x",ord($1))/eg;
    return $toencode;
}

sub save_request {
    my($self) = @_;
    # We're going to play with the package globals now so that if we get called
    # again, we initialize ourselves in exactly the same way.  This allows
    # us to have several of these objects.
    @QUERY_PARAM = $self-&gt;param; # save list of parameters
    foreach (@QUERY_PARAM) {
	$QUERY_PARAM{$_}=$self-&gt;{$_};
    }
}

sub parse_params {
    my($self,$tosplit) = @_;
    my(@pairs) = split(/[&amp;;]/,$tosplit);
    my($param,$value);
    foreach (@pairs) {
	($param,$value) = split('=',$_,2);
	$param = unescape($param);
	$value = unescape($value);
	$self-&gt;add_parameter($param);
	push (@{$self-&gt;{$param}},$value);
    }
}

sub add_parameter {
    my($self,$param)=@_;
    push (@{$self-&gt;{'.parameters'}},$param) 
	unless defined($self-&gt;{$param});
}

sub all_parameters {
    my $self = shift;
    return () unless defined($self) &amp;&amp; $self-&gt;{'.parameters'};
    return () unless @{$self-&gt;{'.parameters'}};
    return @{$self-&gt;{'.parameters'}};
}

# put a filehandle into binary mode (DOS)
sub binmode {
    CORE::binmode($_[1]);
}

sub _make_tag_func {
    my ($self,$tagname) = @_;
    my $func = qq#
	sub $tagname { 
	    shift if \$_[0] &amp;&amp; 
		(!ref(\$_[0]) &amp;&amp; \$_[0] eq \$CGI::DefaultClass) ||
		    (ref(\$_[0]) &amp;&amp;
		     (substr(ref(\$_[0]),0,3) eq 'CGI' ||
		    UNIVERSAL::isa(\$_[0],'CGI')));
	    
	    my(\$attr) = '';
	    if (ref(\$_[0]) &amp;&amp; ref(\$_[0]) eq 'HASH') {
		my(\@attr) = make_attributes( '',shift() );
		\$attr = " \@attr" if \@attr;
	    }
	#;
    if ($tagname=~/start_(\w+)/i) {
	$func .= qq! return "&lt;\U$1\E\$attr&gt;";} !;
    } elsif ($tagname=~/end_(\w+)/i) {
	$func .= qq! return "&lt;\U/$1\E&gt;"; } !;
    } else {
	$func .= qq#
	    my(\$tag,\$untag) = ("\U&lt;$tagname\E\$attr&gt;","\U&lt;/$tagname&gt;\E");
	    return \$tag unless \@_;
	    my \@result = map { "\$tag\$_\$untag" } (ref(\$_[0]) eq 'ARRAY') ? \@{\$_[0]} : "\@_";
	    return "\@result";
            }#;
    }
return $func;
}

sub AUTOLOAD {
    print STDERR "CGI::AUTOLOAD for $AUTOLOAD\n" if $CGI::AUTOLOAD_DEBUG;
    my $func = &amp;_compile;
    goto &amp;$func;
}

# PRIVATE SUBROUTINE
# Smart rearrangement of parameters to allow named parameter
# calling.  We do the rearangement if:
# 1. The first parameter begins with a -
# 2. The use_named_parameters() method returns true
sub rearrange {
    my($self,$order,@param) = @_;
    return () unless @param;

    if (ref($param[0]) eq 'HASH') {
	@param = %{$param[0]};
    } else {
	return @param 
	    unless (defined($param[0]) &amp;&amp; substr($param[0],0,1) eq '-')
		|| $self-&gt;use_named_parameters;
    }

    # map parameters into positional indices
    my ($i,%pos);
    $i = 0;
    foreach (@$order) {
	foreach (ref($_) eq 'ARRAY' ? @$_ : $_) { $pos{$_} = $i; }
	$i++;
    }

    my (@result,%leftover);
    $#result = $#$order;  # preextend
    while (@param) {
	my $key = uc(shift(@param));
	$key =~ s/^\-//;
	if (exists $pos{$key}) {
	    $result[$pos{$key}] = shift(@param);
	} else {
	    $leftover{$key} = shift(@param);
	}
    }

    push (@result,$self-&gt;make_attributes(\%leftover)) if %leftover;
    @result;
}

sub _compile {
    my($func) = $AUTOLOAD;
    my($pack,$func_name);
    {
	local($1,$2); # this fixes an obscure variable suicide problem.
	$func=~/(.+)::([^:]+)$/;
	($pack,$func_name) = ($1,$2);
	$pack=~s/::SUPER$//;	# fix another obscure problem
	$pack = ${"$pack\:\:AutoloadClass"} || $CGI::DefaultClass
	    unless defined(${"$pack\:\:AUTOLOADED_ROUTINES"});

        my($sub) = \%{"$pack\:\:SUBS"};
        unless (%$sub) {
	   my($auto) = \${"$pack\:\:AUTOLOADED_ROUTINES"};
	   eval "package $pack; $$auto";
	   die $@ if $@;
           $$auto = '';  # Free the unneeded storage (but don't undef it!!!)
       }
       my($code) = $sub-&gt;{$func_name};

       $code = "sub $AUTOLOAD { }" if (!$code and $func_name eq 'DESTROY');
       if (!$code) {
	   (my $base = $func_name) =~ s/^(start_|end_)//i;
	   if ($EXPORT{':any'} || 
	       $EXPORT{'-any'} ||
	       $EXPORT{$base} || 
	       (%EXPORT_OK || grep(++$EXPORT_OK{$_},&amp;expand_tags(':html')))
	           &amp;&amp; $EXPORT_OK{$base}) {
	       $code = $CGI::DefaultClass-&gt;_make_tag_func($func_name);
	   }
       }
       die "Undefined subroutine $AUTOLOAD\n" unless $code;
       eval "package $pack; $code";
       if ($@) {
	   $@ =~ s/ at .*\n//;
	   die $@;
       }
    }       
    delete($sub-&gt;{$func_name});  #free storage
    return "$pack\:\:$func_name";
}

sub _reset_globals { initialize_globals(); }

sub _setup_symbols {
    my $self = shift;
    my $compile = 0;
    foreach (@_) {
	$HEADERS_ONCE++,         next if /^[:-]unique_headers$/;
	$NPH++,                  next if /^[:-]nph$/;
	$NO_DEBUG++,             next if /^[:-]no_?[Dd]ebug$/;
	$USE_PARAM_SEMICOLONS++, next if /^[:-]newstyle_urls$/;
	$PRIVATE_TEMPFILES++,    next if /^[:-]private_tempfiles$/;
	$EXPORT{$_}++,           next if /^[:-]any$/;
	$compile++,              next if /^[:-]compile$/;
	
	# This is probably extremely evil code -- to be deleted some day.
	if (/^[-]autoload$/) {
	    my($pkg) = caller(1);
	    *{"${pkg}::AUTOLOAD"} = sub { 
		my($routine) = $AUTOLOAD;
		$routine =~ s/^.*::/CGI::/;
		&amp;$routine;
	    };
	    next;
	}

	foreach (&amp;expand_tags($_)) {
	    tr/a-zA-Z0-9_//cd;  # don't allow weird function names
	    $EXPORT{$_}++;
	}
    }
    _compile_all(keys %EXPORT) if $compile;
}

###############################################################################
################# THESE FUNCTIONS ARE AUTOLOADED ON DEMAND ####################
###############################################################################
$AUTOLOADED_ROUTINES = '';      # get rid of -w warning
$AUTOLOADED_ROUTINES=&lt;&lt;'END_OF_AUTOLOAD';

%SUBS = (

'URL_ENCODED'=&gt; &lt;&lt;'END_OF_FUNC',
sub URL_ENCODED { 'application/x-www-form-urlencoded'; }
END_OF_FUNC

'MULTIPART' =&gt; &lt;&lt;'END_OF_FUNC',
sub MULTIPART {  'multipart/form-data'; }
END_OF_FUNC

'SERVER_PUSH' =&gt; &lt;&lt;'END_OF_FUNC',
sub SERVER_PUSH { 'multipart/x-mixed-replace; boundary="' . shift() . '"'; }
END_OF_FUNC

'use_named_parameters' =&gt; &lt;&lt;'END_OF_FUNC',
#### Method: use_named_parameters
# Force CGI.pm to use named parameter-style method calls
# rather than positional parameters.  The same effect
# will happen automatically if the first parameter
# begins with a -.
sub use_named_parameters {
    my($self,$use_named) = self_or_default(@_);
    return $self-&gt;{'.named'} unless defined ($use_named);

    # stupidity to avoid annoying warnings
    return $self-&gt;{'.named'}=$use_named;
}
END_OF_FUNC

'new_MultipartBuffer' =&gt; &lt;&lt;'END_OF_FUNC',
# Create a new multipart buffer
sub new_MultipartBuffer {
    my($self,$boundary,$length,$filehandle) = @_;
    return MultipartBuffer-&gt;new($self,$boundary,$length,$filehandle);
}
END_OF_FUNC

'read_from_client' =&gt; &lt;&lt;'END_OF_FUNC',
# Read data from a file handle
sub read_from_client {
    my($self, $fh, $buff, $len, $offset) = @_;
    local $^W=0;                # prevent a warning
    return undef unless defined($fh);
    return read($fh, $$buff, $len, $offset);
}
END_OF_FUNC

'delete' =&gt; &lt;&lt;'END_OF_FUNC',
#### Method: delete
# Deletes the named parameter entirely.
####
sub delete {
    my($self,$name) = self_or_default(@_);
    delete $self-&gt;{$name};
    delete $self-&gt;{'.fieldnames'}-&gt;{$name};
    @{$self-&gt;{'.parameters'}}=grep($_ ne $name,$self-&gt;param());
    return wantarray ? () : undef;
}
END_OF_FUNC

#### Method: import_names
# Import all parameters into the given namespace.
# Assumes namespace 'Q' if not specified
####
'import_names' =&gt; &lt;&lt;'END_OF_FUNC',
sub import_names {
    my($self,$namespace,$delete) = self_or_default(@_);
    $namespace = 'Q' unless defined($namespace);
    die "Can't import names into \"main\"\n" if \%{"${namespace}::"} == \%::;
    if ($delete || $MOD_PERL) {
	# can anyone find an easier way to do this?
	foreach (keys %{"${namespace}::"}) {
	    local *symbol = "${namespace}::${_}";
	    undef $symbol;
	    undef @symbol;
	    undef %symbol;
	}
    }
    my($param,@value,$var);
    foreach $param ($self-&gt;param) {
	# protect against silly names
	($var = $param)=~tr/a-zA-Z0-9_/_/c;
	$var =~ s/^(?=\d)/_/;
	local *symbol = "${namespace}::$var";
	@value = $self-&gt;param($param);
	@symbol = @value;
	$symbol = $value[0];
    }
}
END_OF_FUNC

#### Method: keywords
# Keywords acts a bit differently.  Calling it in a list context
# returns the list of keywords.  
# Calling it in a scalar context gives you the size of the list.
####
'keywords' =&gt; &lt;&lt;'END_OF_FUNC',
sub keywords {
    my($self,@values) = self_or_default(@_);
    # If values is provided, then we set it.
    $self-&gt;{'keywords'}=[@values] if defined(@values);
    my(@result) = defined($self-&gt;{'keywords'}) ? @{$self-&gt;{'keywords'}} : ();
    @result;
}
END_OF_FUNC

# These are some tie() interfaces for compatibility
# with Steve Brenner's cgi-lib.pl routines
'ReadParse' =&gt; &lt;&lt;'END_OF_FUNC',
sub ReadParse {
    local(*in);
    if (@_) {
	*in = $_[0];
    } else {
	my $pkg = caller();
	*in=*{"${pkg}::in"};
    }
    tie(%in,CGI);
    return scalar(keys %in);
}
END_OF_FUNC

'PrintHeader' =&gt; &lt;&lt;'END_OF_FUNC',
sub PrintHeader {
    my($self) = self_or_default(@_);
    return $self-&gt;header();
}
END_OF_FUNC

'HtmlTop' =&gt; &lt;&lt;'END_OF_FUNC',
sub HtmlTop {
    my($self,@p) = self_or_default(@_);
    return $self-&gt;start_html(@p);
}
END_OF_FUNC

'HtmlBot' =&gt; &lt;&lt;'END_OF_FUNC',
sub HtmlBot {
    my($self,@p) = self_or_default(@_);
    return $self-&gt;end_html(@p);
}
END_OF_FUNC

'SplitParam' =&gt; &lt;&lt;'END_OF_FUNC',
sub SplitParam {
    my ($param) = @_;
    my (@params) = split ("\0", $param);
    return (wantarray ? @params : $params[0]);
}
END_OF_FUNC

'MethGet' =&gt; &lt;&lt;'END_OF_FUNC',
sub MethGet {
    return request_method() eq 'GET';
}
END_OF_FUNC

'MethPost' =&gt; &lt;&lt;'END_OF_FUNC',
sub MethPost {
    return request_method() eq 'POST';
}
END_OF_FUNC

'TIEHASH' =&gt; &lt;&lt;'END_OF_FUNC',
sub TIEHASH { 
    return $Q || new CGI;
}
END_OF_FUNC

'STORE' =&gt; &lt;&lt;'END_OF_FUNC',
sub STORE {
    $_[0]-&gt;param($_[1],split("\0",$_[2]));
}
END_OF_FUNC

'FETCH' =&gt; &lt;&lt;'END_OF_FUNC',
sub FETCH {
    return $_[0] if $_[1] eq 'CGI';
    return undef unless defined $_[0]-&gt;param($_[1]);
    return join("\0",$_[0]-&gt;param($_[1]));
}
END_OF_FUNC

'FIRSTKEY' =&gt; &lt;&lt;'END_OF_FUNC',
sub FIRSTKEY {
    $_[0]-&gt;{'.iterator'}=0;
    $_[0]-&gt;{'.parameters'}-&gt;[$_[0]-&gt;{'.iterator'}++];
}
END_OF_FUNC

'NEXTKEY' =&gt; &lt;&lt;'END_OF_FUNC',
sub NEXTKEY {
    $_[0]-&gt;{'.parameters'}-&gt;[$_[0]-&gt;{'.iterator'}++];
}
END_OF_FUNC

'EXISTS' =&gt; &lt;&lt;'END_OF_FUNC',
sub EXISTS {
    exists $_[0]-&gt;{$_[1]};
}
END_OF_FUNC

'DELETE' =&gt; &lt;&lt;'END_OF_FUNC',
sub DELETE {
    $_[0]-&gt;delete($_[1]);
}
END_OF_FUNC

'CLEAR' =&gt; &lt;&lt;'END_OF_FUNC',
sub CLEAR {
    %{$_[0]}=();
}
####
END_OF_FUNC

####
# Append a new value to an existing query
####
'append' =&gt; &lt;&lt;'EOF',
sub append {
    my($self,@p) = @_;
    my($name,$value) = $self-&gt;rearrange([NAME,[VALUE,VALUES]],@p);
    my(@values) = defined($value) ? (ref($value) ? @{$value} : $value) : ();
    if (@values) {
	$self-&gt;add_parameter($name);
	push(@{$self-&gt;{$name}},@values);
    }
    return $self-&gt;param($name);
}
EOF

#### Method: delete_all
# Delete all parameters
####
'delete_all' =&gt; &lt;&lt;'EOF',
sub delete_all {
    my($self) = self_or_default(@_);
    undef %{$self};
}
EOF

'Delete' =&gt; &lt;&lt;'EOF',
sub Delete {
    my($self,@p) = self_or_default(@_);
    $self-&gt;delete(@p);
}
EOF

'Delete_all' =&gt; &lt;&lt;'EOF',
sub Delete_all {
    my($self,@p) = self_or_default(@_);
    $self-&gt;delete_all(@p);
}
EOF

#### Method: autoescape
# If you want to turn off the autoescaping features,
# call this method with undef as the argument
'autoEscape' =&gt; &lt;&lt;'END_OF_FUNC',
sub autoEscape {
    my($self,$escape) = self_or_default(@_);
    $self-&gt;{'dontescape'}=!$escape;
}
END_OF_FUNC


#### Method: version
# Return the current version
####
'version' =&gt; &lt;&lt;'END_OF_FUNC',
sub version {
    return $VERSION;
}
END_OF_FUNC

'make_attributes' =&gt; &lt;&lt;'END_OF_FUNC',
sub make_attributes {
    my($self,$attr) = @_;
    return () unless $attr &amp;&amp; ref($attr) &amp;&amp; ref($attr) eq 'HASH';
    my(@att);
    foreach (keys %{$attr}) {
	my($key) = $_;
	$key=~s/^\-//;     # get rid of initial - if present
	$key=~tr/a-z_/A-Z-/; # parameters are upper case, use dashes
	push(@att,defined($attr-&gt;{$_}) ? qq/$key="$attr-&gt;{$_}"/ : qq/$key/);
    }
    return @att;
}
END_OF_FUNC

#### Method: url_param
# Return a parameter in the QUERY_STRING, regardless of
# whether this was a POST or a GET
####
'url_param' =&gt; &lt;&lt;'END_OF_FUNC',
sub url_param {
    my ($self,@p) = self_or_default(@_);
    my $name = shift(@p);
    return undef unless exists($ENV{QUERY_STRING});
    unless (exists($self-&gt;{'.url_param'})) {
	$self-&gt;{'.url_param'}={}; # empty hash
	if ($ENV{QUERY_STRING} =~ /=/) {
	    my(@pairs) = split(/[&amp;;]/,$ENV{QUERY_STRING});
	    my($param,$value);
	    foreach (@pairs) {
		($param,$value) = split('=',$_,2);
		$param = unescape($param);
		$value = unescape($value);
		push(@{$self-&gt;{'.url_param'}-&gt;{$param}},$value);
	    }
	} else {
	    $self-&gt;{'.url_param'}-&gt;{'keywords'} = [$self-&gt;parse_keywordlist($ENV{QUERY_STRING})];
	}
    }
    return keys %{$self-&gt;{'.url_param'}} unless defined($name);
    return () unless $self-&gt;{'.url_param'}-&gt;{$name};
    return wantarray ? @{$self-&gt;{'.url_param'}-&gt;{$name}}
                     : $self-&gt;{'.url_param'}-&gt;{$name}-&gt;[0];
}
END_OF_FUNC

#### Method: dump
# Returns a string in which all the known parameter/value 
# pairs are represented as nested lists, mainly for the purposes 
# of debugging.
####
'dump' =&gt; &lt;&lt;'END_OF_FUNC',
sub dump {
    my($self) = self_or_default(@_);
    my($param,$value,@result);
    return '&lt;UL&gt;&lt;/UL&gt;' unless $self-&gt;param;
    push(@result,"&lt;UL&gt;");
    foreach $param ($self-&gt;param) {
	my($name)=$self-&gt;escapeHTML($param);
	push(@result,"&lt;LI&gt;&lt;STRONG&gt;$param&lt;/STRONG&gt;");
	push(@result,"&lt;UL&gt;");
	foreach $value ($self-&gt;param($param)) {
	    $value = $self-&gt;escapeHTML($value);
	    push(@result,"&lt;LI&gt;$value");
	}
	push(@result,"&lt;/UL&gt;");
    }
    push(@result,"&lt;/UL&gt;\n");
    return join("\n",@result);
}
END_OF_FUNC

#### Method as_string
#
# synonym for "dump"
####
'as_string' =&gt; &lt;&lt;'END_OF_FUNC',
sub as_string {
    &amp;dump(@_);
}
END_OF_FUNC

#### Method: save
# Write values out to a filehandle in such a way that they can
# be reinitialized by the filehandle form of the new() method
####
'save' =&gt; &lt;&lt;'END_OF_FUNC',
sub save {
    my($self,$filehandle) = self_or_default(@_);
    $filehandle = to_filehandle($filehandle);
    my($param);
    local($,) = '';  # set print field separator back to a sane value
    local($\) = '';  # set output line separator to a sane value
    foreach $param ($self-&gt;param) {
	my($escaped_param) = escape($param);
	my($value);
	foreach $value ($self-&gt;param($param)) {
	    print $filehandle "$escaped_param=",escape($value),"\n";
	}
    }
    print $filehandle "=\n";    # end of record
}
END_OF_FUNC


#### Method: save_parameters
# An alias for save() that is a better name for exportation.
# Only intended to be used with the function (non-OO) interface.
####
'save_parameters' =&gt; &lt;&lt;'END_OF_FUNC',
sub save_parameters {
    my $fh = shift;
    return save(to_filehandle($fh));
}
END_OF_FUNC

#### Method: restore_parameters
# A way to restore CGI parameters from an initializer.
# Only intended to be used with the function (non-OO) interface.
####
'restore_parameters' =&gt; &lt;&lt;'END_OF_FUNC',
sub restore_parameters {
    $Q = $CGI::DefaultClass-&gt;new(@_);
}
END_OF_FUNC

#### Method: multipart_init
# Return a Content-Type: style header for server-push
# This has to be NPH, and it is advisable to set $| = 1
#
# Many thanks to Ed Jordan &lt;ed@fidalgo.net&gt; for this
# contribution
####
'multipart_init' =&gt; &lt;&lt;'END_OF_FUNC',
sub multipart_init {
    my($self,@p) = self_or_default(@_);
    my($boundary,@other) = $self-&gt;rearrange([BOUNDARY],@p);
    $boundary = $boundary || '------- =_aaaaaaaaaa0';
    $self-&gt;{'separator'} = "\n--$boundary\n";
    $type = SERVER_PUSH($boundary);
    return $self-&gt;header(
	-nph =&gt; 1,
	-type =&gt; $type,
	(map { split "=", $_, 2 } @other),
    ) . $self-&gt;multipart_end;
}
END_OF_FUNC


#### Method: multipart_start
# Return a Content-Type: style header for server-push, start of section
#
# Many thanks to Ed Jordan &lt;ed@fidalgo.net&gt; for this
# contribution
####
'multipart_start' =&gt; &lt;&lt;'END_OF_FUNC',
sub multipart_start {
    my($self,@p) = self_or_default(@_);
    my($type,@other) = $self-&gt;rearrange([TYPE],@p);
    $type = $type || 'text/html';
    return $self-&gt;header(
	-type =&gt; $type,
	(map { split "=", $_, 2 } @other),
    );
}
END_OF_FUNC


#### Method: multipart_end
# Return a Content-Type: style header for server-push, end of section
#
# Many thanks to Ed Jordan &lt;ed@fidalgo.net&gt; for this
# contribution
####
'multipart_end' =&gt; &lt;&lt;'END_OF_FUNC',
sub multipart_end {
    my($self,@p) = self_or_default(@_);
    return $self-&gt;{'separator'};
}
END_OF_FUNC


#### Method: header
# Return a Content-Type: style header
#
####
'header' =&gt; &lt;&lt;'END_OF_FUNC',
sub header {
    my($self,@p) = self_or_default(@_);
    my(@header);

    return undef if $self-&gt;{'.header_printed'}++ and $HEADERS_ONCE;

    my($type,$status,$cookie,$target,$expires,$nph,@other) = 
	$self-&gt;rearrange([['TYPE','CONTENT_TYPE','CONTENT-TYPE'],
			  STATUS,[COOKIE,COOKIES],TARGET,EXPIRES,NPH],@p);

    $nph ||= $NPH;
    # rearrange() was designed for the HTML portion, so we
    # need to fix it up a little.
    foreach (@other) {
        next unless my($header,$value) = /([^\s=]+)=\"?(.+?)\"?$/;
	($_ = $header) =~ s/^(\w)(.*)/$1 . lc ($2) . ": $value"/e;
    }

    $type ||= 'text/html' unless defined($type);

    # Maybe future compatibility.  Maybe not.
    my $protocol = $ENV{SERVER_PROTOCOL} || 'HTTP/1.0';
    push(@header,$protocol . ' ' . ($status || '200 OK')) if $nph;

    push(@header,"Status: $status") if $status;
    push(@header,"Window-Target: $target") if $target;
    # push all the cookies -- there may be several
    if ($cookie) {
	my(@cookie) = ref($cookie) &amp;&amp; ref($cookie) eq 'ARRAY' ? @{$cookie} : $cookie;
	foreach (@cookie) {
            my $cs = UNIVERSAL::isa($_,'CGI::Cookie') ? $_-&gt;as_string : $_;
	    push(@header,"Set-Cookie: $cs") if $cs ne '';
	}
    }
    # if the user indicates an expiration time, then we need
    # both an Expires and a Date header (so that the browser is
    # uses OUR clock)
    push(@header,"Expires: " . expires($expires,'http'))
	if $expires;
    push(@header,"Date: " . expires(0,'http')) if $expires || $cookie;
    push(@header,"Pragma: no-cache") if $self-&gt;cache();
    push(@header,@other);
    push(@header,"Content-Type: $type") if $type ne '';

    my $header = join($CRLF,@header)."${CRLF}${CRLF}";
    if ($MOD_PERL and not $nph) {
	my $r = Apache-&gt;request;
	$r-&gt;send_cgi_header($header);
	return '';
    }
    return $header;
}
END_OF_FUNC


#### Method: cache
# Control whether header() will produce the no-cache
# Pragma directive.
####
'cache' =&gt; &lt;&lt;'END_OF_FUNC',
sub cache {
    my($self,$new_value) = self_or_default(@_);
    $new_value = '' unless $new_value;
    if ($new_value ne '') {
	$self-&gt;{'cache'} = $new_value;
    }
    return $self-&gt;{'cache'};
}
END_OF_FUNC


#### Method: redirect
# Return a Location: style header
#
####
'redirect' =&gt; &lt;&lt;'END_OF_FUNC',
sub redirect {
    my($self,@p) = self_or_default(@_);
    my($url,$target,$cookie,$nph,@other) = $self-&gt;rearrange([[LOCATION,URI,URL],TARGET,COOKIE,NPH],@p);
    $url = $url || $self-&gt;self_url;
    my(@o);
    foreach (@other) { tr/\"//d; push(@o,split("=",$_,2)); }
    unshift(@o,
	 '-Status'=&gt;'302 Moved',
	 '-Location'=&gt;$url,
	 '-nph'=&gt;$nph);
    unshift(@o,'-Target'=&gt;$target) if $target;
    unshift(@o,'-Cookie'=&gt;$cookie) if $cookie;
    unshift(@o,'-Type'=&gt;'');
    return $self-&gt;header(@o);
}
END_OF_FUNC


#### Method: start_html
# Canned HTML header
#
# Parameters:
# $title -&gt; (optional) The title for this HTML document (-title)
# $author -&gt; (optional) e-mail address of the author (-author)
# $base -&gt; (optional) if set to true, will enter the BASE address of this document
#          for resolving relative references (-base) 
# $xbase -&gt; (optional) alternative base at some remote location (-xbase)
# $target -&gt; (optional) target window to load all links into (-target)
# $script -&gt; (option) Javascript code (-script)
# $no_script -&gt; (option) Javascript &lt;noscript&gt; tag (-noscript)
# $meta -&gt; (optional) Meta information tags
# $head -&gt; (optional) any other elements you'd like to incorporate into the &lt;HEAD&gt; tag
#           (a scalar or array ref)
# $style -&gt; (optional) reference to an external style sheet
# @other -&gt; (optional) any other named parameters you'd like to incorporate into
#           the &lt;BODY&gt; tag.
####
'start_html' =&gt; &lt;&lt;'END_OF_FUNC',
sub start_html {
    my($self,@p) = &amp;self_or_default(@_);
    my($title,$author,$base,$xbase,$script,$noscript,$target,$meta,$head,$style,$dtd,@other) = 
	$self-&gt;rearrange([TITLE,AUTHOR,BASE,XBASE,SCRIPT,NOSCRIPT,TARGET,META,HEAD,STYLE,DTD],@p);

    # strangely enough, the title needs to be escaped as HTML
    # while the author needs to be escaped as a URL
    $title = $self-&gt;escapeHTML($title || 'Untitled Document');
    $author = $self-&gt;escape($author);
    my(@result);
    $dtd = $DEFAULT_DTD unless $dtd &amp;&amp; $dtd =~ m|^-//|;
    push(@result,qq(&lt;!DOCTYPE HTML PUBLIC "$dtd"&gt;)) if $dtd;
    push(@result,"&lt;HTML&gt;&lt;HEAD&gt;&lt;TITLE&gt;$title&lt;/TITLE&gt;");
    push(@result,"&lt;LINK REV=MADE HREF=\"mailto:$author\"&gt;") if defined $author;

    if ($base || $xbase || $target) {
	my $href = $xbase || $self-&gt;url('-path'=&gt;1);
	my $t = $target ? qq/ TARGET="$target"/ : '';
	push(@result,qq/&lt;BASE HREF="$href"$t&gt;/);
    }

    if ($meta &amp;&amp; ref($meta) &amp;&amp; (ref($meta) eq 'HASH')) {
	foreach (keys %$meta) { push(@result,qq(&lt;META NAME="$_" CONTENT="$meta-&gt;{$_}"&gt;)); }
    }

    push(@result,ref($head) ? @$head : $head) if $head;

    # handle the infrequently-used -style and -script parameters
    push(@result,$self-&gt;_style($style)) if defined $style;
    push(@result,$self-&gt;_script($script)) if defined $script;

    # handle -noscript parameter
    push(@result,&lt;&lt;END) if $noscript;
&lt;NOSCRIPT&gt;
$noscript
&lt;/NOSCRIPT&gt;
END
    ;
    my($other) = @other ? " @other" : '';
    push(@result,"&lt;/HEAD&gt;&lt;BODY$other&gt;");
    return join("\n",@result);
}
END_OF_FUNC

### Method: _style
# internal method for generating a CSS style section
####
'_style' =&gt; &lt;&lt;'END_OF_FUNC',
sub _style {
    my ($self,$style) = @_;
    my (@result);
    my $type = 'text/css';
    if (ref($style)) {
	my($src,$code,$stype,@other) =
	    $self-&gt;rearrange([SRC,CODE,TYPE],
			     '-foo'=&gt;'bar',	# a trick to allow the '-' to be omitted
			     ref($style) eq 'ARRAY' ? @$style : %$style);
	$type = $stype if $stype;
	push(@result,qq/&lt;LINK REL="stylesheet" HREF="$src"&gt;/) if $src;
	push(@result,style({'type'=&gt;$type},"&lt;!--\n$code\n--&gt;")) if $code;
    } else {
	push(@result,style({'type'=&gt;$type},"&lt;!--\n$style\n--&gt;"));
    }
    @result;
}
END_OF_FUNC


'_script' =&gt; &lt;&lt;'END_OF_FUNC',
sub _script {
    my ($self,$script) = @_;
    my (@result);
    my (@scripts) = ref($script) eq 'ARRAY' ? @$script : ($script);
    foreach $script (@scripts) {
	my($src,$code,$language);
	if (ref($script)) { # script is a hash
	    ($src,$code,$language) =
		$self-&gt;rearrange([SRC,CODE,LANGUAGE],
				 '-foo'=&gt;'bar',	# a trick to allow the '-' to be omitted
				 ref($style) eq 'ARRAY' ? @$script : %$script);
	    
	} else {
	    ($src,$code,$language) = ('',$script,'JavaScript');
	}
	my(@satts);
	push(@satts,'src'=&gt;$src) if $src;
	push(@satts,'language'=&gt;$language || 'JavaScript');
	$code = "&lt;!-- Hide script\n$code\n// End script hiding --&gt;"
	    if $code &amp;&amp; $language=~/javascript/i;
	$code = "&lt;!-- Hide script\n$code\n\# End script hiding --&gt;"
	    if $code &amp;&amp; $language=~/perl/i;
	push(@result,script({@satts},$code));
    }
    @result;
}
END_OF_FUNC

#### Method: end_html
# End an HTML document.
# Trivial method for completeness.  Just returns "&lt;/BODY&gt;"
####
'end_html' =&gt; &lt;&lt;'END_OF_FUNC',
sub end_html {
    return "&lt;/BODY&gt;&lt;/HTML&gt;";
}
END_OF_FUNC


################################
# METHODS USED IN BUILDING FORMS
################################

#### Method: isindex
# Just prints out the isindex tag.
# Parameters:
#  $action -&gt; optional URL of script to run
# Returns:
#   A string containing a &lt;ISINDEX&gt; tag
'isindex' =&gt; &lt;&lt;'END_OF_FUNC',
sub isindex {
    my($self,@p) = self_or_default(@_);
    my($action,@other) = $self-&gt;rearrange([ACTION],@p);
    $action = qq/ACTION="$action"/ if $action;
    my($other) = @other ? " @other" : '';
    return "&lt;ISINDEX $action$other&gt;";
}
END_OF_FUNC


#### Method: startform
# Start a form
# Parameters:
#   $method -&gt; optional submission method to use (GET or POST)
#   $action -&gt; optional URL of script to run
#   $enctype -&gt;encoding to use (URL_ENCODED or MULTIPART)
'startform' =&gt; &lt;&lt;'END_OF_FUNC',
sub startform {
    my($self,@p) = self_or_default(@_);

    my($method,$action,$enctype,@other) = 
	$self-&gt;rearrange([METHOD,ACTION,ENCTYPE],@p);

    $method = $method || 'POST';
    $enctype = $enctype || &amp;URL_ENCODED;
    $action = $action ? qq/ACTION="$action"/ : $method eq 'GET' ?
	'ACTION="'.$self-&gt;script_name.'"' : '';
    my($other) = @other ? " @other" : '';
    $self-&gt;{'.parametersToAdd'}={};
    return qq/&lt;FORM METHOD="$method" $action ENCTYPE="$enctype"$other&gt;\n/;
}
END_OF_FUNC


#### Method: start_form
# synonym for startform
'start_form' =&gt; &lt;&lt;'END_OF_FUNC',
sub start_form {
    &amp;startform;
}
END_OF_FUNC

'end_multipart_form' =&gt; &lt;&lt;'END_OF_FUNC',
sub end_multipart_form {
    &amp;endform;
}
END_OF_FUNC

#### Method: start_multipart_form
# synonym for startform
'start_multipart_form' =&gt; &lt;&lt;'END_OF_FUNC',
sub start_multipart_form {
    my($self,@p) = self_or_default(@_);
    if ($self-&gt;use_named_parameters || 
	(defined($param[0]) &amp;&amp; substr($param[0],0,1) eq '-')) {
	my(%p) = @p;
	$p{'-enctype'}=&amp;MULTIPART;
	return $self-&gt;startform(%p);
    } else {
	my($method,$action,@other) = 
	    $self-&gt;rearrange([METHOD,ACTION],@p);
	return $self-&gt;startform($method,$action,&amp;MULTIPART,@other);
    }
}
END_OF_FUNC


#### Method: endform
# End a form
'endform' =&gt; &lt;&lt;'END_OF_FUNC',
sub endform {
    my($self,@p) = self_or_default(@_);    
    return ($self-&gt;get_fields,"&lt;/FORM&gt;");
}
END_OF_FUNC


#### Method: end_form
# synonym for endform
'end_form' =&gt; &lt;&lt;'END_OF_FUNC',
sub end_form {
    &amp;endform;
}
END_OF_FUNC


'_textfield' =&gt; &lt;&lt;'END_OF_FUNC',
sub _textfield {
    my($self,$tag,@p) = self_or_default(@_);
    my($name,$default,$size,$maxlength,$override,@other) = 
	$self-&gt;rearrange([NAME,[DEFAULT,VALUE],SIZE,MAXLENGTH,[OVERRIDE,FORCE]],@p);

    my $current = $override ? $default : 
	(defined($self-&gt;param($name)) ? $self-&gt;param($name) : $default);

    $current = defined($current) ? $self-&gt;escapeHTML($current) : '';
    $name = defined($name) ? $self-&gt;escapeHTML($name) : '';
    my($s) = defined($size) ? qq/ SIZE=$size/ : '';
    my($m) = defined($maxlength) ? qq/ MAXLENGTH=$maxlength/ : '';
    my($other) = @other ? " @other" : '';
    # this entered at cristy's request to fix problems with file upload fields
    # and WebTV -- not sure it won't break stuff
    my($value) = $current ne '' ? qq(VALUE="$current") : '';
    return qq/&lt;INPUT TYPE="$tag" NAME="$name" $value$s$m$other&gt;/;
}
END_OF_FUNC

#### Method: textfield
# Parameters:
#   $name -&gt; Name of the text field
#   $default -&gt; Optional default value of the field if not
#                already defined.
#   $size -&gt;  Optional width of field in characaters.
#   $maxlength -&gt; Optional maximum number of characters.
# Returns:
#   A string containing a &lt;INPUT TYPE="text"&gt; field
#
'textfield' =&gt; &lt;&lt;'END_OF_FUNC',
sub textfield {
    my($self,@p) = self_or_default(@_);
    $self-&gt;_textfield('text',@p);
}
END_OF_FUNC


#### Method: filefield
# Parameters:
#   $name -&gt; Name of the file upload field
#   $size -&gt;  Optional width of field in characaters.
#   $maxlength -&gt; Optional maximum number of characters.
# Returns:
#   A string containing a &lt;INPUT TYPE="text"&gt; field
#
'filefield' =&gt; &lt;&lt;'END_OF_FUNC',
sub filefield {
    my($self,@p) = self_or_default(@_);
    $self-&gt;_textfield('file',@p);
}
END_OF_FUNC


#### Method: password
# Create a "secret password" entry field
# Parameters:
#   $name -&gt; Name of the field
#   $default -&gt; Optional default value of the field if not
#                already defined.
#   $size -&gt;  Optional width of field in characters.
#   $maxlength -&gt; Optional maximum characters that can be entered.
# Returns:
#   A string containing a &lt;INPUT TYPE="password"&gt; field
#
'password_field' =&gt; &lt;&lt;'END_OF_FUNC',
sub password_field {
    my ($self,@p) = self_or_default(@_);
    $self-&gt;_textfield('password',@p);
}
END_OF_FUNC

#### Method: textarea
# Parameters:
#   $name -&gt; Name of the text field
#   $default -&gt; Optional default value of the field if not
#                already defined.
#   $rows -&gt;  Optional number of rows in text area
#   $columns -&gt; Optional number of columns in text area
# Returns:
#   A string containing a &lt;TEXTAREA&gt;&lt;/TEXTAREA&gt; tag
#
'textarea' =&gt; &lt;&lt;'END_OF_FUNC',
sub textarea {
    my($self,@p) = self_or_default(@_);
    
    my($name,$default,$rows,$cols,$override,@other) =
	$self-&gt;rearrange([NAME,[DEFAULT,VALUE],ROWS,[COLS,COLUMNS],[OVERRIDE,FORCE]],@p);

    my($current)= $override ? $default :
	(defined($self-&gt;param($name)) ? $self-&gt;param($name) : $default);

    $name = defined($name) ? $self-&gt;escapeHTML($name) : '';
    $current = defined($current) ? $self-&gt;escapeHTML($current) : '';
    my($r) = $rows ? " ROWS=$rows" : '';
    my($c) = $cols ? " COLS=$cols" : '';
    my($other) = @other ? " @other" : '';
    return qq{&lt;TEXTAREA NAME="$name"$r$c$other&gt;$current&lt;/TEXTAREA&gt;};
}
END_OF_FUNC


#### Method: button
# Create a javascript button.
# Parameters:
#   $name -&gt;  (optional) Name for the button. (-name)
#   $value -&gt; (optional) Value of the button when selected (and visible name) (-value)
#   $onclick -&gt; (optional) Text of the JavaScript to run when the button is
#                clicked.
# Returns:
#   A string containing a &lt;INPUT TYPE="button"&gt; tag
####
'button' =&gt; &lt;&lt;'END_OF_FUNC',
sub button {
    my($self,@p) = self_or_default(@_);

    my($label,$value,$script,@other) = $self-&gt;rearrange([NAME,[VALUE,LABEL],
							 [ONCLICK,SCRIPT]],@p);

    $label=$self-&gt;escapeHTML($label);
    $value=$self-&gt;escapeHTML($value);
    $script=$self-&gt;escapeHTML($script);

    my($name) = '';
    $name = qq/ NAME="$label"/ if $label;
    $value = $value || $label;
    my($val) = '';
    $val = qq/ VALUE="$value"/ if $value;
    $script = qq/ ONCLICK="$script"/ if $script;
    my($other) = @other ? " @other" : '';
    return qq/&lt;INPUT TYPE="button"$name$val$script$other&gt;/;
}
END_OF_FUNC


#### Method: submit
# Create a "submit query" button.
# Parameters:
#   $name -&gt;  (optional) Name for the button.
#   $value -&gt; (optional) Value of the button when selected (also doubles as label).
#   $label -&gt; (optional) Label printed on the button(also doubles as the value).
# Returns:
#   A string containing a &lt;INPUT TYPE="submit"&gt; tag
####
'submit' =&gt; &lt;&lt;'END_OF_FUNC',
sub submit {
    my($self,@p) = self_or_default(@_);

    my($label,$value,@other) = $self-&gt;rearrange([NAME,[VALUE,LABEL]],@p);

    $label=$self-&gt;escapeHTML($label);
    $value=$self-&gt;escapeHTML($value);

    my($name) = ' NAME=".submit"';
    $name = qq/ NAME="$label"/ if defined($label);
    $value = defined($value) ? $value : $label;
    my($val) = '';
    $val = qq/ VALUE="$value"/ if defined($value);
    my($other) = @other ? " @other" : '';
    return qq/&lt;INPUT TYPE="submit"$name$val$other&gt;/;
}
END_OF_FUNC


#### Method: reset
# Create a "reset" button.
# Parameters:
#   $name -&gt; (optional) Name for the button.
# Returns:
#   A string containing a &lt;INPUT TYPE="reset"&gt; tag
####
'reset' =&gt; &lt;&lt;'END_OF_FUNC',
sub reset {
    my($self,@p) = self_or_default(@_);
    my($label,@other) = $self-&gt;rearrange([NAME],@p);
    $label=$self-&gt;escapeHTML($label);
    my($value) = defined($label) ? qq/ VALUE="$label"/ : '';
    my($other) = @other ? " @other" : '';
    return qq/&lt;INPUT TYPE="reset"$value$other&gt;/;
}
END_OF_FUNC


#### Method: defaults
# Create a "defaults" button.
# Parameters:
#   $name -&gt; (optional) Name for the button.
# Returns:
#   A string containing a &lt;INPUT TYPE="submit" NAME=".defaults"&gt; tag
#
# Note: this button has a special meaning to the initialization script,
# and tells it to ERASE the current query string so that your defaults
# are used again!
####
'defaults' =&gt; &lt;&lt;'END_OF_FUNC',
sub defaults {
    my($self,@p) = self_or_default(@_);

    my($label,@other) = $self-&gt;rearrange([[NAME,VALUE]],@p);

    $label=$self-&gt;escapeHTML($label);
    $label = $label || "Defaults";
    my($value) = qq/ VALUE="$label"/;
    my($other) = @other ? " @other" : '';
    return qq/&lt;INPUT TYPE="submit" NAME=".defaults"$value$other&gt;/;
}
END_OF_FUNC


#### Method: comment
# Create an HTML &lt;!-- comment --&gt;
# Parameters: a string
'comment' =&gt; &lt;&lt;'END_OF_FUNC',
sub comment {
    my($self,@p) = self_or_CGI(@_);
    return "&lt;!-- @p --&gt;";
}
END_OF_FUNC

#### Method: checkbox
# Create a checkbox that is not logically linked to any others.
# The field value is "on" when the button is checked.
# Parameters:
#   $name -&gt; Name of the checkbox
#   $checked -&gt; (optional) turned on by default if true
#   $value -&gt; (optional) value of the checkbox, 'on' by default
#   $label -&gt; (optional) a user-readable label printed next to the box.
#             Otherwise the checkbox name is used.
# Returns:
#   A string containing a &lt;INPUT TYPE="checkbox"&gt; field
####
'checkbox' =&gt; &lt;&lt;'END_OF_FUNC',
sub checkbox {
    my($self,@p) = self_or_default(@_);

    my($name,$checked,$value,$label,$override,@other) = 
	$self-&gt;rearrange([NAME,[CHECKED,SELECTED,ON],VALUE,LABEL,[OVERRIDE,FORCE]],@p);
    
    $value = defined $value ? $value : 'on';

    if (!$override &amp;&amp; ($self-&gt;{'.fieldnames'}-&gt;{$name} || 
		       defined $self-&gt;param($name))) {
	$checked = grep($_ eq $value,$self-&gt;param($name)) ? ' CHECKED' : '';
    } else {
	$checked = $checked ? ' CHECKED' : '';
    }
    my($the_label) = defined $label ? $label : $name;
    $name = $self-&gt;escapeHTML($name);
    $value = $self-&gt;escapeHTML($value);
    $the_label = $self-&gt;escapeHTML($the_label);
    my($other) = @other ? " @other" : '';
    $self-&gt;register_parameter($name);
    return &lt;&lt;END;
&lt;INPUT TYPE="checkbox" NAME="$name" VALUE="$value"$checked$other&gt;$the_label
END
}
END_OF_FUNC


#### Method: checkbox_group
# Create a list of logically-linked checkboxes.
# Parameters:
#   $name -&gt; Common name for all the check boxes
#   $values -&gt; A pointer to a regular array containing the
#             values for each checkbox in the group.
#   $defaults -&gt; (optional)
#             1. If a pointer to a regular array of checkbox values,
#             then this will be used to decide which
#             checkboxes to turn on by default.
#             2. If a scalar, will be assumed to hold the
#             value of a single checkbox in the group to turn on. 
#   $linebreak -&gt; (optional) Set to true to place linebreaks
#             between the buttons.
#   $labels -&gt; (optional)
#             A pointer to an associative array of labels to print next to each checkbox
#             in the form $label{'value'}="Long explanatory label".
#             Otherwise the provided values are used as the labels.
# Returns:
#   An ARRAY containing a series of &lt;INPUT TYPE="checkbox"&gt; fields
####
'checkbox_group' =&gt; &lt;&lt;'END_OF_FUNC',
sub checkbox_group {
    my($self,@p) = self_or_default(@_);

    my($name,$values,$defaults,$linebreak,$labels,$rows,$columns,
       $rowheaders,$colheaders,$override,$nolabels,@other) =
	$self-&gt;rearrange([NAME,[VALUES,VALUE],[DEFAULTS,DEFAULT],
			  LINEBREAK,LABELS,ROWS,[COLUMNS,COLS],
			  ROWHEADERS,COLHEADERS,
			  [OVERRIDE,FORCE],NOLABELS],@p);

    my($checked,$break,$result,$label);

    my(%checked) = $self-&gt;previous_or_default($name,$defaults,$override);

    $break = $linebreak ? "&lt;BR&gt;" : '';
    $name=$self-&gt;escapeHTML($name);

    # Create the elements
    my(@elements,@values);

    @values = $self-&gt;_set_values_and_labels($values,\$labels,$name);

    my($other) = @other ? " @other" : '';
    foreach (@values) {
	$checked = $checked{$_} ? ' CHECKED' : '';
	$label = '';
	unless (defined($nolabels) &amp;&amp; $nolabels) {
	    $label = $_;
	    $label = $labels-&gt;{$_} if defined($labels) &amp;&amp; defined($labels-&gt;{$_});
	    $label = $self-&gt;escapeHTML($label);
	}
	$_ = $self-&gt;escapeHTML($_);
	push(@elements,qq/&lt;INPUT TYPE="checkbox" NAME="$name" VALUE="$_"$checked$other&gt;${label}${break}/);
    }
    $self-&gt;register_parameter($name);
    return wantarray ? @elements : join(' ',@elements)            
        unless defined($columns) || defined($rows);
    return _tableize($rows,$columns,$rowheaders,$colheaders,@elements);
}
END_OF_FUNC

# Escape HTML -- used internally
'escapeHTML' =&gt; &lt;&lt;'END_OF_FUNC',
sub escapeHTML {
    my($self,$toencode) = @_;
    $toencode = $self unless ref($self);
    return undef unless defined($toencode);
    return $toencode if ref($self) &amp;&amp; $self-&gt;{'dontescape'};

    $toencode=~s/&amp;/&amp;amp;/g;
    $toencode=~s/\"/&amp;quot;/g;
    $toencode=~s/&gt;/&amp;gt;/g;
    $toencode=~s/&lt;/&amp;lt;/g;
    return $toencode;
}
END_OF_FUNC

# unescape HTML -- used internally
'unescapeHTML' =&gt; &lt;&lt;'END_OF_FUNC',
sub unescapeHTML {
    my $string = ref($_[0]) ? $_[1] : $_[0];
    return undef unless defined($string);
    # thanks to Randal Schwartz for the correct solution to this one
    $string=~ s[&amp;(.*?);]{
	local $_ = $1;
	/^amp$/i	? "&amp;" :
	/^quot$/i	? '"' :
        /^gt$/i		? "&gt;" :
	/^lt$/i		? "&lt;" :
	/^#(\d+)$/	? chr($1) :
	/^#x([0-9a-f]+)$/i ? chr(hex($1)) :
	$_
	}gex;
    return $string;
}
END_OF_FUNC

# Internal procedure - don't use
'_tableize' =&gt; &lt;&lt;'END_OF_FUNC',
sub _tableize {
    my($rows,$columns,$rowheaders,$colheaders,@elements) = @_;
    my($result);

    if (defined($columns)) {
	$rows = int(0.99 + @elements/$columns) unless defined($rows);
    }
    if (defined($rows)) {
	$columns = int(0.99 + @elements/$rows) unless defined($columns);
    }
    
    # rearrange into a pretty table
    $result = "&lt;TABLE&gt;";
    my($row,$column);
    unshift(@$colheaders,'') if defined(@$colheaders) &amp;&amp; defined(@$rowheaders);
    $result .= "&lt;TR&gt;" if defined(@{$colheaders});
    foreach (@{$colheaders}) {
	$result .= "&lt;TH&gt;$_&lt;/TH&gt;";
    }
    for ($row=0;$row&lt;$rows;$row++) {
	$result .= "&lt;TR&gt;";
	$result .= "&lt;TH&gt;$rowheaders-&gt;[$row]&lt;/TH&gt;" if defined(@$rowheaders);
	for ($column=0;$column&lt;$columns;$column++) {
	    $result .= "&lt;TD&gt;" . $elements[$column*$rows + $row] . "&lt;/TD&gt;"
		if defined($elements[$column*$rows + $row]);
	}
	$result .= "&lt;/TR&gt;";
    }
    $result .= "&lt;/TABLE&gt;";
    return $result;
}
END_OF_FUNC


#### Method: radio_group
# Create a list of logically-linked radio buttons.
# Parameters:
#   $name -&gt; Common name for all the buttons.
#   $values -&gt; A pointer to a regular array containing the
#             values for each button in the group.
#   $default -&gt; (optional) Value of the button to turn on by default.  Pass '-'
#               to turn _nothing_ on.
#   $linebreak -&gt; (optional) Set to true to place linebreaks
#             between the buttons.
#   $labels -&gt; (optional)
#             A pointer to an associative array of labels to print next to each checkbox
#             in the form $label{'value'}="Long explanatory label".
#             Otherwise the provided values are used as the labels.
# Returns:
#   An ARRAY containing a series of &lt;INPUT TYPE="radio"&gt; fields
####
'radio_group' =&gt; &lt;&lt;'END_OF_FUNC',
sub radio_group {
    my($self,@p) = self_or_default(@_);

    my($name,$values,$default,$linebreak,$labels,
       $rows,$columns,$rowheaders,$colheaders,$override,$nolabels,@other) =
	$self-&gt;rearrange([NAME,[VALUES,VALUE],DEFAULT,LINEBREAK,LABELS,
			  ROWS,[COLUMNS,COLS],
			  ROWHEADERS,COLHEADERS,
			  [OVERRIDE,FORCE],NOLABELS],@p);
    my($result,$checked);

    if (!$override &amp;&amp; defined($self-&gt;param($name))) {
	$checked = $self-&gt;param($name);
    } else {
	$checked = $default;
    }
    my(@elements,@values);
    @values = $self-&gt;_set_values_and_labels($values,\$labels,$name);

    # If no check array is specified, check the first by default
    $checked = $values[0] unless defined($checked) &amp;&amp; $checked ne '';
    $name=$self-&gt;escapeHTML($name);

    my($other) = @other ? " @other" : '';
    foreach (@values) {
	my($checkit) = $checked eq $_ ? ' CHECKED' : '';
	my($break) = $linebreak ? '&lt;BR&gt;' : '';
	my($label)='';
	unless (defined($nolabels) &amp;&amp; $nolabels) {
	    $label = $_;
	    $label = $labels-&gt;{$_} if defined($labels) &amp;&amp; defined($labels-&gt;{$_});
	    $label = $self-&gt;escapeHTML($label);
	}
	$_=$self-&gt;escapeHTML($_);
	push(@elements,qq/&lt;INPUT TYPE="radio" NAME="$name" VALUE="$_"$checkit$other&gt;${label}${break}/);
    }
    $self-&gt;register_parameter($name);
    return wantarray ? @elements : join(' ',@elements) 
           unless defined($columns) || defined($rows);
    return _tableize($rows,$columns,$rowheaders,$colheaders,@elements);
}
END_OF_FUNC


#### Method: popup_menu
# Create a popup menu.
# Parameters:
#   $name -&gt; Name for all the menu
#   $values -&gt; A pointer to a regular array containing the
#             text of each menu item.
#   $default -&gt; (optional) Default item to display
#   $labels -&gt; (optional)
#             A pointer to an associative array of labels to print next to each checkbox
#             in the form $label{'value'}="Long explanatory label".
#             Otherwise the provided values are used as the labels.
# Returns:
#   A string containing the definition of a popup menu.
####
'popup_menu' =&gt; &lt;&lt;'END_OF_FUNC',
sub popup_menu {
    my($self,@p) = self_or_default(@_);

    my($name,$values,$default,$labels,$override,@other) =
	$self-&gt;rearrange([NAME,[VALUES,VALUE],[DEFAULT,DEFAULTS],LABELS,[OVERRIDE,FORCE]],@p);
    my($result,$selected);

    if (!$override &amp;&amp; defined($self-&gt;param($name))) {
	$selected = $self-&gt;param($name);
    } else {
	$selected = $default;
    }
    $name=$self-&gt;escapeHTML($name);
    my($other) = @other ? " @other" : '';

    my(@values);
    @values = $self-&gt;_set_values_and_labels($values,\$labels,$name);

    $result = qq/&lt;SELECT NAME="$name"$other&gt;\n/;
    foreach (@values) {
	my($selectit) = defined($selected) ? ($selected eq $_ ? 'SELECTED' : '' ) : '';
	my($label) = $_;
	$label = $labels-&gt;{$_} if defined($labels) &amp;&amp; defined($labels-&gt;{$_});
	my($value) = $self-&gt;escapeHTML($_);
	$label=$self-&gt;escapeHTML($label);
	$result .= "&lt;OPTION $selectit VALUE=\"$value\"&gt;$label\n";
    }

    $result .= "&lt;/SELECT&gt;\n";
    return $result;
}
END_OF_FUNC


#### Method: scrolling_list
# Create a scrolling list.
# Parameters:
#   $name -&gt; name for the list
#   $values -&gt; A pointer to a regular array containing the
#             values for each option line in the list.
#   $defaults -&gt; (optional)
#             1. If a pointer to a regular array of options,
#             then this will be used to decide which
#             lines to turn on by default.
#             2. Otherwise holds the value of the single line to turn on.
#   $size -&gt; (optional) Size of the list.
#   $multiple -&gt; (optional) If set, allow multiple selections.
#   $labels -&gt; (optional)
#             A pointer to an associative array of labels to print next to each checkbox
#             in the form $label{'value'}="Long explanatory label".
#             Otherwise the provided values are used as the labels.
# Returns:
#   A string containing the definition of a scrolling list.
####
'scrolling_list' =&gt; &lt;&lt;'END_OF_FUNC',
sub scrolling_list {
    my($self,@p) = self_or_default(@_);
    my($name,$values,$defaults,$size,$multiple,$labels,$override,@other)
	= $self-&gt;rearrange([NAME,[VALUES,VALUE],[DEFAULTS,DEFAULT],
			    SIZE,MULTIPLE,LABELS,[OVERRIDE,FORCE]],@p);

    my($result,@values);
    @values = $self-&gt;_set_values_and_labels($values,\$labels,$name);

    $size = $size || scalar(@values);

    my(%selected) = $self-&gt;previous_or_default($name,$defaults,$override);
    my($is_multiple) = $multiple ? ' MULTIPLE' : '';
    my($has_size) = $size ? " SIZE=$size" : '';
    my($other) = @other ? " @other" : '';

    $name=$self-&gt;escapeHTML($name);
    $result = qq/&lt;SELECT NAME="$name"$has_size$is_multiple$other&gt;\n/;
    foreach (@values) {
	my($selectit) = $selected{$_} ? 'SELECTED' : '';
	my($label) = $_;
	$label = $labels-&gt;{$_} if defined($labels) &amp;&amp; defined($labels-&gt;{$_});
	$label=$self-&gt;escapeHTML($label);
	my($value)=$self-&gt;escapeHTML($_);
	$result .= "&lt;OPTION $selectit VALUE=\"$value\"&gt;$label\n";
    }
    $result .= "&lt;/SELECT&gt;\n";
    $self-&gt;register_parameter($name);
    return $result;
}
END_OF_FUNC


#### Method: hidden
# Parameters:
#   $name -&gt; Name of the hidden field
#   @default -&gt; (optional) Initial values of field (may be an array)
#      or
#   $default-&gt;[initial values of field]
# Returns:
#   A string containing a &lt;INPUT TYPE="hidden" NAME="name" VALUE="value"&gt;
####
'hidden' =&gt; &lt;&lt;'END_OF_FUNC',
sub hidden {
    my($self,@p) = self_or_default(@_);

    # this is the one place where we departed from our standard
    # calling scheme, so we have to special-case (darn)
    my(@result,@value);
    my($name,$default,$override,@other) = 
	$self-&gt;rearrange([NAME,[DEFAULT,VALUE,VALUES],[OVERRIDE,FORCE]],@p);

    my $do_override = 0;
    if ( ref($p[0]) || substr($p[0],0,1) eq '-' || $self-&gt;use_named_parameters ) {
	@value = ref($default) ? @{$default} : $default;
	$do_override = $override;
    } else {
	foreach ($default,$override,@other) {
	    push(@value,$_) if defined($_);
	}
    }

    # use previous values if override is not set
    my @prev = $self-&gt;param($name);
    @value = @prev if !$do_override &amp;&amp; @prev;

    $name=$self-&gt;escapeHTML($name);
    foreach (@value) {
	$_=$self-&gt;escapeHTML($_);
	push(@result,qq/&lt;INPUT TYPE="hidden" NAME="$name" VALUE="$_"&gt;/);
    }
    return wantarray ? @result : join('',@result);
}
END_OF_FUNC


#### Method: image_button
# Parameters:
#   $name -&gt; Name of the button
#   $src -&gt;  URL of the image source
#   $align -&gt; Alignment style (TOP, BOTTOM or MIDDLE)
# Returns:
#   A string containing a &lt;INPUT TYPE="image" NAME="name" SRC="url" ALIGN="alignment"&gt;
####
'image_button' =&gt; &lt;&lt;'END_OF_FUNC',
sub image_button {
    my($self,@p) = self_or_default(@_);

    my($name,$src,$alignment,@other) =
	$self-&gt;rearrange([NAME,SRC,ALIGN],@p);

    my($align) = $alignment ? " ALIGN=\U$alignment" : '';
    my($other) = @other ? " @other" : '';
    $name=$self-&gt;escapeHTML($name);
    return qq/&lt;INPUT TYPE="image" NAME="$name" SRC="$src"$align$other&gt;/;
}
END_OF_FUNC


#### Method: self_url
# Returns a URL containing the current script and all its
# param/value pairs arranged as a query.  You can use this
# to create a link that, when selected, will reinvoke the
# script with all its state information preserved.
####
'self_url' =&gt; &lt;&lt;'END_OF_FUNC',
sub self_url {
    my($self,@p) = self_or_default(@_);
    return $self-&gt;url('-path_info'=&gt;1,'-query'=&gt;1,'-full'=&gt;1,@p);
}
END_OF_FUNC


# This is provided as a synonym to self_url() for people unfortunate
# enough to have incorporated it into their programs already!
'state' =&gt; &lt;&lt;'END_OF_FUNC',
sub state {
    &amp;self_url;
}
END_OF_FUNC


#### Method: url
# Like self_url, but doesn't return the query string part of
# the URL.
####
'url' =&gt; &lt;&lt;'END_OF_FUNC',
sub url {
    my($self,@p) = self_or_default(@_);
    my ($relative,$absolute,$full,$path_info,$query) = 
	$self-&gt;rearrange(['RELATIVE','ABSOLUTE','FULL',['PATH','PATH_INFO'],['QUERY','QUERY_STRING']],@p);
    my $url;
    $full++ if !($relative || $absolute);

    if ($full) {
	my $protocol = $self-&gt;protocol();
	$url = "$protocol://";
	my $vh = http('host');
	if ($vh) {
	    $url .= $vh;
	} else {
	    $url .= server_name();
	    my $port = $self-&gt;server_port;
	    $url .= ":" . $port
		unless (lc($protocol) eq 'http' &amp;&amp; $port == 80)
		    || (lc($protocol) eq 'https' &amp;&amp; $port == 443);
	}
	$url .= $self-&gt;script_name;
    } elsif ($relative) {
	($url) = $self-&gt;script_name =~ m!([^/]+)$!;
    } elsif ($absolute) {
	$url = $self-&gt;script_name;
    }
    $url .= $self-&gt;path_info if $path_info and $self-&gt;path_info;
    $url .= "?" . $self-&gt;query_string if $query and $self-&gt;query_string;
    return $url;
}

END_OF_FUNC

#### Method: cookie
# Set or read a cookie from the specified name.
# Cookie can then be passed to header().
# Usual rules apply to the stickiness of -value.
#  Parameters:
#   -name -&gt; name for this cookie (optional)
#   -value -&gt; value of this cookie (scalar, array or hash) 
#   -path -&gt; paths for which this cookie is valid (optional)
#   -domain -&gt; internet domain in which this cookie is valid (optional)
#   -secure -&gt; if true, cookie only passed through secure channel (optional)
#   -expires -&gt; expiry date in format Wdy, DD-Mon-YYYY HH:MM:SS GMT (optional)
####
'cookie' =&gt; &lt;&lt;'END_OF_FUNC',
sub cookie {
    my($self,@p) = self_or_default(@_);
    my($name,$value,$path,$domain,$secure,$expires) =
	$self-&gt;rearrange([NAME,[VALUE,VALUES],PATH,DOMAIN,SECURE,EXPIRES],@p);

    require CGI::Cookie;

    # if no value is supplied, then we retrieve the
    # value of the cookie, if any.  For efficiency, we cache the parsed
    # cookies in our state variables.
    unless ( defined($value) ) {
	$self-&gt;{'.cookies'} = CGI::Cookie-&gt;fetch
	    unless $self-&gt;{'.cookies'};

	# If no name is supplied, then retrieve the names of all our cookies.
	return () unless $self-&gt;{'.cookies'};
	return keys %{$self-&gt;{'.cookies'}} unless $name;
	return () unless $self-&gt;{'.cookies'}-&gt;{$name};
	return $self-&gt;{'.cookies'}-&gt;{$name}-&gt;value if defined($name) &amp;&amp; $name ne '';
    }

    # If we get here, we're creating a new cookie
    return undef unless $name;	# this is an error

    my @param;
    push(@param,'-name'=&gt;$name);
    push(@param,'-value'=&gt;$value);
    push(@param,'-domain'=&gt;$domain) if $domain;
    push(@param,'-path'=&gt;$path) if $path;
    push(@param,'-expires'=&gt;$expires) if $expires;
    push(@param,'-secure'=&gt;$secure) if $secure;

    return new CGI::Cookie(@param);
}
END_OF_FUNC

# This internal routine creates an expires time exactly some number of
# hours from the current time.  It incorporates modifications from 
# Mark Fisher.
'expire_calc' =&gt; &lt;&lt;'END_OF_FUNC',
sub expire_calc {
    my($time) = @_;
    my(%mult) = ('s'=&gt;1,
                 'm'=&gt;60,
                 'h'=&gt;60*60,
                 'd'=&gt;60*60*24,
                 'M'=&gt;60*60*24*30,
                 'y'=&gt;60*60*24*365);
    # format for time can be in any of the forms...
    # "now" -- expire immediately
    # "+180s" -- in 180 seconds
    # "+2m" -- in 2 minutes
    # "+12h" -- in 12 hours
    # "+1d"  -- in 1 day
    # "+3M"  -- in 3 months
    # "+2y"  -- in 2 years
    # "-3m"  -- 3 minutes ago(!)
    # If you don't supply one of these forms, we assume you are
    # specifying the date yourself
    my($offset);
    if (!$time || (lc($time) eq 'now')) {
        $offset = 0;
    } elsif ($time=~/^([+-]?(?:\d+|\d*\.\d*))([mhdMy]?)/) {
        $offset = ($mult{$2} || 1)*$1;
    } else {
        return $time;
    }
    return (time+$offset);
}
END_OF_FUNC

# This internal routine creates date strings suitable for use in
# cookies and HTTP headers.  (They differ, unfortunately.)
# Thanks to Fisher Mark for this.
'expires' =&gt; &lt;&lt;'END_OF_FUNC',
sub expires {
    my($time,$format) = @_;
    $format ||= 'http';

    my(@MON)=qw/Jan Feb Mar Apr May Jun Jul Aug Sep Oct Nov Dec/;
    my(@WDAY) = qw/Sun Mon Tue Wed Thu Fri Sat/;

    # pass through preformatted dates for the sake of expire_calc()
    $time = expire_calc($time);
    return $time unless $time =~ /^\d+$/;

    # make HTTP/cookie date string from GMT'ed time
    # (cookies use '-' as date separator, HTTP uses ' ')
    my($sc) = ' ';
    $sc = '-' if $format eq "cookie";
    my($sec,$min,$hour,$mday,$mon,$year,$wday) = gmtime($time);
    $year += 1900;
    return sprintf("%s, %02d$sc%s$sc%04d %02d:%02d:%02d GMT",
                   $WDAY[$wday],$mday,$MON[$mon],$year,$hour,$min,$sec);
}
END_OF_FUNC

'parse_keywordlist' =&gt; &lt;&lt;'END_OF_FUNC',
sub parse_keywordlist {
    my($self,$tosplit) = @_;
    $tosplit = unescape($tosplit); # unescape the keywords
    $tosplit=~tr/+/ /;          # pluses to spaces
    my(@keywords) = split(/\s+/,$tosplit);
    return @keywords;
}
END_OF_FUNC

'param_fetch' =&gt; &lt;&lt;'END_OF_FUNC',
sub param_fetch {
    my($self,@p) = self_or_default(@_);
    my($name) = $self-&gt;rearrange([NAME],@p);
    unless (exists($self-&gt;{$name})) {
	$self-&gt;add_parameter($name);
	$self-&gt;{$name} = [];
    }
    
    return $self-&gt;{$name};
}
END_OF_FUNC

###############################################
# OTHER INFORMATION PROVIDED BY THE ENVIRONMENT
###############################################

#### Method: path_info
# Return the extra virtual path information provided
# after the URL (if any)
####
'path_info' =&gt; &lt;&lt;'END_OF_FUNC',
sub path_info {
    my ($self,$info) = self_or_default(@_);
    if (defined($info)) {
	$info = "/$info" if $info ne '' &amp;&amp;  substr($info,0,1) ne '/';
	$self-&gt;{'.path_info'} = $info;
    } elsif (! defined($self-&gt;{'.path_info'}) ) {
	$self-&gt;{'.path_info'} = defined($ENV{'PATH_INFO'}) ? 
	    $ENV{'PATH_INFO'} : '';

	# hack to fix broken path info in IIS
	$self-&gt;{'.path_info'} =~ s/^\Q$ENV{'SCRIPT_NAME'}\E// if $IIS;

    }
    return $self-&gt;{'.path_info'};
}
END_OF_FUNC


#### Method: request_method
# Returns 'POST', 'GET', 'PUT' or 'HEAD'
####
'request_method' =&gt; &lt;&lt;'END_OF_FUNC',
sub request_method {
    return $ENV{'REQUEST_METHOD'};
}
END_OF_FUNC

#### Method: path_translated
# Return the physical path information provided
# by the URL (if any)
####
'path_translated' =&gt; &lt;&lt;'END_OF_FUNC',
sub path_translated {
    return $ENV{'PATH_TRANSLATED'};
}
END_OF_FUNC


#### Method: query_string
# Synthesize a query string from our current
# parameters
####
'query_string' =&gt; &lt;&lt;'END_OF_FUNC',
sub query_string {
    my($self) = self_or_default(@_);
    my($param,$value,@pairs);
    foreach $param ($self-&gt;param) {
	my($eparam) = escape($param);
	foreach $value ($self-&gt;param($param)) {
	    $value = escape($value);
	    push(@pairs,"$eparam=$value");
	}
    }
    return join($USE_PARAM_SEMICOLONS ? ';' : '&amp;',@pairs);
}
END_OF_FUNC


#### Method: accept
# Without parameters, returns an array of the
# MIME types the browser accepts.
# With a single parameter equal to a MIME
# type, will return undef if the browser won't
# accept it, 1 if the browser accepts it but
# doesn't give a preference, or a floating point
# value between 0.0 and 1.0 if the browser
# declares a quantitative score for it.
# This handles MIME type globs correctly.
####
'Accept' =&gt; &lt;&lt;'END_OF_FUNC',
sub Accept {
    my($self,$search) = self_or_CGI(@_);
    my(%prefs,$type,$pref,$pat);
    
    my(@accept) = split(',',$self-&gt;http('accept'));

    foreach (@accept) {
	($pref) = /q=(\d\.\d+|\d+)/;
	($type) = m#(\S+/[^;]+)#;
	next unless $type;
	$prefs{$type}=$pref || 1;
    }

    return keys %prefs unless $search;
    
    # if a search type is provided, we may need to
    # perform a pattern matching operation.
    # The MIME types use a glob mechanism, which
    # is easily translated into a perl pattern match

    # First return the preference for directly supported
    # types:
    return $prefs{$search} if $prefs{$search};

    # Didn't get it, so try pattern matching.
    foreach (keys %prefs) {
	next unless /\*/;       # not a pattern match
	($pat = $_) =~ s/([^\w*])/\\$1/g; # escape meta characters
	$pat =~ s/\*/.*/g; # turn it into a pattern
	return $prefs{$_} if $search=~/$pat/;
    }
}
END_OF_FUNC


#### Method: user_agent
# If called with no parameters, returns the user agent.
# If called with one parameter, does a pattern match (case
# insensitive) on the user agent.
####
'user_agent' =&gt; &lt;&lt;'END_OF_FUNC',
sub user_agent {
    my($self,$match)=self_or_CGI(@_);
    return $self-&gt;http('user_agent') unless $match;
    return $self-&gt;http('user_agent') =~ /$match/i;
}
END_OF_FUNC


#### Method: raw_cookie
# Returns the magic cookies for the session.
# The cookies are not parsed or altered in any way, i.e.
# cookies are returned exactly as given in the HTTP
# headers.  If a cookie name is given, only that cookie's
# value is returned, otherwise the entire raw cookie
# is returned.
####
'raw_cookie' =&gt; &lt;&lt;'END_OF_FUNC',
sub raw_cookie {
    my($self,$key) = self_or_CGI(@_);

    require CGI::Cookie;

    if (defined($key)) {
	$self-&gt;{'.raw_cookies'} = CGI::Cookie-&gt;raw_fetch
	    unless $self-&gt;{'.raw_cookies'};

	return () unless $self-&gt;{'.raw_cookies'};
	return () unless $self-&gt;{'.raw_cookies'}-&gt;{$key};
	return $self-&gt;{'.raw_cookies'}-&gt;{$key};
    }
    return $self-&gt;http('cookie') || $ENV{'COOKIE'} || '';
}
END_OF_FUNC

#### Method: virtual_host
# Return the name of the virtual_host, which
# is not always the same as the server
######
'virtual_host' =&gt; &lt;&lt;'END_OF_FUNC',
sub virtual_host {
    my $vh = http('host') || server_name();
    $vh =~ s/:\d+$//;		# get rid of port number
    return $vh;
}
END_OF_FUNC

#### Method: remote_host
# Return the name of the remote host, or its IP
# address if unavailable.  If this variable isn't
# defined, it returns "localhost" for debugging
# purposes.
####
'remote_host' =&gt; &lt;&lt;'END_OF_FUNC',
sub remote_host {
    return $ENV{'REMOTE_HOST'} || $ENV{'REMOTE_ADDR'} 
    || 'localhost';
}
END_OF_FUNC


#### Method: remote_addr
# Return the IP addr of the remote host.
####
'remote_addr' =&gt; &lt;&lt;'END_OF_FUNC',
sub remote_addr {
    return $ENV{'REMOTE_ADDR'} || '127.0.0.1';
}
END_OF_FUNC


#### Method: script_name
# Return the partial URL to this script for
# self-referencing scripts.  Also see
# self_url(), which returns a URL with all state information
# preserved.
####
'script_name' =&gt; &lt;&lt;'END_OF_FUNC',
sub script_name {
    return $ENV{'SCRIPT_NAME'} if defined($ENV{'SCRIPT_NAME'});
    # These are for debugging
    return "/$0" unless $0=~/^\//;
    return $0;
}
END_OF_FUNC


#### Method: referer
# Return the HTTP_REFERER: useful for generating
# a GO BACK button.
####
'referer' =&gt; &lt;&lt;'END_OF_FUNC',
sub referer {
    my($self) = self_or_CGI(@_);
    return $self-&gt;http('referer');
}
END_OF_FUNC


#### Method: server_name
# Return the name of the server
####
'server_name' =&gt; &lt;&lt;'END_OF_FUNC',
sub server_name {
    return $ENV{'SERVER_NAME'} || 'localhost';
}
END_OF_FUNC

#### Method: server_software
# Return the name of the server software
####
'server_software' =&gt; &lt;&lt;'END_OF_FUNC',
sub server_software {
    return $ENV{'SERVER_SOFTWARE'} || 'cmdline';
}
END_OF_FUNC

#### Method: server_port
# Return the tcp/ip port the server is running on
####
'server_port' =&gt; &lt;&lt;'END_OF_FUNC',
sub server_port {
    return $ENV{'SERVER_PORT'} || 80; # for debugging
}
END_OF_FUNC

#### Method: server_protocol
# Return the protocol (usually HTTP/1.0)
####
'server_protocol' =&gt; &lt;&lt;'END_OF_FUNC',
sub server_protocol {
    return $ENV{'SERVER_PROTOCOL'} || 'HTTP/1.0'; # for debugging
}
END_OF_FUNC

#### Method: http
# Return the value of an HTTP variable, or
# the list of variables if none provided
####
'http' =&gt; &lt;&lt;'END_OF_FUNC',
sub http {
    my ($self,$parameter) = self_or_CGI(@_);
    return $ENV{$parameter} if $parameter=~/^HTTP/;
    return $ENV{"HTTP_\U$parameter\E"} if $parameter;
    my(@p);
    foreach (keys %ENV) {
	push(@p,$_) if /^HTTP/;
    }
    return @p;
}
END_OF_FUNC

#### Method: https
# Return the value of HTTPS
####
'https' =&gt; &lt;&lt;'END_OF_FUNC',
sub https {
    local($^W)=0;
    my ($self,$parameter) = self_or_CGI(@_);
    return $ENV{HTTPS} unless $parameter;
    return $ENV{$parameter} if $parameter=~/^HTTPS/;
    return $ENV{"HTTPS_\U$parameter\E"} if $parameter;
    my(@p);
    foreach (keys %ENV) {
	push(@p,$_) if /^HTTPS/;
    }
    return @p;
}
END_OF_FUNC

#### Method: protocol
# Return the protocol (http or https currently)
####
'protocol' =&gt; &lt;&lt;'END_OF_FUNC',
sub protocol {
    local($^W)=0;
    my $self = shift;
    return 'https' if uc($self-&gt;https()) eq 'ON'; 
    return 'https' if $self-&gt;server_port == 443;
    my $prot = $self-&gt;server_protocol;
    my($protocol,$version) = split('/',$prot);
    return "\L$protocol\E";
}
END_OF_FUNC

#### Method: remote_ident
# Return the identity of the remote user
# (but only if his host is running identd)
####
'remote_ident' =&gt; &lt;&lt;'END_OF_FUNC',
sub remote_ident {
    return $ENV{'REMOTE_IDENT'};
}
END_OF_FUNC


#### Method: auth_type
# Return the type of use verification/authorization in use, if any.
####
'auth_type' =&gt; &lt;&lt;'END_OF_FUNC',
sub auth_type {
    return $ENV{'AUTH_TYPE'};
}
END_OF_FUNC


#### Method: remote_user
# Return the authorization name used for user
# verification.
####
'remote_user' =&gt; &lt;&lt;'END_OF_FUNC',
sub remote_user {
    return $ENV{'REMOTE_USER'};
}
END_OF_FUNC


#### Method: user_name
# Try to return the remote user's name by hook or by
# crook
####
'user_name' =&gt; &lt;&lt;'END_OF_FUNC',
sub user_name {
    my ($self) = self_or_CGI(@_);
    return $self-&gt;http('from') || $ENV{'REMOTE_IDENT'} || $ENV{'REMOTE_USER'};
}
END_OF_FUNC

#### Method: nph
# Set or return the NPH global flag
####
'nph' =&gt; &lt;&lt;'END_OF_FUNC',
sub nph {
    my ($self,$param) = self_or_CGI(@_);
    $CGI::NPH = $param if defined($param);
    return $CGI::NPH;
}
END_OF_FUNC

#### Method: private_tempfiles
# Set or return the private_tempfiles global flag
####
'private_tempfiles' =&gt; &lt;&lt;'END_OF_FUNC',
sub private_tempfiles {
    my ($self,$param) = self_or_CGI(@_);
    $CGI::PRIVATE_TEMPFILES = $param if defined($param);
    return $CGI::PRIVATE_TEMPFILES;
}
END_OF_FUNC

#### Method: default_dtd
# Set or return the default_dtd global
####
'default_dtd' =&gt; &lt;&lt;'END_OF_FUNC',
sub default_dtd {
    my ($self,$param) = self_or_CGI(@_);
    $CGI::DEFAULT_DTD = $param if defined($param);
    return $CGI::DEFAULT_DTD;
}
END_OF_FUNC

# -------------- really private subroutines -----------------
'previous_or_default' =&gt; &lt;&lt;'END_OF_FUNC',
sub previous_or_default {
    my($self,$name,$defaults,$override) = @_;
    my(%selected);

    if (!$override &amp;&amp; ($self-&gt;{'.fieldnames'}-&gt;{$name} || 
		       defined($self-&gt;param($name)) ) ) {
	grep($selected{$_}++,$self-&gt;param($name));
    } elsif (defined($defaults) &amp;&amp; ref($defaults) &amp;&amp; 
	     (ref($defaults) eq 'ARRAY')) {
	grep($selected{$_}++,@{$defaults});
    } else {
	$selected{$defaults}++ if defined($defaults);
    }

    return %selected;
}
END_OF_FUNC

'register_parameter' =&gt; &lt;&lt;'END_OF_FUNC',
sub register_parameter {
    my($self,$param) = @_;
    $self-&gt;{'.parametersToAdd'}-&gt;{$param}++;
}
END_OF_FUNC

'get_fields' =&gt; &lt;&lt;'END_OF_FUNC',
sub get_fields {
    my($self) = @_;
    return $self-&gt;CGI::hidden('-name'=&gt;'.cgifields',
			      '-values'=&gt;[keys %{$self-&gt;{'.parametersToAdd'}}],
			      '-override'=&gt;1);
}
END_OF_FUNC

'read_from_cmdline' =&gt; &lt;&lt;'END_OF_FUNC',
sub read_from_cmdline {
    my($input,@words);
    my($query_string);
    if (@ARGV) {
	@words = @ARGV;
    } else {
	require "shellwords.pl";
	print STDERR "(offline mode: enter name=value pairs on standard input)\n";
	chomp(@lines = &lt;STDIN&gt;); # remove newlines
	$input = join(" ",@lines);
	@words = &amp;shellwords($input);    
    }
    foreach (@words) {
	s/\\=/%3D/g;
	s/\\&amp;/%26/g;	    
    }

    if ("@words"=~/=/) {
	$query_string = join('&amp;',@words);
    } else {
	$query_string = join('+',@words);
    }
    return $query_string;
}
END_OF_FUNC

#####
# subroutine: read_multipart
#
# Read multipart data and store it into our parameters.
# An interesting feature is that if any of the parts is a file, we
# create a temporary file and open up a filehandle on it so that the
# caller can read from it if necessary.
#####
'read_multipart' =&gt; &lt;&lt;'END_OF_FUNC',
sub read_multipart {
    my($self,$boundary,$length,$filehandle) = @_;
    my($buffer) = $self-&gt;new_MultipartBuffer($boundary,$length,$filehandle);
    return unless $buffer;
    my(%header,$body);
    my $filenumber = 0;
    while (!$buffer-&gt;eof) {
	%header = $buffer-&gt;readHeader;
	die "Malformed multipart POST\n" unless %header;

	my($param)= $header{'Content-Disposition'}=~/ name="?([^\";]*)"?/;

	# Bug:  Netscape doesn't escape quotation marks in file names!!!
	my($filename) = $header{'Content-Disposition'}=~/ filename="?([^\";]*)"?/;

	# add this parameter to our list
	$self-&gt;add_parameter($param);

	# If no filename specified, then just read the data and assign it
	# to our parameter list.
	unless ($filename) {
	    my($value) = $buffer-&gt;readBody;
	    push(@{$self-&gt;{$param}},$value);
	    next;
	}

	my ($tmpfile,$tmp,$filehandle);
      UPLOADS: {
	  # If we get here, then we are dealing with a potentially large
	  # uploaded form.  Save the data to a temporary file, then open
	  # the file for reading.

	  # skip the file if uploads disabled
	  if ($DISABLE_UPLOADS) {
	      while (defined($data = $buffer-&gt;read)) { }
	      last UPLOADS;
	  }

	  $tmpfile = new TempFile;
	  $tmp = $tmpfile-&gt;as_string;
	  
	  $filehandle = Fh-&gt;new($filename,$tmp,$PRIVATE_TEMPFILES);

	  $CGI::DefaultClass-&gt;binmode($filehandle) if $CGI::needs_binmode;
	  chmod 0600,$tmp;    # only the owner can tamper with it

	  my ($data);
	  local($\) = '';
	  while (defined($data = $buffer-&gt;read)) {
	      print $filehandle $data;
	  }

	  # back up to beginning of file
	  seek($filehandle,0,0);
	  $CGI::DefaultClass-&gt;binmode($filehandle) if $CGI::needs_binmode;

	  # Save some information about the uploaded file where we can get
	  # at it later.
	  $self-&gt;{'.tmpfiles'}-&gt;{$filename}= {
	      name =&gt; $tmpfile,
	      info =&gt; {%header},
	  };
	  push(@{$self-&gt;{$param}},$filehandle);
      }
    }
}
END_OF_FUNC

'tmpFileName' =&gt; &lt;&lt;'END_OF_FUNC',
sub tmpFileName {
    my($self,$filename) = self_or_default(@_);
    return $self-&gt;{'.tmpfiles'}-&gt;{$filename}-&gt;{name} ?
	$self-&gt;{'.tmpfiles'}-&gt;{$filename}-&gt;{name}-&gt;as_string
	    : '';
}
END_OF_FUNC

'uploadInfo' =&gt; &lt;&lt;'END_OF_FUNC',
sub uploadInfo {
    my($self,$filename) = self_or_default(@_);
    return $self-&gt;{'.tmpfiles'}-&gt;{$filename}-&gt;{info};
}
END_OF_FUNC

# internal routine, don't use
'_set_values_and_labels' =&gt; &lt;&lt;'END_OF_FUNC',
sub _set_values_and_labels {
    my $self = shift;
    my ($v,$l,$n) = @_;
    $$l = $v if ref($v) eq 'HASH' &amp;&amp; !ref($$l);
    return $self-&gt;param($n) if !defined($v);
    return $v if !ref($v);
    return ref($v) eq 'HASH' ? keys %$v : @$v;
}
END_OF_FUNC

'_compile_all' =&gt; &lt;&lt;'END_OF_FUNC',
sub _compile_all {
    foreach (@_) {
	next if defined(&amp;$_);
	$AUTOLOAD = "CGI::$_";
	_compile();
    }
}
END_OF_FUNC

);
END_OF_AUTOLOAD
;

#########################################################
# Globals and stubs for other packages that we use.
#########################################################

################### Fh -- lightweight filehandle ###############
package Fh;
use overload 
    '""'  =&gt; \&amp;asString,
    'cmp' =&gt; \&amp;compare,
    'fallback'=&gt;1;

$FH='fh00000';

*Fh::AUTOLOAD = \&amp;CGI::AUTOLOAD;

$AUTOLOADED_ROUTINES = '';      # prevent -w error
$AUTOLOADED_ROUTINES=&lt;&lt;'END_OF_AUTOLOAD';
%SUBS =  (
'asString' =&gt; &lt;&lt;'END_OF_FUNC',
sub asString {
    my $self = shift;
    # get rid of package name
    (my $i = $$self) =~ s/^\*(\w+::)+//; 
    $i =~ s/\\(.)/$1/g;
    return $i;
# BEGIN DEAD CODE
# This was an extremely clever patch that allowed "use strict refs".
# Unfortunately it relied on another bug that caused leaky file descriptors.
# The underlying bug has been fixed, so this no longer works.  However
# "strict refs" still works for some reason.
#    my $self = shift;
#    return ${*{$self}{SCALAR}};
# END DEAD CODE
}
END_OF_FUNC

'compare' =&gt; &lt;&lt;'END_OF_FUNC',
sub compare {
    my $self = shift;
    my $value = shift;
    return "$self" cmp $value;
}
END_OF_FUNC

'new'  =&gt; &lt;&lt;'END_OF_FUNC',
sub new {
    my($pack,$name,$file,$delete) = @_;
    require Fcntl unless defined &amp;Fcntl::O_RDWR;
    ++$FH;
    my $ref = \*{'Fh::' . quotemeta($name)}; 
    sysopen($ref,$file,Fcntl::O_RDWR()|Fcntl::O_CREAT()|Fcntl::O_EXCL()) 
	|| die "CGI open of $file: $!\n";
    unlink($file) if $delete;
    delete $Fh::{$FH};
    return bless $ref,$pack;
}
END_OF_FUNC

'DESTROY'  =&gt; &lt;&lt;'END_OF_FUNC',
sub DESTROY {
    my $self = shift;
    close $self;
}
END_OF_FUNC

);
END_OF_AUTOLOAD

######################## MultipartBuffer ####################
package MultipartBuffer;

# how many bytes to read at a time.  We use
# a 4K buffer by default.
$INITIAL_FILLUNIT = 1024 * 4;
$TIMEOUT = 240*60;       # 4 hour timeout for big files
$SPIN_LOOP_MAX = 2000;  # bug fix for some Netscape servers
$CRLF=$CGI::CRLF;

#reuse the autoload function
*MultipartBuffer::AUTOLOAD = \&amp;CGI::AUTOLOAD;

# avoid autoloader warnings
sub DESTROY {}

###############################################################################
################# THESE FUNCTIONS ARE AUTOLOADED ON DEMAND ####################
###############################################################################
$AUTOLOADED_ROUTINES = '';      # prevent -w error
$AUTOLOADED_ROUTINES=&lt;&lt;'END_OF_AUTOLOAD';
%SUBS =  (

'new' =&gt; &lt;&lt;'END_OF_FUNC',
sub new {
    my($package,$interface,$boundary,$length,$filehandle) = @_;
    $FILLUNIT = $INITIAL_FILLUNIT;
    my $IN;
    if ($filehandle) {
	my($package) = caller;
	# force into caller's package if necessary
	$IN = $filehandle=~/[':]/ ? $filehandle : "$package\:\:$filehandle"; 
    }
    $IN = "main::STDIN" unless $IN;

    $CGI::DefaultClass-&gt;binmode($IN) if $CGI::needs_binmode;
    
    # If the user types garbage into the file upload field,
    # then Netscape passes NOTHING to the server (not good).
    # We may hang on this read in that case. So we implement
    # a read timeout.  If nothing is ready to read
    # by then, we return.

    # Netscape seems to be a little bit unreliable
    # about providing boundary strings.
    if ($boundary) {

	# Under the MIME spec, the boundary consists of the 
	# characters "--" PLUS the Boundary string

	# BUG: IE 3.01 on the Macintosh uses just the boundary -- not
	# the two extra hyphens.  We do a special case here on the user-agent!!!!
	$boundary = "--$boundary" unless CGI::user_agent('MSIE 3\.0[12];  ?Mac');

    } else { # otherwise we find it ourselves
	my($old);
	($old,$/) = ($/,$CRLF); # read a CRLF-delimited line
	$boundary = &lt;$IN&gt;;      # BUG: This won't work correctly under mod_perl
	$length -= length($boundary);
	chomp($boundary);               # remove the CRLF
	$/ = $old;                      # restore old line separator
    }

    my $self = {LENGTH=&gt;$length,
		BOUNDARY=&gt;$boundary,
		IN=&gt;$IN,
		INTERFACE=&gt;$interface,
		BUFFER=&gt;'',
	    };

    $FILLUNIT = length($boundary)
	if length($boundary) &gt; $FILLUNIT;

    my $retval = bless $self,ref $package || $package;

    # Read the preamble and the topmost (boundary) line plus the CRLF.
    while ($self-&gt;read(0)) { }
    die "Malformed multipart POST\n" if $self-&gt;eof;

    return $retval;
}
END_OF_FUNC

'readHeader' =&gt; &lt;&lt;'END_OF_FUNC',
sub readHeader {
    my($self) = @_;
    my($end);
    my($ok) = 0;
    my($bad) = 0;

    if ($CGI::OS eq 'VMS') {  # tssk, tssk: inconsistency alert!
	local($CRLF) = "\015\012";
    }

    do {
	$self-&gt;fillBuffer($FILLUNIT);
	$ok++ if ($end = index($self-&gt;{BUFFER},"${CRLF}${CRLF}")) &gt;= 0;
	$ok++ if $self-&gt;{BUFFER} eq '';
	$bad++ if !$ok &amp;&amp; $self-&gt;{LENGTH} &lt;= 0;
	# this was a bad idea
	# $FILLUNIT *= 2 if length($self-&gt;{BUFFER}) &gt;= $FILLUNIT; 
    } until $ok || $bad;
    return () if $bad;

    my($header) = substr($self-&gt;{BUFFER},0,$end+2);
    substr($self-&gt;{BUFFER},0,$end+4) = '';
    my %return;

    
    # See RFC 2045 Appendix A and RFC 822 sections 3.4.8
    #   (Folding Long Header Fields), 3.4.3 (Comments)
    #   and 3.4.5 (Quoted-Strings).

    my $token = '[-\w!\#$%&amp;\'*+.^_\`|{}~]';
    $header=~s/$CRLF\s+/ /og;		# merge continuation lines
    while ($header=~/($token+):\s+([^$CRLF]*)/mgox) {
	my ($field_name,$field_value) = ($1,$2); # avoid taintedness
	$field_name =~ s/\b(\w)/uc($1)/eg; #canonicalize
	$return{$field_name}=$field_value;
    }
    return %return;
}
END_OF_FUNC

# This reads and returns the body as a single scalar value.
'readBody' =&gt; &lt;&lt;'END_OF_FUNC',
sub readBody {
    my($self) = @_;
    my($data);
    my($returnval)='';
    while (defined($data = $self-&gt;read)) {
	$returnval .= $data;
    }
    return $returnval;
}
END_OF_FUNC

# This will read $bytes or until the boundary is hit, whichever happens
# first.  After the boundary is hit, we return undef.  The next read will
# skip over the boundary and begin reading again;
'read' =&gt; &lt;&lt;'END_OF_FUNC',
sub read {
    my($self,$bytes) = @_;

    # default number of bytes to read
    $bytes = $bytes || $FILLUNIT;       

    # Fill up our internal buffer in such a way that the boundary
    # is never split between reads.
    $self-&gt;fillBuffer($bytes);

    # Find the boundary in the buffer (it may not be there).
    my $start = index($self-&gt;{BUFFER},$self-&gt;{BOUNDARY});
    # protect against malformed multipart POST operations
    die "Malformed multipart POST\n" unless ($start &gt;= 0) || ($self-&gt;{LENGTH} &gt; 0);

    # If the boundary begins the data, then skip past it
    # and return undef.  The +2 here is a fiendish plot to
    # remove the CR/LF pair at the end of the boundary.
    if ($start == 0) {

	# clear us out completely if we've hit the last boundary.
	if (index($self-&gt;{BUFFER},"$self-&gt;{BOUNDARY}--")==0) {
	    $self-&gt;{BUFFER}='';
	    $self-&gt;{LENGTH}=0;
	    return undef;
	}

	# just remove the boundary.
	substr($self-&gt;{BUFFER},0,length($self-&gt;{BOUNDARY})+2)='';
	return undef;
    }

    my $bytesToReturn;    
    if ($start &gt; 0) {           # read up to the boundary
	$bytesToReturn = $start &gt; $bytes ? $bytes : $start;
    } else {    # read the requested number of bytes
	# leave enough bytes in the buffer to allow us to read
	# the boundary.  Thanks to Kevin Hendrick for finding
	# this one.
	$bytesToReturn = $bytes - (length($self-&gt;{BOUNDARY})+1);
    }

    my $returnval=substr($self-&gt;{BUFFER},0,$bytesToReturn);
    substr($self-&gt;{BUFFER},0,$bytesToReturn)='';
    
    # If we hit the boundary, remove the CRLF from the end.
    return ($start &gt; 0) ? substr($returnval,0,-2) : $returnval;
}
END_OF_FUNC


# This fills up our internal buffer in such a way that the
# boundary is never split between reads
'fillBuffer' =&gt; &lt;&lt;'END_OF_FUNC',
sub fillBuffer {
    my($self,$bytes) = @_;
    return unless $self-&gt;{LENGTH};

    my($boundaryLength) = length($self-&gt;{BOUNDARY});
    my($bufferLength) = length($self-&gt;{BUFFER});
    my($bytesToRead) = $bytes - $bufferLength + $boundaryLength + 2;
    $bytesToRead = $self-&gt;{LENGTH} if $self-&gt;{LENGTH} &lt; $bytesToRead;

    # Try to read some data.  We may hang here if the browser is screwed up.  
    my $bytesRead = $self-&gt;{INTERFACE}-&gt;read_from_client($self-&gt;{IN},
							 \$self-&gt;{BUFFER},
							 $bytesToRead,
							 $bufferLength);
    $self-&gt;{BUFFER} = '' unless defined $self-&gt;{BUFFER};

    # An apparent bug in the Apache server causes the read()
    # to return zero bytes repeatedly without blocking if the
    # remote user aborts during a file transfer.  I don't know how
    # they manage this, but the workaround is to abort if we get
    # more than SPIN_LOOP_MAX consecutive zero reads.
    if ($bytesRead == 0) {
	die  "CGI.pm: Server closed socket during multipart read (client aborted?).\n"
	    if ($self-&gt;{ZERO_LOOP_COUNTER}++ &gt;= $SPIN_LOOP_MAX);
    } else {
	$self-&gt;{ZERO_LOOP_COUNTER}=0;
    }

    $self-&gt;{LENGTH} -= $bytesRead;
}
END_OF_FUNC


# Return true when we've finished reading
'eof' =&gt; &lt;&lt;'END_OF_FUNC'
sub eof {
    my($self) = @_;
    return 1 if (length($self-&gt;{BUFFER}) == 0)
		 &amp;&amp; ($self-&gt;{LENGTH} &lt;= 0);
    undef;
}
END_OF_FUNC

);
END_OF_AUTOLOAD

####################################################################################
################################## TEMPORARY FILES #################################
####################################################################################
package TempFile;

$SL = $CGI::SL;
$MAC = $CGI::OS eq 'MACINTOSH';
my ($vol) = $MAC ? MacPerl::Volumes() =~ /:(.*)/ : "";
unless ($TMPDIRECTORY) {
    @TEMP=("${SL}usr${SL}tmp","${SL}var${SL}tmp",
	   "C:${SL}temp","${SL}tmp","${SL}temp","${vol}${SL}Temporary Items",
	   "${SL}WWW_ROOT");
    foreach (@TEMP) {
	do {$TMPDIRECTORY = $_; last} if -d $_ &amp;&amp; -w _;
    }
}

$TMPDIRECTORY  = $MAC ? "" : "." unless $TMPDIRECTORY;
$SEQUENCE=0;
$MAXTRIES = 5000;

# cute feature, but overload implementation broke it
# %OVERLOAD = ('""'=&gt;'as_string');
*TempFile::AUTOLOAD = \&amp;CGI::AUTOLOAD;

###############################################################################
################# THESE FUNCTIONS ARE AUTOLOADED ON DEMAND ####################
###############################################################################
$AUTOLOADED_ROUTINES = '';      # prevent -w error
$AUTOLOADED_ROUTINES=&lt;&lt;'END_OF_AUTOLOAD';
%SUBS = (

'new' =&gt; &lt;&lt;'END_OF_FUNC',
sub new {
    my($package) = @_;
    my $directory;
    my $i;
    for ($i = 0; $i &lt; $MAXTRIES; $i++) {
	$directory = sprintf("${TMPDIRECTORY}${SL}CGItemp%d%04d",${$},++$SEQUENCE);
	last if ! -f $directory;
    }
    return bless \$directory;
}
END_OF_FUNC

'DESTROY' =&gt; &lt;&lt;'END_OF_FUNC',
sub DESTROY {
    my($self) = @_;
    unlink $$self;              # get rid of the file
}
END_OF_FUNC

'as_string' =&gt; &lt;&lt;'END_OF_FUNC'
sub as_string {
    my($self) = @_;
    return $$self;
}
END_OF_FUNC

);
END_OF_AUTOLOAD

package CGI;

# We get a whole bunch of warnings about "possibly uninitialized variables"
# when running with the -w switch.  Touch them all once to get rid of the
# warnings.  This is ugly and I hate it.
if ($^W) {
    $CGI::CGI = '';
    $CGI::CGI=&lt;&lt;EOF;
    $CGI::VERSION;
    $MultipartBuffer::SPIN_LOOP_MAX;
    $MultipartBuffer::CRLF;
    $MultipartBuffer::TIMEOUT;
    $MultipartBuffer::INITIAL_FILLUNIT;
    $TempFile::SEQUENCE;
EOF
    ;
}

1;

__END__

=head1 NAME

CGI - Simple Common Gateway Interface Class

=head1 SYNOPSIS

  # CGI script that creates a fill-out form
  # and echoes back its values.

  use CGI qw/:standard/;
  print header,
        start_html('A Simple Example'),
        h1('A Simple Example'),
        start_form,
        "What's your name? ",textfield('name'),p,
        "What's the combination?", p,
        checkbox_group(-name=&gt;'words',
		       -values=&gt;['eenie','meenie','minie','moe'],
		       -defaults=&gt;['eenie','minie']), p,
        "What's your favorite color? ",
        popup_menu(-name=&gt;'color',
	           -values=&gt;['red','green','blue','chartreuse']),p,
        submit,
        end_form,
        hr;

   if (param()) {
       print "Your name is",em(param('name')),p,
	     "The keywords are: ",em(join(", ",param('words'))),p,
	     "Your favorite color is ",em(param('color')),
	     hr;
   }

=head1 ABSTRACT

This perl library uses perl5 objects to make it easy to create Web
fill-out forms and parse their contents.  This package defines CGI
objects, entities that contain the values of the current query string
and other state variables.  Using a CGI object's methods, you can
examine keywords and parameters passed to your script, and create
forms whose initial values are taken from the current query (thereby
preserving state information).  The module provides shortcut functions
that produce boilerplate HTML, reducing typing and coding errors. It
also provides functionality for some of the more advanced features of
CGI scripting, including support for file uploads, cookies, cascading
style sheets, server push, and frames.

CGI.pm also provides a simple function-oriented programming style for
those who don't need its object-oriented features.

The current version of CGI.pm is available at

  http://www.genome.wi.mit.edu/ftp/pub/software/WWW/cgi_docs.html
  ftp://ftp-genome.wi.mit.edu/pub/software/WWW/

=head1 DESCRIPTION

=head2 PROGRAMMING STYLE

There are two styles of programming with CGI.pm, an object-oriented
style and a function-oriented style.  In the object-oriented style you
create one or more CGI objects and then use object methods to create
the various elements of the page.  Each CGI object starts out with the
list of named parameters that were passed to your CGI script by the
server.  You can modify the objects, save them to a file or database
and recreate them.  Because each object corresponds to the "state" of
the CGI script, and because each object's parameter list is
independent of the others, this allows you to save the state of the
script and restore it later.

For example, using the object oriented style, here is now you create
a simple "Hello World" HTML page:

   #!/usr/local/bin/perl
   use CGI;                             # load CGI routines
   $q = new CGI;                        # create new CGI object
   print $q-&gt;header,                    # create the HTTP header
         $q-&gt;start_html('hello world'), # start the HTML
         $q-&gt;h1('hello world'),         # level 1 header
         $q-&gt;end_html;                  # end the HTML

In the function-oriented style, there is one default CGI object that
you rarely deal with directly.  Instead you just call functions to
retrieve CGI parameters, create HTML tags, manage cookies, and so
on.  This provides you with a cleaner programming interface, but
limits you to using one CGI object at a time.  The following example
prints the same page, but uses the function-oriented interface.
The main differences are that we now need to import a set of functions
into our name space (usually the "standard" functions), and we don't
need to create the CGI object.

   #!/usr/local/bin/perl
   use CGI qw/:standard/;           # load standard CGI routines
   print header,                    # create the HTTP header
         start_html('hello world'), # start the HTML
         h1('hello world'),         # level 1 header
         end_html;                  # end the HTML

The examples in this document mainly use the object-oriented style.
See HOW TO IMPORT FUNCTIONS for important information on
function-oriented programming in CGI.pm

=head2 CALLING CGI.PM ROUTINES

Most CGI.pm routines accept several arguments, sometimes as many as 20
optional ones!  To simplify this interface, all routines use a named
argument calling style that looks like this:

   print $q-&gt;header(-type=&gt;'image/gif',-expires=&gt;'+3d');

Each argument name is preceded by a dash.  Neither case nor order
matters in the argument list.  -type, -Type, and -TYPE are all
acceptable.  In fact, only the first argument needs to begin with a
dash.  If a dash is present in the first argument, CGI.pm assumes
dashes for the subsequent ones.

You don't have to use the hyphen at allif you don't want to.  After
creating a CGI object, call the B&lt;use_named_parameters()&gt; method with
a nonzero value.  This will tell CGI.pm that you intend to use named
parameters exclusively:

   $query = new CGI;
   $query-&gt;use_named_parameters(1);
   $field = $query-&gt;radio_group('name'=&gt;'OS',
				'values'=&gt;['Unix','Windows','Macintosh'],
				'default'=&gt;'Unix');

Several routines are commonly called with just one argument.  In the
case of these routines you can provide the single argument without an
argument name.  header() happens to be one of these routines.  In this
case, the single argument is the document type.

   print $q-&gt;header('text/html');

Other such routines are documented below.

Sometimes named arguments expect a scalar, sometimes a reference to an
array, and sometimes a reference to a hash.  Often, you can pass any
type of argument and the routine will do whatever is most appropriate.
For example, the param() routine is used to set a CGI parameter to a
single or a multi-valued value.  The two cases are shown below:

   $q-&gt;param(-name=&gt;'veggie',-value=&gt;'tomato');
   $q-&gt;param(-name=&gt;'veggie',-value=&gt;'[tomato','tomahto','potato','potahto']);

A large number of routines in CGI.pm actually aren't specifically
defined in the module, but are generated automatically as needed.
These are the "HTML shortcuts," routines that generate HTML tags for
use in dynamically-generated pages.  HTML tags have both attributes
(the attribute="value" pairs within the tag itself) and contents (the
part between the opening and closing pairs.)  To distinguish between
attributes and contents, CGI.pm uses the convention of passing HTML
attributes as a hash reference as the first argument, and the
contents, if any, as any subsequent arguments.  It works out like
this:

   Code                           Generated HTML
   ----                           --------------
   h1()                           &lt;H1&gt;
   h1('some','contents');         &lt;H1&gt;some contents&lt;/H1&gt;
   h1({-align=&gt;left});            &lt;H1 ALIGN="LEFT"&gt;
   h1({-align=&gt;left},'contents'); &lt;H1 ALIGN="LEFT"&gt;contents&lt;/H1&gt;

HTML tags are described in more detail later.  

Many newcomers to CGI.pm are puzzled by the difference between the
calling conventions for the HTML shortcuts, which require curly braces
around the HTML tag attributes, and the calling conventions for other
routines, which manage to generate attributes without the curly
brackets.  Don't be confused.  As a convenience the curly braces are
optional in all but the HTML shortcuts.  If you like, you can use
curly braces when calling any routine that takes named arguments.  For
example:

   print $q-&gt;header( {-type=&gt;'image/gif',-expires=&gt;'+3d'} );

If you use the B&lt;-w&gt; switch, you will be warned that some CGI.pm argument
names conflict with built-in Perl functions.  The most frequent of
these is the -values argument, used to create multi-valued menus,
radio button clusters and the like.  To get around this warning, you
have several choices:

=over 4

=item 1. Use another name for the argument, if one is available.  For
example, -value is an alias for -values.

=item 2. Change the capitalization, e.g. -Values

=item 3. Put quotes around the argument name, e.g. '-values'

=back

Many routines will do something useful with a named argument that it
doesn't recognize.  For example, you can produce non-standard HTTP
header fields by providing them as named arguments:

  print $q-&gt;header(-type  =&gt;  'text/html',
                   -cost  =&gt;  'Three smackers',
                   -annoyance_level =&gt; 'high',
                   -complaints_to   =&gt; 'bit bucket');

This will produce the following nonstandard HTTP header:

   HTTP/1.0 200 OK
   Cost: Three smackers
   Annoyance-level: high
   Complaints-to: bit bucket
   Content-type: text/html

Notice the way that underscores are translated automatically into
hyphens.  HTML-generating routines perform a different type of
translation. 

This feature allows you to keep up with the rapidly changing HTTP and
HTML "standards".

=head2 CREATING A NEW QUERY OBJECT (OBJECT-ORIENTED STYLE):

     $query = new CGI;

This will parse the input (from both POST and GET methods) and store
it into a perl5 object called $query.  

=head2 CREATING A NEW QUERY OBJECT FROM AN INPUT FILE

     $query = new CGI(INPUTFILE);

If you provide a file handle to the new() method, it will read
parameters from the file (or STDIN, or whatever).  The file can be in
any of the forms describing below under debugging (i.e. a series of
newline delimited TAG=VALUE pairs will work).  Conveniently, this type
of file is created by the save() method (see below).  Multiple records
can be saved and restored.

Perl purists will be pleased to know that this syntax accepts
references to file handles, or even references to filehandle globs,
which is the "official" way to pass a filehandle:

    $query = new CGI(\*STDIN);

You can also initialize the CGI object with a FileHandle or IO::File
object.

If you are using the function-oriented interface and want to
initialize CGI state from a file handle, the way to do this is with
B&lt;restore_parameters()&gt;.  This will (re)initialize the
default CGI object from the indicated file handle.

    open (IN,"test.in") || die;
    restore_parameters(IN);
    close IN;

You can also initialize the query object from an associative array
reference:

    $query = new CGI( {'dinosaur'=&gt;'barney',
		       'song'=&gt;'I love you',
		       'friends'=&gt;[qw/Jessica George Nancy/]}
		    );

or from a properly formatted, URL-escaped query string:

    $query = new CGI('dinosaur=barney&amp;color=purple');

or from a previously existing CGI object (currently this clones the
parameter list, but none of the other object-specific fields, such as
autoescaping):

    $old_query = new CGI;
    $new_query = new CGI($old_query);

To create an empty query, initialize it from an empty string or hash:

   $empty_query = new CGI("");

       -or-

   $empty_query = new CGI({});

=head2 FETCHING A LIST OF KEYWORDS FROM THE QUERY:

     @keywords = $query-&gt;keywords

If the script was invoked as the result of an &lt;ISINDEX&gt; search, the
parsed keywords can be obtained as an array using the keywords() method.

=head2 FETCHING THE NAMES OF ALL THE PARAMETERS PASSED TO YOUR SCRIPT:

     @names = $query-&gt;param

If the script was invoked with a parameter list
(e.g. "name1=value1&amp;name2=value2&amp;name3=value3"), the param()
method will return the parameter names as a list.  If the
script was invoked as an &lt;ISINDEX&gt; script, there will be a
single parameter named 'keywords'.

NOTE: As of version 1.5, the array of parameter names returned will
be in the same order as they were submitted by the browser.
Usually this order is the same as the order in which the 
parameters are defined in the form (however, this isn't part
of the spec, and so isn't guaranteed).

=head2 FETCHING THE VALUE OR VALUES OF A SINGLE NAMED PARAMETER:

    @values = $query-&gt;param('foo');

	      -or-

    $value = $query-&gt;param('foo');

Pass the param() method a single argument to fetch the value of the
named parameter. If the parameter is multivalued (e.g. from multiple
selections in a scrolling list), you can ask to receive an array.  Otherwise
the method will return a single value.

=head2 SETTING THE VALUE(S) OF A NAMED PARAMETER:

    $query-&gt;param('foo','an','array','of','values');

This sets the value for the named parameter 'foo' to an array of
values.  This is one way to change the value of a field AFTER
the script has been invoked once before.  (Another way is with
the -override parameter accepted by all methods that generate
form elements.)

param() also recognizes a named parameter style of calling described
in more detail later:

    $query-&gt;param(-name=&gt;'foo',-values=&gt;['an','array','of','values']);

			      -or-

    $query-&gt;param(-name=&gt;'foo',-value=&gt;'the value');

=head2 APPENDING ADDITIONAL VALUES TO A NAMED PARAMETER:

   $query-&gt;append(-name=&gt;'foo',-values=&gt;['yet','more','values']);

This adds a value or list of values to the named parameter.  The
values are appended to the end of the parameter if it already exists.
Otherwise the parameter is created.  Note that this method only
recognizes the named argument calling syntax.

=head2 IMPORTING ALL PARAMETERS INTO A NAMESPACE:

   $query-&gt;import_names('R');

This creates a series of variables in the 'R' namespace.  For example,
$R::foo, @R:foo.  For keyword lists, a variable @R::keywords will appear.
If no namespace is given, this method will assume 'Q'.
WARNING:  don't import anything into 'main'; this is a major security
risk!!!!

In older versions, this method was called B&lt;import()&gt;.  As of version 2.20, 
this name has been removed completely to avoid conflict with the built-in
Perl module B&lt;import&gt; operator.

=head2 DELETING A PARAMETER COMPLETELY:

    $query-&gt;delete('foo');

This completely clears a parameter.  It sometimes useful for
resetting parameters that you don't want passed down between
script invocations.

If you are using the function call interface, use "Delete()" instead
to avoid conflicts with Perl's built-in delete operator.

=head2 DELETING ALL PARAMETERS:

   $query-&gt;delete_all();

This clears the CGI object completely.  It might be useful to ensure
that all the defaults are taken when you create a fill-out form.

Use Delete_all() instead if you are using the function call interface.

=head2 DIRECT ACCESS TO THE PARAMETER LIST:

   $q-&gt;param_fetch('address')-&gt;[1] = '1313 Mockingbird Lane';
   unshift @{$q-&gt;param_fetch(-name=&gt;'address')},'George Munster';

If you need access to the parameter list in a way that isn't covered
by the methods above, you can obtain a direct reference to it by
calling the B&lt;param_fetch()&gt; method with the name of the .  This
will return an array reference to the named parameters, which you then
can manipulate in any way you like.

You can also use a named argument style using the B&lt;-name&gt; argument.

=head2 SAVING THE STATE OF THE SCRIPT TO A FILE:

    $query-&gt;save(FILEHANDLE)

This will write the current state of the form to the provided
filehandle.  You can read it back in by providing a filehandle
to the new() method.  Note that the filehandle can be a file, a pipe,
or whatever!

The format of the saved file is:

	NAME1=VALUE1
	NAME1=VALUE1'
	NAME2=VALUE2
	NAME3=VALUE3
	=

Both name and value are URL escaped.  Multi-valued CGI parameters are
represented as repeated names.  A session record is delimited by a
single = symbol.  You can write out multiple records and read them
back in with several calls to B&lt;new&gt;.  You can do this across several
sessions by opening the file in append mode, allowing you to create
primitive guest books, or to keep a history of users' queries.  Here's
a short example of creating multiple session records:

   use CGI;

   open (OUT,"&gt;&gt;test.out") || die;
   $records = 5;
   foreach (0..$records) {
       my $q = new CGI;
       $q-&gt;param(-name=&gt;'counter',-value=&gt;$_);
       $q-&gt;save(OUT);
   }
   close OUT;

   # reopen for reading
   open (IN,"test.out") || die;
   while (!eof(IN)) {
       my $q = new CGI(IN);
       print $q-&gt;param('counter'),"\n";
   }

The file format used for save/restore is identical to that used by the
Whitehead Genome Center's data exchange format "Boulderio", and can be
manipulated and even databased using Boulderio utilities.  See
	
  http://www.genome.wi.mit.edu/genome_software/other/boulder.html

for further details.

If you wish to use this method from the function-oriented (non-OO)
interface, the exported name for this method is B&lt;save_parameters()&gt;.

=head2 USING THE FUNCTION-ORIENTED INTERFACE

To use the function-oriented interface, you must specify which CGI.pm
routines or sets of routines to import into your script's namespace.
There is a small overhead associated with this importation, but it
isn't much.

   use CGI &lt;list of methods&gt;;

The listed methods will be imported into the current package; you can
call them directly without creating a CGI object first.  This example
shows how to import the B&lt;param()&gt; and B&lt;header()&gt;
methods, and then use them directly:

   use CGI 'param','header';
   print header('text/plain');
   $zipcode = param('zipcode');

More frequently, you'll import common sets of functions by referring
to the gropus by name.  All function sets are preceded with a ":"
character as in ":html3" (for tags defined in the HTML 3 standard).

Here is a list of the function sets you can import:

=over 4

=item B&lt;:cgi&gt;

Import all CGI-handling methods, such as B&lt;param()&gt;, B&lt;path_info()&gt;
and the like.

=item B&lt;:form&gt;

Import all fill-out form generating methods, such as B&lt;textfield()&gt;.

=item B&lt;:html2&gt;

Import all methods that generate HTML 2.0 standard elements.

=item B&lt;:html3&gt;

Import all methods that generate HTML 3.0 proposed elements (such as
&lt;table&gt;, &lt;super&gt; and &lt;sub&gt;).

=item B&lt;:netscape&gt;

Import all methods that generate Netscape-specific HTML extensions.

=item B&lt;:html&gt;

Import all HTML-generating shortcuts (i.e. 'html2' + 'html3' +
'netscape')...

=item B&lt;:standard&gt;

Import "standard" features, 'html2', 'html3', 'form' and 'cgi'.

=item B&lt;:all&gt;

Import all the available methods.  For the full list, see the CGI.pm
code, where the variable %TAGS is defined.

=back

If you import a function name that is not part of CGI.pm, the module
will treat it as a new HTML tag and generate the appropriate
subroutine.  You can then use it like any other HTML tag.  This is to
provide for the rapidly-evolving HTML "standard."  For example, say
Microsoft comes out with a new tag called &lt;GRADIENT&gt; (which causes the
user's desktop to be flooded with a rotating gradient fill until his
machine reboots).  You don't need to wait for a new version of CGI.pm
to start using it immeidately:

   use CGI qw/:standard :html3 gradient/;
   print gradient({-start=&gt;'red',-end=&gt;'blue'});

Note that in the interests of execution speed CGI.pm does B&lt;not&gt; use
the standard L&lt;Exporter&gt; syntax for specifying load symbols.  This may
change in the future.

If you import any of the state-maintaining CGI or form-generating
methods, a default CGI object will be created and initialized
automatically the first time you use any of the methods that require
one to be present.  This includes B&lt;param()&gt;, B&lt;textfield()&gt;,
B&lt;submit()&gt; and the like.  (If you need direct access to the CGI
object, you can find it in the global variable B&lt;$CGI::Q&gt;).  By
importing CGI.pm methods, you can create visually elegant scripts:

   use CGI qw/:standard/;
   print 
       header,
       start_html('Simple Script'),
       h1('Simple Script'),
       start_form,
       "What's your name? ",textfield('name'),p,
       "What's the combination?",
       checkbox_group(-name=&gt;'words',
		      -values=&gt;['eenie','meenie','minie','moe'],
		      -defaults=&gt;['eenie','moe']),p,
       "What's your favorite color?",
       popup_menu(-name=&gt;'color',
		  -values=&gt;['red','green','blue','chartreuse']),p,
       submit,
       end_form,
       hr,"\n";

    if (param) {
       print 
	   "Your name is ",em(param('name')),p,
	   "The keywords are: ",em(join(", ",param('words'))),p,
	   "Your favorite color is ",em(param('color')),".\n";
    }
    print end_html;

=head2 PRAGMAS

In addition to the function sets, there are a number of pragmas that
you can import.  Pragmas, which are always preceded by a hyphen,
change the way that CGI.pm functions in various ways.  Pragmas,
function sets, and individual functions can all be imported in the
same use() line.  For example, the following use statement imports the
standard set of functions and disables debugging mode (pragma
-no_debug):

   use CGI qw/:standard -no_debug/;

The current list of pragmas is as follows:

=over 4

=item -any

When you I&lt;use CGI -any&gt;, then any method that the query object
doesn't recognize will be interpreted as a new HTML tag.  This allows
you to support the next I&lt;ad hoc&gt; Netscape or Microsoft HTML
extension.  This lets you go wild with new and unsupported tags:

   use CGI qw(-any);
   $q=new CGI;
   print $q-&gt;gradient({speed=&gt;'fast',start=&gt;'red',end=&gt;'blue'});

Since using &lt;cite&gt;any&lt;/cite&gt; causes any mistyped method name
to be interpreted as an HTML tag, use it with care or not at
all.

=item -compile

This causes the indicated autoloaded methods to be compiled up front,
rather than deferred to later.  This is useful for scripts that run
for an extended period of time under FastCGI or mod_perl, and for
those destined to be crunched by Malcom Beattie's Perl compiler.  Use
it in conjunction with the methods or method familes you plan to use.

   use CGI qw(-compile :standard :html3);

or even

   use CGI qw(-compile :all);

Note that using the -compile pragma in this way will always have
the effect of importing the compiled functions into the current
namespace.  If you want to compile without importing use the
compile() method instead (see below).

=item -nph

This makes CGI.pm produce a header appropriate for an NPH (no
parsed header) script.  You may need to do other things as well
to tell the server that the script is NPH.  See the discussion
of NPH scripts below.

=item -newstyle_urls

Separate the name=value pairs in CGI parameter query strings with
semicolons rather than ampersands.  For example:

   ?name=fred;age=24;favorite_color=3

Semicolon-delimited query strings are always accepted, but will not be
emitted by self_url() and query_string() unless the -newstyle_urls
pragma is specified.

=item -autoload

This overrides the autoloader so that any function in your program
that is not recognized is referred to CGI.pm for possible evaluation.
This allows you to use all the CGI.pm functions without adding them to
your symbol table, which is of concern for mod_perl users who are
worried about memory consumption.  I&lt;Warning:&gt; when
I&lt;-autoload&gt; is in effect, you cannot use "poetry mode"
(functions without the parenthesis).  Use I&lt;hr()&gt; rather
than I&lt;hr&gt;, or add something like I&lt;use subs qw/hr p header/&gt; 
to the top of your script.

=item -no_debug

This turns off the command-line processing features.  If you want to
run a CGI.pm script from the command line to produce HTML, and you
don't want it pausing to request CGI parameters from standard input or
the command line, then use this pragma:

   use CGI qw(-no_debug :standard);

If you'd like to process the command-line parameters but not standard
input, this should work:

   use CGI qw(-no_debug :standard);
   restore_parameters(join('&amp;',@ARGV));
  
See the section on debugging for more details.

=item -private_tempfiles

CGI.pm can process uploaded file. Ordinarily it spools the
uploaded file to a temporary directory, then deletes the file
when done.  However, this opens the risk of eavesdropping as
described in the file upload section.
Another CGI script author could peek at this data during the
upload, even if it is confidential information. On Unix systems,
the -private_tempfiles pragma will cause the temporary file to be unlinked as soon
as it is opened and before any data is written into it,
eliminating the risk of eavesdropping.

=back

=head2 SPECIAL FORMS FOR IMPORTING HTML-TAG FUNCTIONS

Many of the methods generate HTML tags.  As described below, tag
functions automatically generate both the opening and closing tags.
For example:

  print h1('Level 1 Header');

produces

  &lt;H1&gt;Level 1 Header&lt;/H1&gt;

There will be some times when you want to produce the start and end
tags yourself.  In this case, you can use the form start_I&lt;tag_name&gt;
and end_I&lt;tag_name&gt;, as in:

  print start_h1,'Level 1 Header',end_h1;

With a few exceptions (described below), start_I&lt;tag_name&gt; and
end_I&lt;tag_name&gt; functions are not generated automatically when you
I&lt;use CGI&gt;.  However, you can specify the tags you want to generate
I&lt;start/end&gt; functions for by putting an asterisk in front of their
name, or, alternatively, requesting either "start_I&lt;tag_name&gt;" or
"end_I&lt;tag_name&gt;" in the import list.

Example:

  use CGI qw/:standard *table start_ul/;

In this example, the following functions are generated in addition to
the standard ones:

=over 4

=item 1. start_table() (generates a &lt;TABLE&gt; tag)

=item 2. end_table() (generates a &lt;/TABLE&gt; tag)

=item 3. start_ul() (generates a &lt;UL&gt; tag)

=item 4. end_ul() (generates a &lt;/UL&gt; tag)

=back

=head1 GENERATING DYNAMIC DOCUMENTS

Most of CGI.pm's functions deal with creating documents on the fly.
Generally you will produce the HTTP header first, followed by the
document itself.  CGI.pm provides functions for generating HTTP
headers of various types as well as for generating HTML.  For creating
GIF images, see the GD.pm module.

Each of these functions produces a fragment of HTML or HTTP which you
can print out directly so that it displays in the browser window,
append to a string, or save to a file for later use.

=head2 CREATING A STANDARD HTTP HEADER:

Normally the first thing you will do in any CGI script is print out an
HTTP header.  This tells the browser what type of document to expect,
and gives other optional information, such as the language, expiration
date, and whether to cache the document.  The header can also be
manipulated for special purposes, such as server push and pay per view
pages.

	print $query-&gt;header;

	     -or-

	print $query-&gt;header('image/gif');

	     -or-

	print $query-&gt;header('text/html','204 No response');

	     -or-

	print $query-&gt;header(-type=&gt;'image/gif',
			     -nph=&gt;1,
			     -status=&gt;'402 Payment required',
			     -expires=&gt;'+3d',
			     -cookie=&gt;$cookie,
			     -Cost=&gt;'$2.00');

header() returns the Content-type: header.  You can provide your own
MIME type if you choose, otherwise it defaults to text/html.  An
optional second parameter specifies the status code and a human-readable
message.  For example, you can specify 204, "No response" to create a
script that tells the browser to do nothing at all.

The last example shows the named argument style for passing arguments
to the CGI methods using named parameters.  Recognized parameters are
B&lt;-type&gt;, B&lt;-status&gt;, B&lt;-expires&gt;, and B&lt;-cookie&gt;.  Any other named
parameters will be stripped of their initial hyphens and turned into
header fields, allowing you to specify any HTTP header you desire.
Internal underscores will be turned into hyphens:

    print $query-&gt;header(-Content_length=&gt;3002);

Most browsers will not cache the output from CGI scripts.  Every time
the browser reloads the page, the script is invoked anew.  You can
change this behavior with the B&lt;-expires&gt; parameter.  When you specify
an absolute or relative expiration interval with this parameter, some
browsers and proxy servers will cache the script's output until the
indicated expiration date.  The following forms are all valid for the
-expires field:

	+30s                              30 seconds from now
	+10m                              ten minutes from now
	+1h                               one hour from now
	-1d                               yesterday (i.e. "ASAP!")
	now                               immediately
	+3M                               in three months
	+10y                              in ten years time
	Thursday, 25-Apr-1999 00:40:33 GMT  at the indicated time &amp; date

The B&lt;-cookie&gt; parameter generates a header that tells the browser to provide
a "magic cookie" during all subsequent transactions with your script.
Netscape cookies have a special format that includes interesting attributes
such as expiration time.  Use the cookie() method to create and retrieve
session cookies.

The B&lt;-nph&gt; parameter, if set to a true value, will issue the correct
headers to work with a NPH (no-parse-header) script.  This is important
to use with certain servers, such as Microsoft Internet Explorer, which
expect all their scripts to be NPH.

=head2 GENERATING A REDIRECTION HEADER

   print $query-&gt;redirect('http://somewhere.else/in/movie/land');

Sometimes you don't want to produce a document yourself, but simply
redirect the browser elsewhere, perhaps choosing a URL based on the
time of day or the identity of the user.  

The redirect() function redirects the browser to a different URL.  If
you use redirection like this, you should B&lt;not&gt; print out a header as
well.  As of version 2.0, we produce both the unofficial Location:
header and the official URI: header.  This should satisfy most servers
and browsers.

One hint I can offer is that relative links may not work correctly
when you generate a redirection to another document on your site.
This is due to a well-intentioned optimization that some servers use.
The solution to this is to use the full URL (including the http: part)
of the document you are redirecting to.

You can also use named arguments:

    print $query-&gt;redirect(-uri=&gt;'http://somewhere.else/in/movie/land',
			   -nph=&gt;1);

The B&lt;-nph&gt; parameter, if set to a true value, will issue the correct
headers to work with a NPH (no-parse-header) script.  This is important
to use with certain servers, such as Microsoft Internet Explorer, which
expect all their scripts to be NPH.

=head2 CREATING THE HTML DOCUMENT HEADER

   print $query-&gt;start_html(-title=&gt;'Secrets of the Pyramids',
			    -author=&gt;'fred@capricorn.org',
			    -base=&gt;'true',
			    -target=&gt;'_blank',
			    -meta=&gt;{'keywords'=&gt;'pharaoh secret mummy',
				    'copyright'=&gt;'copyright 1996 King Tut'},
			    -style=&gt;{'src'=&gt;'/styles/style1.css'},
			    -BGCOLOR=&gt;'blue');

After creating the HTTP header, most CGI scripts will start writing
out an HTML document.  The start_html() routine creates the top of the
page, along with a lot of optional information that controls the
page's appearance and behavior.

This method returns a canned HTML header and the opening &lt;BODY&gt; tag.
All parameters are optional.  In the named parameter form, recognized
parameters are -title, -author, -base, -xbase and -target (see below
for the explanation).  Any additional parameters you provide, such as
the Netscape unofficial BGCOLOR attribute, are added to the &lt;BODY&gt;
tag.  Additional parameters must be proceeded by a hyphen.

The argument B&lt;-xbase&gt; allows you to provide an HREF for the &lt;BASE&gt; tag
different from the current location, as in

    -xbase=&gt;"http://home.mcom.com/"

All relative links will be interpreted relative to this tag.

The argument B&lt;-target&gt; allows you to provide a default target frame
for all the links and fill-out forms on the page.  See the Netscape
documentation on frames for details of how to manipulate this.

    -target=&gt;"answer_window"

All relative links will be interpreted relative to this tag.
You add arbitrary meta information to the header with the B&lt;-meta&gt;
argument.  This argument expects a reference to an associative array
containing name/value pairs of meta information.  These will be turned
into a series of header &lt;META&gt; tags that look something like this:

    &lt;META NAME="keywords" CONTENT="pharaoh secret mummy"&gt;
    &lt;META NAME="description" CONTENT="copyright 1996 King Tut"&gt;

There is no support for the HTTP-EQUIV type of &lt;META&gt; tag.  This is
because you can modify the HTTP header directly with the B&lt;header()&gt;
method.  For example, if you want to send the Refresh: header, do it
in the header() method:

    print $q-&gt;header(-Refresh=&gt;'10; URL=http://www.capricorn.com');

The B&lt;-style&gt; tag is used to incorporate cascading stylesheets into
your code.  See the section on CASCADING STYLESHEETS for more information.

You can place other arbitrary HTML elements to the &lt;HEAD&gt; section with the
B&lt;-head&gt; tag.  For example, to place the rarely-used &lt;LINK&gt; element in the
head section, use this:

    print $q-&gt;start_html(-head=&gt;Link({-rel=&gt;'next',
				  -href=&gt;'http://www.capricorn.com/s2.html'}));

To incorporate multiple HTML elements into the &lt;HEAD&gt; section, just pass an
array reference:

    print $q-&gt;start_html(-head=&gt;[ 
                              Link({-rel=&gt;'next',
				    -href=&gt;'http://www.capricorn.com/s2.html'}),
			      Link({-rel=&gt;'previous',
				    -href=&gt;'http://www.capricorn.com/s1.html'})
			     ]
		     );

JAVASCRIPTING: The B&lt;-script&gt;, B&lt;-noScript&gt;, B&lt;-onLoad&gt;,
B&lt;-onMouseOver&gt;, B&lt;-onMouseOut&gt; and B&lt;-onUnload&gt; parameters are used
to add Netscape JavaScript calls to your pages.  B&lt;-script&gt; should
point to a block of text containing JavaScript function definitions.
This block will be placed within a &lt;SCRIPT&gt; block inside the HTML (not
HTTP) header.  The block is placed in the header in order to give your
page a fighting chance of having all its JavaScript functions in place
even if the user presses the stop button before the page has loaded
completely.  CGI.pm attempts to format the script in such a way that
JavaScript-naive browsers will not choke on the code: unfortunately
there are some browsers, such as Chimera for Unix, that get confused
by it nevertheless.

The B&lt;-onLoad&gt; and B&lt;-onUnload&gt; parameters point to fragments of JavaScript
code to execute when the page is respectively opened and closed by the
browser.  Usually these parameters are calls to functions defined in the
B&lt;-script&gt; field:

      $query = new CGI;
      print $query-&gt;header;
      $JSCRIPT=&lt;&lt;END;
      // Ask a silly question
      function riddle_me_this() {
	 var r = prompt("What walks on four legs in the morning, " +
		       "two legs in the afternoon, " +
		       "and three legs in the evening?");
	 response(r);
      }
      // Get a silly answer
      function response(answer) {
	 if (answer == "man")
	    alert("Right you are!");
	 else
	    alert("Wrong!  Guess again.");
      }
      END
      print $query-&gt;start_html(-title=&gt;'The Riddle of the Sphinx',
			       -script=&gt;$JSCRIPT);

Use the B&lt;-noScript&gt; parameter to pass some HTML text that will be displayed on 
browsers that do not have JavaScript (or browsers where JavaScript is turned
off).

Netscape 3.0 recognizes several attributes of the &lt;SCRIPT&gt; tag,
including LANGUAGE and SRC.  The latter is particularly interesting,
as it allows you to keep the JavaScript code in a file or CGI script
rather than cluttering up each page with the source.  To use these
attributes pass a HASH reference in the B&lt;-script&gt; parameter containing
one or more of -language, -src, or -code:

    print $q-&gt;start_html(-title=&gt;'The Riddle of the Sphinx',
			 -script=&gt;{-language=&gt;'JAVASCRIPT',
                                   -src=&gt;'/javascript/sphinx.js'}
			 );

    print $q-&gt;(-title=&gt;'The Riddle of the Sphinx',
	       -script=&gt;{-language=&gt;'PERLSCRIPT'},
			 -code=&gt;'print "hello world!\n;"'
	       );


A final feature allows you to incorporate multiple &lt;SCRIPT&gt; sections into the
header.  Just pass the list of script sections as an array reference.
this allows you to specify different source files for different dialects
of JavaScript.  Example:     

     print $q-&amp;gt;start_html(-title=&amp;gt;'The Riddle of the Sphinx',
                          -script=&amp;gt;[
                                    { -language =&amp;gt; 'JavaScript1.0',
                                      -src      =&amp;gt; '/javascript/utilities10.js'
                                    },
                                    { -language =&amp;gt; 'JavaScript1.1',
                                      -src      =&amp;gt; '/javascript/utilities11.js'
                                    },
                                    { -language =&amp;gt; 'JavaScript1.2',
                                      -src      =&amp;gt; '/javascript/utilities12.js'
                                    },
                                    { -language =&amp;gt; 'JavaScript28.2',
                                      -src      =&amp;gt; '/javascript/utilities219.js'
                                    }
                                 ]
                             );
     &lt;/pre&gt;

If this looks a bit extreme, take my advice and stick with straight CGI scripting.  

See

   http://home.netscape.com/eng/mozilla/2.0/handbook/javascript/

for more information about JavaScript.

The old-style positional parameters are as follows:

=over 4

=item B&lt;Parameters:&gt;

=item 1.

The title

=item 2.

The author's e-mail address (will create a &lt;LINK REV="MADE"&gt; tag if present

=item 3.

A 'true' flag if you want to include a &lt;BASE&gt; tag in the header.  This
helps resolve relative addresses to absolute ones when the document is moved, 
but makes the document hierarchy non-portable.  Use with care!

=item 4, 5, 6...

Any other parameters you want to include in the &lt;BODY&gt; tag.  This is a good
place to put Netscape extensions, such as colors and wallpaper patterns.

=back

=head2 ENDING THE HTML DOCUMENT:

	print $query-&gt;end_html

This ends an HTML document by printing the &lt;/BODY&gt;&lt;/HTML&gt; tags.

=head2 CREATING A SELF-REFERENCING URL THAT PRESERVES STATE INFORMATION:

    $myself = $query-&gt;self_url;
    print "&lt;A HREF=$myself&gt;I'm talking to myself.&lt;/A&gt;";

self_url() will return a URL, that, when selected, will reinvoke
this script with all its state information intact.  This is most
useful when you want to jump around within the document using
internal anchors but you don't want to disrupt the current contents
of the form(s).  Something like this will do the trick.

     $myself = $query-&gt;self_url;
     print "&lt;A HREF=$myself#table1&gt;See table 1&lt;/A&gt;";
     print "&lt;A HREF=$myself#table2&gt;See table 2&lt;/A&gt;";
     print "&lt;A HREF=$myself#yourself&gt;See for yourself&lt;/A&gt;";

If you want more control over what's returned, using the B&lt;url()&gt;
method instead.

You can also retrieve the unprocessed query string with query_string():

    $the_string = $query-&gt;query_string;

=head2 OBTAINING THE SCRIPT'S URL

    $full_url      = $query-&gt;url();
    $full_url      = $query-&gt;url(-full=&gt;1);  #alternative syntax
    $relative_url  = $query-&gt;url(-relative=&gt;1);
    $absolute_url  = $query-&gt;url(-absolute=&gt;1);
    $url_with_path = $query-&gt;url(-path_info=&gt;1);
    $url_with_path_and_query = $query-&gt;url(-path_info=&gt;1,-query=&gt;1);

B&lt;url()&gt; returns the script's URL in a variety of formats.  Called
without any arguments, it returns the full form of the URL, including
host name and port number

    http://your.host.com/path/to/script.cgi

You can modify this format with the following named arguments:

=over 4

=item B&lt;-absolute&gt;

If true, produce an absolute URL, e.g.

    /path/to/script.cgi

=item B&lt;-relative&gt;

Produce a relative URL.  This is useful if you want to reinvoke your
script with different parameters. For example:

    script.cgi

=item B&lt;-full&gt;

Produce the full URL, exactly as if called without any arguments.
This overrides the -relative and -absolute arguments.

=item B&lt;-path&gt; (B&lt;-path_info&gt;)

Append the additional path information to the URL.  This can be
combined with B&lt;-full&gt;, B&lt;-absolute&gt; or B&lt;-relative&gt;.  B&lt;-path_info&gt;
is provided as a synonym.

=item B&lt;-query&gt; (B&lt;-query_string&gt;)

Append the query string to the URL.  This can be combined with
B&lt;-full&gt;, B&lt;-absolute&gt; or B&lt;-relative&gt;.  B&lt;-query_string&gt; is provided
as a synonym.

=back

=head2 MIXING POST AND URL PARAMETERS

   $color = $query-&amp;gt;url_param('color');

It is possible for a script to receive CGI parameters in the URL as
well as in the fill-out form by creating a form that POSTs to a URL
containing a query string (a "?" mark followed by arguments).  The
B&lt;param()&gt; method will always return the contents of the POSTed
fill-out form, ignoring the URL's query string.  To retrieve URL
parameters, call the B&lt;url_param()&gt; method.  Use it in the same way as
B&lt;param()&gt;.  The main difference is that it allows you to read the
parameters, but not set them.


Under no circumstances will the contents of the URL query string
interfere with similarly-named CGI parameters in POSTed forms.  If you
try to mix a URL query string with a form submitted with the GET
method, the results will not be what you expect.

=head1 CREATING STANDARD HTML ELEMENTS:

CGI.pm defines general HTML shortcut methods for most, if not all of
the HTML 3 and HTML 4 tags.  HTML shortcuts are named after a single
HTML element and return a fragment of HTML text that you can then
print or manipulate as you like.  Each shortcut returns a fragment of
HTML code that you can append to a string, save to a file, or, most
commonly, print out so that it displays in the browser window.

This example shows how to use the HTML methods:

   $q = new CGI;
   print $q-&gt;blockquote(
		     "Many years ago on the island of",
		     $q-&gt;a({href=&gt;"http://crete.org/"},"Crete"),
		     "there lived a minotaur named",
		     $q-&gt;strong("Fred."),
		    ),
       $q-&gt;hr;

This results in the following HTML code (extra newlines have been
added for readability):

   &lt;blockquote&gt;
   Many years ago on the island of
   &lt;a HREF="http://crete.org/"&gt;Crete&lt;/a&gt; there lived
   a minotaur named &lt;strong&gt;Fred.&lt;/strong&gt; 
   &lt;/blockquote&gt;
   &lt;hr&gt;

If you find the syntax for calling the HTML shortcuts awkward, you can
import them into your namespace and dispense with the object syntax
completely (see the next section for more details):

   use CGI ':standard';
   print blockquote(
      "Many years ago on the island of",
      a({href=&gt;"http://crete.org/"},"Crete"),
      "there lived a minotaur named",
      strong("Fred."),
      ),
      hr;

=head2 PROVIDING ARGUMENTS TO HTML SHORTCUTS

The HTML methods will accept zero, one or multiple arguments.  If you
provide no arguments, you get a single tag:

   print hr;  	#  &lt;HR&gt;

If you provide one or more string arguments, they are concatenated
together with spaces and placed between opening and closing tags:

   print h1("Chapter","1"); # &lt;H1&gt;Chapter 1&lt;/H1&gt;"

If the first argument is an associative array reference, then the keys
and values of the associative array become the HTML tag's attributes:

   print a({-href=&gt;'fred.html',-target=&gt;'_new'},
      "Open a new frame");

	    &lt;A HREF="fred.html",TARGET="_new"&gt;Open a new frame&lt;/A&gt;
   
You may dispense with the dashes in front of the attribute names if
you prefer:

   print img {src=&gt;'fred.gif',align=&gt;'LEFT'};

	   &lt;IMG ALIGN="LEFT" SRC="fred.gif"&gt;

Sometimes an HTML tag attribute has no argument.  For example, ordered
lists can be marked as COMPACT.  The syntax for this is an argument that
that points to an undef string:

   print ol({compact=&gt;undef},li('one'),li('two'),li('three'));

Prior to CGI.pm version 2.41, providing an empty ('') string as an
attribute argument was the same as providing undef.  However, this has
changed in order to accomodate those who want to create tags of the form 
&lt;IMG ALT=""&gt;.  The difference is shown in these two pieces of code:
  
   CODE                   RESULT
   img({alt=&gt;undef})      &lt;IMG ALT&gt;
   img({alt=&gt;''})         &lt;IMT ALT=""&gt;

=head2 THE DISTRIBUTIVE PROPERTY OF HTML SHORTCUTS

One of the cool features of the HTML shortcuts is that they are
distributive.  If you give them an argument consisting of a
B&lt;reference&gt; to a list, the tag will be distributed across each
element of the list.  For example, here's one way to make an ordered
list:

   print ul(
             li({-type=&gt;'disc'},['Sneezy','Doc','Sleepy','Happy']);
           );

This example will result in HTML output that looks like this:

   &lt;UL&gt;
     &lt;LI TYPE="disc"&gt;Sneezy&lt;/LI&gt;
     &lt;LI TYPE="disc"&gt;Doc&lt;/LI&gt;
     &lt;LI TYPE="disc"&gt;Sleepy&lt;/LI&gt;
     &lt;LI TYPE="disc"&gt;Happy&lt;/LI&gt;
   &lt;/UL&gt;

This is extremely useful for creating tables.  For example:

   print table({-border=&gt;undef},
           caption('When Should You Eat Your Vegetables?'),
           Tr({-align=&gt;CENTER,-valign=&gt;TOP},
           [
              th(['Vegetable', 'Breakfast','Lunch','Dinner']),
              td(['Tomatoes' , 'no', 'yes', 'yes']),
              td(['Broccoli' , 'no', 'no',  'yes']),
              td(['Onions'   , 'yes','yes', 'yes'])
           ]
           )
        );

=head2 HTML SHORTCUTS AND LIST INTERPOLATION

Consider this bit of code:

   print blockquote(em('Hi'),'mom!'));

It will ordinarily return the string that you probably expect, namely:

   &lt;BLOCKQUOTE&gt;&lt;EM&gt;Hi&lt;/EM&gt; mom!&lt;/BLOCKQUOTE&gt;

Note the space between the element "Hi" and the element "mom!".
CGI.pm puts the extra space there using array interpolation, which is
controlled by the magic $" variable.  Sometimes this extra space is
not what you want, for example, when you are trying to align a series
of images.  In this case, you can simply change the value of $" to an
empty string.

   {
      local($") = '';
      print blockquote(em('Hi'),'mom!'));
    }

I suggest you put the code in a block as shown here.  Otherwise the
change to $" will affect all subsequent code until you explicitly
reset it.

=head2 NON-STANDARD HTML SHORTCUTS

A few HTML tags don't follow the standard pattern for various
reasons.  

B&lt;comment()&gt; generates an HTML comment (&lt;!-- comment --&gt;).  Call it
like

    print comment('here is my comment');

Because of conflicts with built-in Perl functions, the following functions
begin with initial caps:

    Select
    Tr
    Link
    Delete
    Accept
    Sub

In addition, start_html(), end_html(), start_form(), end_form(),
start_multipart_form() and all the fill-out form tags are special.
See their respective sections.

=head2 PRETTY-PRINTING HTML

By default, all the HTML produced by these functions comes out as one
long line without carriage returns or indentation. This is yuck, but
it does reduce the size of the documents by 10-20%.  To get
pretty-printed output, please use L&lt;CGI::Pretty&gt;, a subclass
contributed by Brian Paulsen.

=head1 CREATING FILL-OUT FORMS:

I&lt;General note&gt;  The various form-creating methods all return strings
to the caller, containing the tag or tags that will create the requested
form element.  You are responsible for actually printing out these strings.
It's set up this way so that you can place formatting tags
around the form elements.

I&lt;Another note&gt; The default values that you specify for the forms are only
used the B&lt;first&gt; time the script is invoked (when there is no query
string).  On subsequent invocations of the script (when there is a query
string), the former values are used even if they are blank.  

If you want to change the value of a field from its previous value, you have two
choices:

(1) call the param() method to set it.

(2) use the -override (alias -force) parameter (a new feature in version 2.15).
This forces the default value to be used, regardless of the previous value:

   print $query-&gt;textfield(-name=&gt;'field_name',
			   -default=&gt;'starting value',
			   -override=&gt;1,
			   -size=&gt;50,
			   -maxlength=&gt;80);

I&lt;Yet another note&gt; By default, the text and labels of form elements are
escaped according to HTML rules.  This means that you can safely use
"&lt;CLICK ME&gt;" as the label for a button.  However, it also interferes with
your ability to incorporate special HTML character sequences, such as &amp;Aacute;,
into your fields.  If you wish to turn off automatic escaping, call the
autoEscape() method with a false value immediately after creating the CGI object:

   $query = new CGI;
   $query-&gt;autoEscape(undef);
			     

=head2 CREATING AN ISINDEX TAG

   print $query-&gt;isindex(-action=&gt;$action);

	 -or-

   print $query-&gt;isindex($action);

Prints out an &lt;ISINDEX&gt; tag.  Not very exciting.  The parameter
-action specifies the URL of the script to process the query.  The
default is to process the query with the current script.

=head2 STARTING AND ENDING A FORM

    print $query-&gt;startform(-method=&gt;$method,
			    -action=&gt;$action,
			    -enctype=&gt;$encoding);
      &lt;... various form stuff ...&gt;
    print $query-&gt;endform;

	-or-

    print $query-&gt;startform($method,$action,$encoding);
      &lt;... various form stuff ...&gt;
    print $query-&gt;endform;

startform() will return a &lt;FORM&gt; tag with the optional method,
action and form encoding that you specify.  The defaults are:
	
    method: POST
    action: this script
    enctype: application/x-www-form-urlencoded

endform() returns the closing &lt;/FORM&gt; tag.  

Startform()'s enctype argument tells the browser how to package the various
fields of the form before sending the form to the server.  Two
values are possible:

=over 4

=item B&lt;application/x-www-form-urlencoded&gt;

This is the older type of encoding used by all browsers prior to
Netscape 2.0.  It is compatible with many CGI scripts and is
suitable for short fields containing text data.  For your
convenience, CGI.pm stores the name of this encoding
type in B&lt;$CGI::URL_ENCODED&gt;.

=item B&lt;multipart/form-data&gt;

This is the newer type of encoding introduced by Netscape 2.0.
It is suitable for forms that contain very large fields or that
are intended for transferring binary data.  Most importantly,
it enables the "file upload" feature of Netscape 2.0 forms.  For
your convenience, CGI.pm stores the name of this encoding type
in B&lt;&amp;CGI::MULTIPART&gt;

Forms that use this type of encoding are not easily interpreted
by CGI scripts unless they use CGI.pm or another library designed
to handle them.

=back

For compatibility, the startform() method uses the older form of
encoding by default.  If you want to use the newer form of encoding
by default, you can call B&lt;start_multipart_form()&gt; instead of
B&lt;startform()&gt;.

JAVASCRIPTING: The B&lt;-name&gt; and B&lt;-onSubmit&gt; parameters are provided
for use with JavaScript.  The -name parameter gives the
form a name so that it can be identified and manipulated by
JavaScript functions.  -onSubmit should point to a JavaScript
function that will be executed just before the form is submitted to your
server.  You can use this opportunity to check the contents of the form 
for consistency and completeness.  If you find something wrong, you
can put up an alert box or maybe fix things up yourself.  You can 
abort the submission by returning false from this function.  

Usually the bulk of JavaScript functions are defined in a &lt;SCRIPT&gt;
block in the HTML header and -onSubmit points to one of these function
call.  See start_html() for details.

=head2 CREATING A TEXT FIELD

    print $query-&gt;textfield(-name=&gt;'field_name',
			    -default=&gt;'starting value',
			    -size=&gt;50,
			    -maxlength=&gt;80);
	-or-

    print $query-&gt;textfield('field_name','starting value',50,80);

textfield() will return a text input field.  

=over 4

=item B&lt;Parameters&gt;

=item 1.

The first parameter is the required name for the field (-name).  

=item 2.

The optional second parameter is the default starting value for the field
contents (-default).  

=item 3.

The optional third parameter is the size of the field in
      characters (-size).

=item 4.

The optional fourth parameter is the maximum number of characters the
      field will accept (-maxlength).

=back

As with all these methods, the field will be initialized with its 
previous contents from earlier invocations of the script.
When the form is processed, the value of the text field can be
retrieved with:

       $value = $query-&gt;param('foo');

If you want to reset it from its initial value after the script has been
called once, you can do so like this:

       $query-&gt;param('foo',"I'm taking over this value!");

NEW AS OF VERSION 2.15: If you don't want the field to take on its previous
value, you can force its current value by using the -override (alias -force)
parameter:

    print $query-&gt;textfield(-name=&gt;'field_name',
			    -default=&gt;'starting value',
			    -override=&gt;1,
			    -size=&gt;50,
			    -maxlength=&gt;80);

JAVASCRIPTING: You can also provide B&lt;-onChange&gt;, B&lt;-onFocus&gt;,
B&lt;-onBlur&gt;, B&lt;-onMouseOver&gt;, B&lt;-onMouseOut&gt; and B&lt;-onSelect&gt;
parameters to register JavaScript event handlers.  The onChange
handler will be called whenever the user changes the contents of the
text field.  You can do text validation if you like.  onFocus and
onBlur are called respectively when the insertion point moves into and
out of the text field.  onSelect is called when the user changes the
portion of the text that is selected.

=head2 CREATING A BIG TEXT FIELD

   print $query-&gt;textarea(-name=&gt;'foo',
			  -default=&gt;'starting value',
			  -rows=&gt;10,
			  -columns=&gt;50);

	-or

   print $query-&gt;textarea('foo','starting value',10,50);

textarea() is just like textfield, but it allows you to specify
rows and columns for a multiline text entry box.  You can provide
a starting value for the field, which can be long and contain
multiple lines.

JAVASCRIPTING: The B&lt;-onChange&gt;, B&lt;-onFocus&gt;, B&lt;-onBlur&gt; ,
B&lt;-onMouseOver&gt;, B&lt;-onMouseOut&gt;, and B&lt;-onSelect&gt; parameters are
recognized.  See textfield().

=head2 CREATING A PASSWORD FIELD

   print $query-&gt;password_field(-name=&gt;'secret',
				-value=&gt;'starting value',
				-size=&gt;50,
				-maxlength=&gt;80);
	-or-

   print $query-&gt;password_field('secret','starting value',50,80);

password_field() is identical to textfield(), except that its contents 
will be starred out on the web page.

JAVASCRIPTING: The B&lt;-onChange&gt;, B&lt;-onFocus&gt;, B&lt;-onBlur&gt;,
B&lt;-onMouseOver&gt;, B&lt;-onMouseOut&gt; and B&lt;-onSelect&gt; parameters are
recognized.  See textfield().

=head2 CREATING A FILE UPLOAD FIELD

    print $query-&gt;filefield(-name=&gt;'uploaded_file',
			    -default=&gt;'starting value',
			    -size=&gt;50,
			    -maxlength=&gt;80);
	-or-

    print $query-&gt;filefield('uploaded_file','starting value',50,80);

filefield() will return a file upload field for Netscape 2.0 browsers.
In order to take full advantage of this I&lt;you must use the new 
multipart encoding scheme&gt; for the form.  You can do this either
by calling B&lt;startform()&gt; with an encoding type of B&lt;$CGI::MULTIPART&gt;,
or by calling the new method B&lt;start_multipart_form()&gt; instead of
vanilla B&lt;startform()&gt;.

=over 4

=item B&lt;Parameters&gt;

=item 1.

The first parameter is the required name for the field (-name).  

=item 2.

The optional second parameter is the starting value for the field contents
to be used as the default file name (-default).

For security reasons, browsers don't pay any attention to this field,
and so the starting value will always be blank.  Worse, the field
loses its "sticky" behavior and forgets its previous contents.  The
starting value field is called for in the HTML specification, however,
and possibly some browser will eventually provide support for it.

=item 3.

The optional third parameter is the size of the field in
characters (-size).

=item 4.

The optional fourth parameter is the maximum number of characters the
field will accept (-maxlength).

=back

When the form is processed, you can retrieve the entered filename
by calling param().

       $filename = $query-&gt;param('uploaded_file');

In Netscape Navigator 2.0, the filename that gets returned is the full
local filename on the B&lt;remote user's&gt; machine.  If the remote user is
on a Unix machine, the filename will follow Unix conventions:

	/path/to/the/file

On an MS-DOS/Windows and OS/2 machines, the filename will follow DOS conventions:

	C:\PATH\TO\THE\FILE.MSW

On a Macintosh machine, the filename will follow Mac conventions:

	HD 40:Desktop Folder:Sort Through:Reminders

The filename returned is also a file handle.  You can read the contents
of the file using standard Perl file reading calls:

	# Read a text file and print it out
	while (&lt;$filename&gt;) {
	   print;
	}

	# Copy a binary file to somewhere safe
	open (OUTFILE,"&gt;&gt;/usr/local/web/users/feedback");
	while ($bytesread=read($filename,$buffer,1024)) {
	   print OUTFILE $buffer;
	}

When a file is uploaded the browser usually sends along some
information along with it in the format of headers.  The information
usually includes the MIME content type.  Future browsers may send
other information as well (such as modification date and size). To
retrieve this information, call uploadInfo().  It returns a reference to
an associative array containing all the document headers.

       $filename = $query-&gt;param('uploaded_file');
       $type = $query-&gt;uploadInfo($filename)-&gt;{'Content-Type'};
       unless ($type eq 'text/html') {
	  die "HTML FILES ONLY!";
       }

If you are using a machine that recognizes "text" and "binary" data
modes, be sure to understand when and how to use them (see the Camel book).  
Otherwise you may find that binary files are corrupted during file uploads.

JAVASCRIPTING: The B&lt;-onChange&gt;, B&lt;-onFocus&gt;, B&lt;-onBlur&gt;,
B&lt;-onMouseOver&gt;, B&lt;-onMouseOut&gt; and B&lt;-onSelect&gt; parameters are
recognized.  See textfield() for details.

=head2 CREATING A POPUP MENU

   print $query-&gt;popup_menu('menu_name',
			    ['eenie','meenie','minie'],
			    'meenie');

      -or-

   %labels = ('eenie'=&gt;'your first choice',
	      'meenie'=&gt;'your second choice',
	      'minie'=&gt;'your third choice');
   print $query-&gt;popup_menu('menu_name',
			    ['eenie','meenie','minie'],
			    'meenie',\%labels);

	-or (named parameter style)-

   print $query-&gt;popup_menu(-name=&gt;'menu_name',
			    -values=&gt;['eenie','meenie','minie'],
			    -default=&gt;'meenie',
			    -labels=&gt;\%labels);

popup_menu() creates a menu.

=over 4

=item 1.

The required first argument is the menu's name (-name).

=item 2.

The required second argument (-values) is an array B&lt;reference&gt;
containing the list of menu items in the menu.  You can pass the
method an anonymous array, as shown in the example, or a reference to
a named array, such as "\@foo".

=item 3.

The optional third parameter (-default) is the name of the default
menu choice.  If not specified, the first item will be the default.
The values of the previous choice will be maintained across queries.

=item 4.

The optional fourth parameter (-labels) is provided for people who
want to use different values for the user-visible label inside the
popup menu nd the value returned to your script.  It's a pointer to an
associative array relating menu values to user-visible labels.  If you
leave this parameter blank, the menu values will be displayed by
default.  (You can also leave a label undefined if you want to).

=back

When the form is processed, the selected value of the popup menu can
be retrieved using:

      $popup_menu_value = $query-&gt;param('menu_name');

JAVASCRIPTING: popup_menu() recognizes the following event handlers:
B&lt;-onChange&gt;, B&lt;-onFocus&gt;, B&lt;-onMouseOver&gt;, B&lt;-onMouseOut&gt;, and
B&lt;-onBlur&gt;.  See the textfield() section for details on when these
handlers are called.

=head2 CREATING A SCROLLING LIST

   print $query-&gt;scrolling_list('list_name',
				['eenie','meenie','minie','moe'],
				['eenie','moe'],5,'true');
      -or-

   print $query-&gt;scrolling_list('list_name',
				['eenie','meenie','minie','moe'],
				['eenie','moe'],5,'true',
				\%labels);

	-or-

   print $query-&gt;scrolling_list(-name=&gt;'list_name',
				-values=&gt;['eenie','meenie','minie','moe'],
				-default=&gt;['eenie','moe'],
				-size=&gt;5,
				-multiple=&gt;'true',
				-labels=&gt;\%labels);

scrolling_list() creates a scrolling list.  

=over 4

=item B&lt;Parameters:&gt;

=item 1.

The first and second arguments are the list name (-name) and values
(-values).  As in the popup menu, the second argument should be an
array reference.

=item 2.

The optional third argument (-default) can be either a reference to a
list containing the values to be selected by default, or can be a
single value to select.  If this argument is missing or undefined,
then nothing is selected when the list first appears.  In the named
parameter version, you can use the synonym "-defaults" for this
parameter.

=item 3.

The optional fourth argument is the size of the list (-size).

=item 4.

The optional fifth argument can be set to true to allow multiple
simultaneous selections (-multiple).  Otherwise only one selection
will be allowed at a time.

=item 5.

The optional sixth argument is a pointer to an associative array
containing long user-visible labels for the list items (-labels).
If not provided, the values will be displayed.

When this form is processed, all selected list items will be returned as
a list under the parameter name 'list_name'.  The values of the
selected items can be retrieved with:

      @selected = $query-&gt;param('list_name');

=back

JAVASCRIPTING: scrolling_list() recognizes the following event
handlers: B&lt;-onChange&gt;, B&lt;-onFocus&gt;, B&lt;-onMouseOver&gt;, B&lt;-onMouseOut&gt;
and B&lt;-onBlur&gt;.  See textfield() for the description of when these
handlers are called.

=head2 CREATING A GROUP OF RELATED CHECKBOXES

   print $query-&gt;checkbox_group(-name=&gt;'group_name',
				-values=&gt;['eenie','meenie','minie','moe'],
				-default=&gt;['eenie','moe'],
				-linebreak=&gt;'true',
				-labels=&gt;\%labels);

   print $query-&gt;checkbox_group('group_name',
				['eenie','meenie','minie','moe'],
				['eenie','moe'],'true',\%labels);

   HTML3-COMPATIBLE BROWSERS ONLY:

   print $query-&gt;checkbox_group(-name=&gt;'group_name',
				-values=&gt;['eenie','meenie','minie','moe'],
				-rows=2,-columns=&gt;2);
    

checkbox_group() creates a list of checkboxes that are related
by the same name.

=over 4

=item B&lt;Parameters:&gt;

=item 1.

The first and second arguments are the checkbox name and values,
respectively (-name and -values).  As in the popup menu, the second
argument should be an array reference.  These values are used for the
user-readable labels printed next to the checkboxes as well as for the
values passed to your script in the query string.

=item 2.

The optional third argument (-default) can be either a reference to a
list containing the values to be checked by default, or can be a
single value to checked.  If this argument is missing or undefined,
then nothing is selected when the list first appears.

=item 3.

The optional fourth argument (-linebreak) can be set to true to place
line breaks between the checkboxes so that they appear as a vertical
list.  Otherwise, they will be strung together on a horizontal line.

=item 4.

The optional fifth argument is a pointer to an associative array
relating the checkbox values to the user-visible labels that will
be printed next to them (-labels).  If not provided, the values will
be used as the default.

=item 5.

B&lt;HTML3-compatible browsers&gt; (such as Netscape) can take advantage of
the optional parameters B&lt;-rows&gt;, and B&lt;-columns&gt;.  These parameters
cause checkbox_group() to return an HTML3 compatible table containing
the checkbox group formatted with the specified number of rows and
columns.  You can provide just the -columns parameter if you wish;
checkbox_group will calculate the correct number of rows for you.

To include row and column headings in the returned table, you
can use the B&lt;-rowheaders&gt; and B&lt;-colheaders&gt; parameters.  Both
of these accept a pointer to an array of headings to use.
The headings are just decorative.  They don't reorganize the
interpretation of the checkboxes -- they're still a single named
unit.

=back

When the form is processed, all checked boxes will be returned as
a list under the parameter name 'group_name'.  The values of the
"on" checkboxes can be retrieved with:

      @turned_on = $query-&gt;param('group_name');

The value returned by checkbox_group() is actually an array of button
elements.  You can capture them and use them within tables, lists,
or in other creative ways:

    @h = $query-&gt;checkbox_group(-name=&gt;'group_name',-values=&gt;\@values);
    &amp;use_in_creative_way(@h);

JAVASCRIPTING: checkbox_group() recognizes the B&lt;-onClick&gt;
parameter.  This specifies a JavaScript code fragment or
function call to be executed every time the user clicks on
any of the buttons in the group.  You can retrieve the identity
of the particular button clicked on using the "this" variable.

=head2 CREATING A STANDALONE CHECKBOX

    print $query-&gt;checkbox(-name=&gt;'checkbox_name',
			   -checked=&gt;'checked',
			   -value=&gt;'ON',
			   -label=&gt;'CLICK ME');

	-or-

    print $query-&gt;checkbox('checkbox_name','checked','ON','CLICK ME');

checkbox() is used to create an isolated checkbox that isn't logically
related to any others.

=over 4

=item B&lt;Parameters:&gt;

=item 1.

The first parameter is the required name for the checkbox (-name).  It
will also be used for the user-readable label printed next to the
checkbox.

=item 2.

The optional second parameter (-checked) specifies that the checkbox
is turned on by default.  Synonyms are -selected and -on.

=item 3.

The optional third parameter (-value) specifies the value of the
checkbox when it is checked.  If not provided, the word "on" is
assumed.

=item 4.

The optional fourth parameter (-label) is the user-readable label to
be attached to the checkbox.  If not provided, the checkbox name is
used.

=back

The value of the checkbox can be retrieved using:

    $turned_on = $query-&gt;param('checkbox_name');

JAVASCRIPTING: checkbox() recognizes the B&lt;-onClick&gt;
parameter.  See checkbox_group() for further details.

=head2 CREATING A RADIO BUTTON GROUP

   print $query-&gt;radio_group(-name=&gt;'group_name',
			     -values=&gt;['eenie','meenie','minie'],
			     -default=&gt;'meenie',
			     -linebreak=&gt;'true',
			     -labels=&gt;\%labels);

	-or-

   print $query-&gt;radio_group('group_name',['eenie','meenie','minie'],
					  'meenie','true',\%labels);


   HTML3-COMPATIBLE BROWSERS ONLY:

   print $query-&gt;radio_group(-name=&gt;'group_name',
			     -values=&gt;['eenie','meenie','minie','moe'],
			     -rows=2,-columns=&gt;2);

radio_group() creates a set of logically-related radio buttons
(turning one member of the group on turns the others off)

=over 4

=item B&lt;Parameters:&gt;

=item 1.

The first argument is the name of the group and is required (-name).

=item 2.

The second argument (-values) is the list of values for the radio
buttons.  The values and the labels that appear on the page are
identical.  Pass an array I&lt;reference&gt; in the second argument, either
using an anonymous array, as shown, or by referencing a named array as
in "\@foo".

=item 3.

The optional third parameter (-default) is the name of the default
button to turn on. If not specified, the first item will be the
default.  You can provide a nonexistent button name, such as "-" to
start up with no buttons selected.

=item 4.

The optional fourth parameter (-linebreak) can be set to 'true' to put
line breaks between the buttons, creating a vertical list.

=item 5.

The optional fifth parameter (-labels) is a pointer to an associative
array relating the radio button values to user-visible labels to be
used in the display.  If not provided, the values themselves are
displayed.

=item 6.

B&lt;HTML3-compatible browsers&gt; (such as Netscape) can take advantage 
of the optional 
parameters B&lt;-rows&gt;, and B&lt;-columns&gt;.  These parameters cause
radio_group() to return an HTML3 compatible table containing
the radio group formatted with the specified number of rows
and columns.  You can provide just the -columns parameter if you
wish; radio_group will calculate the correct number of rows
for you.

To include row and column headings in the returned table, you
can use the B&lt;-rowheader&gt; and B&lt;-colheader&gt; parameters.  Both
of these accept a pointer to an array of headings to use.
The headings are just decorative.  They don't reorganize the
interpetation of the radio buttons -- they're still a single named
unit.

=back

When the form is processed, the selected radio button can
be retrieved using:

      $which_radio_button = $query-&gt;param('group_name');

The value returned by radio_group() is actually an array of button
elements.  You can capture them and use them within tables, lists,
or in other creative ways:

    @h = $query-&gt;radio_group(-name=&gt;'group_name',-values=&gt;\@values);
    &amp;use_in_creative_way(@h);

=head2 CREATING A SUBMIT BUTTON 

   print $query-&gt;submit(-name=&gt;'button_name',
			-value=&gt;'value');

	-or-

   print $query-&gt;submit('button_name','value');

submit() will create the query submission button.  Every form
should have one of these.

=over 4

=item B&lt;Parameters:&gt;

=item 1.

The first argument (-name) is optional.  You can give the button a
name if you have several submission buttons in your form and you want
to distinguish between them.  The name will also be used as the
user-visible label.  Be aware that a few older browsers don't deal with this correctly and
B&lt;never&gt; send back a value from a button.

=item 2.

The second argument (-value) is also optional.  This gives the button
a value that will be passed to your script in the query string.

=back

You can figure out which button was pressed by using different
values for each one:

     $which_one = $query-&gt;param('button_name');

JAVASCRIPTING: radio_group() recognizes the B&lt;-onClick&gt;
parameter.  See checkbox_group() for further details.

=head2 CREATING A RESET BUTTON

   print $query-&gt;reset

reset() creates the "reset" button.  Note that it restores the
form to its value from the last time the script was called, 
NOT necessarily to the defaults.

Note that this conflicts with the Perl reset() built-in.  Use
CORE::reset() to get the original reset function.

=head2 CREATING A DEFAULT BUTTON

   print $query-&gt;defaults('button_label')

defaults() creates a button that, when invoked, will cause the
form to be completely reset to its defaults, wiping out all the
changes the user ever made.

=head2 CREATING A HIDDEN FIELD

	print $query-&gt;hidden(-name=&gt;'hidden_name',
			     -default=&gt;['value1','value2'...]);

		-or-

	print $query-&gt;hidden('hidden_name','value1','value2'...);

hidden() produces a text field that can't be seen by the user.  It
is useful for passing state variable information from one invocation
of the script to the next.

=over 4

=item B&lt;Parameters:&gt;

=item 1.

The first argument is required and specifies the name of this
field (-name).

=item 2.  

The second argument is also required and specifies its value
(-default).  In the named parameter style of calling, you can provide
a single value here or a reference to a whole list

=back

Fetch the value of a hidden field this way:

     $hidden_value = $query-&gt;param('hidden_name');

Note, that just like all the other form elements, the value of a
hidden field is "sticky".  If you want to replace a hidden field with
some other values after the script has been called once you'll have to
do it manually:

     $query-&gt;param('hidden_name','new','values','here');

=head2 CREATING A CLICKABLE IMAGE BUTTON

     print $query-&gt;image_button(-name=&gt;'button_name',
				-src=&gt;'/source/URL',
				-align=&gt;'MIDDLE');      

	-or-

     print $query-&gt;image_button('button_name','/source/URL','MIDDLE');

image_button() produces a clickable image.  When it's clicked on the
position of the click is returned to your script as "button_name.x"
and "button_name.y", where "button_name" is the name you've assigned
to it.

JAVASCRIPTING: image_button() recognizes the B&lt;-onClick&gt;
parameter.  See checkbox_group() for further details.

=over 4

=item B&lt;Parameters:&gt;

=item 1.

The first argument (-name) is required and specifies the name of this
field.

=item 2.

The second argument (-src) is also required and specifies the URL

=item 3.
The third option (-align, optional) is an alignment type, and may be
TOP, BOTTOM or MIDDLE

=back

Fetch the value of the button this way:
     $x = $query-&gt;param('button_name.x');
     $y = $query-&gt;param('button_name.y');

=head2 CREATING A JAVASCRIPT ACTION BUTTON

     print $query-&gt;button(-name=&gt;'button_name',
			  -value=&gt;'user visible label',
			  -onClick=&gt;"do_something()");

	-or-

     print $query-&gt;button('button_name',"do_something()");

button() produces a button that is compatible with Netscape 2.0's
JavaScript.  When it's pressed the fragment of JavaScript code
pointed to by the B&lt;-onClick&gt; parameter will be executed.  On
non-Netscape browsers this form element will probably not even
display.

=head1 HTTP COOKIES

Netscape browsers versions 1.1 and higher, and all versions of
Internet Explorer, support a so-called "cookie" designed to help
maintain state within a browser session.  CGI.pm has several methods
that support cookies.

A cookie is a name=value pair much like the named parameters in a CGI
query string.  CGI scripts create one or more cookies and send
them to the browser in the HTTP header.  The browser maintains a list
of cookies that belong to a particular Web server, and returns them
to the CGI script during subsequent interactions.

In addition to the required name=value pair, each cookie has several
optional attributes:

=over 4

=item 1. an expiration time

This is a time/date string (in a special GMT format) that indicates
when a cookie expires.  The cookie will be saved and returned to your
script until this expiration date is reached if the user exits
the browser and restarts it.  If an expiration date isn't specified, the cookie
will remain active until the user quits the browser.

=item 2. a domain

This is a partial or complete domain name for which the cookie is 
valid.  The browser will return the cookie to any host that matches
the partial domain name.  For example, if you specify a domain name
of ".capricorn.com", then the browser will return the cookie to
Web servers running on any of the machines "www.capricorn.com", 
"www2.capricorn.com", "feckless.capricorn.com", etc.  Domain names
must contain at least two periods to prevent attempts to match
on top level domains like ".edu".  If no domain is specified, then
the browser will only return the cookie to servers on the host the
cookie originated from.

=item 3. a path

If you provide a cookie path attribute, the browser will check it
against your script's URL before returning the cookie.  For example,
if you specify the path "/cgi-bin", then the cookie will be returned
to each of the scripts "/cgi-bin/tally.pl", "/cgi-bin/order.pl",
and "/cgi-bin/customer_service/complain.pl", but not to the script
"/cgi-private/site_admin.pl".  By default, path is set to "/", which
causes the cookie to be sent to any CGI script on your site.

=item 4. a "secure" flag

If the "secure" attribute is set, the cookie will only be sent to your
script if the CGI request is occurring on a secure channel, such as SSL.

=back

The interface to HTTP cookies is the B&lt;cookie()&gt; method:

    $cookie = $query-&gt;cookie(-name=&gt;'sessionID',
			     -value=&gt;'xyzzy',
			     -expires=&gt;'+1h',
			     -path=&gt;'/cgi-bin/database',
			     -domain=&gt;'.capricorn.org',
			     -secure=&gt;1);
    print $query-&gt;header(-cookie=&gt;$cookie);

B&lt;cookie()&gt; creates a new cookie.  Its parameters include:

=over 4

=item B&lt;-name&gt;

The name of the cookie (required).  This can be any string at all.
Although browsers limit their cookie names to non-whitespace
alphanumeric characters, CGI.pm removes this restriction by escaping
and unescaping cookies behind the scenes.

=item B&lt;-value&gt;

The value of the cookie.  This can be any scalar value,
array reference, or even associative array reference.  For example,
you can store an entire associative array into a cookie this way:

	$cookie=$query-&gt;cookie(-name=&gt;'family information',
			       -value=&gt;\%childrens_ages);

=item B&lt;-path&gt;

The optional partial path for which this cookie will be valid, as described
above.

=item B&lt;-domain&gt;

The optional partial domain for which this cookie will be valid, as described
above.

=item B&lt;-expires&gt;

The optional expiration date for this cookie.  The format is as described 
in the section on the B&lt;header()&gt; method:

	"+1h"  one hour from now

=item B&lt;-secure&gt;

If set to true, this cookie will only be used within a secure
SSL session.

=back

The cookie created by cookie() must be incorporated into the HTTP
header within the string returned by the header() method:

	print $query-&gt;header(-cookie=&gt;$my_cookie);

To create multiple cookies, give header() an array reference:

	$cookie1 = $query-&gt;cookie(-name=&gt;'riddle_name',
				  -value=&gt;"The Sphynx's Question");
	$cookie2 = $query-&gt;cookie(-name=&gt;'answers',
				  -value=&gt;\%answers);
	print $query-&gt;header(-cookie=&gt;[$cookie1,$cookie2]);

To retrieve a cookie, request it by name by calling cookie()
method without the B&lt;-value&gt; parameter:

	use CGI;
	$query = new CGI;
	%answers = $query-&gt;cookie(-name=&gt;'answers');
	# $query-&gt;cookie('answers') will work too!

The cookie and CGI namespaces are separate.  If you have a parameter
named 'answers' and a cookie named 'answers', the values retrieved by
param() and cookie() are independent of each other.  However, it's
simple to turn a CGI parameter into a cookie, and vice-versa:

   # turn a CGI parameter into a cookie
   $c=$q-&gt;cookie(-name=&gt;'answers',-value=&gt;[$q-&gt;param('answers')]);
   # vice-versa
   $q-&gt;param(-name=&gt;'answers',-value=&gt;[$q-&gt;cookie('answers')]);

See the B&lt;cookie.cgi&gt; example script for some ideas on how to use
cookies effectively.

=head1 WORKING WITH FRAMES

It's possible for CGI.pm scripts to write into several browser panels
and windows using the HTML 4 frame mechanism.  There are three
techniques for defining new frames programmatically:

=over 4

=item 1. Create a &lt;Frameset&gt; document

After writing out the HTTP header, instead of creating a standard
HTML document using the start_html() call, create a &lt;FRAMESET&gt; 
document that defines the frames on the page.  Specify your script(s)
(with appropriate parameters) as the SRC for each of the frames.

There is no specific support for creating &lt;FRAMESET&gt; sections 
in CGI.pm, but the HTML is very simple to write.  See the frame
documentation in Netscape's home pages for details 

  http://home.netscape.com/assist/net_sites/frames.html

=item 2. Specify the destination for the document in the HTTP header

You may provide a B&lt;-target&gt; parameter to the header() method:
   
    print $q-&gt;header(-target=&gt;'ResultsWindow');

This will tell the browser to load the output of your script into the
frame named "ResultsWindow".  If a frame of that name doesn't already
exist, the browser will pop up a new window and load your script's
document into that.  There are a number of magic names that you can
use for targets.  See the frame documents on Netscape's home pages for
details.

=item 3. Specify the destination for the document in the &lt;FORM&gt; tag

You can specify the frame to load in the FORM tag itself.  With
CGI.pm it looks like this:

    print $q-&gt;startform(-target=&gt;'ResultsWindow');

When your script is reinvoked by the form, its output will be loaded
into the frame named "ResultsWindow".  If one doesn't already exist
a new window will be created.

=back

The script "frameset.cgi" in the examples directory shows one way to
create pages in which the fill-out form and the response live in
side-by-side frames.

=head1 LIMITED SUPPORT FOR CASCADING STYLE SHEETS

CGI.pm has limited support for HTML3's cascading style sheets (css).
To incorporate a stylesheet into your document, pass the
start_html() method a B&lt;-style&gt; parameter.  The value of this
parameter may be a scalar, in which case it is incorporated directly
into a &lt;STYLE&gt; section, or it may be a hash reference.  In the latter
case you should provide the hash with one or more of B&lt;-src&gt; or
B&lt;-code&gt;.  B&lt;-src&gt; points to a URL where an externally-defined
stylesheet can be found.  B&lt;-code&gt; points to a scalar value to be
incorporated into a &lt;STYLE&gt; section.  Style definitions in B&lt;-code&gt;
override similarly-named ones in B&lt;-src&gt;, hence the name "cascading."

You may also specify the type of the stylesheet by adding the optional
B&lt;-type&gt; parameter to the hash pointed to by B&lt;-style&gt;.  If not
specified, the style defaults to 'text/css'.

To refer to a style within the body of your document, add the
B&lt;-class&gt; parameter to any HTML element:

    print h1({-class=&gt;'Fancy'},'Welcome to the Party');

Or define styles on the fly with the B&lt;-style&gt; parameter:

    print h1({-style=&gt;'Color: red;'},'Welcome to Hell');

You may also use the new B&lt;span()&gt; element to apply a style to a
section of text:

    print span({-style=&gt;'Color: red;'},
	       h1('Welcome to Hell'),
	       "Where did that handbasket get to?"
	       );

Note that you must import the ":html3" definitions to have the
B&lt;span()&gt; method available.  Here's a quick and dirty example of using
CSS's.  See the CSS specification at
http://www.w3.org/pub/WWW/TR/Wd-css-1.html for more information.

    use CGI qw/:standard :html3/;

    #here's a stylesheet incorporated directly into the page
    $newStyle=&lt;&lt;END;
    &lt;!-- 
    P.Tip {
	margin-right: 50pt;
	margin-left: 50pt;
        color: red;
    }
    P.Alert {
	font-size: 30pt;
        font-family: sans-serif;
      color: red;
    }
    --&gt;
    END
    print header();
    print start_html( -title=&gt;'CGI with Style',
		      -style=&gt;{-src=&gt;'http://www.capricorn.com/style/st1.css',
		               -code=&gt;$newStyle}
	             );
    print h1('CGI with Style'),
          p({-class=&gt;'Tip'},
	    "Better read the cascading style sheet spec before playing with this!"),
          span({-style=&gt;'color: magenta'},
	       "Look Mom, no hands!",
	       p(),
	       "Whooo wee!"
	       );
    print end_html;

=head1 DEBUGGING

If you are running the script
from the command line or in the perl debugger, you can pass the script
a list of keywords or parameter=value pairs on the command line or 
from standard input (you don't have to worry about tricking your
script into reading from environment variables).
You can pass keywords like this:

    your_script.pl keyword1 keyword2 keyword3

or this:

   your_script.pl keyword1+keyword2+keyword3

or this:

    your_script.pl name1=value1 name2=value2

or this:

    your_script.pl name1=value1&amp;name2=value2

or even as newline-delimited parameters on standard input.

When debugging, you can use quotes and backslashes to escape 
characters in the familiar shell manner, letting you place
spaces and other funny characters in your parameter=value
pairs:

   your_script.pl "name1='I am a long value'" "name2=two\ words"

=head2 DUMPING OUT ALL THE NAME/VALUE PAIRS

The dump() method produces a string consisting of all the query's
name/value pairs formatted nicely as a nested list.  This is useful
for debugging purposes:

    print $query-&gt;dump
    

Produces something that looks like:

    &lt;UL&gt;
    &lt;LI&gt;name1
	&lt;UL&gt;
	&lt;LI&gt;value1
	&lt;LI&gt;value2
	&lt;/UL&gt;
    &lt;LI&gt;name2
	&lt;UL&gt;
	&lt;LI&gt;value1
	&lt;/UL&gt;
    &lt;/UL&gt;

As a shortcut, you can interpolate the entire CGI object into a string
and it will be replaced with the a nice HTML dump shown above:

    $query=new CGI;
    print "&lt;H2&gt;Current Values&lt;/H2&gt; $query\n";

=head1 FETCHING ENVIRONMENT VARIABLES

Some of the more useful environment variables can be fetched
through this interface.  The methods are as follows:

=over 4

=item B&lt;Accept()&gt;

Return a list of MIME types that the remote browser accepts. If you
give this method a single argument corresponding to a MIME type, as in
$query-&gt;Accept('text/html'), it will return a floating point value
corresponding to the browser's preference for this type from 0.0
(don't want) to 1.0.  Glob types (e.g. text/*) in the browser's accept
list are handled correctly.

Note that the capitalization changed between version 2.43 and 2.44 in
order to avoid conflict with Perl's accept() function.

=item B&lt;raw_cookie()&gt;

Returns the HTTP_COOKIE variable, an HTTP extension implemented by
Netscape browsers version 1.1 and higher, and all versions of Internet
Explorer.  Cookies have a special format, and this method call just
returns the raw form (?cookie dough).  See cookie() for ways of
setting and retrieving cooked cookies.

Called with no parameters, raw_cookie() returns the packed cookie
structure.  You can separate it into individual cookies by splitting
on the character sequence "; ".  Called with the name of a cookie,
retrieves the B&lt;unescaped&gt; form of the cookie.  You can use the
regular cookie() method to get the names, or use the raw_fetch()
method from the CGI::Cookie module.

=item B&lt;user_agent()&gt;

Returns the HTTP_USER_AGENT variable.  If you give
this method a single argument, it will attempt to
pattern match on it, allowing you to do something
like $query-&gt;user_agent(netscape);

=item B&lt;path_info()&gt;

Returns additional path information from the script URL.
E.G. fetching /cgi-bin/your_script/additional/stuff will
result in $query-&gt;path_info() returning
"additional/stuff".

NOTE: The Microsoft Internet Information Server
is broken with respect to additional path information.  If
you use the Perl DLL library, the IIS server will attempt to
execute the additional path information as a Perl script.
If you use the ordinary file associations mapping, the
path information will be present in the environment, 
but incorrect.  The best thing to do is to avoid using additional
path information in CGI scripts destined for use with IIS.

=item B&lt;path_translated()&gt;

As per path_info() but returns the additional
path information translated into a physical path, e.g.
"/usr/local/etc/httpd/htdocs/additional/stuff".

The Microsoft IIS is broken with respect to the translated
path as well.

=item B&lt;remote_host()&gt;

Returns either the remote host name or IP address.
if the former is unavailable.

=item B&lt;script_name()&gt;
Return the script name as a partial URL, for self-refering
scripts.

=item B&lt;referer()&gt;

Return the URL of the page the browser was viewing
prior to fetching your script.  Not available for all
browsers.

=item B&lt;auth_type ()&gt;

Return the authorization/verification method in use for this
script, if any.

=item B&lt;server_name ()&gt;

Returns the name of the server, usually the machine's host
name.

=item B&lt;virtual_host ()&gt;

When using virtual hosts, returns the name of the host that
the browser attempted to contact

=item B&lt;server_software ()&gt;

Returns the server software and version number.

=item B&lt;remote_user ()&gt;

Return the authorization/verification name used for user
verification, if this script is protected.

=item B&lt;user_name ()&gt;

Attempt to obtain the remote user's name, using a variety of different
techniques.  This only works with older browsers such as Mosaic.
Newer browsers do not report the user name for privacy reasons!

=item B&lt;request_method()&gt;

Returns the method used to access your script, usually
one of 'POST', 'GET' or 'HEAD'.

=back

=head1 USING NPH SCRIPTS

NPH, or "no-parsed-header", scripts bypass the server completely by
sending the complete HTTP header directly to the browser.  This has
slight performance benefits, but is of most use for taking advantage
of HTTP extensions that are not directly supported by your server,
such as server push and PICS headers.

Servers use a variety of conventions for designating CGI scripts as
NPH.  Many Unix servers look at the beginning of the script's name for
the prefix "nph-".  The Macintosh WebSTAR server and Microsoft's
Internet Information Server, in contrast, try to decide whether a
program is an NPH script by examining the first line of script output.


CGI.pm supports NPH scripts with a special NPH mode.  When in this
mode, CGI.pm will output the necessary extra header information when
the header() and redirect() methods are
called.

The Microsoft Internet Information Server requires NPH mode.  As of version
2.30, CGI.pm will automatically detect when the script is running under IIS
and put itself into this mode.  You do not need to do this manually, although
it won't hurt anything if you do.

There are a number of ways to put CGI.pm into NPH mode:

=over 4

=item In the B&lt;use&gt; statement 

Simply add the "-nph" pragmato the list of symbols to be imported into
your script:

      use CGI qw(:standard -nph)

=item By calling the B&lt;nph()&gt; method:

Call B&lt;nph()&gt; with a non-zero parameter at any point after using CGI.pm in your program.

      CGI-&gt;nph(1)

=item By using B&lt;-nph&gt; parameters in the B&lt;header()&gt; and B&lt;redirect()&gt;  statements:

      print $q-&gt;header(-nph=&gt;1);

=back

=head1 Server Push

CGI.pm provides three simple functions for producing multipart
documents of the type needed to implement server push.  These
functions were graciously provided by Ed Jordan &lt;ed@fidalgo.net&gt;.  To
import these into your namespace, you must import the ":push" set.
You are also advised to put the script into NPH mode and to set $| to
1 to avoid buffering problems.

Here is a simple script that demonstrates server push:

  #!/usr/local/bin/perl
  use CGI qw/:push -nph/;
  $| = 1;
  print multipart_init(-boundary=&gt;'----------------here we go!');
  while (1) {
      print multipart_start(-type=&gt;'text/plain'),
            "The current time is ",scalar(localtime),"\n",
            multipart_end;
      sleep 1;
  }

This script initializes server push by calling B&lt;multipart_init()&gt;.
It then enters an infinite loop in which it begins a new multipart
section by calling B&lt;multipart_start()&gt;, prints the current local time,
and ends a multipart section with B&lt;multipart_end()&gt;.  It then sleeps
a second, and begins again.

=over 4

=item multipart_init()
     
  multipart_init(-boundary=&gt;$boundary);

Initialize the multipart system.  The -boundary argument specifies
what MIME boundary string to use to separate parts of the document.
If not provided, CGI.pm chooses a reasonable boundary for you.

=item multipart_start()

  multipart_start(-type=&gt;$type)

Start a new part of the multipart document using the specified MIME
type.  If not specified, text/html is assumed.

=item multipart_end()

  multipart_end()

End a part.  You must remember to call multipart_end() once for each
multipart_start().

=back

Users interested in server push applications should also have a look
at the CGI::Push module.

=head1 Avoiding Denial of Service Attacks

A potential problem with CGI.pm is that, by default, it attempts to
process form POSTings no matter how large they are.  A wily hacker
could attack your site by sending a CGI script a huge POST of many
megabytes.  CGI.pm will attempt to read the entire POST into a
variable, growing hugely in size until it runs out of memory.  While
the script attempts to allocate the memory the system may slow down
dramatically.  This is a form of denial of service attack.

Another possible attack is for the remote user to force CGI.pm to
accept a huge file upload.  CGI.pm will accept the upload and store it
in a temporary directory even if your script doesn't expect to receive
an uploaded file.  CGI.pm will delete the file automatically when it
terminates, but in the meantime the remote user may have filled up the
server's disk space, causing problems for other programs.

The best way to avoid denial of service attacks is to limit the amount
of memory, CPU time and disk space that CGI scripts can use.  Some Web
servers come with built-in facilities to accomplish this. In other
cases, you can use the shell I&lt;limit&gt; or I&lt;ulimit&gt;
commands to put ceilings on CGI resource usage.


CGI.pm also has some simple built-in protections against denial of
service attacks, but you must activate them before you can use them.
These take the form of two global variables in the CGI name space:

=over 4

=item B&lt;$CGI::POST_MAX&gt;

If set to a non-negative integer, this variable puts a ceiling
on the size of POSTings, in bytes.  If CGI.pm detects a POST
that is greater than the ceiling, it will immediately exit with an error
message.  This value will affect both ordinary POSTs and
multipart POSTs, meaning that it limits the maximum size of file
uploads as well.  You should set this to a reasonably high
value, such as 1 megabyte.

=item B&lt;$CGI::DISABLE_UPLOADS&gt;

If set to a non-zero value, this will disable file uploads
completely.  Other fill-out form values will work as usual.

=back

You can use these variables in either of two ways.

=over 4

=item B&lt;1. On a script-by-script basis&gt;

Set the variable at the top of the script, right after the "use" statement:

    use CGI qw/:standard/;
    use CGI::Carp 'fatalsToBrowser';
    $CGI::POST_MAX=1024 * 100;  # max 100K posts
    $CGI::DISABLE_UPLOADS = 1;  # no uploads

=item B&lt;2. Globally for all scripts&gt;

Open up CGI.pm, find the definitions for $POST_MAX and 
$DISABLE_UPLOADS, and set them to the desired values.  You'll 
find them towards the top of the file in a subroutine named 
initialize_globals().

=back

Since an attempt to send a POST larger than $POST_MAX bytes
will cause a fatal error, you might want to use CGI::Carp to echo the
fatal error message to the browser window as shown in the example
above.  Otherwise the remote user will see only a generic "Internal
Server" error message.  See the L&lt;CGI::Carp&gt; manual page for more
details.

=head1 COMPATIBILITY WITH CGI-LIB.PL

To make it easier to port existing programs that use cgi-lib.pl
the compatibility routine "ReadParse" is provided.  Porting is
simple:

OLD VERSION
    require "cgi-lib.pl";
    &amp;ReadParse;
    print "The value of the antique is $in{antique}.\n";

NEW VERSION
    use CGI;
    CGI::ReadParse
    print "The value of the antique is $in{antique}.\n";

CGI.pm's ReadParse() routine creates a tied variable named %in,
which can be accessed to obtain the query variables.  Like
ReadParse, you can also provide your own variable.  Infrequently
used features of ReadParse, such as the creation of @in and $in 
variables, are not supported.

Once you use ReadParse, you can retrieve the query object itself
this way:

    $q = $in{CGI};
    print $q-&gt;textfield(-name=&gt;'wow',
			-value=&gt;'does this really work?');

This allows you to start using the more interesting features
of CGI.pm without rewriting your old scripts from scratch.

=head1 AUTHOR INFORMATION

Copyright 1995-1998, Lincoln D. Stein.  All rights reserved.  

This library is free software; you can redistribute it and/or modify
it under the same terms as Perl itself.

Address bug reports and comments to: lstein@cshl.org.  When sending
bug reports, please provide the version of CGI.pm, the version of
Perl, the name and version of your Web server, and the name and
version of the operating system you are using.  If the problem is even
remotely browser dependent, please provide information about the
affected browers as well.

=head1 CREDITS

Thanks very much to:

=over 4

=item Matt Heffron (heffron@falstaff.css.beckman.com)

=item James Taylor (james.taylor@srs.gov)

=item Scott Anguish &lt;sanguish@digifix.com&gt;

=item Mike Jewell (mlj3u@virginia.edu)

=item Timothy Shimmin (tes@kbs.citri.edu.au)

=item Joergen Haegg (jh@axis.se)

=item Laurent Delfosse (delfosse@delfosse.com)

=item Richard Resnick (applepi1@aol.com)

=item Craig Bishop (csb@barwonwater.vic.gov.au)

=item Tony Curtis (tc@vcpc.univie.ac.at)

=item Tim Bunce (Tim.Bunce@ig.co.uk)

=item Tom Christiansen (tchrist@convex.com)

=item Andreas Koenig (k@franz.ww.TU-Berlin.DE)

=item Tim MacKenzie (Tim.MacKenzie@fulcrum.com.au)

=item Kevin B. Hendricks (kbhend@dogwood.tyler.wm.edu)

=item Stephen Dahmen (joyfire@inxpress.net)

=item Ed Jordan (ed@fidalgo.net)

=item David Alan Pisoni (david@cnation.com)

=item Doug MacEachern (dougm@opengroup.org)

=item Robin Houston (robin@oneworld.org)

=item ...and many many more...

for suggestions and bug fixes.

=back

=head1 A COMPLETE EXAMPLE OF A SIMPLE FORM-BASED SCRIPT


	#!/usr/local/bin/perl
     
	use CGI;
 
	$query = new CGI;

	print $query-&gt;header;
	print $query-&gt;start_html("Example CGI.pm Form");
	print "&lt;H1&gt; Example CGI.pm Form&lt;/H1&gt;\n";
	&amp;print_prompt($query);
	&amp;do_work($query);
	&amp;print_tail;
	print $query-&gt;end_html;
 
	sub print_prompt {
	   my($query) = @_;
 
	   print $query-&gt;startform;
	   print "&lt;EM&gt;What's your name?&lt;/EM&gt;&lt;BR&gt;";
	   print $query-&gt;textfield('name');
	   print $query-&gt;checkbox('Not my real name');
 
	   print "&lt;P&gt;&lt;EM&gt;Where can you find English Sparrows?&lt;/EM&gt;&lt;BR&gt;";
	   print $query-&gt;checkbox_group(
				 -name=&gt;'Sparrow locations',
				 -values=&gt;[England,France,Spain,Asia,Hoboken],
				 -linebreak=&gt;'yes',
				 -defaults=&gt;[England,Asia]);
 
	   print "&lt;P&gt;&lt;EM&gt;How far can they fly?&lt;/EM&gt;&lt;BR&gt;",
		$query-&gt;radio_group(
			-name=&gt;'how far',
			-values=&gt;['10 ft','1 mile','10 miles','real far'],
			-default=&gt;'1 mile');
 
	   print "&lt;P&gt;&lt;EM&gt;What's your favorite color?&lt;/EM&gt;  ";
	   print $query-&gt;popup_menu(-name=&gt;'Color',
				    -values=&gt;['black','brown','red','yellow'],
				    -default=&gt;'red');
 
	   print $query-&gt;hidden('Reference','Monty Python and the Holy Grail');
 
	   print "&lt;P&gt;&lt;EM&gt;What have you got there?&lt;/EM&gt;&lt;BR&gt;";
	   print $query-&gt;scrolling_list(
			 -name=&gt;'possessions',
			 -values=&gt;['A Coconut','A Grail','An Icon',
				   'A Sword','A Ticket'],
			 -size=&gt;5,
			 -multiple=&gt;'true');
 
	   print "&lt;P&gt;&lt;EM&gt;Any parting comments?&lt;/EM&gt;&lt;BR&gt;";
	   print $query-&gt;textarea(-name=&gt;'Comments',
				  -rows=&gt;10,
				  -columns=&gt;50);
 
	   print "&lt;P&gt;",$query-&gt;Reset;
	   print $query-&gt;submit('Action','Shout');
	   print $query-&gt;submit('Action','Scream');
	   print $query-&gt;endform;
	   print "&lt;HR&gt;\n";
	}
 
	sub do_work {
	   my($query) = @_;
	   my(@values,$key);

	   print "&lt;H2&gt;Here are the current settings in this form&lt;/H2&gt;";

	   foreach $key ($query-&gt;param) {
	      print "&lt;STRONG&gt;$key&lt;/STRONG&gt; -&gt; ";
	      @values = $query-&gt;param($key);
	      print join(", ",@values),"&lt;BR&gt;\n";
	  }
	}
 
	sub print_tail {
	   print &lt;&lt;END;
	&lt;HR&gt;
	&lt;ADDRESS&gt;Lincoln D. Stein&lt;/ADDRESS&gt;&lt;BR&gt;
	&lt;A HREF="/"&gt;Home Page&lt;/A&gt;
	END
	}

=head1 BUGS

This module has grown large and monolithic.  Furthermore it's doing many
things, such as handling URLs, parsing CGI input, writing HTML, etc., that
are also done in the LWP modules. It should be discarded in favor of
the CGI::* modules, but somehow I continue to work on it.

Note that the code is truly contorted in order to avoid spurious
warnings when programs are run with the B&lt;-w&gt; switch.

=head1 SEE ALSO

L&lt;CGI::Carp&gt;, L&lt;URI::URL&gt;, L&lt;CGI::Request&gt;, L&lt;CGI::MiniSvr&gt;,
L&lt;CGI::Base&gt;, L&lt;CGI::Form&gt;, L&lt;CGI::Push&gt;, L&lt;CGI::Fast&gt;,
L&lt;CGI::Pretty&gt;

=cut

</pre></body></html>