<html><head><meta name="color-scheme" content="light dark"></head><body><pre style="word-wrap: break-word; white-space: pre-wrap;">package YAML::Syck;

# See documentation after the __END__ mark.

use strict;
use vars qw(
  @ISA @EXPORT @EXPORT_OK $VERSION
  $Headless $SortKeys $SingleQuote
  $ImplicitBinary $ImplicitTyping $ImplicitUnicode
  $UseCode $LoadCode $DumpCode
  $DeparseObject $LoadBlessed
);
use 5.006;
use Exporter;

BEGIN {
    $VERSION   = '1.27';
    @EXPORT    = qw( Dump Load DumpFile LoadFile );
    @EXPORT_OK = qw( DumpInto );
    @ISA       = qw( Exporter );

    $SortKeys    = 1;
    $LoadBlessed = 1;

    local $@;
    eval {
        require XSLoader;
        XSLoader::load( __PACKAGE__, $VERSION );
        1;
    } or do {
        require DynaLoader;
        push @ISA, 'DynaLoader';
        __PACKAGE__-&gt;bootstrap($VERSION);
    };

}

use constant QR_MAP =&gt; {
    ''   =&gt; sub { qr{$_[0]} },
    x    =&gt; sub { qr{$_[0]}x },
    i    =&gt; sub { qr{$_[0]}i },
    s    =&gt; sub { qr{$_[0]}s },
    m    =&gt; sub { qr{$_[0]}m },
    ix   =&gt; sub { qr{$_[0]}ix },
    sx   =&gt; sub { qr{$_[0]}sx },
    mx   =&gt; sub { qr{$_[0]}mx },
    si   =&gt; sub { qr{$_[0]}si },
    mi   =&gt; sub { qr{$_[0]}mi },
    ms   =&gt; sub { qr{$_[0]}sm },
    six  =&gt; sub { qr{$_[0]}six },
    mix  =&gt; sub { qr{$_[0]}mix },
    msx  =&gt; sub { qr{$_[0]}msx },
    msi  =&gt; sub { qr{$_[0]}msi },
    msix =&gt; sub { qr{$_[0]}msix },
};

sub __qr_helper {
    if ( $_[0] =~ /\A  \(\?  ([ixsm]*)  (?:-  (?:[ixsm]*))?  : (.*) \)  \z/x ) {
        my $sub = QR_MAP()-&gt;{$1} || QR_MAP()-&gt;{''};
        &amp;$sub($2);
    }
    else {
        qr/$_[0]/;
    }
}

sub Dump {
    $#_
      ? join( '', map { YAML::Syck::DumpYAML($_) } @_ )
      : YAML::Syck::DumpYAML( $_[0] );
}

sub Load {
    if (wantarray) {
        my ($rv) = YAML::Syck::LoadYAML( $_[0] );
        @{$rv};
    }
    else {
        @_ = $_[0];
        goto &amp;YAML::Syck::LoadYAML;
    }
}

sub _is_glob {
    my $h = shift;

    return 1 if ( ref($h) eq 'GLOB' );
    return 1 if ( ref( \$h ) eq 'GLOB' );
    return 1 if ( ref($h) =~ m/^IO::/ );

    return;
}

sub DumpFile {
    my $file = shift;
    if ( _is_glob($file) ) {
        for (@_) {
            my $err = YAML::Syck::DumpYAMLFile( $_, $file );
            if ($err) {
                $! = 0 + $err;
                die "Error writing to filehandle $file: $!\n";
            }
        }
    }
    else {
        open( my $fh, '&gt;', $file ) or die "Cannot write to $file: $!";
        for (@_) {
            my $err = YAML::Syck::DumpYAMLFile( $_, $fh );
            if ($err) {
                $! = 0 + $err;
                die "Error writing to file $file: $!\n";
            }
        }
        close $fh
          or die "Error writing to file $file: $!\n";
    }
    return 1;
}

sub LoadFile {
    my $file = shift;
    if ( _is_glob($file) ) {
        Load(
            do { local $/; &lt;$file&gt; }
        );
    }
    else {
        if ( !-e $file || -z $file ) {
            die("'$file' is empty or non-existent");
        }
        open( my $fh, '&lt;', $file ) or die "Cannot read from $file: $!";
        Load(
            do { local $/; &lt;$fh&gt; }
        );
    }
}

sub DumpInto {
    my $bufref = shift;
    ( ref $bufref ) or die "DumpInto not given reference to output buffer\n";
    YAML::Syck::DumpYAMLInto( $_, $bufref ) for @_;
    1;
}

1;

__END__
=pod

=head1 NAME 

YAML::Syck - Fast, lightweight YAML loader and dumper

=head1 SYNOPSIS

    use YAML::Syck;

    # Set this for interoperability with other YAML/Syck bindings:
    # e.g. Load('Yes') becomes 1 and Load('No') becomes ''.
    $YAML::Syck::ImplicitTyping = 1;

    $data = Load($yaml);
    $yaml = Dump($data);

    # $file can be an IO object, or a filename
    $data = LoadFile($file);
    DumpFile($file, $data);

    # A string with multiple YAML streams in it
    $yaml = Dump(@data);
    @data = Load($yaml);

    # Dumping into a pre-existing output buffer
    my $yaml;
    DumpInto(\$yaml, @data);

=head1 DESCRIPTION

This module provides a Perl interface to the B&lt;libsyck&gt; data serialization
library.  It exports the C&lt;Dump&gt; and C&lt;Load&gt; functions for converting
Perl data structures to YAML strings, and the other way around.

B&lt;NOTE&gt;: If you are working with other language's YAML/Syck bindings
(such as Ruby), please set C&lt;$YAML::Syck::ImplicitTyping&gt; to C&lt;1&gt; before
calling the C&lt;Load&gt;/C&lt;Dump&gt; functions.  The default setting is for
preserving backward-compatibility with C&lt;YAML.pm&gt;.

=head1 Differences Between YAML::Syck and YAML

=head2 Error handling

Some calls are designed to die rather than returning YAML. You should wrap
your calls in eval to assure you do not get unexpected results.

=head1 FLAGS

=head2 $YAML::Syck::Headless

Defaults to false.  Setting this to a true value will make C&lt;Dump&gt; omit the
leading C&lt;---\n&gt; marker.

=head2 $YAML::Syck::SortKeys

Defaults to false.  Setting this to a true value will make C&lt;Dump&gt; sort
hash keys.

=head2 $YAML::Syck::SingleQuote

Defaults to false.  Setting this to a true value will make C&lt;Dump&gt; always emit
single quotes instead of bare strings.

=head2 $YAML::Syck::ImplicitTyping

Defaults to false.  Setting this to a true value will make C&lt;Load&gt; recognize
various implicit types in YAML, such as unquoted C&lt;true&gt;, C&lt;false&gt;, as well as
integers and floating-point numbers.  Otherwise, only C&lt;~&gt; is recognized to
be C&lt;undef&gt;.

=head2 $YAML::Syck::ImplicitUnicode

Defaults to false.  For Perl 5.8.0 or later, setting this to a true value will
make C&lt;Load&gt; set Unicode flag on for every string that contains valid UTF8
sequences, and make C&lt;Dump&gt; return a unicode string.

Regardless of this flag, Unicode strings are dumped verbatim without escaping;
byte strings with high-bit set will be dumped with backslash escaping.

However, because YAML does not distinguish between these two kinds of strings,
so this flag will affect loading of both variants of strings.

If you want to use LoadFile or DumpFile with unicode, you are required to open
your own file in order to assure it's UTF8 encoded:

  open(my $fh, "&gt;:encoding(UTF-8)", "out.yml");
  DumpFile($fh, $hashref);

=head2 $YAML::Syck::ImplicitBinary

Defaults to false.  For Perl 5.8.0 or later, setting this to a true value will
make C&lt;Dump&gt; generate Base64-encoded C&lt;!!binary&gt; data for all non-Unicode
scalars containing high-bit bytes.

=head2 $YAML::Syck::UseCode / $YAML::Syck::LoadCode / $YAML::Syck::DumpCode

These flags control whether or not to try and eval/deparse perl source code;
each of them defaults to false.

Setting C&lt;$YAML::Syck::UseCode&gt; to a true value is equivalent to setting
both C&lt;$YAML::Syck::LoadCode&gt; and C&lt;$YAML::Syck::DumpCode&gt; to true.

=head2 $YAML::Syck::LoadBlessed

Defaults to true. Setting to false will block YAML::Syck from doing ANY
blessing. This is an interface change since 1.21. The variable name was
misleading, implying that no blessing would happen when in fact it did.

Prior to 1.22, setting this to a false value only prevented C&lt;Load&gt; from
blessing tag names that did not begin with C&lt;!!perl&gt; or C&lt;!perl&gt;;.

=head1 BUGS

Dumping Glob/IO values do not work yet.

Dumping of Tied variables is unsupported.

Dumping into tied (or other magic variables) with C&lt;DumpInto&gt; might not work
properly in all cases.

=head1 CAVEATS

This module implements the YAML 1.0 spec.  To deal with data in YAML 1.1, 
please use the C&lt;YAML::XS&gt; module instead.

The current implementation bundles libsyck source code; if your system has a
site-wide shared libsyck, it will I&lt;not&gt; be used.

Tag names such as C&lt;!!perl/hash:Foo&gt; is blessed into the package C&lt;Foo&gt;, but
the C&lt;!hs/foo&gt; and C&lt;!!hs/Foo&gt; tags are blessed into C&lt;hs::Foo&gt;.  Note that
this holds true even if the tag contains non-word characters; for example,
C&lt;!haskell.org/Foo&gt; is blessed into C&lt;haskell.org::Foo&gt;.  Please use
L&lt;Class::Rebless&gt; to cast it into other user-defined packages. You can also
set the LoadBlessed flag false to disable all blessing.

This module has L&lt;a lot of known
issues|https://rt.cpan.org/Public/Dist/Display.html?Name=YAML-Syck&gt;
and has only been semi-actively maintained since 2007. If you
encounter an issue with it probably won't be fixed unless you L&lt;offer
up a patch|http://github.com/toddr/YAML-Syck&gt; in Git that's ready for
release.

There are still good reasons to use this module, such as better
interoperability with other syck wrappers (like Ruby's), or some edge
case of YAML's syntax that it handles better. It'll probably work
perfectly for you, but if it doesn't you may want to look at
L&lt;YAML::XS&gt;, or perhaps at looking another serialization format like
L&lt;JSON&gt;.

=head1 SEE ALSO

L&lt;YAML&gt;, L&lt;JSON::Syck&gt;

L&lt;http://www.yaml.org/&gt;

=head1 AUTHORS

Audrey Tang E&lt;lt&gt;cpan@audreyt.orgE&lt;gt&gt;

=head1 COPYRIGHT

Copyright 2005-2009 by Audrey Tang E&lt;lt&gt;cpan@audreyt.orgE&lt;gt&gt;.

This software is released under the MIT license cited below.

The F&lt;libsyck&gt; code bundled with this library is released by
"why the lucky stiff", under a BSD-style license.  See the F&lt;COPYING&gt;
file for details.

=head2 The "MIT" License

Permission is hereby granted, free of charge, to any person obtaining a copy
of this software and associated documentation files (the "Software"), to deal
in the Software without restriction, including without limitation the rights
to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
copies of the Software, and to permit persons to whom the Software is
furnished to do so, subject to the following conditions:

The above copyright notice and this permission notice shall be included in
all copies or substantial portions of the Software.

THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS
OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL
THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER
DEALINGS IN THE SOFTWARE.

=cut
</pre></body></html>