<html><head><meta name="color-scheme" content="light dark"></head><body><pre style="word-wrap: break-word; white-space: pre-wrap;">package Module::Build;

# This module doesn't do much of anything itself, it inherits from the
# modules that do the real work.  The only real thing it has to do is
# figure out which OS-specific module to pull in.  Many of the
# OS-specific modules don't do anything either - most of the work is
# done in Module::Build::Base.

use strict;
use File::Spec ();
use File::Path ();
use File::Basename ();
use Perl::OSType ();

use Module::Build::Base;

use vars qw($VERSION @ISA);
@ISA = qw(Module::Build::Base);
$VERSION = '0.4003';
$VERSION = eval $VERSION;


# Inserts the given module into the @ISA hierarchy between
# Module::Build and its immediate parent
sub _interpose_module {
  my ($self, $mod) = @_;
  eval "use $mod";
  die $@ if $@;

  no strict 'refs';
  my $top_class = $mod;
  while (@{"${top_class}::ISA"}) {
    last if ${"${top_class}::ISA"}[0] eq $ISA[0];
    $top_class = ${"${top_class}::ISA"}[0];
  }

  @{"${top_class}::ISA"} = @ISA;
  @ISA = ($mod);
}

if (grep {-e File::Spec-&gt;catfile($_, qw(Module Build Platform), $^O) . '.pm'} @INC) {
  __PACKAGE__-&gt;_interpose_module("Module::Build::Platform::$^O");

} elsif ( my $ostype = os_type() ) {
  __PACKAGE__-&gt;_interpose_module("Module::Build::Platform::$ostype");

} else {
  warn "Unknown OS type '$^O' - using default settings\n";
}

sub os_type { return Perl::OSType::os_type() }

sub is_vmsish { return Perl::OSType::is_os_type('VMS') }
sub is_windowsish { return Perl::OSType::is_os_type('Windows') }
sub is_unixish { return Perl::OSType::is_os_type('Unix') }

1;

__END__

=for :stopwords
bindoc binhtml destdir distcheck distclean distdir distmeta distsign disttest
fakeinstall html installdirs installsitebin installsitescript installvendorbin
installvendorscript libdoc libhtml pardist ppd ppmdist realclean skipcheck
testall testcover testdb testpod testpodcoverage versioninstall

=head1 NAME

Module::Build - Build and install Perl modules

=head1 SYNOPSIS

Standard process for building &amp; installing modules:

  perl Build.PL
  ./Build
  ./Build test
  ./Build install

Or, if you're on a platform (like DOS or Windows) that doesn't require
the "./" notation, you can do this:

  perl Build.PL
  Build
  Build test
  Build install


=head1 DESCRIPTION

C&lt;Module::Build&gt; is a system for building, testing, and installing
Perl modules.  It is meant to be an alternative to
C&lt;ExtUtils::MakeMaker&gt;.  Developers may alter the behavior of the
module through subclassing in a much more straightforward way than
with C&lt;MakeMaker&gt;.  It also does not require a C&lt;make&gt; on your system
- most of the C&lt;Module::Build&gt; code is pure-perl and written in a very
cross-platform way.  In fact, you don't even need a shell, so even
platforms like MacOS (traditional) can use it fairly easily.  Its only
prerequisites are modules that are included with perl 5.6.0, and it
works fine on perl 5.005 if you can install a few additional modules.

See L&lt;"MOTIVATIONS"&gt; for more comparisons between C&lt;ExtUtils::MakeMaker&gt;
and C&lt;Module::Build&gt;.

To install C&lt;Module::Build&gt;, and any other module that uses
C&lt;Module::Build&gt; for its installation process, do the following:

  perl Build.PL       # 'Build.PL' script creates the 'Build' script
  ./Build             # Need ./ to ensure we're using this "Build" script
  ./Build test        # and not another one that happens to be in the PATH
  ./Build install

This illustrates initial configuration and the running of three
'actions'.  In this case the actions run are 'build' (the default
action), 'test', and 'install'.  Other actions defined so far include:

  build                          manifest
  clean                          manifest_skip
  code                           manpages
  config_data                    pardist
  diff                           ppd
  dist                           ppmdist
  distcheck                      prereq_data
  distclean                      prereq_report
  distdir                        pure_install
  distinstall                    realclean
  distmeta                       retest
  distsign                       skipcheck
  disttest                       test
  docs                           testall
  fakeinstall                    testcover
  help                           testdb
  html                           testpod
  install                        testpodcoverage
  installdeps                    versioninstall

You can run the 'help' action for a complete list of actions.


=head1 GUIDE TO DOCUMENTATION

The documentation for C&lt;Module::Build&gt; is broken up into sections:

=over

=item General Usage (L&lt;Module::Build&gt;)

This is the document you are currently reading. It describes basic
usage and background information.  Its main purpose is to assist the
user who wants to learn how to invoke and control C&lt;Module::Build&gt;
scripts at the command line.

=item Authoring Reference (L&lt;Module::Build::Authoring&gt;)

This document describes the structure and organization of
C&lt;Module::Build&gt;, and the relevant concepts needed by authors who are
writing F&lt;Build.PL&gt; scripts for a distribution or controlling
C&lt;Module::Build&gt; processes programmatically.

=item API Reference (L&lt;Module::Build::API&gt;)

This is a reference to the C&lt;Module::Build&gt; API.

=item Cookbook (L&lt;Module::Build::Cookbook&gt;)

This document demonstrates how to accomplish many common tasks.  It
covers general command line usage and authoring of F&lt;Build.PL&gt;
scripts.  Includes working examples.

=back


=head1 ACTIONS

There are some general principles at work here.  First, each task when
building a module is called an "action".  These actions are listed
above; they correspond to the building, testing, installing,
packaging, etc., tasks.

Second, arguments are processed in a very systematic way.  Arguments
are always key=value pairs.  They may be specified at C&lt;perl Build.PL&gt;
time (i.e. C&lt;perl Build.PL destdir=/my/secret/place&gt;), in which case
their values last for the lifetime of the C&lt;Build&gt; script.  They may
also be specified when executing a particular action (i.e.
C&lt;Build test verbose=1&gt;), in which case their values last only for the
lifetime of that command.  Per-action command line parameters take
precedence over parameters specified at C&lt;perl Build.PL&gt; time.

The build process also relies heavily on the C&lt;Config.pm&gt; module.
If the user wishes to override any of the
values in C&lt;Config.pm&gt;, she may specify them like so:

  perl Build.PL --config cc=gcc --config ld=gcc

The following build actions are provided by default.

=over 4

=item build

[version 0.01]

If you run the C&lt;Build&gt; script without any arguments, it runs the
C&lt;build&gt; action, which in turn runs the C&lt;code&gt; and C&lt;docs&gt; actions.

This is analogous to the C&lt;MakeMaker&gt; I&lt;make all&gt; target.

=item clean

[version 0.01]

This action will clean up any files that the build process may have
created, including the C&lt;blib/&gt; directory (but not including the
C&lt;_build/&gt; directory and the C&lt;Build&gt; script itself).

=item code

[version 0.20]

This action builds your code base.

By default it just creates a C&lt;blib/&gt; directory and copies any C&lt;.pm&gt;
and C&lt;.pod&gt; files from your C&lt;lib/&gt; directory into the C&lt;blib/&gt;
directory.  It also compiles any C&lt;.xs&gt; files from C&lt;lib/&gt; and places
them in C&lt;blib/&gt;.  Of course, you need a working C compiler (probably
the same one that built perl itself) for the compilation to work
properly.

The C&lt;code&gt; action also runs any C&lt;.PL&gt; files in your F&lt;lib/&gt;
directory.  Typically these create other files, named the same but
without the C&lt;.PL&gt; ending.  For example, a file F&lt;lib/Foo/Bar.pm.PL&gt;
could create the file F&lt;lib/Foo/Bar.pm&gt;.  The C&lt;.PL&gt; files are
processed first, so any C&lt;.pm&gt; files (or other kinds that we deal
with) will get copied correctly.

=item config_data

[version 0.26]

...

=item diff

[version 0.14]

This action will compare the files about to be installed with their
installed counterparts.  For .pm and .pod files, a diff will be shown
(this currently requires a 'diff' program to be in your PATH).  For
other files like compiled binary files, we simply report whether they
differ.

A C&lt;flags&gt; parameter may be passed to the action, which will be passed
to the 'diff' program.  Consult your 'diff' documentation for the
parameters it will accept - a good one is C&lt;-u&gt;:

  ./Build diff flags=-u

=item dist

[version 0.02]

This action is helpful for module authors who want to package up their
module for source distribution through a medium like CPAN.  It will create a
tarball of the files listed in F&lt;MANIFEST&gt; and compress the tarball using
GZIP compression.

By default, this action will use the C&lt;Archive::Tar&gt; module. However, you can
force it to use binary "tar" and "gzip" executables by supplying an explicit
C&lt;tar&gt; (and optional C&lt;gzip&gt;) parameter:

  ./Build dist --tar C:\path\to\tar.exe --gzip C:\path\to\zip.exe

=item distcheck

[version 0.05]

Reports which files are in the build directory but not in the
F&lt;MANIFEST&gt; file, and vice versa.  (See L&lt;manifest&gt; for details.)

=item distclean

[version 0.05]

Performs the 'realclean' action and then the 'distcheck' action.

=item distdir

[version 0.05]

Creates a "distribution directory" named C&lt;$dist_name-$dist_version&gt;
(if that directory already exists, it will be removed first), then
copies all the files listed in the F&lt;MANIFEST&gt; file to that directory.
This directory is what the distribution tarball is created from.

=item distinstall

[version 0.37]

Performs the 'distdir' action, then switches into that directory and runs a
C&lt;perl Build.PL&gt;, followed by the 'build' and 'install' actions in that
directory.  Use PERL_MB_OPT or F&lt;.modulebuildrc&gt; to set options that should be
applied during subprocesses

=item distmeta

[version 0.21]

Creates the F&lt;META.yml&gt; file that describes the distribution.

F&lt;META.yml&gt; is a file containing various bits of I&lt;metadata&gt; about the
distribution.  The metadata includes the distribution name, version,
abstract, prerequisites, license, and various other data about the
distribution.  This file is created as F&lt;META.yml&gt; in a simplified YAML format.

F&lt;META.yml&gt; file must also be listed in F&lt;MANIFEST&gt; - if it's not, a
warning will be issued.

The current version of the F&lt;META.yml&gt; specification can be found
on CPAN as L&lt;CPAN::Meta::Spec&gt;.

=item distsign

[version 0.16]

Uses C&lt;Module::Signature&gt; to create a SIGNATURE file for your
distribution, and adds the SIGNATURE file to the distribution's
MANIFEST.

=item disttest

[version 0.05]

Performs the 'distdir' action, then switches into that directory and runs a
C&lt;perl Build.PL&gt;, followed by the 'build' and 'test' actions in that directory.
Use PERL_MB_OPT or F&lt;.modulebuildrc&gt; to set options that should be applied
during subprocesses


=item docs

[version 0.20]

This will generate documentation (e.g. Unix man pages and HTML
documents) for any installable items under B&lt;blib/&gt; that
contain POD.  If there are no C&lt;bindoc&gt; or C&lt;libdoc&gt; installation
targets defined (as will be the case on systems that don't support
Unix manpages) no action is taken for manpages.  If there are no
C&lt;binhtml&gt; or C&lt;libhtml&gt; installation targets defined no action is
taken for HTML documents.

=item fakeinstall

[version 0.02]

This is just like the C&lt;install&gt; action, but it won't actually do
anything, it will just report what it I&lt;would&gt; have done if you had
actually run the C&lt;install&gt; action.

=item help

[version 0.03]

This action will simply print out a message that is meant to help you
use the build process.  It will show you a list of available build
actions too.

With an optional argument specifying an action name (e.g. C&lt;Build help
test&gt;), the 'help' action will show you any POD documentation it can
find for that action.

=item html

[version 0.26]

This will generate HTML documentation for any binary or library files
under B&lt;blib/&gt; that contain POD.  The HTML documentation will only be
installed if the install paths can be determined from values in
C&lt;Config.pm&gt;.  You can also supply or override install paths on the
command line by specifying C&lt;install_path&gt; values for the C&lt;binhtml&gt;
and/or C&lt;libhtml&gt; installation targets.

=item install

[version 0.01]

This action will use C&lt;ExtUtils::Install&gt; to install the files from
C&lt;blib/&gt; into the system.  See L&lt;"INSTALL PATHS"&gt;
for details about how Module::Build determines where to install
things, and how to influence this process.

If you want the installation process to look around in C&lt;@INC&gt; for
other versions of the stuff you're installing and try to delete it,
you can use the C&lt;uninst&gt; parameter, which tells C&lt;ExtUtils::Install&gt; to
do so:

  ./Build install uninst=1

This can be a good idea, as it helps prevent multiple versions of a
module from being present on your system, which can be a confusing
situation indeed.

=item installdeps

[version 0.36]

This action will use the C&lt;cpan_client&gt; parameter as a command to install
missing prerequisites.  You will be prompted whether to install
optional dependencies.

The C&lt;cpan_client&gt; option defaults to 'cpan' but can be set as an option or in
F&lt;.modulebuildrc&gt;.  It must be a shell command that takes a list of modules to
install as arguments (e.g. 'cpanp -i' for CPANPLUS).  If the program part is a
relative path (e.g. 'cpan' or 'cpanp'), it will be located relative to the perl
program that executed Build.PL.

  /opt/perl/5.8.9/bin/perl Build.PL
  ./Build installdeps --cpan_client 'cpanp -i'
  # installs to 5.8.9

=item manifest

[version 0.05]

This is an action intended for use by module authors, not people
installing modules.  It will bring the F&lt;MANIFEST&gt; up to date with the
files currently present in the distribution.  You may use a
F&lt;MANIFEST.SKIP&gt; file to exclude certain files or directories from
inclusion in the F&lt;MANIFEST&gt;.  F&lt;MANIFEST.SKIP&gt; should contain a bunch
of regular expressions, one per line.  If a file in the distribution
directory matches any of the regular expressions, it won't be included
in the F&lt;MANIFEST&gt;.

The following is a reasonable F&lt;MANIFEST.SKIP&gt; starting point, you can
add your own stuff to it:

  ^_build
  ^Build$
  ^blib
  ~$
  \.bak$
  ^MANIFEST\.SKIP$
  CVS

See the L&lt;distcheck&gt; and L&lt;skipcheck&gt; actions if you want to find out
what the C&lt;manifest&gt; action would do, without actually doing anything.

=item manifest_skip

[version 0.3608]

This is an action intended for use by module authors, not people
installing modules.  It will generate a boilerplate MANIFEST.SKIP file
if one does not already exist.

=item manpages

[version 0.28]

This will generate man pages for any binary or library files under
B&lt;blib/&gt; that contain POD.  The man pages will only be installed if the
install paths can be determined from values in C&lt;Config.pm&gt;.  You can
also supply or override install paths by specifying there values on
the command line with the C&lt;bindoc&gt; and C&lt;libdoc&gt; installation
targets.

=item pardist

[version 0.2806]

Generates a PAR binary distribution for use with L&lt;PAR&gt; or L&lt;PAR::Dist&gt;.

It requires that the PAR::Dist module (version 0.17 and up) is
installed on your system.

=item ppd

[version 0.20]

Build a PPD file for your distribution.

This action takes an optional argument C&lt;codebase&gt; which is used in
the generated PPD file to specify the (usually relative) URL of the
distribution.  By default, this value is the distribution name without
any path information.

Example:

  ./Build ppd --codebase "MSWin32-x86-multi-thread/Module-Build-0.21.tar.gz"

=item ppmdist

[version 0.23]

Generates a PPM binary distribution and a PPD description file.  This
action also invokes the C&lt;ppd&gt; action, so it can accept the same
C&lt;codebase&gt; argument described under that action.

This uses the same mechanism as the C&lt;dist&gt; action to tar &amp; zip its
output, so you can supply C&lt;tar&gt; and/or C&lt;gzip&gt; parameters to affect
the result.

=item prereq_data

[version 0.32]

This action prints out a Perl data structure of all prerequisites and the versions
required.  The output can be loaded again using C&lt;eval()&gt;.  This can be useful for
external tools that wish to query a Build script for prerequisites.

=item prereq_report

[version 0.28]

This action prints out a list of all prerequisites, the versions required, and
the versions actually installed.  This can be useful for reviewing the
configuration of your system prior to a build, or when compiling data to send
for a bug report.

=item pure_install

[version 0.28]

This action is identical to the C&lt;install&gt; action.  In the future,
though, when C&lt;install&gt; starts writing to the file
F&lt;$(INSTALLARCHLIB)/perllocal.pod&gt;, C&lt;pure_install&gt; won't, and that
will be the only difference between them.

=item realclean

[version 0.01]

This action is just like the C&lt;clean&gt; action, but also removes the
C&lt;_build&gt; directory and the C&lt;Build&gt; script.  If you run the
C&lt;realclean&gt; action, you are essentially starting over, so you will
have to re-create the C&lt;Build&gt; script again.

=item retest

[version 0.2806]

This is just like the C&lt;test&gt; action, but doesn't actually build the
distribution first, and doesn't add F&lt;blib/&gt; to the load path, and
therefore will test against a I&lt;previously&gt; installed version of the
distribution.  This can be used to verify that a certain installed
distribution still works, or to see whether newer versions of a
distribution still pass the old regression tests, and so on.

=item skipcheck

[version 0.05]

Reports which files are skipped due to the entries in the
F&lt;MANIFEST.SKIP&gt; file (See L&lt;manifest&gt; for details)

=item test

[version 0.01]

This will use C&lt;Test::Harness&gt; or C&lt;TAP::Harness&gt; to run any regression
tests and report their results. Tests can be defined in the standard
places: a file called C&lt;test.pl&gt; in the top-level directory, or several
files ending with C&lt;.t&gt; in a C&lt;t/&gt; directory.

If you want tests to be 'verbose', i.e. show details of test execution
rather than just summary information, pass the argument C&lt;verbose=1&gt;.

If you want to run tests under the perl debugger, pass the argument
C&lt;debugger=1&gt;.

If you want to have Module::Build find test files with different file
name extensions, pass the C&lt;test_file_exts&gt; argument with an array
of extensions, such as C&lt;[qw( .t .s .z )]&gt;.

If you want test to be run by C&lt;TAP::Harness&gt;, rather than C&lt;Test::Harness&gt;,
pass the argument C&lt;tap_harness_args&gt; as an array reference of arguments to
pass to the TAP::Harness constructor.

In addition, if a file called C&lt;visual.pl&gt; exists in the top-level
directory, this file will be executed as a Perl script and its output
will be shown to the user.  This is a good place to put speed tests or
other tests that don't use the C&lt;Test::Harness&gt; format for output.

To override the choice of tests to run, you may pass a C&lt;test_files&gt;
argument whose value is a whitespace-separated list of test scripts to
run.  This is especially useful in development, when you only want to
run a single test to see whether you've squashed a certain bug yet:

  ./Build test --test_files t/something_failing.t

You may also pass several C&lt;test_files&gt; arguments separately:

  ./Build test --test_files t/one.t --test_files t/two.t

or use a C&lt;glob()&gt;-style pattern:

  ./Build test --test_files 't/01-*.t'

=item testall

[version 0.2807]

[Note: the 'testall' action and the code snippets below are currently
in alpha stage, see
L&lt;"http://www.nntp.perl.org/group/perl.module.build/2007/03/msg584.html"&gt; ]

Runs the C&lt;test&gt; action plus each of the C&lt;test$type&gt; actions defined by
the keys of the C&lt;test_types&gt; parameter.

Currently, you need to define the ACTION_test$type method yourself and
enumerate them in the test_types parameter.

  my $mb = Module::Build-&gt;subclass(
    code =&gt; q(
      sub ACTION_testspecial { shift-&gt;generic_test(type =&gt; 'special'); }
      sub ACTION_testauthor  { shift-&gt;generic_test(type =&gt; 'author'); }
    )
  )-&gt;new(
    ...
    test_types  =&gt; {
      special =&gt; '.st',
      author  =&gt; ['.at', '.pt' ],
    },
    ...

=item testcover

[version 0.26]

Runs the C&lt;test&gt; action using C&lt;Devel::Cover&gt;, generating a
code-coverage report showing which parts of the code were actually
exercised during the tests.

To pass options to C&lt;Devel::Cover&gt;, set the C&lt;$DEVEL_COVER_OPTIONS&gt;
environment variable:

  DEVEL_COVER_OPTIONS=-ignore,Build ./Build testcover

=item testdb

[version 0.05]

This is a synonym for the 'test' action with the C&lt;debugger=1&gt;
argument.

=item testpod

[version 0.25]

This checks all the files described in the C&lt;docs&gt; action and
produces C&lt;Test::Harness&gt;-style output.  If you are a module author,
this is useful to run before creating a new release.

=item testpodcoverage

[version 0.28]

This checks the pod coverage of the distribution and
produces C&lt;Test::Harness&gt;-style output. If you are a module author,
this is useful to run before creating a new release.

=item versioninstall

[version 0.16]

** Note: since C&lt;only.pm&gt; is so new, and since we just recently added
support for it here too, this feature is to be considered
experimental. **

If you have the C&lt;only.pm&gt; module installed on your system, you can
use this action to install a module into the version-specific library
trees.  This means that you can have several versions of the same
module installed and C&lt;use&gt; a specific one like this:

  use only MyModule =&gt; 0.55;

To override the default installation libraries in C&lt;only::config&gt;,
specify the C&lt;versionlib&gt; parameter when you run the C&lt;Build.PL&gt; script:

  perl Build.PL --versionlib /my/version/place/

To override which version the module is installed as, specify the
C&lt;version&gt; parameter when you run the C&lt;Build.PL&gt; script:

  perl Build.PL --version 0.50

See the C&lt;only.pm&gt; documentation for more information on
version-specific installs.

=back


=head1 OPTIONS

=head2 Command Line Options

The following options can be used during any invocation of C&lt;Build.PL&gt;
or the Build script, during any action.  For information on other
options specific to an action, see the documentation for the
respective action.

NOTE: There is some preliminary support for options to use the more
familiar long option style.  Most options can be preceded with the
C&lt;--&gt; long option prefix, and the underscores changed to dashes
(e.g. C&lt;--use-rcfile&gt;).  Additionally, the argument to boolean options is
optional, and boolean options can be negated by prefixing them with
C&lt;no&gt; or C&lt;no-&gt; (e.g. C&lt;--noverbose&gt; or C&lt;--no-verbose&gt;).

=over 4

=item quiet

Suppress informative messages on output.

=item verbose

Display extra information about the Build on output.  C&lt;verbose&gt; will
turn off C&lt;quiet&gt;

=item cpan_client

Sets the C&lt;cpan_client&gt; command for use with the C&lt;installdeps&gt; action.
See C&lt;installdeps&gt; for more details.

=item use_rcfile

Load the F&lt;~/.modulebuildrc&gt; option file.  This option can be set to
false to prevent the custom resource file from being loaded.

=item allow_mb_mismatch

Suppresses the check upon startup that the version of Module::Build
we're now running under is the same version that was initially invoked
when building the distribution (i.e. when the C&lt;Build.PL&gt; script was
first run).  As of 0.3601, a mismatch results in a warning instead of
a fatal error, so this option effectively just suppresses the warning.

=item debug

Prints Module::Build debugging information to STDOUT, such as a trace of
executed build actions.

=back

=head2 Default Options File (F&lt;.modulebuildrc&gt;)

[version 0.28]

When Module::Build starts up, it will look first for a file,
F&lt;$ENV{HOME}/.modulebuildrc&gt;.  If it's not found there, it will look
in the the F&lt;.modulebuildrc&gt; file in the directories referred to by
the environment variables C&lt;HOMEDRIVE&gt; + C&lt;HOMEDIR&gt;, C&lt;USERPROFILE&gt;,
C&lt;APPDATA&gt;, C&lt;WINDIR&gt;, C&lt;SYS$LOGIN&gt;.  If the file exists, the options
specified there will be used as defaults, as if they were typed on the
command line.  The defaults can be overridden by specifying new values
on the command line.

The action name must come at the beginning of the line, followed by any
amount of whitespace and then the options.  Options are given the same
as they would be on the command line.  They can be separated by any
amount of whitespace, including newlines, as long there is whitespace at
the beginning of each continued line.  Anything following a hash mark (C&lt;#&gt;)
is considered a comment, and is stripped before parsing.  If more than
one line begins with the same action name, those lines are merged into
one set of options.

Besides the regular actions, there are two special pseudo-actions: the
key C&lt;*&gt; (asterisk) denotes any global options that should be applied
to all actions, and the key 'Build_PL' specifies options to be applied
when you invoke C&lt;perl Build.PL&gt;.

  *           verbose=1   # global options
  diff        flags=-u
  install     --install_base /home/ken
              --install_path html=/home/ken/docs/html
  installdeps --cpan_client 'cpanp -i'

If you wish to locate your resource file in a different location, you
can set the environment variable C&lt;MODULEBUILDRC&gt; to the complete
absolute path of the file containing your options.

=head2 Environment variables

=over

=item MODULEBUILDRC

[version 0.28]

Specifies an alternate location for a default options file as described above.

=item PERL_MB_OPT

[version 0.36]

Command line options that are applied to Build.PL or any Build action.  The
string is split as the shell would (e.g. whitespace) and the result is
prepended to any actual command-line arguments.

=back

=head1 INSTALL PATHS

[version 0.19]

When you invoke Module::Build's C&lt;build&gt; action, it needs to figure
out where to install things.  The nutshell version of how this works
is that default installation locations are determined from
F&lt;Config.pm&gt;, and they may be overridden by using the C&lt;install_path&gt;
parameter.  An C&lt;install_base&gt; parameter lets you specify an
alternative installation root like F&lt;/home/foo&gt;, and a C&lt;destdir&gt; lets
you specify a temporary installation directory like F&lt;/tmp/install&gt; in
case you want to create bundled-up installable packages.

Natively, Module::Build provides default installation locations for
the following types of installable items:

=over 4

=item lib

Usually pure-Perl module files ending in F&lt;.pm&gt;.

=item arch

"Architecture-dependent" module files, usually produced by compiling
XS, L&lt;Inline&gt;, or similar code.

=item script

Programs written in pure Perl.  In order to improve reuse, try to make
these as small as possible - put the code into modules whenever
possible.

=item bin

"Architecture-dependent" executable programs, i.e. compiled C code or
something.  Pretty rare to see this in a perl distribution, but it
happens.

=item bindoc

Documentation for the stuff in C&lt;script&gt; and C&lt;bin&gt;.  Usually
generated from the POD in those files.  Under Unix, these are manual
pages belonging to the 'man1' category.

=item libdoc

Documentation for the stuff in C&lt;lib&gt; and C&lt;arch&gt;.  This is usually
generated from the POD in F&lt;.pm&gt; files.  Under Unix, these are manual
pages belonging to the 'man3' category.

=item binhtml

This is the same as C&lt;bindoc&gt; above, but applies to HTML documents.

=item libhtml

This is the same as C&lt;libdoc&gt; above, but applies to HTML documents.

=back

Four other parameters let you control various aspects of how
installation paths are determined:

=over 4

=item installdirs

The default destinations for these installable things come from
entries in your system's C&lt;Config.pm&gt;.  You can select from three
different sets of default locations by setting the C&lt;installdirs&gt;
parameter as follows:

                          'installdirs' set to:
                   core          site                vendor

              uses the following defaults from Config.pm:

  lib     =&gt; installprivlib  installsitelib      installvendorlib
  arch    =&gt; installarchlib  installsitearch     installvendorarch
  script  =&gt; installscript   installsitescript   installvendorscript
  bin     =&gt; installbin      installsitebin      installvendorbin
  bindoc  =&gt; installman1dir  installsiteman1dir  installvendorman1dir
  libdoc  =&gt; installman3dir  installsiteman3dir  installvendorman3dir
  binhtml =&gt; installhtml1dir installsitehtml1dir installvendorhtml1dir [*]
  libhtml =&gt; installhtml3dir installsitehtml3dir installvendorhtml3dir [*]

  * Under some OS (eg. MSWin32) the destination for HTML documents is
    determined by the C&lt;Config.pm&gt; entry C&lt;installhtmldir&gt;.

The default value of C&lt;installdirs&gt; is "site".  If you're creating
vendor distributions of module packages, you may want to do something
like this:

  perl Build.PL --installdirs vendor

or

  ./Build install --installdirs vendor

If you're installing an updated version of a module that was included
with perl itself (i.e. a "core module"), then you may set
C&lt;installdirs&gt; to "core" to overwrite the module in its present
location.

(Note that the 'script' line is different from C&lt;MakeMaker&gt; -
unfortunately there's no such thing as "installsitescript" or
"installvendorscript" entry in C&lt;Config.pm&gt;, so we use the
"installsitebin" and "installvendorbin" entries to at least get the
general location right.  In the future, if C&lt;Config.pm&gt; adds some more
appropriate entries, we'll start using those.)

=item install_path

Once the defaults have been set, you can override them.

On the command line, that would look like this:

  perl Build.PL --install_path lib=/foo/lib --install_path arch=/foo/lib/arch

or this:

  ./Build install --install_path lib=/foo/lib --install_path arch=/foo/lib/arch

=item install_base

You can also set the whole bunch of installation paths by supplying the
C&lt;install_base&gt; parameter to point to a directory on your system.  For
instance, if you set C&lt;install_base&gt; to "/home/ken" on a Linux
system, you'll install as follows:

  lib     =&gt; /home/ken/lib/perl5
  arch    =&gt; /home/ken/lib/perl5/i386-linux
  script  =&gt; /home/ken/bin
  bin     =&gt; /home/ken/bin
  bindoc  =&gt; /home/ken/man/man1
  libdoc  =&gt; /home/ken/man/man3
  binhtml =&gt; /home/ken/html
  libhtml =&gt; /home/ken/html

Note that this is I&lt;different&gt; from how C&lt;MakeMaker&gt;'s C&lt;PREFIX&gt;
parameter works.  C&lt;install_base&gt; just gives you a default layout under the
directory you specify, which may have little to do with the
C&lt;installdirs=site&gt; layout.

The exact layout under the directory you specify may vary by system -
we try to do the "sensible" thing on each platform.

=item destdir

If you want to install everything into a temporary directory first
(for instance, if you want to create a directory tree that a package
manager like C&lt;rpm&gt; or C&lt;dpkg&gt; could create a package from), you can
use the C&lt;destdir&gt; parameter:

  perl Build.PL --destdir /tmp/foo

or

  ./Build install --destdir /tmp/foo

This will effectively install to "/tmp/foo/$sitelib",
"/tmp/foo/$sitearch", and the like, except that it will use
C&lt;File::Spec&gt; to make the pathnames work correctly on whatever
platform you're installing on.

=item prefix

Provided for compatibility with C&lt;ExtUtils::MakeMaker&gt;'s PREFIX argument.
C&lt;prefix&gt; should be used when you want Module::Build to install your
modules, documentation, and scripts in the same place as
C&lt;ExtUtils::MakeMaker&gt;'s PREFIX mechanism.

The following are equivalent.

    perl Build.PL --prefix /tmp/foo
    perl Makefile.PL PREFIX=/tmp/foo

Because of the complex nature of the prefixification logic, the
behavior of PREFIX in C&lt;MakeMaker&gt; has changed subtly over time.
Module::Build's --prefix logic is equivalent to the PREFIX logic found
in C&lt;ExtUtils::MakeMaker&gt; 6.30.

The maintainers of C&lt;MakeMaker&gt; do understand the troubles with the
PREFIX mechanism, and added INSTALL_BASE support in version 6.31 of
C&lt;MakeMaker&gt;, which was released in 2006.

If you don't need to retain compatibility with old versions (pre-6.31) of C&lt;ExtUtils::MakeMaker&gt; or
are starting a fresh Perl installation we recommend you use
C&lt;install_base&gt; instead (and C&lt;INSTALL_BASE&gt; in C&lt;ExtUtils::MakeMaker&gt;).
See L&lt;Module::Build::Cookbook/Installing in the same location as
ExtUtils::MakeMaker&gt; for further information.


=back


=head1 MOTIVATIONS

There are several reasons I wanted to start over, and not just fix
what I didn't like about C&lt;MakeMaker&gt;:

=over 4

=item *

I don't like the core idea of C&lt;MakeMaker&gt;, namely that C&lt;make&gt; should be
involved in the build process.  Here are my reasons:

=over 4

=item +

When a person is installing a Perl module, what can you assume about
their environment?  Can you assume they have C&lt;make&gt;?  No, but you can
assume they have some version of Perl.

=item +

When a person is writing a Perl module for intended distribution, can
you assume that they know how to build a Makefile, so they can
customize their build process?  No, but you can assume they know Perl,
and could customize that way.

=back

For years, these things have been a barrier to people getting the
build/install process to do what they want.

=item *

There are several architectural decisions in C&lt;MakeMaker&gt; that make it
very difficult to customize its behavior.  For instance, when using
C&lt;MakeMaker&gt; you do C&lt;use ExtUtils::MakeMaker&gt;, but the object created in
C&lt;WriteMakefile()&gt; is actually blessed into a package name that's
created on the fly, so you can't simply subclass
C&lt;ExtUtils::MakeMaker&gt;.  There is a workaround C&lt;MY&gt; package that lets
you override certain C&lt;MakeMaker&gt; methods, but only certain explicitly
preselected (by C&lt;MakeMaker&gt;) methods can be overridden.  Also, the method
of customization is very crude: you have to modify a string containing
the Makefile text for the particular target.  Since these strings
aren't documented, and I&lt;can't&gt; be documented (they take on different
values depending on the platform, version of perl, version of
C&lt;MakeMaker&gt;, etc.), you have no guarantee that your modifications will
work on someone else's machine or after an upgrade of C&lt;MakeMaker&gt; or
perl.

=item *

It is risky to make major changes to C&lt;MakeMaker&gt;, since it does so many
things, is so important, and generally works.  C&lt;Module::Build&gt; is an
entirely separate package so that I can work on it all I want, without
worrying about backward compatibility with C&lt;MakeMaker&gt;.

=item *

Finally, Perl is said to be a language for system administration.
Could it really be the case that Perl isn't up to the task of building
and installing software?  Even if that software is a bunch of
C&lt;.pm&gt; files that just need to be copied from one place to
another?  My sense was that we could design a system to accomplish
this in a flexible, extensible, and friendly manner.  Or die trying.

=back


=head1 TO DO

The current method of relying on time stamps to determine whether a
derived file is out of date isn't likely to scale well, since it
requires tracing all dependencies backward, it runs into problems on
NFS, and it's just generally flimsy.  It would be better to use an MD5
signature or the like, if available.  See C&lt;cons&gt; for an example.

 - append to perllocal.pod
 - add a 'plugin' functionality


=head1 AUTHOR

Ken Williams &lt;kwilliams@cpan.org&gt;

Development questions, bug reports, and patches should be sent to the
Module-Build mailing list at &lt;module-build@perl.org&gt;.

Bug reports are also welcome at
&lt;http://rt.cpan.org/NoAuth/Bugs.html?Dist=Module-Build&gt;.

The latest development version is available from the Git
repository at &lt;https://github.com/Perl-Toolchain-Gang/Module-Build&gt;


=head1 COPYRIGHT

Copyright (c) 2001-2006 Ken Williams.  All rights reserved.

This library is free software; you can redistribute it and/or
modify it under the same terms as Perl itself.


=head1 SEE ALSO

perl(1), L&lt;Module::Build::Cookbook&gt;, L&lt;Module::Build::Authoring&gt;,
L&lt;Module::Build::API&gt;, L&lt;ExtUtils::MakeMaker&gt;

F&lt;META.yml&gt; Specification:
L&lt;CPAN::Meta::Spec&gt;

L&lt;http://www.dsmit.com/cons/&gt;

L&lt;http://search.cpan.org/dist/PerlBuildSystem/&gt;

=cut
</pre></body></html>