<html><head><meta name="color-scheme" content="light dark"></head><body><pre style="word-wrap: break-word; white-space: pre-wrap;"># Copyright Â© 2009-2010 RaphaÃ«l Hertzog &lt;hertzog@debian.org&gt;
#
# This program is free software; you can redistribute it and/or modify
# it under the terms of the GNU General Public License as published by
# the Free Software Foundation; either version 2 of the License, or
# (at your option) any later version.
#
# This program is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with this program.  If not, see &lt;https://www.gnu.org/licenses/&gt;.

package Dpkg::Conf;

use strict;
use warnings;

our $VERSION = '1.01';

use Dpkg::Gettext;
use Dpkg::ErrorHandling;

use parent qw(Dpkg::Interface::Storable);

use overload
    '@{}' =&gt; sub { return [ $_[0]-&gt;get_options() ] },
    fallback =&gt; 1;

=encoding utf8

=head1 NAME

Dpkg::Conf - parse dpkg configuration files

=head1 DESCRIPTION

The Dpkg::Conf object can be used to read options from a configuration
file. It can exports an array that can then be parsed exactly like @ARGV.

=head1 FUNCTIONS

=over 4

=item my $conf = Dpkg::Conf-&gt;new(%opts)

Create a new Dpkg::Conf object. Some options can be set through %opts:
if allow_short evaluates to true (it defaults to false), then short
options are allowed in the configuration file, they should be prepended
with a single hyphen.

=cut

sub new {
    my ($this, %opts) = @_;
    my $class = ref($this) || $this;

    my $self = {
	options =&gt; [],
	allow_short =&gt; 0,
    };
    foreach my $opt (keys %opts) {
	$self-&gt;{$opt} = $opts{$opt};
    }
    bless $self, $class;

    return $self;
}

=item @$conf

=item @options = $conf-&gt;get_options()

Returns the list of options that can be parsed like @ARGV.

=cut

sub get_options {
    my ($self) = @_;
    return @{$self-&gt;{options}};
}

=item $conf-&gt;load($file)

Read options from a file. Return the number of options parsed.

=item $conf-&gt;parse($fh)

Parse options from a file handle. Return the number of options parsed.

=cut

sub parse {
    my ($self, $fh, $desc) = @_;
    my $count = 0;
    while (&lt;$fh&gt;) {
	chomp;
	s/^\s+//; s/\s+$//;   # Strip leading/trailing spaces
	s/\s+=\s+/=/;         # Remove spaces around the first =
	s/\s+/=/ unless m/=/; # First spaces becomes = if no =
	next if /^#/ or /^$/; # Skip empty lines and comments
	if (/^-[^-]/ and not $self-&gt;{allow_short}) {
	    warning(_g('short option not allowed in %s, line %d'), $desc, $.);
	    next;
	}
	if (/^([^=]+)(?:=(.*))?$/) {
	    my ($name, $value) = ($1, $2);
	    $name = "--$name" unless $name =~ /^-/;
	    if (defined $value) {
		$value =~ s/^"(.*)"$/$1/ or $value =~ s/^'(.*)'$/$1/;
		push @{$self-&gt;{options}}, "$name=$value";
	    } else {
		push @{$self-&gt;{options}}, $name;
	    }
	    $count++;
	} else {
	    warning(_g('invalid syntax for option in %s, line %d'), $desc, $.);
	}
    }
    return $count;
}

=item $conf-&gt;filter(remove =&gt; $rmfunc)

=item $conf-&gt;filter(keep =&gt; $keepfunc)

Filter the list of options, either removing or keeping all those that
return true when &amp;$rmfunc($option) or &amp;keepfunc($option) is called.

=cut

sub filter {
    my ($self, %opts) = @_;
    if (defined($opts{remove})) {
	@{$self-&gt;{options}} = grep { not &amp;{$opts{remove}}($_) }
				     @{$self-&gt;{options}};
    }
    if (defined($opts{keep})) {
	@{$self-&gt;{options}} = grep { &amp;{$opts{keep}}($_) }
				     @{$self-&gt;{options}};
    }
}

=item $string = $conf-&gt;output($fh)

Write the options in the given filehandle (if defined) and return a string
representation of the content (that would be) written.

=item "$conf"

Return a string representation of the content.

=item $conf-&gt;save($file)

Save the options in a file.

=cut

sub output {
    my ($self, $fh) = @_;
    my $ret = '';
    foreach my $opt ($self-&gt;get_options()) {
	$opt =~ s/^--//;
	if ($opt =~ s/^([^=]+)=/$1 = "/) {
	    $opt .= '"';
	}
	$opt .= "\n";
	print { $fh } $opt if defined $fh;
	$ret .= $opt;
    }
    return $ret;
}

=back

=head1 AUTHOR

RaphaÃ«l Hertzog &lt;hertzog@debian.org&gt;.

=cut

1;
</pre></body></html>