<html><head><meta name="color-scheme" content="light dark"></head><body><pre style="word-wrap: break-word; white-space: pre-wrap;">package Net::hostent;
use strict;

use 5.006_001;
our $VERSION = '1.01';
our(@EXPORT, @EXPORT_OK, %EXPORT_TAGS);
BEGIN { 
    use Exporter   ();
    @EXPORT      = qw(gethostbyname gethostbyaddr gethost);
    @EXPORT_OK   = qw(
			$h_name	    	@h_aliases
			$h_addrtype 	$h_length
			@h_addr_list 	$h_addr
		   );
    %EXPORT_TAGS = ( FIELDS =&gt; [ @EXPORT_OK, @EXPORT ] );
}
use vars      @EXPORT_OK;

# Class::Struct forbids use of @ISA
sub import { goto &amp;Exporter::import }

use Class::Struct qw(struct);
struct 'Net::hostent' =&gt; [
   name		=&gt; '$',
   aliases	=&gt; '@',
   addrtype	=&gt; '$',
   'length'	=&gt; '$',
   addr_list	=&gt; '@',
];

sub addr { shift-&gt;addr_list-&gt;[0] }

sub populate (@) {
    return unless @_;
    my $hob = new();
    $h_name 	 =    $hob-&gt;[0]     	     = $_[0];
    @h_aliases	 = @{ $hob-&gt;[1] } = split ' ', $_[1];
    $h_addrtype  =    $hob-&gt;[2] 	     = $_[2];
    $h_length	 =    $hob-&gt;[3] 	     = $_[3];
    $h_addr 	 =                             $_[4];
    @h_addr_list = @{ $hob-&gt;[4] } =          @_[ (4 .. $#_) ];
    return $hob;
} 

sub gethostbyname ($)  { populate(CORE::gethostbyname(shift)) } 

sub gethostbyaddr ($;$) { 
    my ($addr, $addrtype);
    $addr = shift;
    require Socket unless @_;
    $addrtype = @_ ? shift : Socket::AF_INET();
    populate(CORE::gethostbyaddr($addr, $addrtype)) 
} 

sub gethost($) {
    if ($_[0] =~ /^\d+(?:\.\d+(?:\.\d+(?:\.\d+)?)?)?$/) {
	require Socket;
	&amp;gethostbyaddr(Socket::inet_aton(shift));
    } else {
	&amp;gethostbyname;
    } 
} 

1;
__END__

=head1 NAME

Net::hostent - by-name interface to Perl's built-in gethost*() functions

=head1 SYNOPSIS

 use Net::hostent;

=head1 DESCRIPTION

This module's default exports override the core gethostbyname() and
gethostbyaddr() functions, replacing them with versions that return
"Net::hostent" objects.  This object has methods that return the similarly
named structure field name from the C's hostent structure from F&lt;netdb.h&gt;;
namely name, aliases, addrtype, length, and addr_list.  The aliases and
addr_list methods return array reference, the rest scalars.  The addr
method is equivalent to the zeroth element in the addr_list array
reference.

You may also import all the structure fields directly into your namespace
as regular variables using the :FIELDS import tag.  (Note that this still
overrides your core functions.)  Access these fields as variables named
with a preceding C&lt;h_&gt;.  Thus, C&lt;$host_obj-E&lt;gt&gt;name()&gt; corresponds to
$h_name if you import the fields.  Array references are available as
regular array variables, so for example C&lt;@{ $host_obj-E&lt;gt&gt;aliases()
}&gt; would be simply @h_aliases.

The gethost() function is a simple front-end that forwards a numeric
argument to gethostbyaddr() by way of Socket::inet_aton, and the rest
to gethostbyname().

To access this functionality without the core overrides,
pass the C&lt;use&gt; an empty import list, and then access
function functions with their full qualified names.
On the other hand, the built-ins are still available
via the C&lt;CORE::&gt; pseudo-package.

=head1 EXAMPLES

 use Net::hostent;
 use Socket;

 @ARGV = ('netscape.com') unless @ARGV;

 for $host ( @ARGV ) {

    unless ($h = gethost($host)) {
	warn "$0: no such host: $host\n";
	next;
    }

    printf "\n%s is %s%s\n", 
	    $host, 
	    lc($h-&gt;name) eq lc($host) ? "" : "*really* ",
	    $h-&gt;name;

    print "\taliases are ", join(", ", @{$h-&gt;aliases}), "\n"
		if @{$h-&gt;aliases};     

    if ( @{$h-&gt;addr_list} &gt; 1 ) { 
	my $i;
	for $addr ( @{$h-&gt;addr_list} ) {
	    printf "\taddr #%d is [%s]\n", $i++, inet_ntoa($addr);
	} 
    } else {
	printf "\taddress is [%s]\n", inet_ntoa($h-&gt;addr);
    } 

    if ($h = gethostbyaddr($h-&gt;addr)) {
	if (lc($h-&gt;name) ne lc($host)) {
	    printf "\tThat addr reverses to host %s!\n", $h-&gt;name;
	    $host = $h-&gt;name;
	    redo;
	} 
    }
 }

=head1 NOTE

While this class is currently implemented using the Class::Struct
module to build a struct-like class, you shouldn't rely upon this.

=head1 AUTHOR

Tom Christiansen
</pre></body></html>