<html><head><meta name="color-scheme" content="light dark"></head><body><pre style="word-wrap: break-word; white-space: pre-wrap;">
require 5;
package Pod::Simple;
use strict;
use Carp ();
BEGIN           { *DEBUG = sub () {0} unless defined &amp;DEBUG }
use integer;
use Pod::Escapes 1.04 ();
use Pod::Simple::LinkSection ();
use Pod::Simple::BlackBox ();
#use utf8;

use vars qw(
  $VERSION @ISA
  @Known_formatting_codes  @Known_directives
  %Known_formatting_codes  %Known_directives
  $NL
);

@ISA = ('Pod::Simple::BlackBox');
$VERSION = '3.28';

@Known_formatting_codes = qw(I B C L E F S X Z); 
%Known_formatting_codes = map(($_=&gt;1), @Known_formatting_codes);
@Known_directives       = qw(head1 head2 head3 head4 item over back); 
%Known_directives       = map(($_=&gt;'Plain'), @Known_directives);
$NL = $/ unless defined $NL;

#-----------------------------------------------------------------------------
# Set up some constants:

BEGIN {
  if(defined &amp;ASCII)    { }
  elsif(chr(65) eq 'A') { *ASCII = sub () {1}  }
  else                  { *ASCII = sub () {''} }

  unless(defined &amp;MANY_LINES) { *MANY_LINES = sub () {20} }
  DEBUG &gt; 4 and print "MANY_LINES is ", MANY_LINES(), "\n";
  unless(MANY_LINES() &gt;= 1) {
    die "MANY_LINES is too small (", MANY_LINES(), ")!\nAborting";
  }
  if(defined &amp;UNICODE) { }
  elsif($] &gt;= 5.008)   { *UNICODE = sub() {1}  }
  else                 { *UNICODE = sub() {''} }
}
if(DEBUG &gt; 2) {
  print "# We are ", ASCII ? '' : 'not ', "in ASCII-land\n";
  print "# We are under a Unicode-safe Perl.\n";
}

# Design note:
# This is a parser for Pod.  It is not a parser for the set of Pod-like
#  languages which happens to contain Pod -- it is just for Pod, plus possibly
#  some extensions.

# @ @ @ @ @ @ @ @ @ @ @ @ @ @ @ @ @ @ @ @ @ @ @ @ @ @ @ @ @ @ @ @ @ @ @ @ @ @
#@ @ @ @ @ @ @ @ @ @ @ @ @ @ @ @ @ @ @ @ @ @ @ @ @ @ @ @ @ @ @ @ @ @ @ @ @ @ @
#@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@

__PACKAGE__-&gt;_accessorize(
  'nbsp_for_S',        # Whether to map S&lt;...&gt;'s to \xA0 characters
  'source_filename',   # Filename of the source, for use in warnings
  'source_dead',       # Whether to consider this parser's source dead

  'output_fh',         # The filehandle we're writing to, if applicable.
                       # Used only in some derived classes.

  'hide_line_numbers', # For some dumping subclasses: whether to pointedly
                       # suppress the start_line attribute

  'line_count',        # the current line number
  'pod_para_count',    # count of pod paragraphs seen so far

  'no_whining',        # whether to suppress whining
  'no_errata_section', # whether to suppress the errata section
  'complain_stderr',   # whether to complain to stderr

  'doc_has_started',   # whether we've fired the open-Document event yet

  'bare_output',       # For some subclasses: whether to prepend
                       #  header-code and postpend footer-code

  'keep_encoding_directive',  # whether to emit =encoding
  'nix_X_codes',       # whether to ignore X&lt;...&gt; codes
  'merge_text',        # whether to avoid breaking a single piece of
                       #  text up into several events

  'preserve_whitespace', # whether to try to keep whitespace as-is
  'strip_verbatim_indent', # What indent to strip from verbatim

  'parse_characters',  # Whether parser should expect chars rather than octets

 'content_seen',      # whether we've seen any real Pod content
 'errors_seen',       # TODO: document.  whether we've seen any errors (fatal or not)

 'codes_in_verbatim', # for PseudoPod extensions

 'code_handler',      # coderef to call when a code (non-pod) line is seen
 'cut_handler',       # ... when a =cut line is seen
 'pod_handler',       # ... when a =pod line is seen
 'whiteline_handler', # ... when a line with only whitespace is seen
 #Called like:
 # $code_handler-&gt;($line, $self-&gt;{'line_count'}, $self) if $code_handler;
 #  $cut_handler-&gt;($line, $self-&gt;{'line_count'}, $self) if $cut_handler;
 #  $pod_handler-&gt;($line, $self-&gt;{'line_count'}, $self) if $pod_handler;
 #   $wl_handler-&gt;($line, $self-&gt;{'line_count'}, $self) if $wl_handler;
 'parse_empty_lists', # whether to acknowledge empty =over/=back blocks

);

#@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@

sub any_errata_seen {  # good for using as an exit() value...
  return shift-&gt;{'errors_seen'} || 0;
}

# Returns the encoding only if it was recognized as being handled and set
sub detected_encoding {
  return shift-&gt;{'detected_encoding'};
}

sub encoding {
  my $this = shift;
  return $this-&gt;{'encoding'} unless @_;  # GET.

  $this-&gt;_handle_encoding_line("=encoding $_[0]");
  if ($this-&gt;{'_processed_encoding'}) {
    delete $this-&gt;{'_processed_encoding'};
    if(! $this-&gt;{'encoding_command_statuses'} ) {
      DEBUG &gt; 2 and print " CRAZY ERROR: encoding wasn't really handled?!\n";
    } elsif( $this-&gt;{'encoding_command_statuses'}[-1] ) {
      $this-&gt;scream( "=encoding $_[0]",
         sprintf "Couldn't do %s: %s",
         $this-&gt;{'encoding_command_reqs'  }[-1],
         $this-&gt;{'encoding_command_statuses'}[-1],
      );
    } else {
      DEBUG &gt; 2 and print " (encoding successfully handled.)\n";
    }
    return $this-&gt;{'encoding'};
  } else {
    return undef;
  }
}

#@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@
# Pull in some functions that, for some reason, I expect to see here too:
BEGIN {
  *pretty        = \&amp;Pod::Simple::BlackBox::pretty;
  *stringify_lol = \&amp;Pod::Simple::BlackBox::stringify_lol;
}

#@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@

sub version_report {
  my $class = ref($_[0]) || $_[0];
  if($class eq __PACKAGE__) {
    return "$class $VERSION";
  } else {
    my $v = $class-&gt;VERSION;
    return "$class $v (" . __PACKAGE__ . " $VERSION)";
  }
}

#@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@

#sub curr_open { # read-only list accessor
#  return @{ $_[0]{'curr_open'} || return() };
#}
#sub _curr_open_listref { $_[0]{'curr_open'} ||= [] }


sub output_string {
  # Works by faking out output_fh.  Simplifies our code.
  #
  my $this = shift;
  return $this-&gt;{'output_string'} unless @_;  # GET.
  
  require Pod::Simple::TiedOutFH;
  my $x = (defined($_[0]) and ref($_[0])) ? $_[0] : \( $_[0] );
  $$x = '' unless defined $$x;
  DEBUG &gt; 4 and print "# Output string set to $x ($$x)\n";
  $this-&gt;{'output_fh'} = Pod::Simple::TiedOutFH-&gt;handle_on($_[0]);
  return
    $this-&gt;{'output_string'} = $_[0];
    #${ ${ $this-&gt;{'output_fh'} } };
}

sub abandon_output_string { $_[0]-&gt;abandon_output_fh; delete $_[0]{'output_string'} }
sub abandon_output_fh     { $_[0]-&gt;output_fh(undef) }
# These don't delete the string or close the FH -- they just delete our
#  references to it/them.
# TODO: document these

#@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@

sub new {
  # takes no parameters
  my $class = ref($_[0]) || $_[0];
  #Carp::croak(__PACKAGE__ . " is a virtual base class -- see perldoc "
  #  . __PACKAGE__ );
  return bless {
    'accept_codes'      =&gt; { map( ($_=&gt;$_), @Known_formatting_codes ) },
    'accept_directives' =&gt; { %Known_directives },
    'accept_targets'    =&gt; {},
  }, $class;
}



# TODO: an option for whether to interpolate E&lt;...&gt;'s, or just resolve to codes.

#@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@

sub _handle_element_start {     # OVERRIDE IN DERIVED CLASS
  my($self, $element_name, $attr_hash_r) = @_;
  return;
}

sub _handle_element_end {       # OVERRIDE IN DERIVED CLASS
  my($self, $element_name) = @_;
  return;
}

sub _handle_text          {     # OVERRIDE IN DERIVED CLASS
  my($self, $text) = @_;
  return;
}

#@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@
#
# And now directives (not targets)

sub accept_directive_as_verbatim  { shift-&gt;_accept_directives('Verbatim', @_) }
sub accept_directive_as_data      { shift-&gt;_accept_directives('Data',     @_) }
sub accept_directive_as_processed { shift-&gt;_accept_directives('Plain',    @_) }

sub _accept_directives {
  my($this, $type) = splice @_,0,2;
  foreach my $d (@_) {
    next unless defined $d and length $d;
    Carp::croak "\"$d\" isn't a valid directive name"
     unless $d =~ m/^[a-zA-Z][a-zA-Z0-9]*$/s;
    Carp::croak "\"$d\" is already a reserved Pod directive name"
     if exists $Known_directives{$d};
    $this-&gt;{'accept_directives'}{$d} = $type;
    DEBUG &gt; 2 and print "Learning to accept \"=$d\" as directive of type $type\n";
  }
  DEBUG &gt; 6 and print "$this\'s accept_directives : ",
   pretty($this-&gt;{'accept_directives'}), "\n";
  
  return sort keys %{ $this-&gt;{'accept_directives'} } if wantarray;
  return;
}

#--------------------------------------------------------------------------
# TODO: document these:

sub unaccept_directive { shift-&gt;unaccept_directives(@_) };

sub unaccept_directives {
  my $this = shift;
  foreach my $d (@_) {
    next unless defined $d and length $d;
    Carp::croak "\"$d\" isn't a valid directive name"
     unless $d =~ m/^[a-zA-Z][a-zA-Z0-9]*$/s;
    Carp::croak "But you must accept \"$d\" directives -- it's a builtin!"
     if exists $Known_directives{$d};
    delete $this-&gt;{'accept_directives'}{$d};
    DEBUG &gt; 2 and print "OK, won't accept \"=$d\" as directive.\n";
  }
  return sort keys %{ $this-&gt;{'accept_directives'} } if wantarray;
  return
}

#@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@
#
# And now targets (not directives)

sub accept_target         { shift-&gt;accept_targets(@_)         } # alias
sub accept_target_as_text { shift-&gt;accept_targets_as_text(@_) } # alias


sub accept_targets         { shift-&gt;_accept_targets('1', @_) }

sub accept_targets_as_text { shift-&gt;_accept_targets('force_resolve', @_) }
 # forces them to be processed, even when there's no ":".

sub _accept_targets {
  my($this, $type) = splice @_,0,2;
  foreach my $t (@_) {
    next unless defined $t and length $t;
    # TODO: enforce some limitations on what a target name can be?
    $this-&gt;{'accept_targets'}{$t} = $type;
    DEBUG &gt; 2 and print "Learning to accept \"$t\" as target of type $type\n";
  }    
  return sort keys %{ $this-&gt;{'accept_targets'} } if wantarray;
  return;
}

#--------------------------------------------------------------------------
sub unaccept_target         { shift-&gt;unaccept_targets(@_) }

sub unaccept_targets {
  my $this = shift;
  foreach my $t (@_) {
    next unless defined $t and length $t;
    # TODO: enforce some limitations on what a target name can be?
    delete $this-&gt;{'accept_targets'}{$t};
    DEBUG &gt; 2 and print "OK, won't accept \"$t\" as target.\n";
  }    
  return sort keys %{ $this-&gt;{'accept_targets'} } if wantarray;
  return;
}

#@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@
#
# And now codes (not targets or directives)

sub accept_code { shift-&gt;accept_codes(@_) } # alias

sub accept_codes {  # Add some codes
  my $this = shift;
  
  foreach my $new_code (@_) {
    next unless defined $new_code and length $new_code;
    if(ASCII) {
      # A good-enough check that it's good as an XML Name symbol:
      Carp::croak "\"$new_code\" isn't a valid element name"
        if $new_code =~
          m/[\x00-\x2C\x2F\x39\x3B-\x40\x5B-\x5E\x60\x7B-\x7F]/
            # Characters under 0x80 that aren't legal in an XML Name.
        or $new_code =~ m/^[-\.0-9]/s
        or $new_code =~ m/:[-\.0-9]/s;
            # The legal under-0x80 Name characters that 
            #  an XML Name still can't start with.
    }
    
    $this-&gt;{'accept_codes'}{$new_code} = $new_code;
    
    # Yes, map to itself -- just so that when we
    #  see "=extend W [whatever] thatelementname", we say that W maps
    #  to whatever $this-&gt;{accept_codes}{thatelementname} is,
    #  i.e., "thatelementname".  Then when we go re-mapping,
    #  a "W" in the treelet turns into "thatelementname".  We only
    #  remap once.
    # If we say we accept "W", then a "W" in the treelet simply turns
    #  into "W".
  }
  
  return;
}

#--------------------------------------------------------------------------
sub unaccept_code { shift-&gt;unaccept_codes(@_) }

sub unaccept_codes { # remove some codes
  my $this = shift;
  
  foreach my $new_code (@_) {
    next unless defined $new_code and length $new_code;
    if(ASCII) {
      # A good-enough check that it's good as an XML Name symbol:
      Carp::croak "\"$new_code\" isn't a valid element name"
        if $new_code =~
          m/[\x00-\x2C\x2F\x39\x3B-\x40\x5B-\x5E\x60\x7B-\x7F]/
            # Characters under 0x80 that aren't legal in an XML Name.
        or $new_code =~ m/^[-\.0-9]/s
        or $new_code =~ m/:[-\.0-9]/s;
            # The legal under-0x80 Name characters that 
            #  an XML Name still can't start with.
    }
    
    Carp::croak "But you must accept \"$new_code\" codes -- it's a builtin!"
     if grep $new_code eq $_, @Known_formatting_codes;

    delete $this-&gt;{'accept_codes'}{$new_code};

    DEBUG &gt; 2 and print "OK, won't accept the code $new_code&lt;...&gt;.\n";
  }
  
  return;
}


#@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@
#@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@

sub parse_string_document {
  my $self = shift;
  my @lines;
  foreach my $line_group (@_) {
    next unless defined $line_group and length $line_group;
    pos($line_group) = 0;
    while($line_group =~
      m/([^\n\r]*)(\r?\n?)/g # supports \r, \n ,\r\n
      #m/([^\n\r]*)((?:\r?\n)?)/g
    ) {
      #print("&gt;&gt; $1\n"),
      $self-&gt;parse_lines($1)
       if length($1) or length($2)
        or pos($line_group) != length($line_group);
       # I.e., unless it's a zero-length "empty line" at the very
       #  end of "foo\nbar\n" (i.e., between the \n and the EOS).
    }
  }
  $self-&gt;parse_lines(undef); # to signal EOF
  return $self;
}

sub _init_fh_source {
  my($self, $source) = @_;

  #DEBUG &gt; 1 and print "Declaring $source as :raw for starters\n";
  #$self-&gt;_apply_binmode($source, ':raw');
  #binmode($source, ":raw");

  return;
}

#:.:.:.:.:.:.:.:.:.:.:.:.:.:.:.:.:.:.:.:.:.:.:.:.:.:.:.:.:.:.:.:.:.:.:.:.:.:.
#

sub parse_file {
  my($self, $source) = (@_);

  if(!defined $source) {
    Carp::croak("Can't use empty-string as a source for parse_file");
  } elsif(ref(\$source) eq 'GLOB') {
    $self-&gt;{'source_filename'} = '' . ($source);
  } elsif(ref $source) {
    $self-&gt;{'source_filename'} = '' . ($source);
  } elsif(!length $source) {
    Carp::croak("Can't use empty-string as a source for parse_file");
  } else {
    {
      local *PODSOURCE;
      open(PODSOURCE, "&lt;$source") || Carp::croak("Can't open $source: $!");
      $self-&gt;{'source_filename'} = $source;
      $source = *PODSOURCE{IO};
    }
    $self-&gt;_init_fh_source($source);
  }
  # By here, $source is a FH.

  $self-&gt;{'source_fh'} = $source;

  my($i, @lines);
  until( $self-&gt;{'source_dead'} ) {
    splice @lines;

    for($i = MANY_LINES; $i--;) {  # read those many lines at a time
      local $/ = $NL;
      push @lines, scalar(&lt;$source&gt;);  # readline
      last unless defined $lines[-1];
       # but pass thru the undef, which will set source_dead to true
    }

    my $at_eof = ! $lines[-1]; # keep track of the undef
    pop @lines if $at_eof; # silence warnings

    # be eol agnostic
    s/\r\n?/\n/g for @lines;
 
    # make sure there are only one line elements for parse_lines
    @lines = split(/(?&lt;=\n)/, join('', @lines));

    # push the undef back after popping it to set source_dead to true
    push @lines, undef if $at_eof;

    $self-&gt;parse_lines(@lines);
  }
  delete($self-&gt;{'source_fh'}); # so it can be GC'd
  return $self;
}

#:.:.:.:.:.:.:.:.:.:.:.:.:.:.:.:.:.:.:.:.:.:.:.:.:.:.:.:.:.:.:.:.:.:.:.:.:.:.

sub parse_from_file {
  # An emulation of Pod::Parser's interface, for the sake of Perldoc.
  # Basically just a wrapper around parse_file.

  my($self, $source, $to) = @_;
  $self = $self-&gt;new unless ref($self); # so we tolerate being a class method
  
  if(!defined $source)             { $source = *STDIN{IO}
  } elsif(ref(\$source) eq 'GLOB') { # stet
  } elsif(ref($source)           ) { # stet
  } elsif(!length $source
     or $source eq '-' or $source =~ m/^&lt;&amp;(STDIN|0)$/i
  ) { 
    $source = *STDIN{IO};
  }

  if(!defined $to) {             $self-&gt;output_fh( *STDOUT{IO}   );
  } elsif(ref(\$to) eq 'GLOB') { $self-&gt;output_fh( $to );
  } elsif(ref($to)) {            $self-&gt;output_fh( $to );
  } elsif(!length $to
     or $to eq '-' or $to =~ m/^&gt;&amp;?(?:STDOUT|1)$/i
  ) {
    $self-&gt;output_fh( *STDOUT{IO} );
  } else {
    require Symbol;
    my $out_fh = Symbol::gensym();
    DEBUG and print "Write-opening to $to\n";
    open($out_fh, "&gt;$to")  or  Carp::croak "Can't write-open $to: $!";
    binmode($out_fh)
     if $self-&gt;can('write_with_binmode') and $self-&gt;write_with_binmode;
    $self-&gt;output_fh($out_fh);
  }

  return $self-&gt;parse_file($source);
}

#-----------------------------------------------------------------------------

sub whine {
  #my($self,$line,$complaint) = @_;
  my $self = shift(@_);
  ++$self-&gt;{'errors_seen'};
  if($self-&gt;{'no_whining'}) {
    DEBUG &gt; 9 and print "Discarding complaint (at line $_[0]) $_[1]\n because no_whining is on.\n";
    return;
  }
  return $self-&gt;_complain_warn(@_) if $self-&gt;{'complain_stderr'};
  return $self-&gt;_complain_errata(@_);
}

sub scream {    # like whine, but not suppressible
  #my($self,$line,$complaint) = @_;
  my $self = shift(@_);
  ++$self-&gt;{'errors_seen'};
  return $self-&gt;_complain_warn(@_) if $self-&gt;{'complain_stderr'};
  return $self-&gt;_complain_errata(@_);
}

sub _complain_warn {
  my($self,$line,$complaint) = @_;
  return printf STDERR "%s around line %s: %s\n",
    $self-&gt;{'source_filename'} || 'Pod input', $line, $complaint;
}

sub _complain_errata {
  my($self,$line,$complaint) = @_;
  if( $self-&gt;{'no_errata_section'} ) {
    DEBUG &gt; 9 and print "Discarding erratum (at line $line) $complaint\n because no_errata_section is on.\n";
  } else {
    DEBUG &gt; 9 and print "Queuing erratum (at line $line) $complaint\n";
    push @{$self-&gt;{'errata'}{$line}}, $complaint
      # for a report to be generated later!
  }
  return 1;
}

#@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@

sub _get_initial_item_type {
  # A hack-wrapper here for when you have like "=over\n\n=item 456\n\n"
  my($self, $para) = @_;
  return $para-&gt;[1]{'~type'}  if $para-&gt;[1]{'~type'};

  return $para-&gt;[1]{'~type'} = 'text'
   if join("\n", @{$para}[2 .. $#$para]) =~ m/^\s*(\d+)\.?\s*$/s and $1 ne '1';
  # Else fall thru to the general case:
  return $self-&gt;_get_item_type($para);
}



sub _get_item_type {       # mutates the item!!
  my($self, $para) = @_;
  return $para-&gt;[1]{'~type'} if $para-&gt;[1]{'~type'};


  # Otherwise we haven't yet been to this node.  Maybe alter it...
  
  my $content = join "\n", @{$para}[2 .. $#$para];

  if($content =~ m/^\s*\*\s*$/s or $content =~ m/^\s*$/s) {
    # Like: "=item *", "=item   *   ", "=item"
    splice @$para, 2; # so it ends up just being ['=item', { attrhash } ]
    $para-&gt;[1]{'~orig_content'} = $content;
    return $para-&gt;[1]{'~type'} = 'bullet';

  } elsif($content =~ m/^\s*\*\s+(.+)/s) {  # tolerance
  
    # Like: "=item * Foo bar baz";
    $para-&gt;[1]{'~orig_content'}      = $content;
    $para-&gt;[1]{'~_freaky_para_hack'} = $1;
    DEBUG &gt; 2 and print " Tolerating $$para[2] as =item *\\n\\n$1\n";
    splice @$para, 2; # so it ends up just being ['=item', { attrhash } ]
    return $para-&gt;[1]{'~type'} = 'bullet';

  } elsif($content =~ m/^\s*(\d+)\.?\s*$/s) {
    # Like: "=item 1.", "=item    123412"
    
    $para-&gt;[1]{'~orig_content'} = $content;
    $para-&gt;[1]{'number'} = $1;  # Yes, stores the number there!

    splice @$para, 2; # so it ends up just being ['=item', { attrhash } ]
    return $para-&gt;[1]{'~type'} = 'number';
    
  } else {
    # It's anything else.
    return $para-&gt;[1]{'~type'} = 'text';

  }
}

#-----------------------------------------------------------------------------

sub _make_treelet {
  my $self = shift;  # and ($para, $start_line)
  my $treelet;
  if(!@_) {
    return [''];
  } if(ref $_[0] and ref $_[0][0] and $_[0][0][0] eq '~Top') {
    # Hack so we can pass in fake-o pre-cooked paragraphs:
    #  just have the first line be a reference to a ['~Top', {}, ...]
    # We use this feechure in gen_errata and stuff.

    DEBUG and print "Applying precooked treelet hack to $_[0][0]\n";
    $treelet = $_[0][0];
    splice @$treelet, 0, 2;  # lop the top off
    return $treelet;
  } else {
    $treelet = $self-&gt;_treelet_from_formatting_codes(@_);
  }
  
  if( $self-&gt;_remap_sequences($treelet) ) {
    $self-&gt;_treat_Zs($treelet);  # Might as well nix these first
    $self-&gt;_treat_Ls($treelet);  # L has to precede E and S
    $self-&gt;_treat_Es($treelet);
    $self-&gt;_treat_Ss($treelet);  # S has to come after E

    $self-&gt;_wrap_up($treelet); # Nix X's and merge texties
    
  } else {
    DEBUG and print "Formatless treelet gets fast-tracked.\n";
     # Very common case!
  }
  
  splice @$treelet, 0, 2;  # lop the top off

  return $treelet;
}

#:.:.:.:.:.:.:.:.:.:.:.:.:.:.:.:.:.:.:.:.:.:.:.:.:.:.:.:.:.:.:.:.:.:.:.:.:.:.

sub _wrap_up {
  my($self, @stack) = @_;
  my $nixx  = $self-&gt;{'nix_X_codes'};
  my $merge = $self-&gt;{'merge_text' };
  return unless $nixx or $merge;

  DEBUG &gt; 2 and print "\nStarting _wrap_up traversal.\n",
   $merge ? (" Merge mode on\n") : (),
   $nixx  ? (" Nix-X mode on\n") : (),
  ;    
  

  my($i, $treelet);
  while($treelet = shift @stack) {
    DEBUG &gt; 3 and print " Considering children of this $treelet-&gt;[0] node...\n";
    for($i = 2; $i &lt; @$treelet; ++$i) { # iterate over children
      DEBUG &gt; 3 and print " Considering child at $i ", pretty($treelet-&gt;[$i]), "\n";
      if($nixx and ref $treelet-&gt;[$i] and $treelet-&gt;[$i][0] eq 'X') {
        DEBUG &gt; 3 and print "   Nixing X node at $i\n";
        splice(@$treelet, $i, 1); # just nix this node (and its descendants)
        # no need to back-update the counter just yet
        redo;

      } elsif($merge and $i != 2 and  # non-initial
         !ref $treelet-&gt;[$i] and !ref $treelet-&gt;[$i - 1]
      ) {
        DEBUG &gt; 3 and print "   Merging ", $i-1,
         ":[$treelet-&gt;[$i-1]] and $i\:[$treelet-&gt;[$i]]\n";
        $treelet-&gt;[$i-1] .= ( splice(@$treelet, $i, 1) )[0];
        DEBUG &gt; 4 and print "    Now: ", $i-1, ":[$treelet-&gt;[$i-1]]\n";
        --$i;
        next; 
        # since we just pulled the possibly last node out from under
        #  ourselves, we can't just redo()

      } elsif( ref $treelet-&gt;[$i] ) {
        DEBUG &gt; 4 and print "  Enqueuing ", pretty($treelet-&gt;[$i]), " for traversal.\n";
        push @stack, $treelet-&gt;[$i];

        if($treelet-&gt;[$i][0] eq 'L') {
          my $thing;
          foreach my $attrname ('section', 'to') {        
            if(defined($thing = $treelet-&gt;[$i][1]{$attrname}) and ref $thing) {
              unshift @stack, $thing;
              DEBUG &gt; 4 and print "  +Enqueuing ",
               pretty( $treelet-&gt;[$i][1]{$attrname} ),
               " as an attribute value to tweak.\n";
            }
          }
        }
      }
    }
  }
  DEBUG &gt; 2 and print "End of _wrap_up traversal.\n\n";

  return;
}

#:.:.:.:.:.:.:.:.:.:.:.:.:.:.:.:.:.:.:.:.:.:.:.:.:.:.:.:.:.:.:.:.:.:.:.:.:.:.

sub _remap_sequences {
  my($self,@stack) = @_;
  
  if(@stack == 1 and @{ $stack[0] } == 3 and !ref $stack[0][2]) {
    # VERY common case: abort it.
    DEBUG and print "Skipping _remap_sequences: formatless treelet.\n";
    return 0;
  }
  
  my $map = ($self-&gt;{'accept_codes'} || die "NO accept_codes in $self?!?");

  my $start_line = $stack[0][1]{'start_line'};
  DEBUG &gt; 2 and printf
   "\nAbout to start _remap_sequences on treelet from line %s.\n",
   $start_line || '[?]'
  ;
  DEBUG &gt; 3 and print " Map: ",
    join('; ', map "$_=" . (
        ref($map-&gt;{$_}) ? join(",", @{$map-&gt;{$_}}) : $map-&gt;{$_}
      ),
      sort keys %$map ),
    ("B~C~E~F~I~L~S~X~Z" eq join '~', sort keys %$map)
     ? "  (all normal)\n" : "\n"
  ;

  # A recursive algorithm implemented iteratively!  Whee!
  
  my($is, $was, $i, $treelet); # scratch
  while($treelet = shift @stack) {
    DEBUG &gt; 3 and print " Considering children of this $treelet-&gt;[0] node...\n";
    for($i = 2; $i &lt; @$treelet; ++$i) { # iterate over children
      next unless ref $treelet-&gt;[$i];  # text nodes are uninteresting
      
      DEBUG &gt; 4 and print "  Noting child $i : $treelet-&gt;[$i][0]&lt;...&gt;\n";
      
      $is = $treelet-&gt;[$i][0] = $map-&gt;{ $was = $treelet-&gt;[$i][0] };
      if( DEBUG &gt; 3 ) {
        if(!defined $is) {
          print "   Code $was&lt;&gt; is UNKNOWN!\n";
        } elsif($is eq $was) {
          DEBUG &gt; 4 and print "   Code $was&lt;&gt; stays the same.\n";
        } else  {
          print "   Code $was&lt;&gt; maps to ",
           ref($is)
            ? ( "tags ", map("$_&lt;", @$is), '...', map('&gt;', @$is), "\n" )
            : "tag $is&lt;...&gt;.\n";
        }
      }
      
      if(!defined $is) {
        $self-&gt;whine($start_line, "Deleting unknown formatting code $was&lt;&gt;");
        $is = $treelet-&gt;[$i][0] = '1';  # But saving the children!
        # I could also insert a leading "$was&lt;" and tailing "&gt;" as
        # children of this node, but something about that seems icky.
      }
      if(ref $is) {
        my @dynasty = @$is;
        DEBUG &gt; 4 and print "    Renaming $was node to $dynasty[-1]\n"; 
        $treelet-&gt;[$i][0] = pop @dynasty;
        my $nugget;
        while(@dynasty) {
          DEBUG &gt; 4 and printf
           "    Grafting a new %s node between %s and %s\n",
           $dynasty[-1], $treelet-&gt;[0], $treelet-&gt;[$i][0], 
          ;
          
          #$nugget = ;
          splice @$treelet, $i, 1, [pop(@dynasty), {}, $treelet-&gt;[$i]];
            # relace node with a new parent
        }
      } elsif($is eq '0') {
        splice(@$treelet, $i, 1); # just nix this node (and its descendants)
        --$i;  # back-update the counter
      } elsif($is eq '1') {
        splice(@$treelet, $i, 1 # replace this node with its children!
          =&gt; splice @{ $treelet-&gt;[$i] },2
              # (not catching its first two (non-child) items)
        );
        --$i;  # back up for new stuff
      } else {
        # otherwise it's unremarkable
        unshift @stack, $treelet-&gt;[$i];  # just recurse
      }
    }
  }
  
  DEBUG &gt; 2 and print "End of _remap_sequences traversal.\n\n";

  if(@_ == 2 and @{ $_[1] } == 3 and !ref $_[1][2]) {
    DEBUG and print "Noting that the treelet is now formatless.\n";
    return 0;
  }
  return 1;
}

# . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . .

sub _ponder_extend {

  # "Go to an extreme, move back to a more comfortable place"
  #  -- /Oblique Strategies/,  Brian Eno and Peter Schmidt
  
  my($self, $para) = @_;
  my $content = join ' ', splice @$para, 2;
  $content =~ s/^\s+//s;
  $content =~ s/\s+$//s;

  DEBUG &gt; 2 and print "Ogling extensor: =extend $content\n";

  if($content =~
    m/^
      (\S+)         # 1 : new item
      \s+
      (\S+)         # 2 : fallback(s)
      (?:\s+(\S+))? # 3 : element name(s)
      \s*
      $
    /xs
  ) {
    my $new_letter = $1;
    my $fallbacks_one = $2;
    my $elements_one;
    $elements_one = defined($3) ? $3 : $1;

    DEBUG &gt; 2 and print "Extensor has good syntax.\n";

    unless($new_letter =~ m/^[A-Z]$/s or $new_letter) {
      DEBUG &gt; 2 and print " $new_letter isn't a valid thing to entend.\n";
      $self-&gt;whine(
        $para-&gt;[1]{'start_line'},
        "You can extend only formatting codes A-Z, not like \"$new_letter\""
      );
      return;
    }
    
    if(grep $new_letter eq $_, @Known_formatting_codes) {
      DEBUG &gt; 2 and print " $new_letter isn't a good thing to extend, because known.\n";
      $self-&gt;whine(
        $para-&gt;[1]{'start_line'},
        "You can't extend an established code like \"$new_letter\""
      );
      
      #TODO: or allow if last bit is same?
      
      return;
    }

    unless($fallbacks_one =~ m/^[A-Z](,[A-Z])*$/s  # like "B", "M,I", etc.
      or $fallbacks_one eq '0' or $fallbacks_one eq '1'
    ) {
      $self-&gt;whine(
        $para-&gt;[1]{'start_line'},
        "Format for second =extend parameter must be like"
        . " M or 1 or 0 or M,N or M,N,O but you have it like "
        . $fallbacks_one
      );
      return;
    }
    
    unless($elements_one =~ m/^[^ ,]+(,[^ ,]+)*$/s) { # like "B", "M,I", etc.
      $self-&gt;whine(
        $para-&gt;[1]{'start_line'},
        "Format for third =extend parameter: like foo or bar,Baz,qu:ux but not like "
        . $elements_one
      );
      return;
    }

    my @fallbacks  = split ',', $fallbacks_one,  -1;
    my @elements   = split ',', $elements_one, -1;

    foreach my $f (@fallbacks) {
      next if exists $Known_formatting_codes{$f} or $f eq '0' or $f eq '1';
      DEBUG &gt; 2 and print "  Can't fall back on unknown code $f\n";
      $self-&gt;whine(
        $para-&gt;[1]{'start_line'},
        "Can't use unknown formatting code '$f' as a fallback for '$new_letter'"
      );
      return;
    }

    DEBUG &gt; 3 and printf "Extensor: Fallbacks &lt;%s&gt; Elements &lt;%s&gt;.\n",
     @fallbacks, @elements;

    my $canonical_form;
    foreach my $e (@elements) {
      if(exists $self-&gt;{'accept_codes'}{$e}) {
        DEBUG &gt; 1 and print " Mapping '$new_letter' to known extension '$e'\n";
        $canonical_form = $e;
        last; # first acceptable elementname wins!
      } else {
        DEBUG &gt; 1 and print " Can't map '$new_letter' to unknown extension '$e'\n";
      }
    }


    if( defined $canonical_form ) {
      # We found a good N =&gt; elementname mapping
      $self-&gt;{'accept_codes'}{$new_letter} = $canonical_form;
      DEBUG &gt; 2 and print
       "Extensor maps $new_letter =&gt; known element $canonical_form.\n";
    } else {
      # We have to use the fallback(s), which might be '0', or '1'.
      $self-&gt;{'accept_codes'}{$new_letter}
        = (@fallbacks == 1) ? $fallbacks[0] : \@fallbacks;
      DEBUG &gt; 2 and print
       "Extensor maps $new_letter =&gt; fallbacks @fallbacks.\n";
    }

  } else {
    DEBUG &gt; 2 and print "Extensor has bad syntax.\n";
    $self-&gt;whine(
      $para-&gt;[1]{'start_line'},
      "Unknown =extend syntax: $content"
    )
  }
  return;
}


#:.:.:.:.:.:.:.:.:.:.:.:.:.:.:.:.:.:.:.:.:.:.:.:.:.:.:.:.:.:.:.:.:.:.:.:.:.:.

sub _treat_Zs {  # Nix Z&lt;...&gt;'s
  my($self,@stack) = @_;

  my($i, $treelet);
  my $start_line = $stack[0][1]{'start_line'};

  # A recursive algorithm implemented iteratively!  Whee!

  while($treelet = shift @stack) {
    for($i = 2; $i &lt; @$treelet; ++$i) { # iterate over children
      next unless ref $treelet-&gt;[$i];  # text nodes are uninteresting
      unless($treelet-&gt;[$i][0] eq 'Z') {
        unshift @stack, $treelet-&gt;[$i]; # recurse
        next;
      }
        
      DEBUG &gt; 1 and print "Nixing Z node @{$treelet-&gt;[$i]}\n";
        
      # bitch UNLESS it's empty
      unless(  @{$treelet-&gt;[$i]} == 2
           or (@{$treelet-&gt;[$i]} == 3 and $treelet-&gt;[$i][2] eq '')
      ) {
        $self-&gt;whine( $start_line, "A non-empty Z&lt;&gt;" );
      }      # but kill it anyway
        
      splice(@$treelet, $i, 1); # thereby just nix this node.
      --$i;
        
    }
  }
  
  return;
}

# . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . .

# Quoting perlpodspec:

# In parsing an L&lt;...&gt; code, Pod parsers must distinguish at least four
# attributes:

############# Not used.  Expressed via the element children plus
#############  the value of the "content-implicit" flag.
# First:
# The link-text. If there is none, this must be undef. (E.g., in "L&lt;Perl
# Functions|perlfunc&gt;", the link-text is "Perl Functions". In
# "L&lt;Time::HiRes&gt;" and even "L&lt;|Time::HiRes&gt;", there is no link text. Note
# that link text may contain formatting.)
# 

############# The element children
# Second:
# The possibly inferred link-text -- i.e., if there was no real link text,
# then this is the text that we'll infer in its place. (E.g., for
# "L&lt;Getopt::Std&gt;", the inferred link text is "Getopt::Std".)
#

############# The "to" attribute (which might be text, or a treelet)
# Third:
# The name or URL, or undef if none. (E.g., in "L&lt;Perl
# Functions|perlfunc&gt;", the name -- also sometimes called the page -- is
# "perlfunc". In "L&lt;/CAVEATS&gt;", the name is undef.)
# 

############# The "section" attribute (which might be next, or a treelet)
# Fourth:
# The section (AKA "item" in older perlpods), or undef if none. E.g., in
# Getopt::Std/DESCRIPTION, "DESCRIPTION" is the section. (Note that this
# is not the same as a manpage section like the "5" in "man 5 crontab".
# "Section Foo" in the Pod sense means the part of the text that's
# introduced by the heading or item whose text is "Foo".)
# 
# Pod parsers may also note additional attributes including:
#

############# The "type" attribute.
# Fifth:
# A flag for whether item 3 (if present) is a URL (like
# "http://lists.perl.org" is), in which case there should be no section
# attribute; a Pod name (like "perldoc" and "Getopt::Std" are); or
# possibly a man page name (like "crontab(5)" is).
#

############# The "raw" attribute that is already there.
# Sixth:
# The raw original L&lt;...&gt; content, before text is split on "|", "/", etc,
# and before E&lt;...&gt; codes are expanded.


# For L&lt;...&gt; codes without a "name|" part, only E&lt;...&gt; and Z&lt;&gt; codes may
# occur -- no other formatting codes. That is, authors should not use
# "L&lt;B&lt;Foo::Bar&gt;&gt;".
#
# Note, however, that formatting codes and Z&lt;&gt;'s can occur in any and all
# parts of an L&lt;...&gt; (i.e., in name, section, text, and url).

sub _treat_Ls {  # Process our dear dear friends, the L&lt;...&gt; sequences

  # L&lt;name&gt;
  # L&lt;name/"sec"&gt; or L&lt;name/sec&gt;
  # L&lt;/"sec"&gt; or L&lt;/sec&gt; or L&lt;"sec"&gt;
  # L&lt;text|name&gt;
  # L&lt;text|name/"sec"&gt; or L&lt;text|name/sec&gt;
  # L&lt;text|/"sec"&gt; or L&lt;text|/sec&gt; or L&lt;text|"sec"&gt;
  # L&lt;scheme:...&gt;
  # L&lt;text|scheme:...&gt;

  my($self,@stack) = @_;

  my($i, $treelet);
  my $start_line = $stack[0][1]{'start_line'};

  # A recursive algorithm implemented iteratively!  Whee!

  while($treelet = shift @stack) {
    for(my $i = 2; $i &lt; @$treelet; ++$i) {
      # iterate over children of current tree node
      next unless ref $treelet-&gt;[$i];  # text nodes are uninteresting
      unless($treelet-&gt;[$i][0] eq 'L') {
        unshift @stack, $treelet-&gt;[$i]; # recurse
        next;
      }
      
      
      # By here, $treelet-&gt;[$i] is definitely an L node
      my $ell = $treelet-&gt;[$i];
      DEBUG &gt; 1 and print "Ogling L node $ell\n";
        
      # bitch if it's empty
      if(  @{$ell} == 2
       or (@{$ell} == 3 and $ell-&gt;[2] eq '')
      ) {
        $self-&gt;whine( $start_line, "An empty L&lt;&gt;" );
        $treelet-&gt;[$i] = 'L&lt;&gt;';  # just make it a text node
        next;  # and move on
      }

      if( (! ref $ell-&gt;[2]  &amp;&amp; $ell-&gt;[2] =~ /\A\s/)
        ||(! ref $ell-&gt;[-1] &amp;&amp; $ell-&gt;[-1] =~ /\s\z/)
      ) {
        $self-&gt;whine( $start_line, "L&lt;&gt; starts or ends with whitespace" );
      }
     
      # Catch URLs:

      # there are a number of possible cases:
      # 1) text node containing url: http://foo.com
      #   -&gt; [ 'http://foo.com' ]
      # 2) text node containing url and text: foo|http://foo.com
      #   -&gt; [ 'foo|http://foo.com' ]
      # 3) text node containing url start: mailto:xE&lt;at&gt;foo.com
      #   -&gt; [ 'mailto:x', [ E ... ], 'foo.com' ]
      # 4) text node containing url start and text: foo|mailto:xE&lt;at&gt;foo.com
      #   -&gt; [ 'foo|mailto:x', [ E ... ], 'foo.com' ]
      # 5) other nodes containing text and url start: OE&lt;39&gt;Malley|http://foo.com
      #   -&gt; [ 'O', [ E ... ], 'Malley', '|http://foo.com' ]
      # ... etc.

      # anything before the url is part of the text.
      # anything after it is part of the url.
      # the url text node itself may contain parts of both.

      if (my ($url_index, $text_part, $url_part) =
        # grep is no good here; we want to bail out immediately so that we can
        # use $1, $2, etc. without having to do the match twice.
        sub {
          for (2..$#$ell) {
            next if ref $ell-&gt;[$_];
            next unless $ell-&gt;[$_] =~ m/^(?:([^|]*)\|)?(\w+:[^:\s]\S*)$/s;
            return ($_, $1, $2);
          }
          return;
        }-&gt;()
      ) {
        $ell-&gt;[1]{'type'} = 'url';

        my @text = @{$ell}[2..$url_index-1];
        push @text, $text_part if defined $text_part;

        my @url  = @{$ell}[$url_index+1..$#$ell];
        unshift @url, $url_part;

        unless (@text) {
          $ell-&gt;[1]{'content-implicit'} = 'yes';
          @text = @url;
        }

        $ell-&gt;[1]{to} = Pod::Simple::LinkSection-&gt;new(
          @url == 1
          ? $url[0]
          : [ '', {}, @url ],
        );

        splice @$ell, 2, $#$ell, @text;

        next;
      }
      
      # Catch some very simple and/or common cases
      if(@{$ell} == 3 and ! ref $ell-&gt;[2]) {
        my $it = $ell-&gt;[2];
        if($it =~ m{^[^/|]+[(][-a-zA-Z0-9]+[)]$}s) { # man sections
          # Hopefully neither too broad nor too restrictive a RE
          DEBUG &gt; 1 and print "Catching \"$it\" as manpage link.\n";
          $ell-&gt;[1]{'type'} = 'man';
          # This's the only place where man links can get made.
          $ell-&gt;[1]{'content-implicit'} = 'yes';
          $ell-&gt;[1]{'to'  } =
            Pod::Simple::LinkSection-&gt;new( $it ); # treelet!

          next;
        }
        if($it =~ m/^[^\/\|,\$\%\@\ \"\&lt;\&gt;\:\#\&amp;\*\{\}\[\]\(\)]+(\:\:[^\/\|,\$\%\@\ \"\&lt;\&gt;\:\#\&amp;\*\{\}\[\]\(\)]+)*$/s) {
          # Extremely forgiving idea of what constitutes a bare
          #  modulename link like L&lt;Foo::Bar&gt; or even L&lt;Thing::1.0::Docs::Tralala&gt;
          DEBUG &gt; 1 and print "Catching \"$it\" as ho-hum L&lt;Modulename&gt; link.\n";
          $ell-&gt;[1]{'type'} = 'pod';
          $ell-&gt;[1]{'content-implicit'} = 'yes';
          $ell-&gt;[1]{'to'  } =
            Pod::Simple::LinkSection-&gt;new( $it ); # treelet!
          next;
        }
        # else fall thru...
      }
      
      

      # ...Uhoh, here's the real L&lt;...&gt; parsing stuff...
      # "With the ill behavior, with the ill behavior, with the ill behavior..."

      DEBUG &gt; 1 and print "Running a real parse on this non-trivial L\n";
      
      
      my $link_text; # set to an arrayref if found
      my @ell_content = @$ell;
      splice @ell_content,0,2; # Knock off the 'L' and {} bits

      DEBUG &gt; 3 and print " Ell content to start: ",
       pretty(@ell_content), "\n";


      # Look for the "|" -- only in CHILDREN (not all underlings!)
      # Like L&lt;I like the strictness|strict&gt;
      DEBUG &gt; 3 and
         print "  Peering at L content for a '|' ...\n";
      for(my $j = 0; $j &lt; @ell_content; ++$j) {
        next if ref $ell_content[$j];
        DEBUG &gt; 3 and
         print "    Peering at L-content text bit \"$ell_content[$j]\" for a '|'.\n";

        if($ell_content[$j] =~ m/^([^\|]*)\|(.*)$/s) {
          my @link_text = ($1);   # might be 0-length
          $ell_content[$j] = $2;  # might be 0-length

          DEBUG &gt; 3 and
           print "     FOUND a '|' in it.  Splitting into [$1] + [$2]\n";

          if ($link_text[0] =~ m{[|/]}) {
            $self-&gt;whine(
              $start_line,
              "alternative text '$link_text[0]' contains non-escaped | or /"
            );
          }

          unshift @link_text, splice @ell_content, 0, $j;
            # leaving only things at J and after
          @ell_content =  grep ref($_)||length($_), @ell_content ;
          $link_text   = [grep ref($_)||length($_), @link_text  ];
          DEBUG &gt; 3 and printf
           "  So link text is %s\n  and remaining ell content is %s\n",
            pretty($link_text), pretty(@ell_content);
          last;
        }
      }
      
      
      # Now look for the "/" -- only in CHILDREN (not all underlings!)
      # And afterward, anything left in @ell_content will be the raw name
      # Like L&lt;Foo::Bar/Object Methods&gt;
      my $section_name;  # set to arrayref if found
      DEBUG &gt; 3 and print "  Peering at L-content for a '/' ...\n";
      for(my $j = 0; $j &lt; @ell_content; ++$j) {
        next if ref $ell_content[$j];
        DEBUG &gt; 3 and
         print "    Peering at L-content text bit \"$ell_content[$j]\" for a '/'.\n";

        if($ell_content[$j] =~ m/^([^\/]*)\/(.*)$/s) {
          my @section_name = ($2); # might be 0-length
          $ell_content[$j] =  $1;  # might be 0-length

          DEBUG &gt; 3 and
           print "     FOUND a '/' in it.",
             "  Splitting to page [...$1] + section [$2...]\n";

          push @section_name, splice @ell_content, 1+$j;
            # leaving only things before and including J
          
          @ell_content  = grep ref($_)||length($_), @ell_content  ;
          @section_name = grep ref($_)||length($_), @section_name ;

          # Turn L&lt;.../"foo"&gt; into L&lt;.../foo&gt;
          if(@section_name
            and !ref($section_name[0]) and !ref($section_name[-1])
            and $section_name[ 0] =~ m/^\"/s
            and $section_name[-1] =~ m/\"$/s
            and !( # catch weird degenerate case of L&lt;"&gt; !
              @section_name == 1 and $section_name[0] eq '"'
            )
          ) {
            $section_name[ 0] =~ s/^\"//s;
            $section_name[-1] =~ s/\"$//s;
            DEBUG &gt; 3 and
             print "     Quotes removed: ", pretty(@section_name), "\n";
          } else {
            DEBUG &gt; 3 and
             print "     No need to remove quotes in ", pretty(@section_name), "\n";
          }

          $section_name = \@section_name;
          last;
        }
      }

      # Turn L&lt;"Foo Bar"&gt; into L&lt;/Foo Bar&gt;
      if(!$section_name and @ell_content
         and !ref($ell_content[0]) and !ref($ell_content[-1])
         and $ell_content[ 0] =~ m/^\"/s
         and $ell_content[-1] =~ m/\"$/s
         and !( # catch weird degenerate case of L&lt;"&gt; !
           @ell_content == 1 and $ell_content[0] eq '"'
         )
      ) {
        $section_name = [splice @ell_content];
        $section_name-&gt;[ 0] =~ s/^\"//s;
        $section_name-&gt;[-1] =~ s/\"$//s;
      }

      # Turn L&lt;Foo Bar&gt; into L&lt;/Foo Bar&gt;.
      if(!$section_name and !$link_text and @ell_content
         and grep !ref($_) &amp;&amp; m/ /s, @ell_content
      ) {
        $section_name = [splice @ell_content];
        # That's support for the now-deprecated syntax.
        # (Maybe generate a warning eventually?)
        # Note that it deliberately won't work on L&lt;...|Foo Bar&gt;
      }


      # Now make up the link_text
      # L&lt;Foo&gt;     -&gt; L&lt;Foo|Foo&gt;
      # L&lt;/Bar&gt;    -&gt; L&lt;"Bar"|Bar&gt;
      # L&lt;Foo/Bar&gt; -&gt; L&lt;"Bar" in Foo/Foo&gt;
      unless($link_text) {
        $ell-&gt;[1]{'content-implicit'} = 'yes';
        $link_text = [];
        push @$link_text, '"', @$section_name, '"' if $section_name;

        if(@ell_content) {
          $link_text-&gt;[-1] .= ' in ' if $section_name;
          push @$link_text, @ell_content;
        }
      }


      # And the E resolver will have to deal with all our treeletty things:

      if(@ell_content == 1 and !ref($ell_content[0])
         and $ell_content[0] =~ m{^[^/]+[(][-a-zA-Z0-9]+[)]$}s
      ) {
        $ell-&gt;[1]{'type'}    = 'man';
        DEBUG &gt; 3 and print "Considering this ($ell_content[0]) a man link.\n";
      } else {
        $ell-&gt;[1]{'type'}    = 'pod';
        DEBUG &gt; 3 and print "Considering this a pod link (not man or url).\n";
      }

      if( defined $section_name ) {
        $ell-&gt;[1]{'section'} = Pod::Simple::LinkSection-&gt;new(
          ['', {}, @$section_name]
        );
        DEBUG &gt; 3 and print "L-section content: ", pretty($ell-&gt;[1]{'section'}), "\n";
      }

      if( @ell_content ) {
        $ell-&gt;[1]{'to'} = Pod::Simple::LinkSection-&gt;new(
          ['', {}, @ell_content]
        );
        DEBUG &gt; 3 and print "L-to content: ", pretty($ell-&gt;[1]{'to'}), "\n";
      }
      
      # And update children to be the link-text:
      @$ell = (@$ell[0,1], defined($link_text) ? splice(@$link_text) : '');
      
      DEBUG &gt; 2 and print "End of L-parsing for this node $treelet-&gt;[$i]\n";

      unshift @stack, $treelet-&gt;[$i]; # might as well recurse
    }
  }

  return;
}

# . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . .

sub _treat_Es {
  my($self,@stack) = @_;

  my($i, $treelet, $content, $replacer, $charnum);
  my $start_line = $stack[0][1]{'start_line'};

  # A recursive algorithm implemented iteratively!  Whee!


  # Has frightening side effects on L nodes' attributes.

  #my @ells_to_tweak;

  while($treelet = shift @stack) {
    for(my $i = 2; $i &lt; @$treelet; ++$i) { # iterate over children
      next unless ref $treelet-&gt;[$i];  # text nodes are uninteresting
      if($treelet-&gt;[$i][0] eq 'L') {
        # SPECIAL STUFF for semi-processed L&lt;&gt;'s
        
        my $thing;
        foreach my $attrname ('section', 'to') {        
          if(defined($thing = $treelet-&gt;[$i][1]{$attrname}) and ref $thing) {
            unshift @stack, $thing;
            DEBUG &gt; 2 and print "  Enqueuing ",
             pretty( $treelet-&gt;[$i][1]{$attrname} ),
             " as an attribute value to tweak.\n";
          }
        }
        
        unshift @stack, $treelet-&gt;[$i]; # recurse
        next;
      } elsif($treelet-&gt;[$i][0] ne 'E') {
        unshift @stack, $treelet-&gt;[$i]; # recurse
        next;
      }
      
      DEBUG &gt; 1 and print "Ogling E node ", pretty($treelet-&gt;[$i]), "\n";

      # bitch if it's empty
      if(  @{$treelet-&gt;[$i]} == 2
       or (@{$treelet-&gt;[$i]} == 3 and $treelet-&gt;[$i][2] eq '')
      ) {
        $self-&gt;whine( $start_line, "An empty E&lt;&gt;" );
        $treelet-&gt;[$i] = 'E&lt;&gt;'; # splice in a literal
        next;
      }
        
      # bitch if content is weird
      unless(@{$treelet-&gt;[$i]} == 3 and !ref($content = $treelet-&gt;[$i][2])) {
        $self-&gt;whine( $start_line, "An E&lt;...&gt; surrounding strange content" );
        $replacer = $treelet-&gt;[$i]; # scratch
        splice(@$treelet, $i, 1,   # fake out a literal
          'E&lt;',
          splice(@$replacer,2), # promote its content
          '&gt;'
        );
        # Don't need to do --$i, as the 'E&lt;' we just added isn't interesting.
        next;
      }

      DEBUG &gt; 1 and print "Ogling E&lt;$content&gt;\n";

      # XXX E&lt;&gt;'s contents *should* be a valid char in the scope of the current
      # =encoding directive. Defaults to iso-8859-1, I believe. Fix this in the
      # future sometime.

      $charnum  = Pod::Escapes::e2charnum($content);
      DEBUG &gt; 1 and print " Considering E&lt;$content&gt; with char ",
        defined($charnum) ? $charnum : "undef", ".\n";

      if(!defined( $charnum )) {
        DEBUG &gt; 1 and print "I don't know how to deal with E&lt;$content&gt;.\n";
        $self-&gt;whine( $start_line, "Unknown E content in E&lt;$content&gt;" );
        $replacer = "E&lt;$content&gt;"; # better than nothing
      } elsif($charnum &gt;= 255 and !UNICODE) {
        $replacer = ASCII ? "\xA4" : "?";
        DEBUG &gt; 1 and print "This Perl version can't handle ", 
          "E&lt;$content&gt; (chr $charnum), so replacing with $replacer\n";
      } else {
        $replacer = Pod::Escapes::e2char($content);
        DEBUG &gt; 1 and print " Replacing E&lt;$content&gt; with $replacer\n";
      }

      splice(@$treelet, $i, 1, $replacer); # no need to back up $i, tho
    }
  }

  return;
}


# . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . .

sub _treat_Ss {
  my($self,$treelet) = @_;
  
  _change_S_to_nbsp($treelet,0) if $self-&gt;{'nbsp_for_S'};

  # TODO: or a change_nbsp_to_S
  #  Normalizing nbsp's to S is harder: for each text node, make S content
  #  out of anything matching m/([^ \xA0]*(?:\xA0+[^ \xA0]*)+)/


  return;
}


sub _change_S_to_nbsp { #  a recursive function
  # Sanely assumes that the top node in the excursion won't be an S node.
  my($treelet, $in_s) = @_;
  
  my $is_s = ('S' eq $treelet-&gt;[0]);
  $in_s ||= $is_s; # So in_s is on either by this being an S element,
                   #  or by an ancestor being an S element.

  for(my $i = 2; $i &lt; @$treelet; ++$i) {
    if(ref $treelet-&gt;[$i]) {
      if( _change_S_to_nbsp( $treelet-&gt;[$i], $in_s ) ) {
        my $to_pull_up = $treelet-&gt;[$i];
        splice @$to_pull_up,0,2;   # ...leaving just its content
        splice @$treelet, $i, 1, @$to_pull_up;  # Pull up content
        $i +=  @$to_pull_up - 1;   # Make $i skip the pulled-up stuff
      }
    } else {
      $treelet-&gt;[$i] =~ s/\s/\xA0/g if ASCII and $in_s;
       # (If not in ASCIIland, we can't assume that \xA0 == nbsp.)
       
       # Note that if you apply nbsp_for_S to text, and so turn
       # "foo S&lt;bar baz&gt; quux" into "foo bar&amp;#160;faz quux", you
       # end up with something that fails to say "and don't hyphenate
       # any part of 'bar baz'".  However, hyphenation is such a vexing
       # problem anyway, that most Pod renderers just don't render it
       # at all.  But if you do want to implement hyphenation, I guess
       # that you'd better have nbsp_for_S off.
    }
  }

  return $is_s;
}

#-----------------------------------------------------------------------------

sub _accessorize {  # A simple-minded method-maker
  no strict 'refs';
  foreach my $attrname (@_) {
    next if $attrname =~ m/::/; # a hack
    *{caller() . '::' . $attrname} = sub {
      use strict;
      $Carp::CarpLevel = 1,  Carp::croak(
       "Accessor usage: \$obj-&gt;$attrname() or \$obj-&gt;$attrname(\$new_value)"
      ) unless (@_ == 1 or @_ == 2) and ref $_[0];
      (@_ == 1) ?  $_[0]-&gt;{$attrname}
                : ($_[0]-&gt;{$attrname} = $_[1]);
    };
  }
  # Ya know, they say accessories make the ensemble!
  return;
}

# . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . .
# . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . .
#=============================================================================

sub filter {
  my($class, $source) = @_;
  my $new = $class-&gt;new;
  $new-&gt;output_fh(*STDOUT{IO});
  
  if(ref($source || '') eq 'SCALAR') {
    $new-&gt;parse_string_document( $$source );
  } elsif(ref($source)) {  # it's a file handle
    $new-&gt;parse_file($source);
  } else {  # it's a filename
    $new-&gt;parse_file($source);
  }
  
  return $new;
}


#-----------------------------------------------------------------------------

sub _out {
  # For use in testing: Class-&gt;_out($source)
  #  returns the transformation of $source
  
  my $class = shift(@_);

  my $mutor = shift(@_) if @_ and ref($_[0] || '') eq 'CODE';

  DEBUG and print "\n\n", '#' x 76,
   "\nAbout to parse source: {{\n$_[0]\n}}\n\n";
  
  
  my $parser = ref $class &amp;&amp; $class-&gt;isa(__PACKAGE__) ? $class : $class-&gt;new;
  $parser-&gt;hide_line_numbers(1);

  my $out = '';
  $parser-&gt;output_string( \$out );
  DEBUG and print " _out to ", \$out, "\n";
  
  $mutor-&gt;($parser) if $mutor;

  $parser-&gt;parse_string_document( $_[0] );
  # use Data::Dumper; print Dumper($parser), "\n";
  return $out;
}


sub _duo {
  # For use in testing: Class-&gt;_duo($source1, $source2)
  #  returns the parse trees of $source1 and $source2.
  # Good in things like: &amp;ok( Class-&gt;duo(... , ...) );
  
  my $class = shift(@_);
  
  Carp::croak "But $class-&gt;_duo is useful only in list context!"
   unless wantarray;

  my $mutor = shift(@_) if @_ and ref($_[0] || '') eq 'CODE';

  Carp::croak "But $class-&gt;_duo takes two parameters, not: @_"
   unless @_ == 2;

  my(@out);
  
  while( @_ ) {
    my $parser = $class-&gt;new;

    push @out, '';
    $parser-&gt;output_string( \( $out[-1] ) );

    DEBUG and print " _duo out to ", $parser-&gt;output_string(),
      " = $parser-&gt;{'output_string'}\n";

    $parser-&gt;hide_line_numbers(1);
    $mutor-&gt;($parser) if $mutor;
    $parser-&gt;parse_string_document( shift( @_ ) );
    # use Data::Dumper; print Dumper($parser), "\n";
  }

  return @out;
}



#-----------------------------------------------------------------------------
1;
__END__

TODO:
A start_formatting_code and end_formatting_code methods, which in the
base class call start_L, end_L, start_C, end_C, etc., if they are
defined.

have the POD FORMATTING ERRORS section note the localtime, and the
version of Pod::Simple.

option to delete all E&lt;shy&gt;s?
option to scream if under-0x20 literals are found in the input, or
under-E&lt;32&gt; E codes are found in the tree. And ditto \x7f-\x9f

Option to turn highbit characters into their compromised form? (applies
to E parsing too)

TODO: BOM/encoding things.

TODO: ascii-compat things in the XML classes?

</pre></body></html>