<html><head><meta name="color-scheme" content="light dark"></head><body><pre style="word-wrap: break-word; white-space: pre-wrap;">package CPAN::Index;
use strict;
use vars qw($LAST_TIME $DATE_OF_02 $DATE_OF_03 $HAVE_REANIMATED $VERSION);
$VERSION = "1.9600";
@CPAN::Index::ISA = qw(CPAN::Debug);
$LAST_TIME ||= 0;
$DATE_OF_03 ||= 0;
# use constant PROTOCOL =&gt; "2.0"; # outcommented to avoid warning on upgrade from 1.57
sub PROTOCOL { 2.0 }

#-&gt; sub CPAN::Index::force_reload ;
sub force_reload {
    my($class) = @_;
    $CPAN::Index::LAST_TIME = 0;
    $class-&gt;reload(1);
}

my @indexbundle =
    (
     {
      reader =&gt; "rd_authindex",
      dir =&gt; "authors",
      remotefile =&gt; '01mailrc.txt.gz',
      shortlocalfile =&gt; '01mailrc.gz',
     },
     {
      reader =&gt; "rd_modpacks",
      dir =&gt; "modules",
      remotefile =&gt; '02packages.details.txt.gz',
      shortlocalfile =&gt; '02packag.gz',
     },
     {
      reader =&gt; "rd_modlist",
      dir =&gt; "modules",
      remotefile =&gt; '03modlist.data.gz',
      shortlocalfile =&gt; '03mlist.gz',
     },
    );

#-&gt; sub CPAN::Index::reload ;
sub reload {
    my($self,$force) = @_;
    my $time = time;

    # XXX check if a newer one is available. (We currently read it
    # from time to time)
    for ($CPAN::Config-&gt;{index_expire}) {
        $_ = 0.001 unless $_ &amp;&amp; $_ &gt; 0.001;
    }
    unless (1 || $CPAN::Have_warned-&gt;{readmetadatacache}++) {
        # debug here when CPAN doesn't seem to read the Metadata
        require Carp;
        Carp::cluck("META-PROTOCOL[$CPAN::META-&gt;{PROTOCOL}]");
    }
    unless ($CPAN::META-&gt;{PROTOCOL}) {
        $self-&gt;read_metadata_cache;
        $CPAN::META-&gt;{PROTOCOL} ||= "1.0";
    }
    if ( $CPAN::META-&gt;{PROTOCOL} &lt; PROTOCOL  ) {
        # warn "Setting last_time to 0";
        $LAST_TIME = 0; # No warning necessary
    }
    if ($LAST_TIME + $CPAN::Config-&gt;{index_expire}*86400 &gt; $time
        and ! $force) {
        # called too often
        # CPAN-&gt;debug("LAST_TIME[$LAST_TIME]index_expire[$CPAN::Config-&gt;{index_expire}]time[$time]");
    } elsif (0) {
        # IFF we are developing, it helps to wipe out the memory
        # between reloads, otherwise it is not what a user expects.
        undef $CPAN::META; # Neue Gruendlichkeit since v1.52(r1.274)
        $CPAN::META = CPAN-&gt;new;
    } else {
        my($debug,$t2);
        local $LAST_TIME = $time;
        local $CPAN::META-&gt;{PROTOCOL} = PROTOCOL;

        my $needshort = $^O eq "dos";

    INX: for my $indexbundle (@indexbundle) {
            my $reader = $indexbundle-&gt;{reader};
            my $localfile = $needshort ? $indexbundle-&gt;{shortlocalfile} : $indexbundle-&gt;{remotefile};
            my $localpath = File::Spec-&gt;catfile($indexbundle-&gt;{dir}, $localfile);
            my $remote = join "/", $indexbundle-&gt;{dir}, $indexbundle-&gt;{remotefile};
            my $localized = $self-&gt;reload_x($remote, $localpath, $force);
            $self-&gt;$reader($localized); # may die but we let the shell catch it
            if ($CPAN::DEBUG){
                $t2 = time;
                $debug = "timing reading 01[".($t2 - $time)."]";
                $time = $t2;
            }
            return if $CPAN::Signal; # this is sometimes lengthy
        }
        $self-&gt;write_metadata_cache;
        if ($CPAN::DEBUG){
            $t2 = time;
            $debug .= "03[".($t2 - $time)."]";
            $time = $t2;
        }
        CPAN-&gt;debug($debug) if $CPAN::DEBUG;
    }
    if ($CPAN::Config-&gt;{build_dir_reuse}) {
        $self-&gt;reanimate_build_dir;
    }
    if (CPAN::_sqlite_running()) {
        $CPAN::SQLite-&gt;reload(time =&gt; $time, force =&gt; $force)
            if not $LAST_TIME;
    }
    $LAST_TIME = $time;
    $CPAN::META-&gt;{PROTOCOL} = PROTOCOL;
}

#-&gt; sub CPAN::Index::reanimate_build_dir ;
sub reanimate_build_dir {
    my($self) = @_;
    unless ($CPAN::META-&gt;has_inst($CPAN::Config-&gt;{yaml_module}||"YAML")) {
        return;
    }
    return if $HAVE_REANIMATED++;
    my $d = $CPAN::Config-&gt;{build_dir};
    my $dh = DirHandle-&gt;new;
    opendir $dh, $d or return; # does not exist
    my $dirent;
    my $i = 0;
    my $painted = 0;
    my $restored = 0;
    my @candidates = map { $_-&gt;[0] }
        sort { $b-&gt;[1] &lt;=&gt; $a-&gt;[1] }
            map { [ $_, -M File::Spec-&gt;catfile($d,$_) ] }
                grep {/(.+)\.yml$/ &amp;&amp; -d File::Spec-&gt;catfile($d,$1)} readdir $dh;
    unless (@candidates) {
        $CPAN::Frontend-&gt;myprint("Build_dir empty, nothing to restore\n");
        return;
    }
    $CPAN::Frontend-&gt;myprint
        (sprintf("Reading %d yaml file%s from %s/\n",
                 scalar @candidates,
                 @candidates==1 ? "" : "s",
                 $CPAN::Config-&gt;{build_dir}
                ));
    my $start = CPAN::FTP::_mytime();
  DISTRO: for $i (0..$#candidates) {
        my $dirent = $candidates[$i];
        my $y = eval {CPAN-&gt;_yaml_loadfile(File::Spec-&gt;catfile($d,$dirent))};
        if ($@) {
            warn "Error while parsing file '$dirent'; error: '$@'";
            next DISTRO;
        }
        my $c = $y-&gt;[0];
        if ($c &amp;&amp; $c-&gt;{perl} &amp;&amp; $c-&gt;{distribution} &amp;&amp; CPAN-&gt;_perl_fingerprint($c-&gt;{perl})) {
            my $key = $c-&gt;{distribution}{ID};
            for my $k (keys %{$c-&gt;{distribution}}) {
                if ($c-&gt;{distribution}{$k}
                    &amp;&amp; ref $c-&gt;{distribution}{$k}
                    &amp;&amp; UNIVERSAL::isa($c-&gt;{distribution}{$k},"CPAN::Distrostatus")) {
                    $c-&gt;{distribution}{$k}{COMMANDID} = $i - @candidates;
                }
            }

            #we tried to restore only if element already
            #exists; but then we do not work with metadata
            #turned off.
            my $do
                = $CPAN::META-&gt;{readwrite}{'CPAN::Distribution'}{$key}
                    = $c-&gt;{distribution};
            for my $skipper (qw(
                                badtestcnt
                                configure_requires_later
                                configure_requires_later_for
                                force_update
                                later
                                later_for
                                notest
                                should_report
                                sponsored_mods
                                prefs
                                negative_prefs_cache
                               )) {
                delete $do-&gt;{$skipper};
            }
            if ($do-&gt;can("tested_ok_but_not_installed")) {
                if ($do-&gt;tested_ok_but_not_installed) {
                    $CPAN::META-&gt;is_tested($do-&gt;{build_dir},$do-&gt;{make_test}{TIME});
                } else {
                    next DISTRO;
                }
            }
            $restored++;
        }
        $i++;
        while (($painted/76) &lt; ($i/@candidates)) {
            $CPAN::Frontend-&gt;myprint(".");
            $painted++;
        }
    }
    my $took = CPAN::FTP::_mytime() - $start;
    $CPAN::Frontend-&gt;myprint(sprintf(
                                     "DONE\nRestored the state of %s (in %.4f secs)\n",
                                     $restored || "none",
                                     $took,
                                    ));
}


#-&gt; sub CPAN::Index::reload_x ;
sub reload_x {
    my($cl,$wanted,$localname,$force) = @_;
    $force |= 2; # means we're dealing with an index here
    CPAN::HandleConfig-&gt;load; # we should guarantee loading wherever
                              # we rely on Config XXX
    $localname ||= $wanted;
    my $abs_wanted = File::Spec-&gt;catfile($CPAN::Config-&gt;{'keep_source_where'},
                                         $localname);
    if (
        -f $abs_wanted &amp;&amp;
        -M $abs_wanted &lt; $CPAN::Config-&gt;{'index_expire'} &amp;&amp;
        !($force &amp; 1)
       ) {
        my $s = $CPAN::Config-&gt;{'index_expire'} == 1 ? "" : "s";
        $cl-&gt;debug(qq{$abs_wanted younger than $CPAN::Config-&gt;{'index_expire'} }.
                   qq{day$s. I\'ll use that.});
        return $abs_wanted;
    } else {
        $force |= 1; # means we're quite serious about it.
    }
    return CPAN::FTP-&gt;localize($wanted,$abs_wanted,$force);
}

#-&gt; sub CPAN::Index::rd_authindex ;
sub rd_authindex {
    my($cl, $index_target) = @_;
    return unless defined $index_target;
    return if CPAN::_sqlite_running();
    my @lines;
    $CPAN::Frontend-&gt;myprint("Reading '$index_target'\n");
    local(*FH);
    tie *FH, 'CPAN::Tarzip', $index_target;
    local($/) = "\n";
    local($_);
    push @lines, split /\012/ while &lt;FH&gt;;
    my $i = 0;
    my $painted = 0;
    foreach (@lines) {
        my($userid,$fullname,$email) =
            m/alias\s+(\S+)\s+\"([^\"\&lt;]*)\s+\&lt;(.*)\&gt;\"/;
        $fullname ||= $email;
        if ($userid &amp;&amp; $fullname &amp;&amp; $email) {
            my $userobj = $CPAN::META-&gt;instance('CPAN::Author',$userid);
            $userobj-&gt;set('FULLNAME' =&gt; $fullname, 'EMAIL' =&gt; $email);
        } else {
            CPAN-&gt;debug(sprintf "line[%s]", $_) if $CPAN::DEBUG;
        }
        $i++;
        while (($painted/76) &lt; ($i/@lines)) {
            $CPAN::Frontend-&gt;myprint(".");
            $painted++;
        }
        return if $CPAN::Signal;
    }
    $CPAN::Frontend-&gt;myprint("DONE\n");
}

sub userid {
  my($self,$dist) = @_;
  $dist = $self-&gt;{'id'} unless defined $dist;
  my($ret) = $dist =~ m|(?:\w/\w\w/)?([^/]+)/|;
  $ret;
}

#-&gt; sub CPAN::Index::rd_modpacks ;
sub rd_modpacks {
    my($self, $index_target) = @_;
    return unless defined $index_target;
    return if CPAN::_sqlite_running();
    $CPAN::Frontend-&gt;myprint("Reading '$index_target'\n");
    my $fh = CPAN::Tarzip-&gt;TIEHANDLE($index_target);
    local $_;
    CPAN-&gt;debug(sprintf "start[%d]", time) if $CPAN::DEBUG;
    my $slurp = "";
    my $chunk;
    while (my $bytes = $fh-&gt;READ(\$chunk,8192)) {
        $slurp.=$chunk;
    }
    my @lines = split /\012/, $slurp;
    CPAN-&gt;debug(sprintf "end[%d]", time) if $CPAN::DEBUG;
    undef $fh;
    # read header
    my($line_count,$last_updated);
    while (@lines) {
        my $shift = shift(@lines);
        last if $shift =~ /^\s*$/;
        $shift =~ /^Line-Count:\s+(\d+)/ and $line_count = $1;
        $shift =~ /^Last-Updated:\s+(.+)/ and $last_updated = $1;
    }
    CPAN-&gt;debug("line_count[$line_count]last_updated[$last_updated]") if $CPAN::DEBUG;
    my $errors = 0;
    if (not defined $line_count) {

        $CPAN::Frontend-&gt;mywarn(qq{Warning: Your $index_target does not contain a Line-Count header.
Please check the validity of the index file by comparing it to more
than one CPAN mirror. I'll continue but problems seem likely to
happen.\a
});
        $errors++;
        $CPAN::Frontend-&gt;mysleep(5);
    } elsif ($line_count != scalar @lines) {

        $CPAN::Frontend-&gt;mywarn(sprintf qq{Warning: Your %s
contains a Line-Count header of %d but I see %d lines there. Please
check the validity of the index file by comparing it to more than one
CPAN mirror. I'll continue but problems seem likely to happen.\a\n},
$index_target, $line_count, scalar(@lines));

    }
    if (not defined $last_updated) {

        $CPAN::Frontend-&gt;mywarn(qq{Warning: Your $index_target does not contain a Last-Updated header.
Please check the validity of the index file by comparing it to more
than one CPAN mirror. I'll continue but problems seem likely to
happen.\a
});
        $errors++;
        $CPAN::Frontend-&gt;mysleep(5);
    } else {

        $CPAN::Frontend
            -&gt;myprint(sprintf qq{  Database was generated on %s\n},
                      $last_updated);
        $DATE_OF_02 = $last_updated;

        my $age = time;
        if ($CPAN::META-&gt;has_inst('HTTP::Date')) {
            require HTTP::Date;
            $age -= HTTP::Date::str2time($last_updated);
        } else {
            $CPAN::Frontend-&gt;mywarn("  HTTP::Date not available\n");
            require Time::Local;
            my(@d) = $last_updated =~ / (\d+) (\w+) (\d+) (\d+):(\d+):(\d+) /;
            $d[1] = index("Jan Feb Mar Apr May Jun Jul Aug Sep Oct Nov Dec", $d[1])/4;
            $age -= $d[1]&gt;=0 ? Time::Local::timegm(@d[5,4,3,0,1,2]) : 0;
        }
        $age /= 3600*24;
        if ($age &gt; 30) {

            $CPAN::Frontend
                -&gt;mywarn(sprintf
                         qq{Warning: This index file is %d days old.
  Please check the host you chose as your CPAN mirror for staleness.
  I'll continue but problems seem likely to happen.\a\n},
                         $age);

        } elsif ($age &lt; -1) {

            $CPAN::Frontend
                -&gt;mywarn(sprintf
                         qq{Warning: Your system date is %d days behind this index file!
  System time:          %s
  Timestamp index file: %s
  Please fix your system time, problems with the make command expected.\n},
                         -$age,
                         scalar gmtime,
                         $DATE_OF_02,
                        );

        }
    }


    # A necessity since we have metadata_cache: delete what isn't
    # there anymore
    my $secondtime = $CPAN::META-&gt;exists("CPAN::Module","CPAN");
    CPAN-&gt;debug("secondtime[$secondtime]") if $CPAN::DEBUG;
    my(%exists);
    my $i = 0;
    my $painted = 0;
 LINE: foreach (@lines) {
        # before 1.56 we split into 3 and discarded the rest. From
        # 1.57 we assign remaining text to $comment thus allowing to
        # influence isa_perl
        my($mod,$version,$dist,$comment) = split " ", $_, 4;
        unless ($mod &amp;&amp; defined $version &amp;&amp; $dist) {
            require Dumpvalue;
            my $dv = Dumpvalue-&gt;new(tick =&gt; '"');
            $CPAN::Frontend-&gt;mywarn(sprintf "Could not split line[%s]\n", $dv-&gt;stringify($_));
            if ($errors++ &gt;= 5){
                $CPAN::Frontend-&gt;mydie("Giving up parsing your $index_target, too many errors");
            }
            next LINE;
        }
        my($bundle,$id,$userid);

        if ($mod eq 'CPAN' &amp;&amp;
            ! (
            CPAN::Queue-&gt;exists('Bundle::CPAN') ||
            CPAN::Queue-&gt;exists('CPAN')
            )
        ) {
            local($^W)= 0;
            if ($version &gt; $CPAN::VERSION) {
                $CPAN::Frontend-&gt;mywarn(qq{
  New CPAN.pm version (v$version) available.
  [Currently running version is v$CPAN::VERSION]
  You might want to try
    install CPAN
    reload cpan
  to both upgrade CPAN.pm and run the new version without leaving
  the current session.

}); #});
                $CPAN::Frontend-&gt;mysleep(2);
                $CPAN::Frontend-&gt;myprint(qq{\n});
            }
            last if $CPAN::Signal;
        } elsif ($mod =~ /^Bundle::(.*)/) {
            $bundle = $1;
        }

        if ($bundle) {
            $id =  $CPAN::META-&gt;instance('CPAN::Bundle',$mod);
            # Let's make it a module too, because bundles have so much
            # in common with modules.

            # Changed in 1.57_63: seems like memory bloat now without
            # any value, so commented out

            # $CPAN::META-&gt;instance('CPAN::Module',$mod);

        } else {

            # instantiate a module object
            $id = $CPAN::META-&gt;instance('CPAN::Module',$mod);

        }

        # Although CPAN prohibits same name with different version the
        # indexer may have changed the version for the same distro
        # since the last time ("Force Reindexing" feature)
        if ($id-&gt;cpan_file ne $dist
            ||
            $id-&gt;cpan_version ne $version
           ) {
            $userid = $id-&gt;userid || $self-&gt;userid($dist);
            $id-&gt;set(
                     'CPAN_USERID' =&gt; $userid,
                     'CPAN_VERSION' =&gt; $version,
                     'CPAN_FILE' =&gt; $dist,
                    );
        }

        # instantiate a distribution object
        if ($CPAN::META-&gt;exists('CPAN::Distribution',$dist)) {
        # we do not need CONTAINSMODS unless we do something with
        # this dist, so we better produce it on demand.

        ## my $obj = $CPAN::META-&gt;instance(
        ##                                 'CPAN::Distribution' =&gt; $dist
        ##                                );
        ## $obj-&gt;{CONTAINSMODS}{$mod} = undef; # experimental
        } else {
            $CPAN::META-&gt;instance(
                                  'CPAN::Distribution' =&gt; $dist
                                 )-&gt;set(
                                        'CPAN_USERID' =&gt; $userid,
                                        'CPAN_COMMENT' =&gt; $comment,
                                       );
        }
        if ($secondtime) {
            for my $name ($mod,$dist) {
                # $self-&gt;debug("exists name[$name]") if $CPAN::DEBUG;
                $exists{$name} = undef;
            }
        }
        $i++;
        while (($painted/76) &lt; ($i/@lines)) {
            $CPAN::Frontend-&gt;myprint(".");
            $painted++;
        }
        return if $CPAN::Signal;
    }
    $CPAN::Frontend-&gt;myprint("DONE\n");
    if ($secondtime) {
        for my $class (qw(CPAN::Module CPAN::Bundle CPAN::Distribution)) {
            for my $o ($CPAN::META-&gt;all_objects($class)) {
                next if exists $exists{$o-&gt;{ID}};
                $CPAN::META-&gt;delete($class,$o-&gt;{ID});
                # CPAN-&gt;debug("deleting ID[$o-&gt;{ID}] in class[$class]")
                #     if $CPAN::DEBUG;
            }
        }
    }
}

#-&gt; sub CPAN::Index::rd_modlist ;
sub rd_modlist {
    my($cl,$index_target) = @_;
    return unless defined $index_target;
    return if CPAN::_sqlite_running();
    $CPAN::Frontend-&gt;myprint("Reading '$index_target'\n");
    my $fh = CPAN::Tarzip-&gt;TIEHANDLE($index_target);
    local $_;
    my $slurp = "";
    my $chunk;
    while (my $bytes = $fh-&gt;READ(\$chunk,8192)) {
        $slurp.=$chunk;
    }
    my @eval2 = split /\012/, $slurp;

    while (@eval2) {
        my $shift = shift(@eval2);
        if ($shift =~ /^Date:\s+(.*)/) {
            if ($DATE_OF_03 eq $1) {
                $CPAN::Frontend-&gt;myprint("Unchanged.\n");
                return;
            }
            ($DATE_OF_03) = $1;
        }
        last if $shift =~ /^\s*$/;
    }
    push @eval2, q{CPAN::Modulelist-&gt;data;};
    local($^W) = 0;
    my($compmt) = Safe-&gt;new("CPAN::Safe1");
    my($eval2) = join("\n", @eval2);
    CPAN-&gt;debug(sprintf "length of eval2[%d]", length $eval2) if $CPAN::DEBUG;
    my $ret = $compmt-&gt;reval($eval2);
    Carp::confess($@) if $@;
    return if $CPAN::Signal;
    my $i = 0;
    my $until = keys(%$ret);
    my $painted = 0;
    CPAN-&gt;debug(sprintf "until[%d]", $until) if $CPAN::DEBUG;
    for (keys %$ret) {
        my $obj = $CPAN::META-&gt;instance("CPAN::Module",$_);
        delete $ret-&gt;{$_}{modid}; # not needed here, maybe elsewhere
        $obj-&gt;set(%{$ret-&gt;{$_}});
        $i++;
        while (($painted/76) &lt; ($i/$until)) {
            $CPAN::Frontend-&gt;myprint(".");
            $painted++;
        }
        return if $CPAN::Signal;
    }
    $CPAN::Frontend-&gt;myprint("DONE\n");
}

#-&gt; sub CPAN::Index::write_metadata_cache ;
sub write_metadata_cache {
    my($self) = @_;
    return unless $CPAN::Config-&gt;{'cache_metadata'};
    return if CPAN::_sqlite_running();
    return unless $CPAN::META-&gt;has_usable("Storable");
    my $cache;
    foreach my $k (qw(CPAN::Bundle CPAN::Author CPAN::Module
                      CPAN::Distribution)) {
        $cache-&gt;{$k} = $CPAN::META-&gt;{readonly}{$k}; # unsafe meta access, ok
    }
    my $metadata_file = File::Spec-&gt;catfile($CPAN::Config-&gt;{cpan_home},"Metadata");
    $cache-&gt;{last_time} = $LAST_TIME;
    $cache-&gt;{DATE_OF_02} = $DATE_OF_02;
    $cache-&gt;{PROTOCOL} = PROTOCOL;
    $CPAN::Frontend-&gt;myprint("Writing $metadata_file\n");
    eval { Storable::nstore($cache, $metadata_file) };
    $CPAN::Frontend-&gt;mywarn($@) if $@; # ?? missing "\n" after $@ in mywarn ??
}

#-&gt; sub CPAN::Index::read_metadata_cache ;
sub read_metadata_cache {
    my($self) = @_;
    return unless $CPAN::Config-&gt;{'cache_metadata'};
    return if CPAN::_sqlite_running();
    return unless $CPAN::META-&gt;has_usable("Storable");
    my $metadata_file = File::Spec-&gt;catfile($CPAN::Config-&gt;{cpan_home},"Metadata");
    return unless -r $metadata_file and -f $metadata_file;
    $CPAN::Frontend-&gt;myprint("Reading '$metadata_file'\n");
    my $cache;
    eval { $cache = Storable::retrieve($metadata_file) };
    $CPAN::Frontend-&gt;mywarn($@) if $@; # ?? missing "\n" after $@ in mywarn ??
    if (!$cache || !UNIVERSAL::isa($cache, 'HASH')) {
        $LAST_TIME = 0;
        return;
    }
    if (exists $cache-&gt;{PROTOCOL}) {
        if (PROTOCOL &gt; $cache-&gt;{PROTOCOL}) {
            $CPAN::Frontend-&gt;mywarn(sprintf("Ignoring Metadata cache written ".
                                            "with protocol v%s, requiring v%s\n",
                                            $cache-&gt;{PROTOCOL},
                                            PROTOCOL)
                                   );
            return;
        }
    } else {
        $CPAN::Frontend-&gt;mywarn("Ignoring Metadata cache written ".
                                "with protocol v1.0\n");
        return;
    }
    my $clcnt = 0;
    my $idcnt = 0;
    while(my($class,$v) = each %$cache) {
        next unless $class =~ /^CPAN::/;
        $CPAN::META-&gt;{readonly}{$class} = $v; # unsafe meta access, ok
        while (my($id,$ro) = each %$v) {
            $CPAN::META-&gt;{readwrite}{$class}{$id} ||=
                $class-&gt;new(ID=&gt;$id, RO=&gt;$ro);
            $idcnt++;
        }
        $clcnt++;
    }
    unless ($clcnt) { # sanity check
        $CPAN::Frontend-&gt;myprint("Warning: Found no data in $metadata_file\n");
        return;
    }
    if ($idcnt &lt; 1000) {
        $CPAN::Frontend-&gt;myprint("Warning: Found only $idcnt objects ".
                                 "in $metadata_file\n");
        return;
    }
    $CPAN::META-&gt;{PROTOCOL} ||=
        $cache-&gt;{PROTOCOL}; # reading does not up or downgrade, but it
                            # does initialize to some protocol
    $LAST_TIME = $cache-&gt;{last_time};
    $DATE_OF_02 = $cache-&gt;{DATE_OF_02};
    $CPAN::Frontend-&gt;myprint("  Database was generated on $DATE_OF_02\n")
        if defined $DATE_OF_02; # An old cache may not contain DATE_OF_02
    return;
}

1;
</pre></body></html>