<html><head><meta name="color-scheme" content="light dark"></head><body><pre style="word-wrap: break-word; white-space: pre-wrap;">package FileCache;

our $VERSION = '1.08';

=head1 NAME

FileCache - keep more files open than the system permits

=head1 SYNOPSIS

    no strict 'refs';

    use FileCache;
    # or
    use FileCache maxopen =&gt; 16;

    cacheout $mode, $path;
    # or
    cacheout $path;
    print $path @data;

    $fh = cacheout $mode, $path;
    # or
    $fh = cacheout $path;
    print $fh @data;

=head1 DESCRIPTION

The C&lt;cacheout&gt; function will make sure that there's a filehandle open
for reading or writing available as the pathname you give it. It
automatically closes and re-opens files if you exceed your system's
maximum number of file descriptors, or the suggested maximum I&lt;maxopen&gt;.

=over

=item cacheout EXPR

The 1-argument form of cacheout will open a file for writing (C&lt;&lt; '&gt;' &gt;&gt;)
on it's first use, and appending (C&lt;&lt;&lt; '&gt;&gt;' &gt;&gt;&gt;) thereafter.

Returns EXPR on success for convenience. You may neglect the
return value and manipulate EXPR as the filehandle directly if you prefer.

=item cacheout MODE, EXPR

The 2-argument form of cacheout will use the supplied mode for the initial
and subsequent openings. Most valid modes for 3-argument C&lt;open&gt; are supported
namely; C&lt;&lt; '&gt;' &gt;&gt;, C&lt;&lt; '+&gt;' &gt;&gt;, C&lt;&lt; '&lt;' &gt;&gt;, C&lt;&lt; '&lt;+' &gt;&gt;, C&lt;&lt;&lt; '&gt;&gt;' &gt;&gt;&gt;,
C&lt; '|-' &gt; and C&lt; '-|' &gt;

To pass supplemental arguments to a program opened with C&lt; '|-' &gt; or C&lt; '-|' &gt;
append them to the command string as you would system EXPR.

Returns EXPR on success for convenience. You may neglect the
return value and manipulate EXPR as the filehandle directly if you prefer.

=back

=head1 CAVEATS

While it is permissible to C&lt;close&gt; a FileCache managed file,
do not do so if you are calling C&lt;FileCache::cacheout&gt; from a package other
than which it was imported, or with another module which overrides C&lt;close&gt;.
If you must, use C&lt;FileCache::cacheout_close&gt;.

Although FileCache can be used with piped opens ('-|' or '|-') doing so is
strongly discouraged.  If FileCache finds it necessary to close and then reopen
a pipe, the command at the far end of the pipe will be reexecuted - the results
of performing IO on FileCache'd pipes is unlikely to be what you expect.  The
ability to use FileCache on pipes may be removed in a future release.

FileCache does not store the current file offset if it finds it necessary to
close a file.  When the file is reopened, the offset will be as specified by the
original C&lt;open&gt; file mode.  This could be construed to be a bug.

The module functionality relies on symbolic references, so things will break
under 'use strict' unless 'no strict "refs"' is also specified.

=head1 BUGS

F&lt;sys/param.h&gt; lies with its C&lt;NOFILE&gt; define on some systems,
so you may have to set I&lt;maxopen&gt; yourself.

=cut

require 5.006;
use Carp;
use strict;
no strict 'refs';

# These are not C&lt;my&gt; for legacy reasons.
# Previous versions requested the user set $cacheout_maxopen by hand.
# Some authors fiddled with %saw to overcome the clobber on initial open.
use vars qw(%saw $cacheout_maxopen);
$cacheout_maxopen = 16;

use base 'Exporter';
our @EXPORT = qw[cacheout cacheout_close];


my %isopen;
my $cacheout_seq = 0;

sub import {
    my ($pkg,%args) = @_;

    # Use Exporter. %args are for us, not Exporter.
    # Make sure to up export_to_level, or we will import into ourselves,
    # rather than our calling package;

    __PACKAGE__-&gt;export_to_level(1);
    Exporter::import( $pkg );

    # Truth is okay here because setting maxopen to 0 would be bad
    return $cacheout_maxopen = $args{maxopen} if $args{maxopen};

    # XXX This code is crazy.  Why is it a one element foreach loop?
    # Why is it using $param both as a filename and filehandle?
    foreach my $param ( '/usr/include/sys/param.h' ){
      if (open($param, '&lt;', $param)) {
	local ($_, $.);
	while (&lt;$param&gt;) {
	  if( /^\s*#\s*define\s+NOFILE\s+(\d+)/ ){
	    $cacheout_maxopen = $1 - 4;
	    close($param);
	    last;
	  }
	}
	close $param;
      }
    }
    $cacheout_maxopen ||= 16;
}

# Open in their package.
sub cacheout_open {
  return open(*{caller(1) . '::' . $_[1]}, $_[0], $_[1]) &amp;&amp; $_[1];
}

# Close in their package.
sub cacheout_close {
  # Short-circuit in case the filehandle disappeared
  my $pkg = caller($_[1]||0);
  defined fileno(*{$pkg . '::' . $_[0]}) &amp;&amp;
    CORE::close(*{$pkg . '::' . $_[0]});
  delete $isopen{$_[0]};
}

# But only this sub name is visible to them.
sub cacheout {
    my($mode, $file, $class, $ret, $ref, $narg);
    croak "Not enough arguments for cacheout"  unless $narg = scalar @_;
    croak "Too many arguments for cacheout"    if $narg &gt; 2;

    ($mode, $file) = @_;
    ($file, $mode) = ($mode, $file) if $narg == 1;
    croak "Invalid mode for cacheout" if $mode &amp;&amp;
      ( $mode !~ /^\s*(?:&gt;&gt;|\+?&gt;|\+?&lt;|\|\-|)|\-\|\s*$/ );

    # Mode changed?
    if( $isopen{$file} &amp;&amp; ($mode||'&gt;') ne $isopen{$file}-&gt;[1] ){
      &amp;cacheout_close($file, 1);
    }

    if( $isopen{$file}) {
      $ret = $file;
      $isopen{$file}-&gt;[0]++;
    }
    else{
      if( scalar keys(%isopen) &gt; $cacheout_maxopen -1 ) {
	my @lru = sort{ $isopen{$a}-&gt;[0] &lt;=&gt; $isopen{$b}-&gt;[0] } keys(%isopen);
	$cacheout_seq = 0;
	$isopen{$_}-&gt;[0] = $cacheout_seq++ for
	  splice(@lru, int($cacheout_maxopen / 3)||$cacheout_maxopen);
	&amp;cacheout_close($_, 1) for @lru;
      }

      unless( $ref ){
	$mode ||= $saw{$file} ? '&gt;&gt;' : ($saw{$file}=1, '&gt;');
      }
      #XXX should we just return the value from cacheout_open, no croak?
      $ret = cacheout_open($mode, $file) or croak("Can't create $file: $!");

      $isopen{$file} = [++$cacheout_seq, $mode];
    }
    return $ret;
}
1;
</pre></body></html>