<html><head><meta name="color-scheme" content="light dark"></head><body><pre style="word-wrap: break-word; white-space: pre-wrap;">package Pod::LaTeX;

=head1 NAME

Pod::LaTeX - Convert Pod data to formatted Latex

=head1 SYNOPSIS

  use Pod::LaTeX;
  my $parser = Pod::LaTeX-&gt;new ( );

  $parser-&gt;parse_from_filehandle;

  $parser-&gt;parse_from_file ('file.pod', 'file.tex');

=head1 DESCRIPTION

C&lt;Pod::LaTeX&gt; is a module to convert documentation in the Pod format
into Latex. The L&lt;B&lt;pod2latex&gt;|pod2latex&gt; X&lt;pod2latex&gt; command uses
this module for translation.

C&lt;Pod::LaTeX&gt; is a derived class from L&lt;Pod::Select|Pod::Select&gt;.

=cut


use strict;
require Pod::ParseUtils;
use base qw/ Pod::Select /;

use if $] &gt; 5.017, 'deprecate';

# use Data::Dumper; # for debugging
use Carp;

use vars qw/ $VERSION %HTML_Escapes @LatexSections /;

$VERSION = '0.61';

# Definitions of =headN -&gt; latex mapping
@LatexSections = (qw/
		  chapter
		  section
		  subsection
		  subsubsection
		  paragraph
		  subparagraph
		  /);

# Standard escape sequences converted to Latex.
# The Unicode name of each character is given in the comments.
# Complete LaTeX set added by Peter Acklam.

%HTML_Escapes = (
     'sol'    =&gt; '\textfractionsolidus{}',  # xxx - or should it be just '/'
     'verbar' =&gt; '|',

     # The stuff below is based on the information available at
     # http://www.w3.org/TR/html401/sgml/entities.html

     # All characters in the range 0xA0-0xFF of the ISO 8859-1 character set.
     # Several of these characters require the `textcomp' LaTeX package.
     'nbsp'   =&gt; q|~|,                     # 0xA0 - no-break space = non-breaking space
     'iexcl'  =&gt; q|\textexclamdown{}|,     # 0xA1 - inverted exclamation mark
     'cent'   =&gt; q|\textcent{}|,           # 0xA2 - cent sign
     'pound'  =&gt; q|\textsterling{}|,       # 0xA3 - pound sign
     'curren' =&gt; q|\textcurrency{}|,       # 0xA4 - currency sign
     'yen'    =&gt; q|\textyen{}|,            # 0xA5 - yen sign = yuan sign
     'brvbar' =&gt; q|\textbrokenbar{}|,      # 0xA6 - broken bar = broken vertical bar
     'sect'   =&gt; q|\textsection{}|,        # 0xA7 - section sign
     'uml'    =&gt; q|\textasciidieresis{}|,  # 0xA8 - diaeresis = spacing diaeresis
     'copy'   =&gt; q|\textcopyright{}|,      # 0xA9 - copyright sign
     'ordf'   =&gt; q|\textordfeminine{}|,    # 0xAA - feminine ordinal indicator
     'laquo'  =&gt; q|\guillemotleft{}|,      # 0xAB - left-pointing double angle quotation mark = left pointing guillemet
     'not'    =&gt; q|\textlnot{}|,           # 0xAC - not sign
     'shy'    =&gt; q|\-|,                    # 0xAD - soft hyphen = discretionary hyphen
     'reg'    =&gt; q|\textregistered{}|,     # 0xAE - registered sign = registered trade mark sign
     'macr'   =&gt; q|\textasciimacron{}|,    # 0xAF - macron = spacing macron = overline = APL overbar
     'deg'    =&gt; q|\textdegree{}|,         # 0xB0 - degree sign
     'plusmn' =&gt; q|\textpm{}|,             # 0xB1 - plus-minus sign = plus-or-minus sign
     'sup2'   =&gt; q|\texttwosuperior{}|,    # 0xB2 - superscript two = superscript digit two = squared
     'sup3'   =&gt; q|\textthreesuperior{}|,  # 0xB3 - superscript three = superscript digit three = cubed
     'acute'  =&gt; q|\textasciiacute{}|,     # 0xB4 - acute accent = spacing acute
     'micro'  =&gt; q|\textmu{}|,             # 0xB5 - micro sign
     'para'   =&gt; q|\textparagraph{}|,      # 0xB6 - pilcrow sign = paragraph sign
     'middot' =&gt; q|\textperiodcentered{}|, # 0xB7 - middle dot = Georgian comma = Greek middle dot
     'cedil'  =&gt; q|\c{}|,                  # 0xB8 - cedilla = spacing cedilla
     'sup1'   =&gt; q|\textonesuperior{}|,    # 0xB9 - superscript one = superscript digit one
     'ordm'   =&gt; q|\textordmasculine{}|,   # 0xBA - masculine ordinal indicator
     'raquo'  =&gt; q|\guillemotright{}|,     # 0xBB - right-pointing double angle quotation mark = right pointing guillemet
     'frac14' =&gt; q|\textonequarter{}|,     # 0xBC - vulgar fraction one quarter = fraction one quarter
     'frac12' =&gt; q|\textonehalf{}|,        # 0xBD - vulgar fraction one half = fraction one half
     'frac34' =&gt; q|\textthreequarters{}|,  # 0xBE - vulgar fraction three quarters = fraction three quarters
     'iquest' =&gt; q|\textquestiondown{}|,   # 0xBF - inverted question mark = turned question mark
     'Agrave' =&gt; q|\`A|,                   # 0xC0 - latin capital letter A with grave = latin capital letter A grave
     'Aacute' =&gt; q|\'A|,             # 0xC1 - latin capital letter A with acute
     'Acirc'  =&gt; q|\^A|,             # 0xC2 - latin capital letter A with circumflex
     'Atilde' =&gt; q|\~A|,             # 0xC3 - latin capital letter A with tilde
     'Auml'   =&gt; q|\"A|,             # 0xC4 - latin capital letter A with diaeresis
     'Aring'  =&gt; q|\AA{}|,           # 0xC5 - latin capital letter A with ring above = latin capital letter A ring
     'AElig'  =&gt; q|\AE{}|,           # 0xC6 - latin capital letter AE = latin capital ligature AE
     'Ccedil' =&gt; q|\c{C}|,           # 0xC7 - latin capital letter C with cedilla
     'Egrave' =&gt; q|\`E|,             # 0xC8 - latin capital letter E with grave
     'Eacute' =&gt; q|\'E|,             # 0xC9 - latin capital letter E with acute
     'Ecirc'  =&gt; q|\^E|,             # 0xCA - latin capital letter E with circumflex
     'Euml'   =&gt; q|\"E|,             # 0xCB - latin capital letter E with diaeresis
     'Igrave' =&gt; q|\`I|,             # 0xCC - latin capital letter I with grave
     'Iacute' =&gt; q|\'I|,             # 0xCD - latin capital letter I with acute
     'Icirc'  =&gt; q|\^I|,             # 0xCE - latin capital letter I with circumflex
     'Iuml'   =&gt; q|\"I|,             # 0xCF - latin capital letter I with diaeresis
     'ETH'    =&gt; q|\DH{}|,           # 0xD0 - latin capital letter ETH
     'Ntilde' =&gt; q|\~N|,             # 0xD1 - latin capital letter N with tilde
     'Ograve' =&gt; q|\`O|,             # 0xD2 - latin capital letter O with grave
     'Oacute' =&gt; q|\'O|,             # 0xD3 - latin capital letter O with acute
     'Ocirc'  =&gt; q|\^O|,             # 0xD4 - latin capital letter O with circumflex
     'Otilde' =&gt; q|\~O|,             # 0xD5 - latin capital letter O with tilde
     'Ouml'   =&gt; q|\"O|,             # 0xD6 - latin capital letter O with diaeresis
     'times'  =&gt; q|\texttimes{}|,    # 0xD7 - multiplication sign
     'Oslash' =&gt; q|\O{}|,            # 0xD8 - latin capital letter O with stroke = latin capital letter O slash
     'Ugrave' =&gt; q|\`U|,             # 0xD9 - latin capital letter U with grave
     'Uacute' =&gt; q|\'U|,             # 0xDA - latin capital letter U with acute
     'Ucirc'  =&gt; q|\^U|,             # 0xDB - latin capital letter U with circumflex
     'Uuml'   =&gt; q|\"U|,             # 0xDC - latin capital letter U with diaeresis
     'Yacute' =&gt; q|\'Y|,             # 0xDD - latin capital letter Y with acute
     'THORN'  =&gt; q|\TH{}|,           # 0xDE - latin capital letter THORN
     'szlig'  =&gt; q|\ss{}|,           # 0xDF - latin small letter sharp s = ess-zed
     'agrave' =&gt; q|\`a|,             # 0xE0 - latin small letter a with grave = latin small letter a grave
     'aacute' =&gt; q|\'a|,             # 0xE1 - latin small letter a with acute
     'acirc'  =&gt; q|\^a|,             # 0xE2 - latin small letter a with circumflex
     'atilde' =&gt; q|\~a|,             # 0xE3 - latin small letter a with tilde
     'auml'   =&gt; q|\"a|,             # 0xE4 - latin small letter a with diaeresis
     'aring'  =&gt; q|\aa{}|,           # 0xE5 - latin small letter a with ring above = latin small letter a ring
     'aelig'  =&gt; q|\ae{}|,           # 0xE6 - latin small letter ae = latin small ligature ae
     'ccedil' =&gt; q|\c{c}|,           # 0xE7 - latin small letter c with cedilla
     'egrave' =&gt; q|\`e|,             # 0xE8 - latin small letter e with grave
     'eacute' =&gt; q|\'e|,             # 0xE9 - latin small letter e with acute
     'ecirc'  =&gt; q|\^e|,             # 0xEA - latin small letter e with circumflex
     'euml'   =&gt; q|\"e|,             # 0xEB - latin small letter e with diaeresis
     'igrave' =&gt; q|\`i|,             # 0xEC - latin small letter i with grave
     'iacute' =&gt; q|\'i|,             # 0xED - latin small letter i with acute
     'icirc'  =&gt; q|\^i|,             # 0xEE - latin small letter i with circumflex
     'iuml'   =&gt; q|\"i|,             # 0xEF - latin small letter i with diaeresis
     'eth'    =&gt; q|\dh{}|,           # 0xF0 - latin small letter eth
     'ntilde' =&gt; q|\~n|,             # 0xF1 - latin small letter n with tilde
     'ograve' =&gt; q|\`o|,             # 0xF2 - latin small letter o with grave
     'oacute' =&gt; q|\'o|,             # 0xF3 - latin small letter o with acute
     'ocirc'  =&gt; q|\^o|,             # 0xF4 - latin small letter o with circumflex
     'otilde' =&gt; q|\~o|,             # 0xF5 - latin small letter o with tilde
     'ouml'   =&gt; q|\"o|,             # 0xF6 - latin small letter o with diaeresis
     'divide' =&gt; q|\textdiv{}|,      # 0xF7 - division sign
     'oslash' =&gt; q|\o{}|,            # 0xF8 - latin small letter o with stroke, = latin small letter o slash
     'ugrave' =&gt; q|\`u|,             # 0xF9 - latin small letter u with grave
     'uacute' =&gt; q|\'u|,             # 0xFA - latin small letter u with acute
     'ucirc'  =&gt; q|\^u|,             # 0xFB - latin small letter u with circumflex
     'uuml'   =&gt; q|\"u|,             # 0xFC - latin small letter u with diaeresis
     'yacute' =&gt; q|\'y|,             # 0xFD - latin small letter y with acute
     'thorn'  =&gt; q|\th{}|,           # 0xFE - latin small letter thorn
     'yuml'   =&gt; q|\"y|,             # 0xFF - latin small letter y with diaeresis

     # Latin Extended-B
     'fnof'   =&gt; q|\textflorin{}|,   # latin small f with hook = function = florin

     # Greek
     'Alpha'    =&gt; q|$\mathrm{A}$|,      # greek capital letter alpha
     'Beta'     =&gt; q|$\mathrm{B}$|,      # greek capital letter beta
     'Gamma'    =&gt; q|$\Gamma$|,          # greek capital letter gamma
     'Delta'    =&gt; q|$\Delta$|,          # greek capital letter delta
     'Epsilon'  =&gt; q|$\mathrm{E}$|,      # greek capital letter epsilon
     'Zeta'     =&gt; q|$\mathrm{Z}$|,      # greek capital letter zeta
     'Eta'      =&gt; q|$\mathrm{H}$|,      # greek capital letter eta
     'Theta'    =&gt; q|$\Theta$|,          # greek capital letter theta
     'Iota'     =&gt; q|$\mathrm{I}$|,      # greek capital letter iota
     'Kappa'    =&gt; q|$\mathrm{K}$|,      # greek capital letter kappa
     'Lambda'   =&gt; q|$\Lambda$|,         # greek capital letter lambda
     'Mu'       =&gt; q|$\mathrm{M}$|,      # greek capital letter mu
     'Nu'       =&gt; q|$\mathrm{N}$|,      # greek capital letter nu
     'Xi'       =&gt; q|$\Xi$|,             # greek capital letter xi
     'Omicron'  =&gt; q|$\mathrm{O}$|,      # greek capital letter omicron
     'Pi'       =&gt; q|$\Pi$|,             # greek capital letter pi
     'Rho'      =&gt; q|$\mathrm{R}$|,      # greek capital letter rho
     'Sigma'    =&gt; q|$\Sigma$|,          # greek capital letter sigma
     'Tau'      =&gt; q|$\mathrm{T}$|,      # greek capital letter tau
     'Upsilon'  =&gt; q|$\Upsilon$|,        # greek capital letter upsilon
     'Phi'      =&gt; q|$\Phi$|,            # greek capital letter phi
     'Chi'      =&gt; q|$\mathrm{X}$|,      # greek capital letter chi
     'Psi'      =&gt; q|$\Psi$|,            # greek capital letter psi
     'Omega'    =&gt; q|$\Omega$|,          # greek capital letter omega

     'alpha'    =&gt; q|$\alpha$|,          # greek small letter alpha
     'beta'     =&gt; q|$\beta$|,           # greek small letter beta
     'gamma'    =&gt; q|$\gamma$|,          # greek small letter gamma
     'delta'    =&gt; q|$\delta$|,          # greek small letter delta
     'epsilon'  =&gt; q|$\epsilon$|,        # greek small letter epsilon
     'zeta'     =&gt; q|$\zeta$|,           # greek small letter zeta
     'eta'      =&gt; q|$\eta$|,            # greek small letter eta
     'theta'    =&gt; q|$\theta$|,          # greek small letter theta
     'iota'     =&gt; q|$\iota$|,           # greek small letter iota
     'kappa'    =&gt; q|$\kappa$|,          # greek small letter kappa
     'lambda'   =&gt; q|$\lambda$|,         # greek small letter lambda
     'mu'       =&gt; q|$\mu$|,             # greek small letter mu
     'nu'       =&gt; q|$\nu$|,             # greek small letter nu
     'xi'       =&gt; q|$\xi$|,             # greek small letter xi
     'omicron'  =&gt; q|$o$|,               # greek small letter omicron
     'pi'       =&gt; q|$\pi$|,             # greek small letter pi
     'rho'      =&gt; q|$\rho$|,            # greek small letter rho
#    'sigmaf'   =&gt; q||,                  # greek small letter final sigma
     'sigma'    =&gt; q|$\sigma$|,          # greek small letter sigma
     'tau'      =&gt; q|$\tau$|,            # greek small letter tau
     'upsilon'  =&gt; q|$\upsilon$|,        # greek small letter upsilon
     'phi'      =&gt; q|$\phi$|,            # greek small letter phi
     'chi'      =&gt; q|$\chi$|,            # greek small letter chi
     'psi'      =&gt; q|$\psi$|,            # greek small letter psi
     'omega'    =&gt; q|$\omega$|,          # greek small letter omega
#    'thetasym' =&gt; q||,                  # greek small letter theta symbol
#    'upsih'    =&gt; q||,                  # greek upsilon with hook symbol
#    'piv'      =&gt; q||,                  # greek pi symbol

     # General Punctuation
     'bull'     =&gt; q|\textbullet{}|,     # bullet = black small circle
     # bullet is NOT the same as bullet operator
     'hellip'   =&gt; q|\textellipsis{}|,           # horizontal ellipsis = three dot leader
     'prime'    =&gt; q|\textquotesingle{}|,        # prime = minutes = feet
     'Prime'    =&gt; q|\textquotedbl{}|,           # double prime = seconds = inches
     'oline'    =&gt; q|\textasciimacron{}|,        # overline = spacing overscore
     'frasl'    =&gt; q|\textfractionsolidus{}|,    # fraction slash

     # Letterlike Symbols
     'weierp'   =&gt; q|$\wp$|,                     # script capital P = power set = Weierstrass p
     'image'    =&gt; q|$\Re$|,                     # blackletter capital I = imaginary part
     'real'     =&gt; q|$\Im$|,                     # blackletter capital R = real part symbol
     'trade'    =&gt; q|\texttrademark{}|,          # trade mark sign
#    'alefsym'  =&gt; q||,                          # alef symbol = first transfinite cardinal
     # alef symbol is NOT the same as hebrew letter alef, although the same
     # glyph could be used to depict both characters

     # Arrows
     'larr'     =&gt; q|\textleftarrow{}|,          # leftwards arrow
     'uarr'     =&gt; q|\textuparrow{}|,            # upwards arrow
     'rarr'     =&gt; q|\textrightarrow{}|,         # rightwards arrow
     'darr'     =&gt; q|\textdownarrow{}|,          # downwards arrow
     'harr'     =&gt; q|$\leftrightarrow$|,         # left right arrow
#    'crarr'    =&gt; q||,                          # downwards arrow with corner leftwards = carriage return
     'lArr'     =&gt; q|$\Leftarrow$|,              # leftwards double arrow
     # ISO 10646 does not say that lArr is the same as the 'is implied by'
     # arrow but also does not have any other character for that function. So
     # lArr can be used for 'is implied by' as ISOtech suggests
     'uArr'     =&gt; q|$\Uparrow$|,                # upwards double arrow
     'rArr'     =&gt; q|$\Rightarrow$|,             # rightwards double arrow
     # ISO 10646 does not say this is the 'implies' character but does not
     # have another character with this function so ? rArr can be used for
     # 'implies' as ISOtech suggests
     'dArr'     =&gt; q|$\Downarrow$|,              # downwards double arrow
     'hArr'     =&gt; q|$\Leftrightarrow$|,         # left right double arrow

     # Mathematical Operators.
     # Some of these require the `amssymb' package.
     'forall'   =&gt; q|$\forall$|,                 # for all
     'part'     =&gt; q|$\partial$|,                # partial differential
     'exist'    =&gt; q|$\exists$|,                 # there exists
     'empty'    =&gt; q|$\emptyset$|,               # empty set = null set = diameter
     'nabla'    =&gt; q|$\nabla$|,                  # nabla = backward difference
     'isin'     =&gt; q|$\in$|,                     # element of
     'notin'    =&gt; q|$\notin$|,                  # not an element of
     'ni'       =&gt; q|$\ni$|,                     # contains as member
     'prod'     =&gt; q|$\prod$|,                   # n-ary product = product sign
     # prod is NOT the same character as 'greek capital letter pi' though the
     # same glyph might be used for both
     'sum'      =&gt; q|$\sum$|,                    # n-ary summation
     # sum is NOT the same character as 'greek capital letter sigma' though
     # the same glyph might be used for both
     'minus'    =&gt; q|$-$|,                       # minus sign
     'lowast'   =&gt; q|$\ast$|,                    # asterisk operator
     'radic'    =&gt; q|$\surd$|,                   # square root = radical sign
     'prop'     =&gt; q|$\propto$|,                 # proportional to
     'infin'    =&gt; q|$\infty$|,                  # infinity
     'ang'      =&gt; q|$\angle$|,                  # angle
     'and'      =&gt; q|$\wedge$|,                  # logical and = wedge
     'or'       =&gt; q|$\vee$|,                    # logical or = vee
     'cap'      =&gt; q|$\cap$|,                    # intersection = cap
     'cup'      =&gt; q|$\cup$|,                    # union = cup
     'int'      =&gt; q|$\int$|,                    # integral
     'there4'   =&gt; q|$\therefore$|,              # therefore
     'sim'      =&gt; q|$\sim$|,                    # tilde operator = varies with = similar to
     # tilde operator is NOT the same character as the tilde
     'cong'     =&gt; q|$\cong$|,                   # approximately equal to
     'asymp'    =&gt; q|$\asymp$|,                  # almost equal to = asymptotic to
     'ne'       =&gt; q|$\neq$|,                    # not equal to
     'equiv'    =&gt; q|$\equiv$|,                  # identical to
     'le'       =&gt; q|$\leq$|,                    # less-than or equal to
     'ge'       =&gt; q|$\geq$|,                    # greater-than or equal to
     'sub'      =&gt; q|$\subset$|,                 # subset of
     'sup'      =&gt; q|$\supset$|,                 # superset of
     # note that nsup, 'not a superset of' is not covered by the Symbol font
     # encoding and is not included.
     'nsub'     =&gt; q|$\not\subset$|,             # not a subset of
     'sube'     =&gt; q|$\subseteq$|,               # subset of or equal to
     'supe'     =&gt; q|$\supseteq$|,               # superset of or equal to
     'oplus'    =&gt; q|$\oplus$|,                  # circled plus = direct sum
     'otimes'   =&gt; q|$\otimes$|,                 # circled times = vector product
     'perp'     =&gt; q|$\perp$|,                   # up tack = orthogonal to = perpendicular
     'sdot'     =&gt; q|$\cdot$|,                   # dot operator
     # dot operator is NOT the same character as middle dot

     # Miscellaneous Technical
     'lceil'    =&gt; q|$\lceil$|,                  # left ceiling = apl upstile
     'rceil'    =&gt; q|$\rceil$|,                  # right ceiling
     'lfloor'   =&gt; q|$\lfloor$|,                 # left floor = apl downstile
     'rfloor'   =&gt; q|$\rfloor$|,                 # right floor
     'lang'     =&gt; q|$\langle$|,                 # left-pointing angle bracket = bra
     # lang is NOT the same character as 'less than' or 'single left-pointing
     # angle quotation mark'
     'rang'     =&gt; q|$\rangle$|,                 # right-pointing angle bracket = ket
     # rang is NOT the same character as 'greater than' or 'single
     # right-pointing angle quotation mark'

     # Geometric Shapes
     'loz'      =&gt; q|$\lozenge$|,                # lozenge

     # Miscellaneous Symbols
     'spades'   =&gt; q|$\spadesuit$|,              # black spade suit
     'clubs'    =&gt; q|$\clubsuit$|,               # black club suit = shamrock
     'hearts'   =&gt; q|$\heartsuit$|,              # black heart suit = valentine
     'diams'    =&gt; q|$\diamondsuit$|,            # black diamond suit

     # C0 Controls and Basic Latin
     'quot'     =&gt; q|"|,                         # quotation mark = APL quote ["]
     'amp'      =&gt; q|\&amp;|,                        # ampersand
     'lt'       =&gt; q|&lt;|,                         # less-than sign
     'gt'       =&gt; q|&gt;|,                         # greater-than sign
     'OElig'    =&gt; q|\OE{}|,                     # latin capital ligature OE
     'oelig'    =&gt; q|\oe{}|,                     # latin small ligature oe
     'Scaron'   =&gt; q|\v{S}|,                     # latin capital letter S with caron
     'scaron'   =&gt; q|\v{s}|,                     # latin small letter s with caron
     'Yuml'     =&gt; q|\"Y|,                       # latin capital letter Y with diaeresis
     'circ'     =&gt; q|\textasciicircum{}|,        # modifier letter circumflex accent
     'tilde'    =&gt; q|\textasciitilde{}|,         # small tilde
     'ensp'     =&gt; q|\phantom{n}|,               # en space
     'emsp'     =&gt; q|\hspace{1em}|,              # em space
     'thinsp'   =&gt; q|\,|,                        # thin space
     'zwnj'     =&gt; q|{}|,                        # zero width non-joiner
#    'zwj'      =&gt; q||,                          # zero width joiner
#    'lrm'      =&gt; q||,                          # left-to-right mark
#    'rlm'      =&gt; q||,                          # right-to-left mark
     'ndash'    =&gt; q|--|,                        # en dash
     'mdash'    =&gt; q|---|,                       # em dash
     'lsquo'    =&gt; q|\textquoteleft{}|,          # left single quotation mark
     'rsquo'    =&gt; q|\textquoteright{}|,         # right single quotation mark
     'sbquo'    =&gt; q|\quotesinglbase{}|,         # single low-9 quotation mark
     'ldquo'    =&gt; q|\textquotedblleft{}|,       # left double quotation mark
     'rdquo'    =&gt; q|\textquotedblright{}|,      # right double quotation mark
     'bdquo'    =&gt; q|\quotedblbase{}|,           # double low-9 quotation mark
     'dagger'   =&gt; q|\textdagger{}|,             # dagger
     'Dagger'   =&gt; q|\textdaggerdbl{}|,          # double dagger
     'permil'   =&gt; q|\textperthousand{}|,        # per mille sign
     'lsaquo'   =&gt; q|\guilsinglleft{}|,          # single left-pointing angle quotation mark
     'rsaquo'   =&gt; q|\guilsinglright{}|,         # single right-pointing angle quotation mark
     'euro'     =&gt; q|\texteuro{}|,               # euro sign
);

=head1 OBJECT METHODS

The following methods are provided in this module. Methods inherited
from C&lt;Pod::Select&gt; are not described in the public interface.

=over 4

=begin __PRIVATE__

=item C&lt;initialize&gt;

Initialise the object. This method is subclassed from C&lt;Pod::Parser&gt;.
The base class method is invoked. This method defines the default
behaviour of the object unless overridden by supplying arguments to
the constructor. 

Internal settings are defaulted as well as the public instance data.
Internal hash values are accessed directly (rather than through
a method) and start with an underscore.

This method should not be invoked by the user directly.

=end __PRIVATE__

=cut



#   - An array for nested lists

# Arguments have already been read by this point

sub initialize {
  my $self = shift;

  # print Dumper($self);

  # Internals
  $self-&gt;{_Lists} = [];             # For nested lists
  $self-&gt;{_suppress_all_para}  = 0; # For =begin blocks
  $self-&gt;{_dont_modify_any_para}=0; # For =begin blocks
  $self-&gt;{_CURRENT_HEAD1}   = '';   # Name of current HEAD1 section

  # Options - only initialise if not already set

  # Cause the '=head1 NAME' field to be treated specially
  # The contents of the NAME paragraph will be converted
  # to a section title. All subsequent =head1 will be converted
  # to =head2 and down. Will not affect =head1's prior to NAME 
  # Assumes:  'Module - purpose' format
  # Also creates a purpose field
  # The name is used for Labeling of the subsequent subsections
  $self-&gt;{ReplaceNAMEwithSection} = 0
    unless exists $self-&gt;{ReplaceNAMEwithSection};
  $self-&gt;{AddPreamble}      = 1    # make full latex document
    unless exists $self-&gt;{AddPreamble};
  $self-&gt;{StartWithNewPage} = 0    # Start new page for pod section
    unless exists $self-&gt;{StartWithNewPage};
  $self-&gt;{TableOfContents}  = 0    # Add table of contents
    unless exists $self-&gt;{TableOfContents};  # only relevant if AddPreamble=1
   $self-&gt;{AddPostamble}     = 1          # Add closing latex code at end
    unless exists $self-&gt;{AddPostamble}; #  effectively end{document} and index
  $self-&gt;{MakeIndex}        = 1         # Add index (only relevant AddPostamble
    unless exists $self-&gt;{MakeIndex};   # and AddPreamble)

  $self-&gt;{UniqueLabels}     = 1          # Use label unique for each pod
    unless exists $self-&gt;{UniqueLabels}; # either based on the filename
                                         # or supplied

  # Control the level of =head1. default is \section
  # 
  $self-&gt;{Head1Level}     = 1   # Offset in latex sections
    unless exists $self-&gt;{Head1Level}; # 0 is chapter, 2 is subsection

  # Control at which level numbering of sections is turned off
  # ie subsection becomes subsection*
  # The numbering is relative to the latex sectioning commands
  # and is independent of Pod heading level
  # default is to number \section but not \subsection
  $self-&gt;{LevelNoNum} = 2
    unless exists $self-&gt;{LevelNoNum};

  # Label to be used as prefix to all internal section names
  # If not defined will attempt to derive it from the filename
  # This can not happen when running parse_from_filehandle though
  # hence the ability to set the label externally
  # The label could then be Pod::Parser_DESCRIPTION or somesuch

  $self-&gt;{Label}            = undef # label to be used as prefix
    unless exists $self-&gt;{Label};   # to all internal section names

  # These allow the caller to add arbitrary latex code to
  # start and end of document. AddPreamble and AddPostamble are ignored
  # if these are set.
  # Also MakeIndex and TableOfContents are also ignored.
  $self-&gt;{UserPreamble}     = undef # User supplied start (AddPreamble =1)
    unless exists $self-&gt;{Label};
  $self-&gt;{UserPostamble}    = undef # Use supplied end    (AddPostamble=1)
    unless exists $self-&gt;{Label};

  # Run base initialize
  $self-&gt;SUPER::initialize;

}

=back

=head2 Data Accessors

The following methods are provided for accessing instance data. These
methods should be used for accessing configuration parameters rather
than assuming the object is a hash.

Default values can be supplied by using these names as keys to a hash
of arguments when using the C&lt;new()&gt; constructor.

=over 4

=item B&lt;AddPreamble&gt;

Logical to control whether a C&lt;latex&gt; preamble is to be written.
If true, a valid C&lt;latex&gt; preamble is written before the pod data is written.
This is similar to:

  \documentclass{article}
  \usepackage[T1]{fontenc}
  \usepackage{textcomp}
  \begin{document}

but will be more complicated if table of contents and indexing are required.
Can be used to set or retrieve the current value.

  $add = $parser-&gt;AddPreamble();
  $parser-&gt;AddPreamble(1);

If used in conjunction with C&lt;AddPostamble&gt; a full latex document will
be written that could be immediately processed by C&lt;latex&gt;.

For some pod escapes it may be necessary to include the amsmath
package. This is not yet added to the preamble automatically.

=cut

sub AddPreamble {
   my $self = shift;
   if (@_) {
     $self-&gt;{AddPreamble} = shift;
   }
   return $self-&gt;{AddPreamble};
}

=item B&lt;AddPostamble&gt;

Logical to control whether a standard C&lt;latex&gt; ending is written to the output
file after the document has been processed.
In its simplest form this is simply:

  \end{document}

but can be more complicated if a index is required.
Can be used to set or retrieve the current value.

  $add = $parser-&gt;AddPostamble();
  $parser-&gt;AddPostamble(1);

If used in conjunction with C&lt;AddPreaamble&gt; a full latex document will
be written that could be immediately processed by C&lt;latex&gt;.

=cut

sub AddPostamble {
   my $self = shift;
   if (@_) {
     $self-&gt;{AddPostamble} = shift;
   }
   return $self-&gt;{AddPostamble};
}

=item B&lt;Head1Level&gt;

The C&lt;latex&gt; sectioning level that should be used to correspond to
a pod C&lt;=head1&gt; directive. This can be used, for example, to turn
a C&lt;=head1&gt; into a C&lt;latex&gt; C&lt;subsection&gt;. This should hold a number
corresponding to the required position in an array containing the
following elements:

 [0] chapter
 [1] section
 [2] subsection
 [3] subsubsection
 [4] paragraph
 [5] subparagraph

Can be used to set or retrieve the current value:

  $parser-&gt;Head1Level(2);
  $sect = $parser-&gt;Head1Level;

Setting this number too high can result in sections that may not be reproducible
in the expected way. For example, setting this to 4 would imply that C&lt;=head3&gt;
do not have a corresponding C&lt;latex&gt; section (C&lt;=head1&gt; would correspond to
a C&lt;paragraph&gt;).

A check is made to ensure that the supplied value is an integer in the
range 0 to 5.

Default is for a value of 1 (i.e. a C&lt;section&gt;).

=cut

sub Head1Level {
   my $self = shift;
   if (@_) {
     my $arg = shift;
     if ($arg =~ /^\d$/ &amp;&amp; $arg &lt;= $#LatexSections) {
       $self-&gt;{Head1Level} = $arg;
     } else {
       carp "Head1Level supplied ($arg) must be integer in range 0 to ".$#LatexSections . "- Ignoring\n";
     }
   }
   return $self-&gt;{Head1Level};
}

=item B&lt;Label&gt;

This is the label that is prefixed to all C&lt;latex&gt; label and index
entries to make them unique. In general, pods have similarly titled
sections (NAME, DESCRIPTION etc) and a C&lt;latex&gt; label will be multiply
defined if more than one pod document is to be included in a single
C&lt;latex&gt; file. To overcome this, this label is prefixed to a label
whenever a label is required (joined with an underscore) or to an
index entry (joined by an exclamation mark which is the normal index
separator). For example, C&lt;\label{text}&gt; becomes C&lt;\label{Label_text}&gt;.

Can be used to set or retrieve the current value:

  $label = $parser-&gt;Label;
  $parser-&gt;Label($label);

This label is only used if C&lt;UniqueLabels&gt; is true.
Its value is set automatically from the C&lt;NAME&gt; field
if C&lt;ReplaceNAMEwithSection&gt; is true. If this is not the case
it must be set manually before starting the parse.

Default value is C&lt;undef&gt;.

=cut

sub Label {
   my $self = shift;
   if (@_) {
     $self-&gt;{Label} = shift;
   }
   return $self-&gt;{Label};
}

=item B&lt;LevelNoNum&gt;

Control the point at which C&lt;latex&gt; section numbering is turned off.
For example, this can be used to make sure that C&lt;latex&gt; sections
are numbered but subsections are not.

Can be used to set or retrieve the current value:

  $lev = $parser-&gt;LevelNoNum;
  $parser-&gt;LevelNoNum(2);

The argument must be an integer between 0 and 5 and is the same as the
number described in C&lt;Head1Level&gt; method description. The number has
nothing to do with the pod heading number, only the C&lt;latex&gt; sectioning.

Default is 2. (i.e. C&lt;latex&gt; subsections are written as C&lt;subsection*&gt;
but sections are numbered).

=cut

sub LevelNoNum {
   my $self = shift;
   if (@_) {
     $self-&gt;{LevelNoNum} = shift;
   }
   return $self-&gt;{LevelNoNum};
}

=item B&lt;MakeIndex&gt;

Controls whether C&lt;latex&gt; commands for creating an index are to be inserted
into the preamble and postamble

  $makeindex = $parser-&gt;MakeIndex;
  $parser-&gt;MakeIndex(0);

Irrelevant if both C&lt;AddPreamble&gt; and C&lt;AddPostamble&gt; are false (or equivalently,
C&lt;UserPreamble&gt; and C&lt;UserPostamble&gt; are set).

Default is for an index to be created.

=cut

sub MakeIndex {
   my $self = shift;
   if (@_) {
     $self-&gt;{MakeIndex} = shift;
   }
   return $self-&gt;{MakeIndex};
}

=item B&lt;ReplaceNAMEwithSection&gt;

This controls whether the C&lt;NAME&gt; section in the pod is to be translated
literally or converted to a slightly modified output where the section
name is the pod name rather than "NAME".

If true, the pod segment

  =head1 NAME

  pod::name - purpose

  =head1 SYNOPSIS

is converted to the C&lt;latex&gt;

  \section{pod::name\label{pod_name}\index{pod::name}}

  Purpose

  \subsection*{SYNOPSIS\label{pod_name_SYNOPSIS}%
               \index{pod::name!SYNOPSIS}}

(dependent on the value of C&lt;Head1Level&gt; and C&lt;LevelNoNum&gt;). Note that
subsequent C&lt;head1&gt; directives translate to subsections rather than
sections and that the labels and index now include the pod name (dependent
on the value of C&lt;UniqueLabels&gt;).

The C&lt;Label&gt; is set from the pod name regardless of any current value
of C&lt;Label&gt;.

  $mod = $parser-&gt;ReplaceNAMEwithSection;
  $parser-&gt;ReplaceNAMEwithSection(0);

Default is to translate the pod literally.

=cut

sub ReplaceNAMEwithSection {
   my $self = shift;
   if (@_) {
     $self-&gt;{ReplaceNAMEwithSection} = shift;
   }
   return $self-&gt;{ReplaceNAMEwithSection};
}

=item B&lt;StartWithNewPage&gt;

If true, each pod translation will begin with a C&lt;latex&gt;
C&lt;\clearpage&gt;.

  $parser-&gt;StartWithNewPage(1);
  $newpage = $parser-&gt;StartWithNewPage;

Default is false.

=cut

sub StartWithNewPage {
   my $self = shift;
   if (@_) {
     $self-&gt;{StartWithNewPage} = shift;
   }
   return $self-&gt;{StartWithNewPage};
}

=item B&lt;TableOfContents&gt;

If true, a table of contents will be created.
Irrelevant if C&lt;AddPreamble&gt; is false or C&lt;UserPreamble&gt;
is set.

  $toc = $parser-&gt;TableOfContents;
  $parser-&gt;TableOfContents(1);

Default is false.

=cut

sub TableOfContents {
   my $self = shift;
   if (@_) {
     $self-&gt;{TableOfContents} = shift;
   }
   return $self-&gt;{TableOfContents};
}

=item B&lt;UniqueLabels&gt;

If true, the translator will attempt to make sure that
each C&lt;latex&gt; label or index entry will be uniquely identified
by prefixing the contents of C&lt;Label&gt;. This allows
multiple documents to be combined without clashing 
common labels such as C&lt;DESCRIPTION&gt; and C&lt;SYNOPSIS&gt;

  $parser-&gt;UniqueLabels(1);
  $unq = $parser-&gt;UniqueLabels;

Default is true.

=cut

sub UniqueLabels {
   my $self = shift;
   if (@_) {
     $self-&gt;{UniqueLabels} = shift;
   }
   return $self-&gt;{UniqueLabels};
}

=item B&lt;UserPreamble&gt;

User supplied C&lt;latex&gt; preamble. Added before the pod translation
data. 

If set, the contents will be prepended to the output file before the translated 
data regardless of the value of C&lt;AddPreamble&gt;.
C&lt;MakeIndex&gt; and C&lt;TableOfContents&gt; will also be ignored.

=cut

sub UserPreamble {
   my $self = shift;
   if (@_) {
     $self-&gt;{UserPreamble} = shift;
   }
   return $self-&gt;{UserPreamble};
}

=item B&lt;UserPostamble&gt;

User supplied C&lt;latex&gt; postamble. Added after the pod translation
data. 

If set, the contents will be prepended to the output file after the translated 
data regardless of the value of C&lt;AddPostamble&gt;.
C&lt;MakeIndex&gt; will also be ignored.

=cut

sub UserPostamble {
   my $self = shift;
   if (@_) {
     $self-&gt;{UserPostamble} = shift;
   }
   return $self-&gt;{UserPostamble};
}

=begin __PRIVATE__

=item B&lt;Lists&gt;

Contains details of the currently active lists.
  The array contains C&lt;Pod::List&gt; objects. A new C&lt;Pod::List&gt;
object is created each time a list is encountered and it is
pushed onto this stack. When the list context ends, it 
is popped from the stack. The array will be empty if no
lists are active.

Returns array of list information in list context
Returns array ref in scalar context

=cut



sub lists {
  my $self = shift;
  return @{ $self-&gt;{_Lists} } if wantarray();
  return $self-&gt;{_Lists};
}

=end __PRIVATE__

=back

=begin __PRIVATE__

=head2 Subclassed methods

The following methods override methods provided in the C&lt;Pod::Select&gt;
base class. See C&lt;Pod::Parser&gt; and C&lt;Pod::Select&gt; for more information
on what these methods require.

=over 4

=cut

######### END ACCESSORS ###################

# Opening pod

=item B&lt;begin_pod&gt;

Writes the C&lt;latex&gt; preamble if requested. Only writes something
if AddPreamble is true. Writes a standard header unless a UserPreamble
is defined.

=cut

sub begin_pod {
  my $self = shift;

  # Get the pod identification
  # This should really come from the '=head1 NAME' paragraph

  my $infile = $self-&gt;input_file;
  my $class = ref($self);
  my $date = gmtime(time);

  # Comment message to say where this came from
  my $comment = &lt;&lt; "__TEX_COMMENT__";
%%  Latex generated from POD in document $infile
%%  Using the perl module $class
%%  Converted on $date
__TEX_COMMENT__

  # Write the preamble
  # If the caller has supplied one then we just use that

  my $preamble = '';

  if ($self-&gt;AddPreamble) {

    if (defined $self-&gt;UserPreamble) {

      $preamble = $self-&gt;UserPreamble;

      # Add the description of where this came from
      $preamble .=  "\n$comment\n%%  Preamble supplied by user.\n\n";

    } else {

      # Write our own preamble

      # Code to initialise index making
      # Use an array so that we can prepend comment if required
      my @makeidx = (
		     '\usepackage{makeidx}',
		     '\makeindex',
		    );

      unless ($self-&gt;MakeIndex) {
	foreach (@makeidx) {
	  $_ = '%% ' . $_;
	}
      }
      my $makeindex = join("\n",@makeidx) . "\n";

      # Table of contents
      my $tableofcontents = '\tableofcontents';

      $tableofcontents = '%% ' . $tableofcontents
	unless $self-&gt;TableOfContents;

      # Roll our own
      $preamble = &lt;&lt; "__TEX_HEADER__";
\\documentclass{article}
\\usepackage[T1]{fontenc}
\\usepackage{textcomp}

$comment

$makeindex

\\begin{document}

$tableofcontents

__TEX_HEADER__

    }
  }

  # Write the header (blank if none)
  $self-&gt;_output($preamble);

  # Start on new page if requested
  $self-&gt;_output("\\clearpage\n") if $self-&gt;StartWithNewPage;

}


=item B&lt;end_pod&gt;

Write the closing C&lt;latex&gt; code. Only writes something if AddPostamble
is true. Writes a standard header unless a UserPostamble is defined.

=cut

sub end_pod {
  my $self = shift;

  # End string
  my $end = '';

  # Use the user version of the postamble if defined
  if ($self-&gt;AddPostamble) {

    if (defined $self-&gt;UserPostamble) {
      $end = $self-&gt;UserPostamble;

    } else {

      # Check for index
      my $makeindex = '\printindex';

      $makeindex = '%% '. $makeindex  unless $self-&gt;MakeIndex;

      $end = "$makeindex\n\n\\end{document}\n";
    }
  }

  $self-&gt;_output($end);

}

=item B&lt;command&gt;

Process basic pod commands.

=cut

sub command {
  my $self = shift;
  my ($command, $paragraph, $line_num, $parobj) = @_;

  # return if we dont care
  return if $command eq 'pod';

  # Store a copy of the raw text in case we are in a =for
  # block and need to preserve the existing latex
  my $rawpara = $paragraph;

  # Do the latex escapes
  $paragraph = $self-&gt;_replace_special_chars($paragraph);

  # Interpolate pod sequences in paragraph
  $paragraph = $self-&gt;interpolate($paragraph, $line_num);
  $paragraph =~ s/\s+$//;

  # Replace characters that can only be done after 
  # interpolation of interior sequences
  $paragraph = $self-&gt;_replace_special_chars_late($paragraph);

  # Now run the command
  if ($command eq 'over') {

    $self-&gt;begin_list($paragraph, $line_num);

  } elsif ($command eq 'item') {

    $self-&gt;add_item($paragraph, $line_num);

  } elsif ($command eq 'back') {

    $self-&gt;end_list($line_num);

  } elsif ($command eq 'head1') {

    # Store the name of the section
    $self-&gt;{_CURRENT_HEAD1} = $paragraph;

    # Print it
    $self-&gt;head(1, $paragraph, $parobj);

  } elsif ($command eq 'head2') {

    $self-&gt;head(2, $paragraph, $parobj);

  } elsif ($command eq 'head3') {

    $self-&gt;head(3, $paragraph, $parobj);

  } elsif ($command eq 'head4') {

    $self-&gt;head(4, $paragraph, $parobj);

  } elsif ($command eq 'head5') {

    $self-&gt;head(5, $paragraph, $parobj);

  } elsif ($command eq 'head6') {

    $self-&gt;head(6, $paragraph, $parobj);

  } elsif ($command eq 'begin') {

    # pass through if latex
    if ($paragraph =~ /^latex/i) {
      # Make sure that subsequent paragraphs are not modfied before printing
      $self-&gt;{_dont_modify_any_para} = 1;

    } else {
      # Suppress all subsequent paragraphs unless 
      # it is explicitly intended for latex
      $self-&gt;{_suppress_all_para} = 1;
    }

  } elsif ($command eq 'for') {

    # =for latex
    #   some latex

    # With =for we will get the text for the full paragraph
    # as well as the format name.
    # We do not get an additional paragraph later on. The next
    # paragraph is not governed by the =for

    # The first line contains the format and the rest is the
    # raw code.
    my ($format, $chunk) = split(/\n/, $rawpara, 2);

    # If we have got some latex code print it out immediately
    # unmodified. Else do nothing.
    if ($format =~ /^latex/i) {
      # Make sure that next paragraph is not modfied before printing
      $self-&gt;_output( $chunk );

    }

  } elsif ($command eq 'end') {

    # Reset suppression
    $self-&gt;{_suppress_all_para} = 0;
    $self-&gt;{_dont_modify_any_para} = 0;

  } elsif ($command eq 'pod') {

    # Do nothing

  } else {
    carp "Command $command not recognised at line $line_num\n";
  }

}

=item B&lt;verbatim&gt;

Verbatim text

=cut

sub verbatim {
  my $self = shift;
  my ($paragraph, $line_num, $parobj) = @_;

  # Expand paragraph unless in =begin block
  if ($self-&gt;{_dont_modify_any_para}) {
    # Just print as is
    $self-&gt;_output($paragraph);

  } else {

    return if $paragraph =~ /^\s+$/;

    # Clean trailing space
    $paragraph =~ s/\s+$//;

    # Clean tabs. Routine taken from Tabs.pm
    # by David Muir Sharnoff muir@idiom.com,
    # slightly modified by hsmyers@sdragons.com 10/22/01
    my @l = split("\n",$paragraph);
    foreach (@l) {
      1 while s/(^|\n)([^\t\n]*)(\t+)/
	$1. $2 . (" " x 
		  (8 * length($3)
		   - (length($2) % 8)))
	  /sex;
    }
    $paragraph = join("\n",@l);
    # End of change.



    $self-&gt;_output('\begin{verbatim}' . "\n$paragraph\n". '\end{verbatim}'."\n");
  }
}

=item B&lt;textblock&gt;

Plain text paragraph.

=cut

sub textblock {
  my $self = shift;
  my ($paragraph, $line_num, $parobj) = @_;

  # print Dumper($self);

  # Expand paragraph unless in =begin block
  if ($self-&gt;{_dont_modify_any_para}) {
    # Just print as is
    $self-&gt;_output($paragraph);

    return;
  }


  # Escape latex special characters
  $paragraph = $self-&gt;_replace_special_chars($paragraph);

  # Interpolate interior sequences
  my $expansion = $self-&gt;interpolate($paragraph, $line_num);
  $expansion =~ s/\s+$//;

  # Escape special characters that can not be done earlier
  $expansion = $self-&gt;_replace_special_chars_late($expansion);

  # If we are replacing 'head1 NAME' with a section
  # we need to look in the paragraph and rewrite things
  # Need to make sure this is called only on the first paragraph
  # following 'head1 NAME' and not on subsequent paragraphs that may be
  # present.
  if ($self-&gt;{_CURRENT_HEAD1} =~ /^NAME/i &amp;&amp; $self-&gt;ReplaceNAMEwithSection()) {

    # Strip white space from start and end
    $paragraph =~ s/^\s+//;
    $paragraph =~ s/\s$//;

    # Split the string into 2 parts
    my ($name, $purpose) = split(/\s+-\s+/, $expansion,2);

    # Now prevent this from triggering until a new head1 NAME is set
    $self-&gt;{_CURRENT_HEAD1} = '_NAME';

    # Might want to clear the Label() before doing this (CHECK)

    # Print the heading
    $self-&gt;head(1, $name, $parobj);

    # Set the labeling in case we want unique names later
    $self-&gt;Label( $self-&gt;_create_label( $name, 1 ) );

    # Raise the Head1Level by one so that subsequent =head1 appear
    # as subsections of the main name section unless we are already
    # at maximum [Head1Level() could check this itself - CHECK]
    $self-&gt;Head1Level( $self-&gt;Head1Level() + 1)
      unless $self-&gt;Head1Level == $#LatexSections;

    # Now write out the new latex paragraph
    $purpose = ucfirst($purpose);
    $self-&gt;_output("\n\n$purpose\n\n");

  } else {
    # Just write the output
    $self-&gt;_output("\n\n$expansion\n\n");
  }

}

=item B&lt;interior_sequence&gt;

Interior sequence expansion

=cut

sub interior_sequence {
  my $self = shift;

  my ($seq_command, $seq_argument, $pod_seq) = @_;

  if ($seq_command eq 'B') {
    return "\\textbf{$seq_argument}";

  } elsif ($seq_command eq 'I') {
    return "\\textit{$seq_argument}";

  } elsif ($seq_command eq 'E') {

    # If it is simply a number
    if ($seq_argument =~ /^\d+$/) {
      return chr($seq_argument);
    # Look up escape in hash table
    } elsif (exists $HTML_Escapes{$seq_argument}) {
      return $HTML_Escapes{$seq_argument};

    } else {
      my ($file, $line) = $pod_seq-&gt;file_line();
      warn "Escape sequence $seq_argument not recognised at line $line of file $file\n";
      return;
    }

  } elsif ($seq_command eq 'Z') {

    # Zero width space
    return '{}';

  } elsif ($seq_command eq 'C') {
    return "\\texttt{$seq_argument}";

  } elsif ($seq_command eq 'F') {
    return "\\emph{$seq_argument}";

  } elsif ($seq_command eq 'S') {
    # non breakable spaces
    my $nbsp = '~';

    $seq_argument =~ s/\s/$nbsp/g;
    return $seq_argument;

  } elsif ($seq_command eq 'L') {
    my $link = new Pod::Hyperlink($seq_argument);

    # undef on failure
    unless (defined $link) {
      carp $@;
      return;
    }

    # Handle internal links differently
    my $type = $link-&gt;type;
    my $page = $link-&gt;page;

    if ($type eq 'section' &amp;&amp; $page eq '') {
      # Use internal latex reference 
      my $node = $link-&gt;node;

      # Convert to a label
      $node = $self-&gt;_create_label($node);

      return "\\S\\ref{$node}";

    } else {
      # Use default markup for external references
      # (although Starlink would use \xlabel)
      my $markup = $link-&gt;markup;
      my ($file, $line) = $pod_seq-&gt;file_line();

      return $self-&gt;interpolate($link-&gt;markup, $line);
    }



  } elsif ($seq_command eq 'P') {
    # Special markup for Pod::Hyperlink
    # Replace :: with / - but not sure if I want to do this
    # any more.
    my $link = $seq_argument;
    $link =~ s|::|/|g;

    my $ref = "\\emph{$seq_argument}";
    return $ref;

  } elsif ($seq_command eq 'Q') {
    # Special markup for Pod::Hyperlink
    return "\\textsf{$seq_argument}";

  } elsif ($seq_command eq 'X') {
    # Index entries

    # use \index command
    # I will let '!' go through for now
    # not sure how sub categories are handled in X&lt;&gt;
    my $index = $self-&gt;_create_index($seq_argument);
    return "\\index{$index}\n";

  } else {
    carp "Unknown sequence $seq_command&lt;$seq_argument&gt;";
  }

}

=back

=head2 List Methods

Methods used to handle lists.

=over 4

=item B&lt;begin_list&gt;

Called when a new list is found (via the C&lt;over&gt; directive).
Creates a new C&lt;Pod::List&gt; object and stores it on the 
list stack.

  $parser-&gt;begin_list($indent, $line_num);

=cut

sub begin_list {
  my $self = shift;
  my $indent = shift;
  my $line_num = shift;

  # Indicate that a list should be started for the next item
  # need to do this to work out the type of list
  push ( @{$self-&gt;lists}, new Pod::List(-indent =&gt; $indent, 
					-start =&gt; $line_num,
					-file =&gt; $self-&gt;input_file,
				       )	 
       );

}

=item B&lt;end_list&gt;

Called when the end of a list is found (the C&lt;back&gt; directive).
Pops the C&lt;Pod::List&gt; object off the stack of lists and writes
the C&lt;latex&gt; code required to close a list.

  $parser-&gt;end_list($line_num);

=cut

sub end_list {
  my $self = shift;
  my $line_num = shift;

  unless (defined $self-&gt;lists-&gt;[-1]) {
    my $file = $self-&gt;input_file;
    warn "No list is active at line $line_num (file=$file). Missing =over?\n";
    return;
  }

  # What to write depends on list type
  my $type = $self-&gt;lists-&gt;[-1]-&gt;type;

  # Don't write anything if the list type is not set
  # iomplying that a list was created but no entries were
  # placed in it (eg because of a =begin/=end combination)
  $self-&gt;_output("\\end{$type}\n")
    if (defined $type &amp;&amp; length($type) &gt; 0);
  
  # Clear list
  pop(@{ $self-&gt;lists});

}

=item B&lt;add_item&gt;

Add items to the list. The first time an item is encountered 
(determined from the state of the current C&lt;Pod::List&gt; object)
the type of list is determined (ordered, unnumbered or description)
and the relevant latex code issued.

  $parser-&gt;add_item($paragraph, $line_num);

=cut

sub add_item {
  my $self = shift;
  my $paragraph = shift;
  my $line_num = shift;

  unless (defined $self-&gt;lists-&gt;[-1]) {
    my $file = $self-&gt;input_file;
    warn "List has already ended by line $line_num of file $file. Missing =over?\n";
    # Replace special chars
#    $paragraph = $self-&gt;_replace_special_chars($paragraph);
    $self-&gt;_output("$paragraph\n\n");
    return;
  }

  # If paragraphs printing is turned off via =begin/=end or whatever
  # simply return immediately
  return if $self-&gt;{_suppress_all_para};

  # Check to see whether we are starting a new lists
  if (scalar($self-&gt;lists-&gt;[-1]-&gt;item) == 0) {

    # Examine the paragraph to determine what type of list
    # we have
    $paragraph =~ s/\s+$//;
    $paragraph =~ s/^\s+//;

    my $type;
    if (substr($paragraph, 0,1) eq '*') {
      $type = 'itemize';
    } elsif ($paragraph =~ /^\d/) {
      $type = 'enumerate';
    } else {
      $type = 'description';
    }
    $self-&gt;lists-&gt;[-1]-&gt;type($type);

    $self-&gt;_output("\\begin{$type}\n");

  }

  my $type = $self-&gt;lists-&gt;[-1]-&gt;type;

  if ($type eq 'description') {
    # Handle long items - long items do not wrap
    # If the string is longer than 40 characters we split
    # it into a real item header and some bold text.
    my $maxlen = 40;
    my ($hunk1, $hunk2) = $self-&gt;_split_delimited( $paragraph, $maxlen );

    # Print the first hunk
    $self-&gt;_output("\n\\item[{$hunk1}] ");

    # and the second hunk if it is defined
    if ($hunk2) {
      $self-&gt;_output("\\textbf{$hunk2}");
    } else {
      # Not there so make sure we have a new line
      $self-&gt;_output("\\mbox{}");
    }

  } else {
    # If the item was '* Something' or '\d+ something' we still need to write
    # out the something. Also allow 1) and 1.
    my $extra_info = $paragraph;
    $extra_info =~ s/^(\*|\d+[\.\)]?)\s*//;
    $self-&gt;_output("\n\\item $extra_info");
  }

  # Store the item name in the object. Required so that 
  # we can tell if the list is new or not
  $self-&gt;lists-&gt;[-1]-&gt;item($paragraph);

}

=back

=head2 Methods for headings

=over 4

=item B&lt;head&gt;

Print a heading of the required level.

  $parser-&gt;head($level, $paragraph, $parobj);

The first argument is the pod heading level. The second argument
is the contents of the heading. The 3rd argument is a Pod::Paragraph
object so that the line number can be extracted.

=cut

sub head {
  my $self = shift;
  my $num = shift;
  my $paragraph = shift;
  my $parobj = shift;

  # If we are replace 'head1 NAME' with a section
  # we return immediately if we get it
  return 
    if ($self-&gt;{_CURRENT_HEAD1} =~ /^NAME/i &amp;&amp; $self-&gt;ReplaceNAMEwithSection());

  # Create a label
  my $label = $self-&gt;_create_label($paragraph);

  # Create an index entry
  my $index = $self-&gt;_create_index($paragraph);

  # Work out position in the above array taking into account
  # that =head1 is equivalent to $self-&gt;Head1Level

  my $level = $self-&gt;Head1Level() - 1 + $num;

  # Warn if heading to large
  if ($num &gt; $#LatexSections) {
    my $line = $parobj-&gt;file_line;
    my $file = $self-&gt;input_file;
    warn "Heading level too large ($level) for LaTeX at line $line of file $file\n";
    $level = $#LatexSections;
  }

  # Check to see whether section should be unnumbered
  my $star = ($level &gt;= $self-&gt;LevelNoNum ? '*' : '');

  # Section
  $self-&gt;_output("\\" .$LatexSections[$level] .$star ."{$paragraph\\label{".$label ."}\\index{".$index."}}\n");

}


=back

=end __PRIVATE__

=begin __PRIVATE__

=head2 Internal methods

Internal routines are described in this section. They do not form part of the
public interface. All private methods start with an underscore.

=over 4

=item B&lt;_output&gt;

Output text to the output filehandle. This method must be always be called
to output parsed text.

   $parser-&gt;_output($text);

Does not write anything if a =begin is active that should be
ignored.

=cut

sub _output { 
  my $self = shift;
  my $text = shift;

  print { $self-&gt;output_handle } $text
    unless $self-&gt;{_suppress_all_para};

}


=item B&lt;_replace_special_chars&gt;

Subroutine to replace characters that are special in C&lt;latex&gt;
with the escaped forms

  $escaped = $parser-&gt;_replace_special_chars($paragraph);

Need to call this routine before interior_sequences are munged but not
if verbatim. It must be called before interpolation of interior
sequences so that curly brackets and special latex characters inserted
during interpolation are not themselves escaped. This means that &lt; and
&gt; can not be modified here since the text still contains interior
sequences.

Special characters and the C&lt;latex&gt; equivalents are:

  }     \}
  {     \{
  _     \_
  $     \$
  %     \%
  &amp;     \&amp;
  \     $\backslash$
  ^     \^{}
  ~     \~{}
  #     \#

=cut

sub _replace_special_chars {
  my $self = shift;
  my $paragraph = shift;

  # Replace a \ with $\backslash$
  # This is made more complicated because the dollars will be escaped
  # by the subsequent replacement. Easiest to add \backslash 
  # now and then add the dollars
  $paragraph =~ s/\\/\\backslash/g;

  # Must be done after escape of \ since this command adds latex escapes
  # Replace characters that can be escaped
  $paragraph =~ s/([\$\#&amp;%_{}])/\\$1/g;

  # Replace ^ characters with \^{} so that $^F works okay
  $paragraph =~ s/(\^)/\\$1\{\}/g;

  # Replace tilde (~) with \texttt{\~{}}
  $paragraph =~ s/~/\\texttt\{\\~\{\}\}/g;

  # Now add the dollars around each \backslash
  $paragraph =~ s/(\\backslash)/\$$1\$/g;

  # Convert ------ to -{}-{}-{}-{}-{}-
  $paragraph =~ s/-(?=-)/-{}/g;

  return $paragraph;
}

=item B&lt;_replace_special_chars_late&gt;

Replace special characters that can not be replaced before interior
sequence interpolation. See C&lt;_replace_special_chars&gt; for a routine
to replace special characters prior to interpolation of interior
sequences.

Does the following transformation:

  &lt;   $&lt;$
  &gt;   $&gt;$
  |   $|$


=cut

sub _replace_special_chars_late {
  my $self = shift;
  my $paragraph = shift;

  # &lt; and &gt;
  $paragraph =~ s/(&lt;|&gt;)/\$$1\$/g;

  # Replace | with $|$
  $paragraph =~ s'\|'$|$'g;


  return $paragraph;
}


=item B&lt;_create_label&gt;

Return a string that can be used as an internal reference
in a C&lt;latex&gt; document (i.e. accepted by the C&lt;\label&gt; command)

 $label = $parser-&gt;_create_label($string)

If UniqueLabels is true returns a label prefixed by Label()
This can be suppressed with an optional second argument.

 $label = $parser-&gt;_create_label($string, $suppress);

If a second argument is supplied (of any value including undef)
the Label() is never prefixed. This means that this routine can
be called to create a Label() without prefixing a previous setting.

=cut

sub _create_label {
  my $self = shift;
  my $paragraph = shift;
  my $suppress = (@_ ? 1 : 0 );

  # Remove latex commands
  $paragraph = $self-&gt;_clean_latex_commands($paragraph);

  # Remove non alphanumerics from the label and replace with underscores
  # want to protect '-' though so use negated character classes 
  $paragraph =~ s/[^-:\w]/_/g;

  # Multiple underscores will look unsightly so remove repeats
  # This will also have the advantage of tidying up the end and
  # start of string
  $paragraph =~ s/_+/_/g;

  # If required need to make sure that the label is unique
  # since it is possible to have multiple pods in a single
  # document
  if (!$suppress &amp;&amp; $self-&gt;UniqueLabels() &amp;&amp; defined $self-&gt;Label) {
    $paragraph = $self-&gt;Label() .'_'. $paragraph;
  }

  return $paragraph;
}


=item B&lt;_create_index&gt;

Similar to C&lt;_create_label&gt; except an index entry is created.
If C&lt;UniqueLabels&gt; is true, the index entry is prefixed by 
the current C&lt;Label&gt; and an exclamation mark.

  $ind = $parser-&gt;_create_index($paragraph);

An exclamation mark is used by C&lt;makeindex&gt; to generate 
sub-entries in an index.

=cut

sub _create_index {
  my $self = shift;
  my $paragraph = shift;
  my $suppress = (@_ ? 1 : 0 );

  # Remove latex commands
  $paragraph = $self-&gt;_clean_latex_commands($paragraph);

  # If required need to make sure that the index entry is unique
  # since it is possible to have multiple pods in a single
  # document
  if (!$suppress &amp;&amp; $self-&gt;UniqueLabels() &amp;&amp; defined $self-&gt;Label) {
    $paragraph = $self-&gt;Label() .'!'. $paragraph;
  }

  # Need to replace _ with space
  $paragraph =~ s/_/ /g;

  return $paragraph;

}

=item B&lt;_clean_latex_commands&gt;

Removes latex commands from text. The latex command is assumed to be of the
form C&lt;\command{ text }&gt;. "C&lt;text&gt;" is retained

  $clean = $parser-&gt;_clean_latex_commands($text);

=cut

sub _clean_latex_commands {
  my $self = shift;
  my $paragraph = shift;

  # Remove latex commands of the form \text{ }
  # and replace with the contents of the { }
  # need to make this non-greedy so that it can handle
  #  "\text{a} and \text2{b}"
  # without converting it to
  #  "a} and \text2{b"
  # This match will still get into trouble if \} is present 
  # This is not vital since the subsequent replacement of non-alphanumeric
  # characters will tidy it up anyway
  $paragraph =~ s/\\\w+{(.*?)}/$1/g;

  return $paragraph
}

=item B&lt;_split_delimited&gt;

Split the supplied string into two parts at approximately the
specified word boundary. Special care is made to make sure that it
does not split in the middle of some curly brackets.

e.g. "this text is \textbf{very bold}" would not be split into
"this text is \textbf{very" and " bold".

  ($hunk1, $hunk2) = $self-&gt;_split_delimited( $para, $length);

The length indicates the maximum length of hunk1.

=cut

# initially Supplied by hsmyers@sdragons.com
# 10/25/01, utility to split \hbox
# busting lines. Reformatted by TimJ to match module style.
sub _split_delimited {
  my $self = shift;
  my $input = shift;
  my $limit = shift;

  # Return immediately if already small
  return ($input, '') if length($input) &lt; $limit;

  my @output;
  my $s = '';
  my $t = '';
  my $depth = 0;
  my $token;

  $input =~ s/\n/ /gm;
  $input .= ' ';
  foreach ( split ( //, $input ) ) {
    $token .= $_;
    if (/\{/) {
      $depth++;
    } elsif ( /}/ ) {
      $depth--;
    } elsif ( / / and $depth == 0) {
      push @output, $token if ( $token and $token ne ' ' );
      $token = '';
    }
  }

  foreach  (@output) {
    if (length($s) &lt; $limit) {
      $s .= $_;
    } else {
      $t .= $_;
    }
  }

  # Tidy up
  $s =~ s/\s+$//;
  $t =~ s/\s+$//;
  return ($s,$t);
}

=back

=end __PRIVATE__

=head1 NOTES

Compatible with C&lt;latex2e&gt; only. Can not be used with C&lt;latex&gt; v2.09
or earlier.

A subclass of C&lt;Pod::Select&gt; so that specific pod sections can be
converted to C&lt;latex&gt; by using the C&lt;select&gt; method.

Some HTML escapes are missing and many have not been tested.

=head1 SEE ALSO

L&lt;Pod::Parser&gt;, L&lt;Pod::Select&gt;, L&lt;pod2latex&gt;, L&lt;Pod::Simple&gt;.

=head1 AUTHORS

Tim Jenness E&lt;lt&gt;tjenness@cpan.orgE&lt;gt&gt;

Bug fixes and improvements have been received from: Simon Cozens
E&lt;lt&gt;simon@cozens.netE&lt;gt&gt;, Mark A. Hershberger
E&lt;lt&gt;mah@everybody.orgE&lt;gt&gt;, Marcel Grunauer
E&lt;lt&gt;marcel@codewerk.comE&lt;gt&gt;, Hugh S Myers
E&lt;lt&gt;hsmyers@sdragons.comE&lt;gt&gt;, Peter J Acklam
E&lt;lt&gt;jacklam@math.uio.noE&lt;gt&gt;, Sudhi Herle E&lt;lt&gt;sudhi@herle.netE&lt;gt&gt;,
Ariel Scolnicov E&lt;lt&gt;ariels@compugen.co.ilE&lt;gt&gt;,
Adriano Rodrigues Ferreira E&lt;lt&gt;ferreira@triang.com.brE&lt;gt&gt;,
R. de Vries E&lt;lt&gt;r.de.vries@dutchspace.nlE&lt;gt&gt; and
Dave Mitchell E&lt;lt&gt;davem@iabyn.comE&lt;gt&gt;.

=head1 COPYRIGHT

Copyright (C) 2011 Tim Jenness.
Copyright (C) 2000-2004 Tim Jenness. All Rights Reserved.

This program is free software; you can redistribute it and/or modify
it under the same terms as Perl itself.

=begin __PRIVATE__

=head1 REVISION

$Id$

=end __PRIVATE__

=cut

1;
</pre></body></html>