<html><head><meta name="color-scheme" content="light dark"></head><body><pre style="word-wrap: break-word; white-space: pre-wrap;">package Digest::SHA;

require 5.003000;

use strict;
use vars qw($VERSION @ISA @EXPORT @EXPORT_OK);
use Fcntl;
use integer;

$VERSION = '5.84_01';

require Exporter;
require DynaLoader;
@ISA = qw(Exporter DynaLoader);
@EXPORT_OK = qw(
	hmac_sha1	hmac_sha1_base64	hmac_sha1_hex
	hmac_sha224	hmac_sha224_base64	hmac_sha224_hex
	hmac_sha256	hmac_sha256_base64	hmac_sha256_hex
	hmac_sha384	hmac_sha384_base64	hmac_sha384_hex
	hmac_sha512	hmac_sha512_base64	hmac_sha512_hex
	hmac_sha512224	hmac_sha512224_base64	hmac_sha512224_hex
	hmac_sha512256	hmac_sha512256_base64	hmac_sha512256_hex
	sha1		sha1_base64		sha1_hex
	sha224		sha224_base64		sha224_hex
	sha256		sha256_base64		sha256_hex
	sha384		sha384_base64		sha384_hex
	sha512		sha512_base64		sha512_hex
	sha512224	sha512224_base64	sha512224_hex
	sha512256	sha512256_base64	sha512256_hex);

# If possible, inherit from Digest::base

eval {
	require Digest::base;
	push(@ISA, 'Digest::base');
};

*addfile   = \&amp;Addfile;
*hexdigest = \&amp;Hexdigest;
*b64digest = \&amp;B64digest;

# The following routines aren't time-critical, so they can be left in Perl

sub new {
	my($class, $alg) = @_;
	$alg =~ s/\D+//g if defined $alg;
	if (ref($class)) {	# instance method
		unless (defined($alg) &amp;&amp; ($alg != $class-&gt;algorithm)) {
			sharewind($$class);
			return($class);
		}
		if ($$class) { shaclose($$class); $$class = undef }
		return unless $$class = shaopen($alg);
		return($class);
	}
	$alg = 1 unless defined $alg;
	my $state = shaopen($alg) || return;
	my $self = \$state;
	bless($self, $class);
	return($self);
}

sub DESTROY {
	my $self = shift;
	if ($$self) { shaclose($$self); $$self = undef }
}

sub clone {
	my $self = shift;
	my $state = shadup($$self) || return;
	my $copy = \$state;
	bless($copy, ref($self));
	return($copy);
}

*reset = \&amp;new;

sub add_bits {
	my($self, $data, $nbits) = @_;
	unless (defined $nbits) {
		$nbits = length($data);
		$data = pack("B*", $data);
	}
	$nbits = length($data) * 8 if $nbits &gt; length($data) * 8;
	shawrite($data, $nbits, $$self);
	return($self);
}

sub _bail {
	my $msg = shift;

	$msg .= ": $!";
        require Carp;
        Carp::croak($msg);
}

sub _addfile {  # this is "addfile" from Digest::base 1.00
    my ($self, $handle) = @_;

    my $n;
    my $buf = "";

    while (($n = read($handle, $buf, 4096))) {
        $self-&gt;add($buf);
    }
    _bail("Read failed") unless defined $n;

    $self;
}

sub Addfile {
	my ($self, $file, $mode) = @_;

	return(_addfile($self, $file)) unless ref(\$file) eq 'SCALAR';

	$mode = defined($mode) ? $mode : "";
	my ($binary, $portable, $BITS) = map { $_ eq $mode } ("b", "p", "0");

		## Always interpret "-" to mean STDIN; otherwise use
		## sysopen to handle full range of POSIX file names
	local *FH;
	$file eq '-' and open(FH, '&lt; -')
		or sysopen(FH, $file, O_RDONLY)
			or _bail('Open failed');

	if ($BITS) {
		my ($n, $buf) = (0, "");
		while (($n = read(FH, $buf, 4096))) {
			$buf =~ s/[^01]//g;
			$self-&gt;add_bits($buf);
		}
		_bail("Read failed") unless defined $n;
		close(FH);
		return($self);
	}

	binmode(FH) if $binary || $portable;
	unless ($portable &amp;&amp; -T $file) {
		$self-&gt;_addfile(*FH);
		close(FH);
		return($self);
	}

	my ($n1, $n2);
	my ($buf1, $buf2) = ("", "");

	while (($n1 = read(FH, $buf1, 4096))) {
		while (substr($buf1, -1) eq "\015") {
			$n2 = read(FH, $buf2, 4096);
			_bail("Read failed") unless defined $n2;
			last unless $n2;
			$buf1 .= $buf2;
		}
		$buf1 =~ s/\015?\015\012/\012/g;	# DOS/Windows
		$buf1 =~ s/\015/\012/g;			# early MacOS
		$self-&gt;add($buf1);
	}
	_bail("Read failed") unless defined $n1;
	close(FH);

	$self;
}

sub dump {
	my $self = shift;
	my $file = shift;

	$file = "" unless defined $file;
	shadump($file, $$self) || return;
	return($self);
}

sub load {
	my $class = shift;
	my $file = shift;

	$file = "" unless defined $file;
	if (ref($class)) {	# instance method
		if ($$class) { shaclose($$class); $$class = undef }
		return unless $$class = shaload($file);
		return($class);
	}
	my $state = shaload($file) || return;
	my $self = \$state;
	bless($self, $class);
	return($self);
}

Digest::SHA-&gt;bootstrap($VERSION);

1;
__END__

=head1 NAME

Digest::SHA - Perl extension for SHA-1/224/256/384/512

=head1 SYNOPSIS

In programs:

		# Functional interface

	use Digest::SHA qw(sha1 sha1_hex sha1_base64 ...);

	$digest = sha1($data);
	$digest = sha1_hex($data);
	$digest = sha1_base64($data);

	$digest = sha256($data);
	$digest = sha384_hex($data);
	$digest = sha512_base64($data);

		# Object-oriented

	use Digest::SHA;

	$sha = Digest::SHA-&gt;new($alg);

	$sha-&gt;add($data);		# feed data into stream

	$sha-&gt;addfile(*F);
	$sha-&gt;addfile($filename);

	$sha-&gt;add_bits($bits);
	$sha-&gt;add_bits($data, $nbits);

	$sha_copy = $sha-&gt;clone;	# if needed, make copy of
	$sha-&gt;dump($file);		#	current digest state,
	$sha-&gt;load($file);		#	or save it on disk

	$digest = $sha-&gt;digest;		# compute digest
	$digest = $sha-&gt;hexdigest;
	$digest = $sha-&gt;b64digest;

From the command line:

	$ shasum files

	$ shasum --help

=head1 SYNOPSIS (HMAC-SHA)

		# Functional interface only

	use Digest::SHA qw(hmac_sha1 hmac_sha1_hex ...);

	$digest = hmac_sha1($data, $key);
	$digest = hmac_sha224_hex($data, $key);
	$digest = hmac_sha256_base64($data, $key);

=head1 ABSTRACT

Digest::SHA is a complete implementation of the NIST Secure Hash Standard.
It gives Perl programmers a convenient way to calculate SHA-1, SHA-224,
SHA-256, SHA-384, SHA-512, SHA-512/224, and SHA-512/256 message digests.
The module can handle all types of input, including partial-byte data.

=head1 DESCRIPTION

Digest::SHA is written in C for speed.  If your platform lacks a
C compiler, you can install the functionally equivalent (but much
slower) L&lt;Digest::SHA::PurePerl&gt; module.

The programming interface is easy to use: it's the same one found
in CPAN's L&lt;Digest&gt; module.  So, if your applications currently
use L&lt;Digest::MD5&gt; and you'd prefer the stronger security of SHA,
it's a simple matter to convert them.

The interface provides two ways to calculate digests:  all-at-once,
or in stages.  To illustrate, the following short program computes
the SHA-256 digest of "hello world" using each approach:

	use Digest::SHA qw(sha256_hex);

	$data = "hello world";
	@frags = split(//, $data);

	# all-at-once (Functional style)
	$digest1 = sha256_hex($data);

	# in-stages (OOP style)
	$state = Digest::SHA-&gt;new(256);
	for (@frags) { $state-&gt;add($_) }
	$digest2 = $state-&gt;hexdigest;

	print $digest1 eq $digest2 ?
		"whew!\n" : "oops!\n";

To calculate the digest of an n-bit message where I&lt;n&gt; is not a
multiple of 8, use the I&lt;add_bits()&gt; method.  For example, consider
the 446-bit message consisting of the bit-string "110" repeated
148 times, followed by "11".  Here's how to display its SHA-1
digest:

	use Digest::SHA;
	$bits = "110" x 148 . "11";
	$sha = Digest::SHA-&gt;new(1)-&gt;add_bits($bits);
	print $sha-&gt;hexdigest, "\n";

Note that for larger bit-strings, it's more efficient to use the
two-argument version I&lt;add_bits($data, $nbits)&gt;, where I&lt;$data&gt; is
in the customary packed binary format used for Perl strings.

The module also lets you save intermediate SHA states to disk, or
display them on standard output.  The I&lt;dump()&gt; method generates
portable, human-readable text describing the current state of
computation.  You can subsequently retrieve the file with I&lt;load()&gt;
to resume where the calculation left off.

To see what a state description looks like, just run the following:

	use Digest::SHA;
	Digest::SHA-&gt;new-&gt;add("Shaw" x 1962)-&gt;dump;

As an added convenience, the Digest::SHA module offers routines to
calculate keyed hashes using the HMAC-SHA-1/224/256/384/512
algorithms.  These services exist in functional form only, and
mimic the style and behavior of the I&lt;sha()&gt;, I&lt;sha_hex()&gt;, and
I&lt;sha_base64()&gt; functions.

	# Test vector from draft-ietf-ipsec-ciph-sha-256-01.txt

	use Digest::SHA qw(hmac_sha256_hex);
	print hmac_sha256_hex("Hi There", chr(0x0b) x 32), "\n";

=head1 UNICODE AND SIDE EFFECTS

Perl supports Unicode strings as of version 5.6.  Such strings may
contain wide characters, namely, characters whose ordinal values are
greater than 255.  This can cause problems for digest algorithms such
as SHA that are specified to operate on sequences of bytes.

The rule by which Digest::SHA handles a Unicode string is easy
to state, but potentially confusing to grasp: the string is interpreted
as a sequence of byte values, where each byte value is equal to the
ordinal value (viz. code point) of its corresponding Unicode character.
That way, the Unicode string 'abc' has exactly the same digest value as
the ordinary string 'abc'.

Since a wide character does not fit into a byte, the Digest::SHA
routines croak if they encounter one.  Whereas if a Unicode string
contains no wide characters, the module accepts it quite happily.
The following code illustrates the two cases:

	$str1 = pack('U*', (0..255));
	print sha1_hex($str1);		# ok

	$str2 = pack('U*', (0..256));
	print sha1_hex($str2);		# croaks

Be aware that the digest routines silently convert UTF-8 input into its
equivalent byte sequence in the native encoding (cf. utf8::downgrade).
This side effect influences only the way Perl stores the data internally,
but otherwise leaves the actual value of the data intact.

=head1 NIST STATEMENT ON SHA-1

NIST acknowledges that the work of Prof. Xiaoyun Wang constitutes a
practical collision attack on SHA-1.  Therefore, NIST encourages the
rapid adoption of the SHA-2 hash functions (e.g. SHA-256) for applications
requiring strong collision resistance, such as digital signatures.

ref. L&lt;http://csrc.nist.gov/groups/ST/hash/statement.html&gt;

=head1 PADDING OF BASE64 DIGESTS

By convention, CPAN Digest modules do B&lt;not&gt; pad their Base64 output.
Problems can occur when feeding such digests to other software that
expects properly padded Base64 encodings.

For the time being, any necessary padding must be done by the user.
Fortunately, this is a simple operation: if the length of a Base64-encoded
digest isn't a multiple of 4, simply append "=" characters to the end
of the digest until it is:

	while (length($b64_digest) % 4) {
		$b64_digest .= '=';
	}

To illustrate, I&lt;sha256_base64("abc")&gt; is computed to be

	ungWv48Bz+pBQUDeXa4iI7ADYaOWF3qctBD/YfIAFa0

which has a length of 43.  So, the properly padded version is

	ungWv48Bz+pBQUDeXa4iI7ADYaOWF3qctBD/YfIAFa0=

=head1 EXPORT

None by default.

=head1 EXPORTABLE FUNCTIONS

Provided your C compiler supports a 64-bit type (e.g. the I&lt;long
long&gt; of C99, or I&lt;__int64&gt; used by Microsoft C/C++), all of these
functions will be available for use.  Otherwise, you won't be able
to perform the SHA-384 and SHA-512 transforms, both of which require
64-bit operations.

I&lt;Functional style&gt;

=over 4

=item B&lt;sha1($data, ...)&gt;

=item B&lt;sha224($data, ...)&gt;

=item B&lt;sha256($data, ...)&gt;

=item B&lt;sha384($data, ...)&gt;

=item B&lt;sha512($data, ...)&gt;

=item B&lt;sha512224($data, ...)&gt;

=item B&lt;sha512256($data, ...)&gt;

Logically joins the arguments into a single string, and returns
its SHA-1/224/256/384/512 digest encoded as a binary string.

=item B&lt;sha1_hex($data, ...)&gt;

=item B&lt;sha224_hex($data, ...)&gt;

=item B&lt;sha256_hex($data, ...)&gt;

=item B&lt;sha384_hex($data, ...)&gt;

=item B&lt;sha512_hex($data, ...)&gt;

=item B&lt;sha512224_hex($data, ...)&gt;

=item B&lt;sha512256_hex($data, ...)&gt;

Logically joins the arguments into a single string, and returns
its SHA-1/224/256/384/512 digest encoded as a hexadecimal string.

=item B&lt;sha1_base64($data, ...)&gt;

=item B&lt;sha224_base64($data, ...)&gt;

=item B&lt;sha256_base64($data, ...)&gt;

=item B&lt;sha384_base64($data, ...)&gt;

=item B&lt;sha512_base64($data, ...)&gt;

=item B&lt;sha512224_base64($data, ...)&gt;

=item B&lt;sha512256_base64($data, ...)&gt;

Logically joins the arguments into a single string, and returns
its SHA-1/224/256/384/512 digest encoded as a Base64 string.

It's important to note that the resulting string does B&lt;not&gt; contain
the padding characters typical of Base64 encodings.  This omission is
deliberate, and is done to maintain compatibility with the family of
CPAN Digest modules.  See L&lt;/"PADDING OF BASE64 DIGESTS"&gt; for details.

=back

I&lt;OOP style&gt;

=over 4

=item B&lt;new($alg)&gt;

Returns a new Digest::SHA object.  Allowed values for I&lt;$alg&gt; are 1,
224, 256, 384, 512, 512224, or 512256.  It's also possible to use
common string representations of the algorithm (e.g. "sha256",
"SHA-384").  If the argument is missing, SHA-1 will be used by
default.

Invoking I&lt;new&gt; as an instance method will not create a new object;
instead, it will simply reset the object to the initial state
associated with I&lt;$alg&gt;.  If the argument is missing, the object
will continue using the same algorithm that was selected at creation.

=item B&lt;reset($alg)&gt;

This method has exactly the same effect as I&lt;new($alg)&gt;.  In fact,
I&lt;reset&gt; is just an alias for I&lt;new&gt;.

=item B&lt;hashsize&gt;

Returns the number of digest bits for this object.  The values are
160, 224, 256, 384, 512, 224, and 256 for SHA-1, SHA-224, SHA-256,
SHA-384, SHA-512, SHA-512/224 and SHA-512/256, respectively.

=item B&lt;algorithm&gt;

Returns the digest algorithm for this object.  The values are 1,
224, 256, 384, 512, 512224, and 512256 for SHA-1, SHA-224, SHA-256,
SHA-384, SHA-512, SHA-512/224, and SHA-512/256, respectively.

=item B&lt;clone&gt;

Returns a duplicate copy of the object.

=item B&lt;add($data, ...)&gt;

Logically joins the arguments into a single string, and uses it to
update the current digest state.  In other words, the following
statements have the same effect:

	$sha-&gt;add("a"); $sha-&gt;add("b"); $sha-&gt;add("c");
	$sha-&gt;add("a")-&gt;add("b")-&gt;add("c");
	$sha-&gt;add("a", "b", "c");
	$sha-&gt;add("abc");

The return value is the updated object itself.

=item B&lt;add_bits($data, $nbits)&gt;

=item B&lt;add_bits($bits)&gt;

Updates the current digest state by appending bits to it.  The
return value is the updated object itself.

The first form causes the most-significant I&lt;$nbits&gt; of I&lt;$data&gt;
to be appended to the stream.  The I&lt;$data&gt; argument is in the
customary binary format used for Perl strings.

The second form takes an ASCII string of "0" and "1" characters as
its argument.  It's equivalent to

	$sha-&gt;add_bits(pack("B*", $bits), length($bits));

So, the following two statements do the same thing:

	$sha-&gt;add_bits("111100001010");
	$sha-&gt;add_bits("\xF0\xA0", 12);

=item B&lt;addfile(*FILE)&gt;

Reads from I&lt;FILE&gt; until EOF, and appends that data to the current
state.  The return value is the updated object itself.

=item B&lt;addfile($filename [, $mode])&gt;

Reads the contents of I&lt;$filename&gt;, and appends that data to the current
state.  The return value is the updated object itself.

By default, I&lt;$filename&gt; is simply opened and read; no special modes
or I/O disciplines are used.  To change this, set the optional I&lt;$mode&gt;
argument to one of the following values:

	"b"	read file in binary mode

	"p"	use portable mode

	"0"	use BITS mode

The "p" mode ensures that the digest value of I&lt;$filename&gt; will be the
same when computed on different operating systems.  It accomplishes
this by internally translating all newlines in text files to UNIX format
before calculating the digest.  Binary files are read in raw mode with
no translation whatsoever.

The BITS mode ("0") interprets the contents of I&lt;$filename&gt; as a logical
stream of bits, where each ASCII '0' or '1' character represents a 0 or
1 bit, respectively.  All other characters are ignored.  This provides
a convenient way to calculate the digest values of partial-byte data by
using files, rather than having to write programs using the I&lt;add_bits&gt;
method.

=item B&lt;dump($filename)&gt;

Provides persistent storage of intermediate SHA states by writing
a portable, human-readable representation of the current state to
I&lt;$filename&gt;.  If the argument is missing, or equal to the empty
string, the state information will be written to STDOUT.

=item B&lt;load($filename)&gt;

Returns a Digest::SHA object representing the intermediate SHA
state that was previously dumped to I&lt;$filename&gt;.  If called as a
class method, a new object is created; if called as an instance
method, the object is reset to the state contained in I&lt;$filename&gt;.
If the argument is missing, or equal to the empty string, the state
information will be read from STDIN.

=item B&lt;digest&gt;

Returns the digest encoded as a binary string.

Note that the I&lt;digest&gt; method is a read-once operation. Once it
has been performed, the Digest::SHA object is automatically reset
in preparation for calculating another digest value.  Call
I&lt;$sha-E&lt;gt&gt;clone-E&lt;gt&gt;digest&gt; if it's necessary to preserve the
original digest state.

=item B&lt;hexdigest&gt;

Returns the digest encoded as a hexadecimal string.

Like I&lt;digest&gt;, this method is a read-once operation.  Call
I&lt;$sha-E&lt;gt&gt;clone-E&lt;gt&gt;hexdigest&gt; if it's necessary to preserve
the original digest state.

This method is inherited if L&lt;Digest::base&gt; is installed on your
system.  Otherwise, a functionally equivalent substitute is used.

=item B&lt;b64digest&gt;

Returns the digest encoded as a Base64 string.

Like I&lt;digest&gt;, this method is a read-once operation.  Call
I&lt;$sha-E&lt;gt&gt;clone-E&lt;gt&gt;b64digest&gt; if it's necessary to preserve
the original digest state.

This method is inherited if L&lt;Digest::base&gt; is installed on your
system.  Otherwise, a functionally equivalent substitute is used.

It's important to note that the resulting string does B&lt;not&gt; contain
the padding characters typical of Base64 encodings.  This omission is
deliberate, and is done to maintain compatibility with the family of
CPAN Digest modules.  See L&lt;/"PADDING OF BASE64 DIGESTS"&gt; for details.

=back

I&lt;HMAC-SHA-1/224/256/384/512&gt;

=over 4

=item B&lt;hmac_sha1($data, $key)&gt;

=item B&lt;hmac_sha224($data, $key)&gt;

=item B&lt;hmac_sha256($data, $key)&gt;

=item B&lt;hmac_sha384($data, $key)&gt;

=item B&lt;hmac_sha512($data, $key)&gt;

=item B&lt;hmac_sha512224($data, $key)&gt;

=item B&lt;hmac_sha512256($data, $key)&gt;

Returns the HMAC-SHA-1/224/256/384/512 digest of I&lt;$data&gt;/I&lt;$key&gt;,
with the result encoded as a binary string.  Multiple I&lt;$data&gt;
arguments are allowed, provided that I&lt;$key&gt; is the last argument
in the list.

=item B&lt;hmac_sha1_hex($data, $key)&gt;

=item B&lt;hmac_sha224_hex($data, $key)&gt;

=item B&lt;hmac_sha256_hex($data, $key)&gt;

=item B&lt;hmac_sha384_hex($data, $key)&gt;

=item B&lt;hmac_sha512_hex($data, $key)&gt;

=item B&lt;hmac_sha512224_hex($data, $key)&gt;

=item B&lt;hmac_sha512256_hex($data, $key)&gt;

Returns the HMAC-SHA-1/224/256/384/512 digest of I&lt;$data&gt;/I&lt;$key&gt;,
with the result encoded as a hexadecimal string.  Multiple I&lt;$data&gt;
arguments are allowed, provided that I&lt;$key&gt; is the last argument
in the list.

=item B&lt;hmac_sha1_base64($data, $key)&gt;

=item B&lt;hmac_sha224_base64($data, $key)&gt;

=item B&lt;hmac_sha256_base64($data, $key)&gt;

=item B&lt;hmac_sha384_base64($data, $key)&gt;

=item B&lt;hmac_sha512_base64($data, $key)&gt;

=item B&lt;hmac_sha512224_base64($data, $key)&gt;

=item B&lt;hmac_sha512256_base64($data, $key)&gt;

Returns the HMAC-SHA-1/224/256/384/512 digest of I&lt;$data&gt;/I&lt;$key&gt;,
with the result encoded as a Base64 string.  Multiple I&lt;$data&gt;
arguments are allowed, provided that I&lt;$key&gt; is the last argument
in the list.

It's important to note that the resulting string does B&lt;not&gt; contain
the padding characters typical of Base64 encodings.  This omission is
deliberate, and is done to maintain compatibility with the family of
CPAN Digest modules.  See L&lt;/"PADDING OF BASE64 DIGESTS"&gt; for details.

=back

=head1 SEE ALSO

L&lt;Digest&gt;, L&lt;Digest::SHA::PurePerl&gt;

The Secure Hash Standard (Draft FIPS PUB 180-4) can be found at:

L&lt;http://csrc.nist.gov/publications/drafts/fips180-4/Draft-FIPS180-4_Feb2011.pdf&gt;

The Keyed-Hash Message Authentication Code (HMAC):

L&lt;http://csrc.nist.gov/publications/fips/fips198/fips-198a.pdf&gt;

=head1 AUTHOR

	Mark Shelor	&lt;mshelor@cpan.org&gt;

=head1 ACKNOWLEDGMENTS

The author is particularly grateful to

	Gisle Aas
	Sean Burke
	Chris Carey
	Alexandr Ciornii
	Jim Doble
	Thomas Drugeon
	Julius Duque
	Jeffrey Friedl
	Robert Gilmour
	Brian Gladman
	Adam Kennedy
	Andy Lester
	Alex Muntada
	Steve Peters
	Chris Skiscim
	Martin Thurn
	Gunnar Wolf
	Adam Woodbury

"who by trained skill rescued life from such great billows and such thick
darkness and moored it in so perfect a calm and in so brilliant a light"
- Lucretius

=head1 COPYRIGHT AND LICENSE

Copyright (C) 2003-2013 Mark Shelor

This library is free software; you can redistribute it and/or modify
it under the same terms as Perl itself.

L&lt;perlartistic&gt;

=cut
</pre></body></html>