<html><head><meta name="color-scheme" content="light dark"></head><body><pre style="word-wrap: break-word; white-space: pre-wrap;">package CPANPLUS::Config;
use deprecate;

use strict;
use warnings;

use base 'Object::Accessor';
use base 'CPANPLUS::Internals::Utils';

use Config;
use File::Spec;
use Module::Load;
use CPANPLUS;
use CPANPLUS::Error;
use CPANPLUS::Internals::Constants;

use File::Basename              qw[dirname];
use IPC::Cmd                    qw[can_run];
use Locale::Maketext::Simple    Class =&gt; 'CPANPLUS', Style =&gt; 'gettext';
use Module::Load::Conditional   qw[check_install];
use version;

use vars qw[$VERSION];
$VERSION = "0.9135";

=pod

=head1 NAME

CPANPLUS::Config - configuration defaults and heuristics for CPANPLUS

=head1 SYNOPSIS

    ### conf object via CPANPLUS::Backend;
    $cb   = CPANPLUS::Backend-&gt;new;
    $conf = $cb-&gt;configure_object;

    ### or as a standalone object
    $conf = CPANPLUS::Configure-&gt;new;

    ### values in 'conf' section
    $verbose = $conf-&gt;get_conf( 'verbose' );
    $conf-&gt;set_conf( verbose =&gt; 1 );

    ### values in 'program' section
    $editor = $conf-&gt;get_program( 'editor' );
    $conf-&gt;set_program( editor =&gt; '/bin/vi' );

=head1 DESCRIPTION

This module contains defaults and heuristics for configuration
information for CPANPLUS. To change any of these values, please
see the documentation in C&lt;CPANPLUS::Configure&gt;.

Below you'll find a list of configuration types and keys, and
their meaning.

=head1 CONFIGURATION

=cut

### BAH! you can't have POD interleaved with a hash
### declaration.. so declare every entry separately :(
my $Conf = {
    '_fetch' =&gt; {
        'blacklist' =&gt; [ 'ftp' ],
    },

    ### _source, _build and _mirror are supposed to be static
    ### no changes should be needed unless pause/cpan changes
    '_source' =&gt; {
        'hosts'             =&gt; 'MIRRORED.BY',
        'auth'              =&gt; '01mailrc.txt.gz',
        'stored'            =&gt; 'sourcefiles',
        'dslip'             =&gt; '03modlist.data.gz',
        'update'            =&gt; '86400',
        'mod'               =&gt; '02packages.details.txt.gz',
        'custom_index'      =&gt; 'packages.txt',
    },
    '_build' =&gt; {
        'plugins'           =&gt; 'plugins',
        'moddir'            =&gt; 'build',
        'startdir'          =&gt; '',
        'distdir'           =&gt; 'dist',
        'autobundle'        =&gt; 'autobundle',
        'autobundle_prefix' =&gt; 'Snapshot',
        'autdir'            =&gt; 'authors',
        'install_log_dir'   =&gt; 'install-logs',
        'custom_sources'    =&gt; 'custom-sources',
        'sanity_check'      =&gt; 1,
    },
    '_mirror' =&gt; {
        'base'              =&gt; 'authors/id/',
        'auth'              =&gt; 'authors/01mailrc.txt.gz',
        'dslip'             =&gt; 'modules/03modlist.data.gz',
        'mod'               =&gt; 'modules/02packages.details.txt.gz'
    },
};

=head2 Section 'conf'

=over 4

=item hosts

An array ref containing hosts entries to be queried for packages.

An example entry would like this:

    {   'scheme' =&gt; 'ftp',
        'path' =&gt; '/pub/CPAN/',
        'host' =&gt; 'ftp.cpan.org'
    },

=cut

    ### default host list
    $Conf-&gt;{'conf'}-&gt;{'hosts'} = [
            {
                'scheme' =&gt; 'ftp',
                'path' =&gt; '/pub/CPAN/',
                'host' =&gt; 'ftp.cpan.org'
            },
            {
                'scheme' =&gt; 'http',
                'path' =&gt; '/',
                'host' =&gt; 'www.cpan.org'
            },
            {
                'scheme' =&gt; 'ftp',
                'path' =&gt; '/',
                'host' =&gt; 'cpan.hexten.net'
            },
            {
                'scheme' =&gt; 'ftp',
                'path' =&gt; '/CPAN/',
                'host' =&gt; 'cpan.cpantesters.org'
            },
            {
                'scheme' =&gt; 'ftp',
                'path' =&gt; '/pub/languages/perl/CPAN/',
                'host' =&gt; 'ftp.funet.fi'
            }
        ];

=item allow_build_interactivity

Boolean flag to indicate whether 'perl Makefile.PL' and similar
are run interactively or not. Defaults to 'true'.

=cut

        $Conf-&gt;{'conf'}-&gt;{'allow_build_interactivity'} = 1;

=item allow_unknown_prereqs

Boolean flag to indicate that unresolvable prereqs are acceptable.
If C&lt;true&gt; then only warnings will be issued (the behaviour before 0.9114)
when a module is unresolvable from any our sources (CPAN and/or
C&lt;custom_sources&gt;). If C&lt;false&gt; then an unresolvable prereq will fail
during the C&lt;prepare&gt; stage of distribution installation.
Defaults to C&lt;true&gt;.

=cut

        $Conf-&gt;{'conf'}-&gt;{'allow_unknown_prereqs'} = 1;

=item base

The directory CPANPLUS keeps all its build and state information in.
Defaults to ~/.cpanplus. If L&lt;File::HomeDir&gt; is available, that will
be used to work out your C&lt;HOME&gt; directory. This may be overriden by
setting the C&lt;PERL5_CPANPLUS_HOME&gt; environment variable, see
L&lt;CPANPLUS::Config::HomeEnv&gt; for more details.

=cut

       $Conf-&gt;{'conf'}-&gt;{'base'} = File::Spec-&gt;catdir(
                                        __PACKAGE__-&gt;_home_dir, DOT_CPANPLUS );

=item buildflags

Any flags to be passed to 'perl Build.PL'. See C&lt;perldoc Module::Build&gt;
for details. Defaults to an empty string.

=cut

        $Conf-&gt;{'conf'}-&gt;{'buildflags'} = '';

=item cpantest

Boolean flag to indicate whether or not to mail test results of module
installations to C&lt;http://testers.cpan.org&gt;. Defaults to 'false'.

=cut

        $Conf-&gt;{'conf'}-&gt;{'cpantest'} = 0;

=item cpantest_mx

String holding an explicit mailserver to use when sending out emails
for C&lt;http://testers.cpan.org&gt;. An empty string will use your system
settings. Defaults to an empty string.

=cut

        $Conf-&gt;{'conf'}-&gt;{'cpantest_mx'} = '';

=item debug

Boolean flag to enable or disable extensive debuggging information.
Defaults to 'false'.

=cut

        $Conf-&gt;{'conf'}-&gt;{'debug'} = 0;

=item dist_type

Default distribution type to use when building packages. See C&lt;cpan2dist&gt;
or C&lt;CPANPLUS::Dist&gt; for details. An empty string will not use any
package building software. Defaults to an empty string.

=cut

        $Conf-&gt;{'conf'}-&gt;{'dist_type'} = '';

=item email

Email address to use for anonymous ftp access and as C&lt;from&gt; address
when sending emails. Defaults to an C&lt;example.com&gt; address.

=cut

        $Conf-&gt;{'conf'}-&gt;{'email'} = DEFAULT_EMAIL;

=item enable_custom_sources

Boolean flag indicating whether custom sources should be enabled or
not. See the C&lt;CUSTOM MODULE SOURCES&gt; in C&lt;CPANPLUS::Backend&gt; for
details on how to use them.

Defaults to C&lt;true&gt;

=cut

        ### this addresses #32248 which requests a possibility to
        ### turn off custom sources
        $Conf-&gt;{'conf'}-&gt;{'enable_custom_sources'} = 1;

=item extractdir

String containing the directory where fetched archives should be
extracted. An empty string will use a directory under your C&lt;base&gt;
directory. Defaults to an empty string.

=cut

        $Conf-&gt;{'conf'}-&gt;{'extractdir'} = '';

=item fetchdir

String containing the directory where fetched archives should be
stored. An empty string will use a directory under your C&lt;base&gt;
directory. Defaults to an empty string.

=cut

        $Conf-&gt;{'conf'}-&gt;{'fetchdir'} = '';

=item flush

Boolean indicating whether build failures, cache dirs etc should
be flushed after every operation or not. Defaults to 'true'.

=cut

        $Conf-&gt;{'conf'}-&gt;{'flush'} = 1;

=item force

Boolean indicating whether files should be forcefully overwritten
if they exist, modules should be installed when they fail tests,
etc. Defaults to 'false'.

=cut

        $Conf-&gt;{'conf'}-&gt;{'force'} = 0;

=item histfile

A string containing the history filename of the CPANPLUS readline instance.

=cut

        $Conf-&gt;{'conf'}-&gt;{'histfile'} = File::Spec-&gt;catdir(
                                        __PACKAGE__-&gt;_home_dir, DOT_CPANPLUS, 'history' );

=item lib

An array ref holding directories to be added to C&lt;@INC&gt; when CPANPLUS
starts up. Defaults to an empty array reference.

=cut

        $Conf-&gt;{'conf'}-&gt;{'lib'} = [];

=item makeflags

A string holding flags that will be passed to the C&lt;make&gt; program
when invoked. Defaults to an empty string.

=cut

        $Conf-&gt;{'conf'}-&gt;{'makeflags'} = '';

=item makemakerflags

A string holding flags that will be passed to C&lt;perl Makefile.PL&gt;
when invoked. Defaults to an empty string.

=cut

        $Conf-&gt;{'conf'}-&gt;{'makemakerflags'} = '';

=item md5

A boolean indicating whether or not sha256 checks should be done when
an archive is fetched. Defaults to 'true' if you have C&lt;Digest::SHA&gt;
installed, 'false' otherwise.

=cut

        $Conf-&gt;{'conf'}-&gt;{'md5'} = (
                            check_install( module =&gt; 'Digest::SHA' ) ? 1 : 0 );

=item no_update

A boolean indicating whether or not C&lt;CPANPLUS&gt;' source files should be
updated or not. Defaults to 'false'.

=cut

        $Conf-&gt;{'conf'}-&gt;{'no_update'} = 0;

=item passive

A boolean indicating whether or not to use passive ftp connections.
Defaults to 'true'.

=cut

        $Conf-&gt;{'conf'}-&gt;{'passive'} = 1;

=item prefer_bin

A boolean indicating whether or not to prefer command line programs
over perl modules. Defaults to 'false' unless you do not have
C&lt;Compress::Zlib&gt; installed (as that would mean we could not extract
C&lt;.tar.gz&gt; files)

=cut

        ### if we dont have c::zlib, we'll need to use /bin/tar or we
        ### can not extract any files. Good time to change the default
        $Conf-&gt;{'conf'}-&gt;{'prefer_bin'} =
                                (eval {require Compress::Zlib; 1} ? 0 : 1 );

=item prefer_makefile

A boolean indicating whether or not prefer a C&lt;Makefile.PL&gt; over a
C&lt;Build.PL&gt; file if both are present. Defaults to 'true', unless
the perl version is at least 5.10.1 or appropriate versions of L&lt;Module::Build&gt;
and L&lt;CPANPLUS::Dist::Build&gt; are available.

=cut

        $Conf-&gt;{'conf'}-&gt;{'prefer_makefile'} =
            ( $] &gt;= 5.010001 or
              ( check_install( module =&gt; 'Module::Build', version =&gt; '0.32' ) and
                check_install( module =&gt; INSTALLER_BUILD, version =&gt; '0.60' ) )
              ? 0 : 1 );

=item prereqs

A digit indicating what to do when a package you are installing has a
prerequisite. Options are:

    0   Do not install
    1   Install
    2   Ask
    3   Ignore  (dangerous, install will probably fail!)

The default is to ask.

=cut

        $Conf-&gt;{'conf'}-&gt;{'prereqs'} = PREREQ_ASK;

=item shell

A string holding the shell class you wish to start up when starting
C&lt;CPANPLUS&gt; in interactive mode.

Defaults to C&lt;CPANPLUS::Shell::Default&gt;, the default CPANPLUS shell.

=cut

        $Conf-&gt;{'conf'}-&gt;{'shell'} = 'CPANPLUS::Shell::Default';

=item show_startup_tip

A boolean indicating whether or not to show start up tips in the
interactive shell. Defaults to 'true'.

=cut

        $Conf-&gt;{'conf'}-&gt;{'show_startup_tip'} = 1;

=item signature

A boolean indicating whether or not check signatures if packages are
signed. Defaults to 'true' if you have C&lt;gpg&gt; or C&lt;Crypt::OpenPGP&gt;
installed, 'false' otherwise.

=cut

        $Conf-&gt;{'conf'}-&gt;{'signature'} = do {
            check_install( module =&gt; 'Module::Signature', version =&gt; '0.06' )
            and ( can_run('gpg') ||
                  check_install(module =&gt; 'Crypt::OpenPGP')
            );
        } ? 1 : 0;

=item skiptest

A boolean indicating whether or not to skip tests when installing modules.
Defaults to 'false'.

=cut

        $Conf-&gt;{'conf'}-&gt;{'skiptest'} = 0;

=item storable

A boolean indicating whether or not to use C&lt;Storable&gt; to write compiled
source file information to disk. This makes for faster startup and look
up times, but takes extra diskspace. Defaults to 'true' if you have
C&lt;Storable&gt; installed and 'false' if you don't.

=cut

       $Conf-&gt;{'conf'}-&gt;{'storable'} =
                        ( check_install( module =&gt; 'Storable' ) ? 1 : 0 );

=item timeout

Digit indicating the time before a fetch request times out (in seconds).
Defaults to 300.

=cut

        $Conf-&gt;{'conf'}-&gt;{'timeout'} = 300;

=item verbose

A boolean indicating whether or not C&lt;CPANPLUS&gt; runs in verbose mode.
Defaults to 'true' if you have the environment variable
C&lt;PERL5_CPANPLUS_VERBOSE&gt; set to true, 'false' otherwise.

It is recommended you run with verbose enabled, but it is disabled
for historical reasons.

=cut

        $Conf-&gt;{'conf'}-&gt;{'verbose'} = $ENV{PERL5_CPANPLUS_VERBOSE} || 0;

=item write_install_log

A boolean indicating whether or not to write install logs after installing
a module using the interactive shell. Defaults to 'true'.


=cut

        $Conf-&gt;{'conf'}-&gt;{'write_install_logs'} = 1;

=item source_engine

Class to use as the source engine, which is generally a subclass of
C&lt;CPANPLUS::Internals::Source&gt;. Default to C&lt;CPANPLUS::Internals::Source::Memory&gt;.

=cut

        $Conf-&gt;{'conf'}-&gt;{'source_engine'} = DEFAULT_SOURCE_ENGINE;

=item cpantest_reporter_args

A hashref of key =&gt; value pairs that are passed to the constructor
of C&lt;Test::Reporter&gt;. If you'd want to enable TLS for example, you'd
set it to:

  { transport       =&gt; 'Net::SMTP::TLS',
    transport_args  =&gt; [ User =&gt; 'Joe', Password =&gt; '123' ],
  }

=cut

        $Conf-&gt;{'conf'}-&gt;{'cpantest_reporter_args'} = {};

=back

=head2 Section 'program'

=cut

    ### Paths get stripped of whitespace on win32 in the constructor
    ### sudo gets emptied if there's no need for it in the constructor

=over 4

=item editor

A string holding the path to your editor of choice. Defaults to your
$ENV{EDITOR}, $ENV{VISUAL}, 'vi' or 'pico' programs, in that order.

=cut

        $Conf-&gt;{'program'}-&gt;{'editor'} = do {
            $ENV{'EDITOR'}  || $ENV{'VISUAL'} ||
            can_run('vi')   || can_run('pico')
        };

=item make

A string holding the path to your C&lt;make&gt; binary. Looks for the C&lt;make&gt;
program used to build perl or failing that, a C&lt;make&gt; in your path.

=cut

        $Conf-&gt;{'program'}-&gt;{'make'} =
            can_run($Config{'make'}) || can_run('make');

=item pager

A string holding the path to your pager of choice. Defaults to your
$ENV{PAGER}, 'less' or 'more' programs, in that order.

=cut

        $Conf-&gt;{'program'}-&gt;{'pager'} =
            $ENV{'PAGER'} || can_run('less') || can_run('more');

        ### no one uses this feature anyway, and it's only working for EU::MM
        ### and not for module::build
        #'perl'      =&gt; '',

=item shell

A string holding the path to your login shell of choice. Defaults to your
$ENV{SHELL} setting, or $ENV{COMSPEC} on Windows.

=cut

        $Conf-&gt;{'program'}-&gt;{'shell'} = $^O eq 'MSWin32'
                                        ? $ENV{COMSPEC}
                                        : $ENV{SHELL};

=item sudo

A string holding the path to your C&lt;sudo&gt; binary if your install path
requires super user permissions. Looks for C&lt;sudo&gt; in your path, or
remains empty if you do not require super user permissions to install.

=cut

        $Conf-&gt;{'program'}-&gt;{'sudo'} = do {
            ### let's assume you dont need sudo,
            ### unless one of the below criteria tells us otherwise
            my $sudo = undef;

            ### you're a normal user, you might need sudo
            if( $&gt; ) {

                ### check for all install dirs!
                ### you have write permissions to the installdir,
                ### you don't need sudo
                if( -w $Config{'installsitelib'} &amp;&amp; -w $Config{'installsitebin'} ) {

                    ### installsiteman3dir is a 5.8'ism.. don't check
                    ### it on 5.6.x...
                    if( defined $Config{'installsiteman3dir'} ) {
                        $sudo = -w $Config{'installsiteman3dir'}
                            ? undef
                            : can_run('sudo');
                    } else {
                        $sudo = undef;
                    }

                ### you have PERL_MM_OPT set to some alternate
                ### install place. You probably have write permissions
                ### to that
                } elsif ( $ENV{'PERL_MM_OPT'} and
                          $ENV{'PERL_MM_OPT'} =~ /INSTALL|LIB|PREFIX/
                ) {
                    $sudo = undef;

                ### you probably don't have write permissions
                } else {
                    $sudo = can_run('sudo');
                }
            }

            ### and return the value
            $sudo;
        };

=item perlwrapper

B&lt;DEPRECATED&gt;

A string holding the path to the C&lt;cpanp-run-perl&gt; utility bundled
with CPANPLUS, which is used to enable autoflushing in spawned processes.

=cut

        ### perlwrapper that allows us to turn on autoflushing
        $Conf-&gt;{'program'}-&gt;{'perlwrapper'} = sub {
            my $name = 'cpanp-run-perl';

            my @bins = do{
                require Config;
                my $ver  = $Config::Config{version};

                ### if we are running with 'versiononly' enabled,
                ### all binaries will have the perlversion appended
                ### ie, cpanp will become cpanp5.9.5
                ### so prefer the versioned binary in that case
                $Config::Config{versiononly}
                        ? ($name.$ver, $name)
                        : ($name, $name.$ver);
            };

            ### patch from Steve Hay Fri 29 Jun 2007 14:26:02 GMT+02:00
            ### Msg-Id: &lt;4684FA5A.7030506@uk.radan.com&gt;
            ### look for files with a ".bat" extension as well on Win32
            @bins = map { $_, "$_.bat" } @bins if $^O eq 'MSWin32';

            my $path;
            BIN: for my $bin (@bins) {

                ### parallel to your cpanp/cpanp-boxed
                my $maybe = File::Spec-&gt;rel2abs(
                                File::Spec-&gt;catfile( dirname($0), $bin )
                            );
                $path = $maybe and last BIN if -f $maybe;

                ### parallel to your CPANPLUS.pm:
                ### $INC{cpanplus}/../bin/cpanp-run-perl
                $maybe = File::Spec-&gt;rel2abs(
                            File::Spec-&gt;catfile(
                                dirname($INC{'CPANPLUS.pm'}),
                                '..',   # lib dir
                                'bin',  # bin dir
                                $bin,   # script
                            )
                         );
                $path = $maybe and last BIN if -f $maybe;

                ### you installed CPANPLUS in a custom prefix,
                ### so go parallel to /that/. PREFIX=/tmp/cp
                ### would put cpanp-run-perl in /tmp/cp/bin and
                ### CPANPLUS.pm in
                ### /tmp/cp/lib/perl5/site_perl/5.8.8
                $maybe = File::Spec-&gt;rel2abs(
                            File::Spec-&gt;catfile(
                                dirname( $INC{'CPANPLUS.pm'} ),
                                '..', '..', '..', '..', # 4x updir
                                'bin',                  # bin dir
                                $bin,                   # script
                            )
                         );
                $path = $maybe and last BIN if -f $maybe;

                ### in your path -- take this one last, the
                ### previous two assume extracted tarballs
                ### or user installs
                ### note that we don't use 'can_run' as it's
                ### not an executable, just a wrapper...
                ### prefer anything that's found in the path paralel to your $^X
                for my $dir (File::Spec-&gt;rel2abs( dirname($^X) ),
                             split(/\Q$Config::Config{path_sep}\E/, $ENV{PATH}),
                             File::Spec-&gt;curdir,
                ) {

                    ### On VMS the path could be in UNIX format, and we
                    ### currently need it to be in VMS format
                    $dir = VMS::Filespec::vmspath($dir) if ON_VMS;

                    $maybe = File::Spec-&gt;catfile( $dir, $bin );
                    $path = $maybe and last BIN if -f $maybe;
                }
            }

            ### we should have a $path by now ideally, if so return it
            return $path if defined $path;

            ### CPANPLUS::Dist::MM doesn't require this anymore
            ### but CPANPLUS::Dist::Build might if it is less than 0.60
            my $cpdb = check_install( module =&gt; INSTALLER_BUILD );
            return '' unless
              $cpdb and eval { version-&gt;parse($cpdb-&gt;{version}) &lt; version-&gt;parse('0.60') };

            ### if not, warn about it and give sensible default.
            ### XXX try to be a no-op instead then..
            ### cross your fingers...
            ### pass '-P' to perl: "run program through C
            ### preprocessor before compilation"
            ### XXX using -P actually changes the way some Makefile.PLs
            ### are executed, so don't do that... --kane
            error(loc(
                "Could not find the '%1' binary in your path".
                "--this may be a problem.\n".
                "Please locate this program and set ".
                "your '%2' config entry to its path.\n".
                "From the default shell, you can do this by typing:\n\n".
                "  %3\n".
                "  %4\n",
                $name, 'perlwrapper',
                's program perlwrapper FULL_PATH_TO_CPANP_RUN_PERL',
                's save'
             ));
             return '';
        }-&gt;();

=back

=cut

sub new {
    my $class   = shift;
    my $obj     = $class-&gt;SUPER::new;

    $obj-&gt;mk_accessors( keys %$Conf );

    for my $acc ( keys %$Conf ) {
        my $subobj = Object::Accessor-&gt;new;
        $subobj-&gt;mk_accessors( keys %{$Conf-&gt;{$acc}} );

        ### read in all the settings from the sub accessors;
        for my $subacc ( $subobj-&gt;ls_accessors ) {
            $subobj-&gt;$subacc( $Conf-&gt;{$acc}-&gt;{$subacc} );
        }

        ### now store it in the parent object
        $obj-&gt;$acc( $subobj );
    }

    $obj-&gt;_clean_up_paths;

    ### shut up IPC::Cmd warning about not findin IPC::Run on win32
    $IPC::Cmd::WARN = 0;

    return $obj;
}

sub _clean_up_paths {
    my $self = shift;

    ### clean up paths if we are on win32
    if( $^O eq 'MSWin32' ) {
        for my $pgm ( $self-&gt;program-&gt;ls_accessors ) {
            my $path = $self-&gt;program-&gt;$pgm;

            ### paths with whitespace needs to be shortened
            ### for shell outs.
            if ($path and $path =~ /\s+/) {
                my($prog, $args);

                ### patch from Steve Hay, 13nd of June 2007
                ### msg-id: &lt;467012A4.6060705@uk.radan.com&gt;
                ### windows directories are not allowed to end with
                ### a space, so any occurrence of '\w\s+/\w+' means
                ### we're dealing with arguments, not directory
                ### names.
                if ($path =~ /^(.*?)(\s+\/.*$)/) {
                    ($prog, $args) = ($1, $2);

                ### otherwise, there are no arguments
                } else {
                    ($prog, $args) = ($path, '');
                }

                $prog = Win32::GetShortPathName( $prog );
                $self-&gt;program-&gt;$pgm( $prog . $args );
            }
        }
    }

    return 1;
}

1;

=pod

=head1 BUG REPORTS

Please report bugs or other issues to E&lt;lt&gt;bug-cpanplus@rt.cpan.org&lt;gt&gt;.

=head1 AUTHOR

This module by Jos Boumans E&lt;lt&gt;kane@cpan.orgE&lt;gt&gt;.

=head1 COPYRIGHT

The CPAN++ interface (of which this module is a part of) is copyright (c)
2001 - 2007, Jos Boumans E&lt;lt&gt;kane@cpan.orgE&lt;gt&gt;. All rights reserved.

This library is free software; you may redistribute and/or modify it
under the same terms as Perl itself.

=head1 SEE ALSO

L&lt;CPANPLUS::Backend&gt;, L&lt;CPANPLUS::Configure::Setup&gt;, L&lt;CPANPLUS::Configure&gt;

=cut

# Local variables:
# c-indentation-style: bsd
# c-basic-offset: 4
# indent-tabs-mode: nil
# End:
# vim: expandtab shiftwidth=4:
</pre></body></html>