<html><head><meta name="color-scheme" content="light dark"></head><body><pre style="word-wrap: break-word; white-space: pre-wrap;">package XML::LibXML::AttributeHash;

use strict;
use warnings;
use Scalar::Util qw//;
use Tie::Hash;
our @ISA = qw/Tie::Hash/;

use vars qw($VERSION);
$VERSION = "2.0108"; # VERSION TEMPLATE: DO NOT CHANGE

BEGIN
{
    *__HAS_WEAKEN  = defined(&amp;Scalar::Util::weaken)
        ? sub () { 1 }
        : sub () { 0 };
};

sub element
{
    return $_[0][0];
}

sub from_clark
{
    my ($self, $str) = @_;
    if ($str =~ m! \{ (.+) \} (.+) !x)
    {
        return ($1, $2);
    }
    return (undef, $str);
}

sub to_clark
{
    my ($self, $ns, $local) = @_;
    defined $ns ? "{$ns}$local" : $local;
}

sub all_keys
{
    my ($self, @keys) = @_;

    my $elem = $self-&gt;element;

    foreach my $attr (defined($elem) ? $elem-&gt;attributes : ())
    {
        if (! $attr-&gt;isa('XML::LibXML::Namespace'))
        {
            push @keys, $self-&gt;to_clark($attr-&gt;namespaceURI, $attr-&gt;localname);
        }
    }

    return sort @keys;
}

sub TIEHASH
{
    my ($class, $element, %args) = @_;
    my $self = bless [$element, undef, \%args], $class;
    if (__HAS_WEAKEN and $args{weaken})
    {
        Scalar::Util::weaken( $self-&gt;[0] );
    }
    return $self;
}

sub STORE
{
    my ($self, $key, $value) = @_;
    my ($key_ns, $key_local) = $self-&gt;from_clark($key);
    if (defined $key_ns)
    {
        return $self-&gt;element-&gt;setAttributeNS($key_ns, "xxx:$key_local", "$value");
    }
    else
    {
        return $self-&gt;element-&gt;setAttribute($key_local, "$value");
    }
}

sub FETCH
{
    my ($self, $key) = @_;
    my ($key_ns, $key_local) = $self-&gt;from_clark($key);
    if (defined $key_ns)
    {
        return $self-&gt;element-&gt;getAttributeNS($key_ns, "$key_local");
    }
    else
    {
        return $self-&gt;element-&gt;getAttribute($key_local);
    }
}

sub EXISTS
{
    my ($self, $key) = @_;
    my ($key_ns, $key_local) = $self-&gt;from_clark($key);
    if (defined $key_ns)
    {
        return $self-&gt;element-&gt;hasAttributeNS($key_ns, "$key_local");
    }
    else
    {
        return $self-&gt;element-&gt;hasAttribute($key_local);
    }
}

sub DELETE
{
    my ($self, $key) = @_;
    my ($key_ns, $key_local) = $self-&gt;from_clark($key);
    if (defined $key_ns)
    {
        return $self-&gt;element-&gt;removeAttributeNS($key_ns, "$key_local");
    }
    else
    {
        return $self-&gt;element-&gt;removeAttribute($key_local);
    }
}

sub FIRSTKEY
{
    my ($self) = @_;
    my @keys = $self-&gt;all_keys;
    $self-&gt;[1] = \@keys;
    if (wantarray)
    {
        return ($keys[0], $self-&gt;FETCH($keys[0]));
    }
    $keys[0];
}

sub NEXTKEY
{
    my ($self, $lastkey) = @_;
    my @keys = defined $self-&gt;[1] ? @{ $self-&gt;[1] } : $self-&gt;all_keys;
    my $found;
    foreach my $k (@keys)
    {
        if ($k gt $lastkey)
        {
            $found = $k and last;
        }
    }
    if (!defined $found)
    {
        $self-&gt;[1] = undef;
        return;
    }
    if (wantarray)
    {
        return ($found, $self-&gt;FETCH($found));
    }
    return $found;
}

sub SCALAR
{
    my ($self) = @_;
    return $self-&gt;element;
}

sub CLEAR
{
    my ($self) = @_;
    foreach my $k ($self-&gt;all_keys)
    {
        $self-&gt;DELETE($k);
    }
    return $self;
}

__PACKAGE__
__END__

=head1 NAME

XML::LibXML::AttributeHash - tie an XML::LibXML::Element to a hash to access its attributes

=head1 SYNOPSIS

 tie my %hash, 'XML::LibXML::AttributeHash', $element;
 $hash{'href'} = 'http://example.com/';
 print $element-&gt;getAttribute('href') . "\n";

=head1 DESCRIPTION

This class allows an element's attributes to be accessed as if they were a
plain old Perl hash. Attribute names become hash keys. Namespaced attributes
are keyed using Clark notation.

 my $XLINK = 'http://www.w3.org/1999/xlink';
 tie my %hash, 'XML::LibXML::AttributeHash', $element;
 $hash{"{$XLINK}href"} = 'http://localhost/';
 print $element-&gt;getAttributeNS($XLINK, 'href') . "\n";

There is rarely any need to use XML::LibXML::AttributeHash directly. In
general, it is possible to take advantage of XML::LibXML::Element's
overloading. The example in the SYNOPSIS could have been written:

 $element-&gt;{'href'} = 'http://example.com/';
 print $element-&gt;getAttribute('href') . "\n";

The tie interface allows the passing of additional arguments to
XML::LibXML::AttributeHash:

 tie my %hash, 'XML::LibXML::AttributeHash', $element, %args;

Currently only one argument is supported, the boolean "weaken" which (if
true) indicates that the tied object's reference to the element should be
a weak reference. This is used by XML::LibXML::Element's overloading. The
"weaken" argument is ignored if you don't have a working Scalar::Util::weaken.
</pre></body></html>