<html><head><meta name="color-scheme" content="light dark"></head><body><pre style="word-wrap: break-word; white-space: pre-wrap;"># -*- mode: perl; perl-indent-level: 2; -*-
# Memoize.pm
#
# Transparent memoization of idempotent functions
#
# Copyright 1998, 1999, 2000, 2001, 2012 M. J. Dominus.
# You may copy and distribute this program under the
# same terms as Perl itself.  If in doubt, 
# write to mjd-perl-memoize+@plover.com for a license.

package Memoize;
$VERSION = '1.03';

# Compile-time constants
sub SCALAR () { 0 } 
sub LIST () { 1 } 


#
# Usage memoize(functionname/ref,
#               { NORMALIZER =&gt; coderef, INSTALL =&gt; name,
#                 LIST_CACHE =&gt; descriptor, SCALAR_CACHE =&gt; descriptor }
#

use Carp;
use Exporter;
use vars qw($DEBUG);
use Config;                     # Dammit.
@ISA = qw(Exporter);
@EXPORT = qw(memoize);
@EXPORT_OK = qw(unmemoize flush_cache);
use strict;

my %memotable;
my %revmemotable;
my @CONTEXT_TAGS = qw(MERGE TIE MEMORY FAULT HASH);
my %IS_CACHE_TAG = map {($_ =&gt; 1)} @CONTEXT_TAGS;

# Raise an error if the user tries to specify one of thesepackage as a
# tie for LIST_CACHE

my %scalar_only = map {($_ =&gt; 1)} qw(DB_File GDBM_File SDBM_File ODBM_File NDBM_File);

sub memoize {
  my $fn = shift;
  my %options = @_;
  my $options = \%options;
  
  unless (defined($fn) &amp;&amp; 
	  (ref $fn eq 'CODE' || ref $fn eq '')) {
    croak "Usage: memoize 'functionname'|coderef {OPTIONS}";
  }

  my $uppack = caller;		# TCL me Elmo!
  my $cref;			# Code reference to original function
  my $name = (ref $fn ? undef : $fn);

  # Convert function names to code references
  $cref = &amp;_make_cref($fn, $uppack);

  # Locate function prototype, if any
  my $proto = prototype $cref;
  if (defined $proto) { $proto = "($proto)" }
  else { $proto = "" }

  # I would like to get rid of the eval, but there seems not to be any
  # other way to set the prototype properly.  The switch here for
  # 'usethreads' works around a bug in threadperl having to do with
  # magic goto.  It would be better to fix the bug and use the magic
  # goto version everywhere.
  my $wrapper = 
      $Config{usethreads} 
        ? eval "sub $proto { &amp;_memoizer(\$cref, \@_); }" 
        : eval "sub $proto { unshift \@_, \$cref; goto &amp;_memoizer; }";

  my $normalizer = $options{NORMALIZER};
  if (defined $normalizer  &amp;&amp; ! ref $normalizer) {
    $normalizer = _make_cref($normalizer, $uppack);
  }
  
  my $install_name;
  if (defined $options-&gt;{INSTALL}) {
    # INSTALL =&gt; name
    $install_name = $options-&gt;{INSTALL};
  } elsif (! exists $options-&gt;{INSTALL}) {
    # No INSTALL option provided; use original name if possible
    $install_name = $name;
  } else {
    # INSTALL =&gt; undef  means don't install
  }

  if (defined $install_name) {
    $install_name = $uppack . '::' . $install_name
	unless $install_name =~ /::/;
    no strict;
    local($^W) = 0;	       # ``Subroutine $install_name redefined at ...''
    *{$install_name} = $wrapper; # Install memoized version
  }

  $revmemotable{$wrapper} = "" . $cref; # Turn code ref into hash key

  # These will be the caches
  my %caches;
  for my $context (qw(SCALAR LIST)) {
    # suppress subsequent 'uninitialized value' warnings
    $options{"${context}_CACHE"} ||= ''; 

    my $cache_opt = $options{"${context}_CACHE"};
    my @cache_opt_args;
    if (ref $cache_opt) {
      @cache_opt_args = @$cache_opt;
      $cache_opt = shift @cache_opt_args;
    }
    if ($cache_opt eq 'FAULT') { # no cache
      $caches{$context} = undef;
    } elsif ($cache_opt eq 'HASH') { # user-supplied hash
      my $cache = $cache_opt_args[0];
      my $package = ref(tied %$cache);
      if ($context eq 'LIST' &amp;&amp; $scalar_only{$package}) {
        croak("You can't use $package for LIST_CACHE because it can only store scalars");
      }
      $caches{$context} = $cache;
    } elsif ($cache_opt eq '' ||  $IS_CACHE_TAG{$cache_opt}) {
      # default is that we make up an in-memory hash
      $caches{$context} = {};
      # (this might get tied later, or MERGEd away)
    } else {
      croak "Unrecognized option to `${context}_CACHE': `$cache_opt' should be one of (@CONTEXT_TAGS); aborting";
    }
  }

  # Perhaps I should check here that you didn't supply *both* merge
  # options.  But if you did, it does do something reasonable: They
  # both get merged to the same in-memory hash.
  if ($options{SCALAR_CACHE} eq 'MERGE' || $options{LIST_CACHE} eq 'MERGE') {
    $options{MERGED} = 1;
    $caches{SCALAR} = $caches{LIST};
  }

  # Now deal with the TIE options
  {
    my $context;
    foreach $context (qw(SCALAR LIST)) {
      # If the relevant option wasn't `TIE', this call does nothing.
      _my_tie($context, $caches{$context}, $options);  # Croaks on failure
    }
  }
  
  # We should put some more stuff in here eventually.
  # We've been saying that for serveral versions now.
  # And you know what?  More stuff keeps going in!
  $memotable{$cref} = 
  {
    O =&gt; $options,  # Short keys here for things we need to access frequently
    N =&gt; $normalizer,
    U =&gt; $cref,
    MEMOIZED =&gt; $wrapper,
    PACKAGE =&gt; $uppack,
    NAME =&gt; $install_name,
    S =&gt; $caches{SCALAR},
    L =&gt; $caches{LIST},
  };

  $wrapper			# Return just memoized version
}

# This function tries to load a tied hash class and tie the hash to it.
sub _my_tie {
  my ($context, $hash, $options) = @_;
  my $fullopt = $options-&gt;{"${context}_CACHE"};

  # We already checked to make sure that this works.
  my $shortopt = (ref $fullopt) ? $fullopt-&gt;[0] : $fullopt;
  
  return unless defined $shortopt &amp;&amp; $shortopt eq 'TIE';
  carp("TIE option to memoize() is deprecated; use HASH instead")
      if $^W;

  my @args = ref $fullopt ? @$fullopt : ();
  shift @args;
  my $module = shift @args;
  if ($context eq 'LIST' &amp;&amp; $scalar_only{$module}) {
    croak("You can't use $module for LIST_CACHE because it can only store scalars");
  }
  my $modulefile = $module . '.pm';
  $modulefile =~ s{::}{/}g;
  eval { require $modulefile };
  if ($@) {
    croak "Memoize: Couldn't load hash tie module `$module': $@; aborting";
  }
  my $rc = (tie %$hash =&gt; $module, @args);
  unless ($rc) {
    croak "Memoize: Couldn't tie hash to `$module': $!; aborting";
  }
  1;
}

sub flush_cache {
  my $func = _make_cref($_[0], scalar caller);
  my $info = $memotable{$revmemotable{$func}};
  die "$func not memoized" unless defined $info;
  for my $context (qw(S L)) {
    my $cache = $info-&gt;{$context};
    if (tied %$cache &amp;&amp; ! (tied %$cache)-&gt;can('CLEAR')) {
      my $funcname = defined($info-&gt;{NAME}) ? 
          "function $info-&gt;{NAME}" : "anonymous function $func";
      my $context = {S =&gt; 'scalar', L =&gt; 'list'}-&gt;{$context};
      croak "Tied cache hash for $context-context $funcname does not support flushing";
    } else {
      %$cache = ();
    }
  }
}

# This is the function that manages the memo tables.
sub _memoizer {
  my $orig = shift;		# stringized version of ref to original func.
  my $info = $memotable{$orig};
  my $normalizer = $info-&gt;{N};
  
  my $argstr;
  my $context = (wantarray() ? LIST : SCALAR);

  if (defined $normalizer) { 
    no strict;
    if ($context == SCALAR) {
      $argstr = &amp;{$normalizer}(@_);
    } elsif ($context == LIST) {
      ($argstr) = &amp;{$normalizer}(@_);
    } else {
      croak "Internal error \#41; context was neither LIST nor SCALAR\n";
    }
  } else {                      # Default normalizer
    local $^W = 0;
    $argstr = join chr(28),@_;  
  }

  if ($context == SCALAR) {
    my $cache = $info-&gt;{S};
    _crap_out($info-&gt;{NAME}, 'scalar') unless $cache;
    if (exists $cache-&gt;{$argstr}) { 
      return $info-&gt;{O}{MERGED}
        ? $cache-&gt;{$argstr}[0] : $cache-&gt;{$argstr};
    } else {
      my $val = &amp;{$info-&gt;{U}}(@_);
      # Scalars are considered to be lists; store appropriately
      if ($info-&gt;{O}{MERGED}) {
	$cache-&gt;{$argstr} = [$val];
      } else {
	$cache-&gt;{$argstr} = $val;
      }
      $val;
    }
  } elsif ($context == LIST) {
    my $cache = $info-&gt;{L};
    _crap_out($info-&gt;{NAME}, 'list') unless $cache;
    if (exists $cache-&gt;{$argstr}) {
      return @{$cache-&gt;{$argstr}};
    } else {
      my @q = &amp;{$info-&gt;{U}}(@_);
      $cache-&gt;{$argstr} = \@q;
      @q;
    }
  } else {
    croak "Internal error \#42; context was neither LIST nor SCALAR\n";
  }
}

sub unmemoize {
  my $f = shift;
  my $uppack = caller;
  my $cref = _make_cref($f, $uppack);

  unless (exists $revmemotable{$cref}) {
    croak "Could not unmemoize function `$f', because it was not memoized to begin with";
  }
  
  my $tabent = $memotable{$revmemotable{$cref}};
  unless (defined $tabent) {
    croak "Could not figure out how to unmemoize function `$f'";
  }
  my $name = $tabent-&gt;{NAME};
  if (defined $name) {
    no strict;
    local($^W) = 0;	       # ``Subroutine $install_name redefined at ...''
    *{$name} = $tabent-&gt;{U}; # Replace with original function
  }
  undef $memotable{$revmemotable{$cref}};
  undef $revmemotable{$cref};

  # This removes the last reference to the (possibly tied) memo tables
  # my ($old_function, $memotabs) = @{$tabent}{'U','S','L'};
  # undef $tabent; 

#  # Untie the memo tables if they were tied.
#  my $i;
#  for $i (0,1) {
#    if (tied %{$memotabs-&gt;[$i]}) {
#      warn "Untying hash #$i\n";
#      untie %{$memotabs-&gt;[$i]};
#    }
#  }

  $tabent-&gt;{U};
}

sub _make_cref {
  my $fn = shift;
  my $uppack = shift;
  my $cref;
  my $name;

  if (ref $fn eq 'CODE') {
    $cref = $fn;
  } elsif (! ref $fn) {
    if ($fn =~ /::/) {
      $name = $fn;
    } else {
      $name = $uppack . '::' . $fn;
    }
    no strict;
    if (defined $name and !defined(&amp;$name)) {
      croak "Cannot operate on nonexistent function `$fn'";
    }
#    $cref = \&amp;$name;
    $cref = *{$name}{CODE};
  } else {
    my $parent = (caller(1))[3]; # Function that called _make_cref
    croak "Usage: argument 1 to `$parent' must be a function name or reference.\n";
  }
  $DEBUG and warn "${name}($fn) =&gt; $cref in _make_cref\n";
  $cref;
}

sub _crap_out {
  my ($funcname, $context) = @_;
  if (defined $funcname) {
    croak "Function `$funcname' called in forbidden $context context; faulting";
  } else {
    croak "Anonymous function called in forbidden $context context; faulting";
  }
}

1;





=head1 NAME

Memoize - Make functions faster by trading space for time

=head1 SYNOPSIS

        # This is the documentation for Memoize 1.03
	use Memoize;
	memoize('slow_function');
	slow_function(arguments);    # Is faster than it was before


This is normally all you need to know.  However, many options are available:

	memoize(function, options...);

Options include:

	NORMALIZER =&gt; function
	INSTALL =&gt; new_name

	SCALAR_CACHE =&gt; 'MEMORY'
        SCALAR_CACHE =&gt; ['HASH', \%cache_hash ]
	SCALAR_CACHE =&gt; 'FAULT'
	SCALAR_CACHE =&gt; 'MERGE'

	LIST_CACHE =&gt; 'MEMORY'
        LIST_CACHE =&gt; ['HASH', \%cache_hash ]
	LIST_CACHE =&gt; 'FAULT'
	LIST_CACHE =&gt; 'MERGE'

=head1 DESCRIPTION

`Memoizing' a function makes it faster by trading space for time.  It
does this by caching the return values of the function in a table.
If you call the function again with the same arguments, C&lt;memoize&gt;
jumps in and gives you the value out of the table, instead of letting
the function compute the value all over again.

Here is an extreme example.  Consider the Fibonacci sequence, defined
by the following function:

	# Compute Fibonacci numbers
	sub fib {
	  my $n = shift;
	  return $n if $n &lt; 2;
	  fib($n-1) + fib($n-2);
	}

This function is very slow.  Why?  To compute fib(14), it first wants
to compute fib(13) and fib(12), and add the results.  But to compute
fib(13), it first has to compute fib(12) and fib(11), and then it
comes back and computes fib(12) all over again even though the answer
is the same.  And both of the times that it wants to compute fib(12),
it has to compute fib(11) from scratch, and then it has to do it
again each time it wants to compute fib(13).  This function does so
much recomputing of old results that it takes a really long time to
run---fib(14) makes 1,200 extra recursive calls to itself, to compute
and recompute things that it already computed.

This function is a good candidate for memoization.  If you memoize the
`fib' function above, it will compute fib(14) exactly once, the first
time it needs to, and then save the result in a table.  Then if you
ask for fib(14) again, it gives you the result out of the table.
While computing fib(14), instead of computing fib(12) twice, it does
it once; the second time it needs the value it gets it from the table.
It doesn't compute fib(11) four times; it computes it once, getting it
from the table the next three times.  Instead of making 1,200
recursive calls to `fib', it makes 15.  This makes the function about
150 times faster.

You could do the memoization yourself, by rewriting the function, like
this:

	# Compute Fibonacci numbers, memoized version
	{ my @fib;
  	  sub fib {
	    my $n = shift;
	    return $fib[$n] if defined $fib[$n];
	    return $fib[$n] = $n if $n &lt; 2;
	    $fib[$n] = fib($n-1) + fib($n-2);
	  }
        }

Or you could use this module, like this:

	use Memoize;
	memoize('fib');

	# Rest of the fib function just like the original version.

This makes it easy to turn memoizing on and off.

Here's an even simpler example: I wrote a simple ray tracer; the
program would look in a certain direction, figure out what it was
looking at, and then convert the `color' value (typically a string
like `red') of that object to a red, green, and blue pixel value, like
this:

    for ($direction = 0; $direction &lt; 300; $direction++) {
      # Figure out which object is in direction $direction
      $color = $object-&gt;{color};
      ($r, $g, $b) = @{&amp;ColorToRGB($color)};
      ...
    }

Since there are relatively few objects in a picture, there are only a
few colors, which get looked up over and over again.  Memoizing
C&lt;ColorToRGB&gt; sped up the program by several percent.

=head1 DETAILS

This module exports exactly one function, C&lt;memoize&gt;.  The rest of the
functions in this package are None of Your Business.

You should say

	memoize(function)

where C&lt;function&gt; is the name of the function you want to memoize, or
a reference to it.  C&lt;memoize&gt; returns a reference to the new,
memoized version of the function, or C&lt;undef&gt; on a non-fatal error.
At present, there are no non-fatal errors, but there might be some in
the future.

If C&lt;function&gt; was the name of a function, then C&lt;memoize&gt; hides the
old version and installs the new memoized version under the old name,
so that C&lt;&amp;function(...)&gt; actually invokes the memoized version.

=head1 OPTIONS

There are some optional options you can pass to C&lt;memoize&gt; to change
the way it behaves a little.  To supply options, invoke C&lt;memoize&gt;
like this:

	memoize(function, NORMALIZER =&gt; function,
			  INSTALL =&gt; newname,
                          SCALAR_CACHE =&gt; option,
	                  LIST_CACHE =&gt; option
			 );

Each of these options is optional; you can include some, all, or none
of them.

=head2 INSTALL

If you supply a function name with C&lt;INSTALL&gt;, memoize will install
the new, memoized version of the function under the name you give.
For example, 

	memoize('fib', INSTALL =&gt; 'fastfib')

installs the memoized version of C&lt;fib&gt; as C&lt;fastfib&gt;; without the
C&lt;INSTALL&gt; option it would have replaced the old C&lt;fib&gt; with the
memoized version.  

To prevent C&lt;memoize&gt; from installing the memoized version anywhere, use
C&lt;INSTALL =E&lt;gt&gt; undef&gt;.

=head2 NORMALIZER

Suppose your function looks like this:

	# Typical call: f('aha!', A =&gt; 11, B =&gt; 12);
	sub f {
	  my $a = shift;
	  my %hash = @_;
	  $hash{B} ||= 2;  # B defaults to 2
	  $hash{C} ||= 7;  # C defaults to 7

	  # Do something with $a, %hash
	}

Now, the following calls to your function are all completely equivalent:

	f(OUCH);
	f(OUCH, B =&gt; 2);
	f(OUCH, C =&gt; 7);
	f(OUCH, B =&gt; 2, C =&gt; 7);
	f(OUCH, C =&gt; 7, B =&gt; 2);
	(etc.)

However, unless you tell C&lt;Memoize&gt; that these calls are equivalent,
it will not know that, and it will compute the values for these
invocations of your function separately, and store them separately.

To prevent this, supply a C&lt;NORMALIZER&gt; function that turns the
program arguments into a string in a way that equivalent arguments
turn into the same string.  A C&lt;NORMALIZER&gt; function for C&lt;f&gt; above
might look like this:

	sub normalize_f {
	  my $a = shift;
	  my %hash = @_;
	  $hash{B} ||= 2;
	  $hash{C} ||= 7;

	  join(',', $a, map ($_ =&gt; $hash{$_}) sort keys %hash);
	}

Each of the argument lists above comes out of the C&lt;normalize_f&gt;
function looking exactly the same, like this:

	OUCH,B,2,C,7

You would tell C&lt;Memoize&gt; to use this normalizer this way:

	memoize('f', NORMALIZER =&gt; 'normalize_f');

C&lt;memoize&gt; knows that if the normalized version of the arguments is
the same for two argument lists, then it can safely look up the value
that it computed for one argument list and return it as the result of
calling the function with the other argument list, even if the
argument lists look different.

The default normalizer just concatenates the arguments with character
28 in between.  (In ASCII, this is called FS or control-\.)  This
always works correctly for functions with only one string argument,
and also when the arguments never contain character 28.  However, it
can confuse certain argument lists:

	normalizer("a\034", "b")
	normalizer("a", "\034b")
	normalizer("a\034\034b")

for example.

Since hash keys are strings, the default normalizer will not
distinguish between C&lt;undef&gt; and the empty string.  It also won't work
when the function's arguments are references.  For example, consider a
function C&lt;g&gt; which gets two arguments: A number, and a reference to
an array of numbers:

	g(13, [1,2,3,4,5,6,7]);

The default normalizer will turn this into something like
C&lt;"13\034ARRAY(0x436c1f)"&gt;.  That would be all right, except that a
subsequent array of numbers might be stored at a different location
even though it contains the same data.  If this happens, C&lt;Memoize&gt;
will think that the arguments are different, even though they are
equivalent.  In this case, a normalizer like this is appropriate:

	sub normalize { join ' ', $_[0], @{$_[1]} }

For the example above, this produces the key "13 1 2 3 4 5 6 7".

Another use for normalizers is when the function depends on data other
than those in its arguments.  Suppose you have a function which
returns a value which depends on the current hour of the day:

	sub on_duty {
          my ($problem_type) = @_;
	  my $hour = (localtime)[2];
          open my $fh, "$DIR/$problem_type" or die...;
          my $line;
          while ($hour-- &gt; 0)
            $line = &lt;$fh&gt;;
          } 
	  return $line;
	}

At 10:23, this function generates the 10th line of a data file; at
3:45 PM it generates the 15th line instead.  By default, C&lt;Memoize&gt;
will only see the $problem_type argument.  To fix this, include the
current hour in the normalizer:

        sub normalize { join ' ', (localtime)[2], @_ }

The calling context of the function (scalar or list context) is
propagated to the normalizer.  This means that if the memoized
function will treat its arguments differently in list context than it
would in scalar context, you can have the normalizer function select
its behavior based on the results of C&lt;wantarray&gt;.  Even if called in
a list context, a normalizer should still return a single string.

=head2 C&lt;SCALAR_CACHE&gt;, C&lt;LIST_CACHE&gt;

Normally, C&lt;Memoize&gt; caches your function's return values into an
ordinary Perl hash variable.  However, you might like to have the
values cached on the disk, so that they persist from one run of your
program to the next, or you might like to associate some other
interesting semantics with the cached values.

There's a slight complication under the hood of C&lt;Memoize&gt;: There are
actually I&lt;two&gt; caches, one for scalar values and one for list values.
When your function is called in scalar context, its return value is
cached in one hash, and when your function is called in list context,
its value is cached in the other hash.  You can control the caching
behavior of both contexts independently with these options.

The argument to C&lt;LIST_CACHE&gt; or C&lt;SCALAR_CACHE&gt; must either be one of
the following four strings:

	MEMORY
	FAULT
	MERGE
        HASH

or else it must be a reference to an array whose first element is one of
these four strings, such as C&lt;[HASH, arguments...]&gt;.

=over 4

=item C&lt;MEMORY&gt;

C&lt;MEMORY&gt; means that return values from the function will be cached in
an ordinary Perl hash variable.  The hash variable will not persist
after the program exits.  This is the default.

=item C&lt;HASH&gt;

C&lt;HASH&gt; allows you to specify that a particular hash that you supply
will be used as the cache.  You can tie this hash beforehand to give
it any behavior you want.

A tied hash can have any semantics at all.  It is typically tied to an
on-disk database, so that cached values are stored in the database and
retrieved from it again when needed, and the disk file typically
persists after your program has exited.  See C&lt;perltie&gt; for more
complete details about C&lt;tie&gt;.

A typical example is:

        use DB_File;
        tie my %cache =&gt; 'DB_File', $filename, O_RDWR|O_CREAT, 0666;
        memoize 'function', SCALAR_CACHE =&gt; [HASH =&gt; \%cache];

This has the effect of storing the cache in a C&lt;DB_File&gt; database
whose name is in C&lt;$filename&gt;.  The cache will persist after the
program has exited.  Next time the program runs, it will find the
cache already populated from the previous run of the program.  Or you
can forcibly populate the cache by constructing a batch program that
runs in the background and populates the cache file.  Then when you
come to run your real program the memoized function will be fast
because all its results have been precomputed.

Another reason to use C&lt;HASH&gt; is to provide your own hash variable.
You can then inspect or modify the contents of the hash to gain finer
control over the cache management.

=item C&lt;TIE&gt;

This option is no longer supported.  It is still documented only to
aid in the debugging of old programs that use it.  Old programs should
be converted to use the C&lt;HASH&gt; option instead.

        memoize ... ['TIE', PACKAGE, ARGS...]

is merely a shortcut for

        require PACKAGE;
	{ tie my %cache, PACKAGE, ARGS...;
          memoize ... [HASH =&gt; \%cache];
        }

=item C&lt;FAULT&gt;

C&lt;FAULT&gt; means that you never expect to call the function in scalar
(or list) context, and that if C&lt;Memoize&gt; detects such a call, it
should abort the program.  The error message is one of

	`foo' function called in forbidden list context at line ...
	`foo' function called in forbidden scalar context at line ...

=item C&lt;MERGE&gt;

C&lt;MERGE&gt; normally means that the memoized function does not
distinguish between list and sclar context, and that return values in
both contexts should be stored together.  Both C&lt;LIST_CACHE =E&lt;gt&gt;
MERGE&gt; and C&lt;SCALAR_CACHE =E&lt;gt&gt; MERGE&gt; mean the same thing.

Consider this function:

	sub complicated {
          # ... time-consuming calculation of $result
          return $result;
        }

The C&lt;complicated&gt; function will return the same numeric C&lt;$result&gt;
regardless of whether it is called in list or in scalar context.

Normally, the following code will result in two calls to C&lt;complicated&gt;, even
if C&lt;complicated&gt; is memoized:

    $x = complicated(142);
    ($y) = complicated(142);
    $z = complicated(142);

The first call will cache the result, say 37, in the scalar cache; the
second will cach the list C&lt;(37)&gt; in the list cache.  The third call
doesn't call the real C&lt;complicated&gt; function; it gets the value 37
from the scalar cache.

Obviously, the second call to C&lt;complicated&gt; is a waste of time, and
storing its return value is a waste of space.  Specifying C&lt;LIST_CACHE
=E&lt;gt&gt; MERGE&gt; will make C&lt;memoize&gt; use the same cache for scalar and
list context return values, so that the second call uses the scalar
cache that was populated by the first call.  C&lt;complicated&gt; ends up
being called only once, and both subsequent calls return C&lt;3&gt; from the
cache, regardless of the calling context.

=head3 List values in scalar context

Consider this function:

    sub iota { return reverse (1..$_[0]) }

This function normally returns a list.  Suppose you memoize it and
merge the caches:

    memoize 'iota', SCALAR_CACHE =&gt; 'MERGE';

    @i7 = iota(7);
    $i7 = iota(7);

Here the first call caches the list (1,2,3,4,5,6,7).  The second call
does not really make sense. C&lt;Memoize&gt; cannot guess what behavior
C&lt;iota&gt; should have in scalar context without actually calling it in
scalar context.  Normally C&lt;Memoize&gt; I&lt;would&gt; call C&lt;iota&gt; in scalar
context and cache the result, but the C&lt;SCALAR_CACHE =E&lt;gt&gt; 'MERGE'&gt;
option says not to do that, but to use the cache list-context value
instead. But it cannot return a list of seven elements in a scalar
context. In this case C&lt;$i7&gt; will receive the B&lt;first element&gt; of the
cached list value, namely 7.

=head3 Merged disk caches

Another use for C&lt;MERGE&gt; is when you want both kinds of return values
stored in the same disk file; this saves you from having to deal with
two disk files instead of one.  You can use a normalizer function to
keep the two sets of return values separate.  For example:

        tie my %cache =&gt; 'MLDBM', 'DB_File', $filename, ...;

	memoize 'myfunc',
	  NORMALIZER =&gt; 'n',
	  SCALAR_CACHE =&gt; [HASH =&gt; \%cache],
	  LIST_CACHE =&gt; 'MERGE',
	;

	sub n {
	  my $context = wantarray() ? 'L' : 'S';
	  # ... now compute the hash key from the arguments ...
	  $hashkey = "$context:$hashkey";
	}

This normalizer function will store scalar context return values in
the disk file under keys that begin with C&lt;S:&gt;, and list context
return values under keys that begin with C&lt;L:&gt;.

=back

=head1 OTHER FACILITIES

=head2 C&lt;unmemoize&gt;

There's an C&lt;unmemoize&gt; function that you can import if you want to.
Why would you want to?  Here's an example: Suppose you have your cache
tied to a DBM file, and you want to make sure that the cache is
written out to disk if someone interrupts the program.  If the program
exits normally, this will happen anyway, but if someone types
control-C or something then the program will terminate immediately
without synchronizing the database.  So what you can do instead is

    $SIG{INT} = sub { unmemoize 'function' };

C&lt;unmemoize&gt; accepts a reference to, or the name of a previously
memoized function, and undoes whatever it did to provide the memoized
version in the first place, including making the name refer to the
unmemoized version if appropriate.  It returns a reference to the
unmemoized version of the function.

If you ask it to unmemoize a function that was never memoized, it
croaks.

=head2 C&lt;flush_cache&gt;

C&lt;flush_cache(function)&gt; will flush out the caches, discarding I&lt;all&gt;
the cached data.  The argument may be a function name or a reference
to a function.  For finer control over when data is discarded or
expired, see the documentation for C&lt;Memoize::Expire&gt;, included in
this package.

Note that if the cache is a tied hash, C&lt;flush_cache&gt; will attempt to
invoke the C&lt;CLEAR&gt; method on the hash.  If there is no C&lt;CLEAR&gt;
method, this will cause a run-time error.

An alternative approach to cache flushing is to use the C&lt;HASH&gt; option
(see above) to request that C&lt;Memoize&gt; use a particular hash variable
as its cache.  Then you can examine or modify the hash at any time in
any way you desire.  You may flush the cache by using C&lt;%hash = ()&gt;. 

=head1 CAVEATS

Memoization is not a cure-all:

=over 4

=item *

Do not memoize a function whose behavior depends on program
state other than its own arguments, such as global variables, the time
of day, or file input.  These functions will not produce correct
results when memoized.  For a particularly easy example:

	sub f {
	  time;
	}

This function takes no arguments, and as far as C&lt;Memoize&gt; is
concerned, it always returns the same result.  C&lt;Memoize&gt; is wrong, of
course, and the memoized version of this function will call C&lt;time&gt; once
to get the current time, and it will return that same time
every time you call it after that.

=item *

Do not memoize a function with side effects.

	sub f {
	  my ($a, $b) = @_;
          my $s = $a + $b;
	  print "$a + $b = $s.\n";
	}

This function accepts two arguments, adds them, and prints their sum.
Its return value is the numuber of characters it printed, but you
probably didn't care about that.  But C&lt;Memoize&gt; doesn't understand
that.  If you memoize this function, you will get the result you
expect the first time you ask it to print the sum of 2 and 3, but
subsequent calls will return 1 (the return value of
C&lt;print&gt;) without actually printing anything.

=item *

Do not memoize a function that returns a data structure that is
modified by its caller.

Consider these functions:  C&lt;getusers&gt; returns a list of users somehow,
and then C&lt;main&gt; throws away the first user on the list and prints the
rest:

	sub main {
	  my $userlist = getusers();
	  shift @$userlist;
	  foreach $u (@$userlist) {
	    print "User $u\n";
	  }
	}

	sub getusers {
	  my @users;
	  # Do something to get a list of users;
	  \@users;  # Return reference to list.
	}

If you memoize C&lt;getusers&gt; here, it will work right exactly once.  The
reference to the users list will be stored in the memo table.  C&lt;main&gt;
will discard the first element from the referenced list.  The next
time you invoke C&lt;main&gt;, C&lt;Memoize&gt; will not call C&lt;getusers&gt;; it will
just return the same reference to the same list it got last time.  But
this time the list has already had its head removed; C&lt;main&gt; will
erroneously remove another element from it.  The list will get shorter
and shorter every time you call C&lt;main&gt;.

Similarly, this:

	$u1 = getusers();    
	$u2 = getusers();    
	pop @$u1;

will modify $u2 as well as $u1, because both variables are references
to the same array.  Had C&lt;getusers&gt; not been memoized, $u1 and $u2
would have referred to different arrays.

=item * 

Do not memoize a very simple function.

Recently someone mentioned to me that the Memoize module made his
program run slower instead of faster.  It turned out that he was
memoizing the following function:

    sub square {
      $_[0] * $_[0];
    }

I pointed out that C&lt;Memoize&gt; uses a hash, and that looking up a
number in the hash is necessarily going to take a lot longer than a
single multiplication.  There really is no way to speed up the
C&lt;square&gt; function.

Memoization is not magical.

=back

=head1 PERSISTENT CACHE SUPPORT

You can tie the cache tables to any sort of tied hash that you want
to, as long as it supports C&lt;TIEHASH&gt;, C&lt;FETCH&gt;, C&lt;STORE&gt;, and
C&lt;EXISTS&gt;.  For example,

        tie my %cache =&gt; 'GDBM_File', $filename, O_RDWR|O_CREAT, 0666;
        memoize 'function', SCALAR_CACHE =&gt; [HASH =&gt; \%cache];

works just fine.  For some storage methods, you need a little glue.

C&lt;SDBM_File&gt; doesn't supply an C&lt;EXISTS&gt; method, so included in this
package is a glue module called C&lt;Memoize::SDBM_File&gt; which does
provide one.  Use this instead of plain C&lt;SDBM_File&gt; to store your
cache table on disk in an C&lt;SDBM_File&gt; database:

        tie my %cache =&gt; 'Memoize::SDBM_File', $filename, O_RDWR|O_CREAT, 0666;
        memoize 'function', SCALAR_CACHE =&gt; [HASH =&gt; \%cache];

C&lt;NDBM_File&gt; has the same problem and the same solution.  (Use
C&lt;Memoize::NDBM_File instead of plain NDBM_File.&gt;)

C&lt;Storable&gt; isn't a tied hash class at all.  You can use it to store a
hash to disk and retrieve it again, but you can't modify the hash while
it's on the disk.  So if you want to store your cache table in a
C&lt;Storable&gt; database, use C&lt;Memoize::Storable&gt;, which puts a hashlike
front-end onto C&lt;Storable&gt;.  The hash table is actually kept in
memory, and is loaded from your C&lt;Storable&gt; file at the time you
memoize the function, and stored back at the time you unmemoize the
function (or when your program exits):

        tie my %cache =&gt; 'Memoize::Storable', $filename;
	memoize 'function', SCALAR_CACHE =&gt; [HASH =&gt; \%cache];

        tie my %cache =&gt; 'Memoize::Storable', $filename, 'nstore';
	memoize 'function', SCALAR_CACHE =&gt; [HASH =&gt; \%cache];

Include the `nstore' option to have the C&lt;Storable&gt; database written
in `network order'.  (See L&lt;Storable&gt; for more details about this.)

The C&lt;flush_cache()&gt; function will raise a run-time error unless the
tied package provides a C&lt;CLEAR&gt; method.

=head1 EXPIRATION SUPPORT

See Memoize::Expire, which is a plug-in module that adds expiration
functionality to Memoize.  If you don't like the kinds of policies
that Memoize::Expire implements, it is easy to write your own plug-in
module to implement whatever policy you desire.  Memoize comes with
several examples.  An expiration manager that implements a LRU policy
is available on CPAN as Memoize::ExpireLRU.

=head1 BUGS

The test suite is much better, but always needs improvement.

There is some problem with the way C&lt;goto &amp;f&gt; works under threaded
Perl, perhaps because of the lexical scoping of C&lt;@_&gt;.  This is a bug
in Perl, and until it is resolved, memoized functions will see a
slightly different C&lt;caller()&gt; and will perform a little more slowly
on threaded perls than unthreaded perls.

Some versions of C&lt;DB_File&gt; won't let you store data under a key of
length 0.  That means that if you have a function C&lt;f&gt; which you
memoized and the cache is in a C&lt;DB_File&gt; database, then the value of
C&lt;f()&gt; (C&lt;f&gt; called with no arguments) will not be memoized.  If this
is a big problem, you can supply a normalizer function that prepends
C&lt;"x"&gt; to every key.

=head1 MAILING LIST

To join a very low-traffic mailing list for announcements about
C&lt;Memoize&gt;, send an empty note to C&lt;mjd-perl-memoize-request@plover.com&gt;.

=head1 AUTHOR

Mark-Jason Dominus (C&lt;mjd-perl-memoize+@plover.com&gt;), Plover Systems co.

See the C&lt;Memoize.pm&gt; Page at http://perl.plover.com/Memoize/
for news and upgrades.  Near this page, at
http://perl.plover.com/MiniMemoize/ there is an article about
memoization and about the internals of Memoize that appeared in The
Perl Journal, issue #13.  (This article is also included in the
Memoize distribution as `article.html'.)

The author's book I&lt;Higher-Order Perl&gt; (2005, ISBN 1558607013, published
by Morgan Kaufmann) discusses memoization (and many other 
topics) in tremendous detail. It is available on-line for free.
For more information, visit http://hop.perl.plover.com/ .

To join a mailing list for announcements about C&lt;Memoize&gt;, send an
empty message to C&lt;mjd-perl-memoize-request@plover.com&gt;.  This mailing
list is for announcements only and has extremely low traffic---fewer than
two messages per year.

=head1 COPYRIGHT AND LICENSE

Copyright 1998, 1999, 2000, 2001, 2012  by Mark Jason Dominus

This library is free software; you may redistribute it and/or modify
it under the same terms as Perl itself.

=head1 THANK YOU

Many thanks to Florian Ragwitz for administration and packaging
assistance, to John Tromp for bug reports, to Jonathan Roy for bug reports
and suggestions, to Michael Schwern for other bug reports and patches,
to Mike Cariaso for helping me to figure out the Right Thing to Do
About Expiration, to Joshua Gerth, Joshua Chamas, Jonathan Roy
(again), Mark D. Anderson, and Andrew Johnson for more suggestions
about expiration, to Brent Powers for the Memoize::ExpireLRU module,
to Ariel Scolnicov for delightful messages about the Fibonacci
function, to Dion Almaer for thought-provoking suggestions about the
default normalizer, to Walt Mankowski and Kurt Starsinic for much help
investigating problems under threaded Perl, to Alex Dudkevich for
reporting the bug in prototyped functions and for checking my patch,
to Tony Bass for many helpful suggestions, to Jonathan Roy (again) for
finding a use for C&lt;unmemoize()&gt;, to Philippe Verdret for enlightening
discussion of C&lt;Hook::PrePostCall&gt;, to Nat Torkington for advice I
ignored, to Chris Nandor for portability advice, to Randal Schwartz
for suggesting the 'C&lt;flush_cache&gt; function, and to Jenda Krynicky for
being a light in the world.

Special thanks to Jarkko Hietaniemi, the 5.8.0 pumpking, for including
this module in the core and for his patient and helpful guidance
during the integration process.

=cut
</pre></body></html>