<html><head><meta name="color-scheme" content="light dark"></head><body><pre style="word-wrap: break-word; white-space: pre-wrap;"># Copyright Â© 2006-2009,2012 Guillem Jover &lt;guillem@debian.org&gt;
# Copyright Â© 2007-2010 RaphaÃ«l Hertzog &lt;hertzog@debian.org&gt;
#
# This program is free software; you can redistribute it and/or modify
# it under the terms of the GNU General Public License as published by
# the Free Software Foundation; either version 2 of the License, or
# (at your option) any later version.
#
# This program is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with this program.  If not, see &lt;https://www.gnu.org/licenses/&gt;.

package Dpkg::Substvars;

use strict;
use warnings;

our $VERSION = '1.02';

use Dpkg ();
use Dpkg::Arch qw(get_host_arch);
use Dpkg::ErrorHandling;
use Dpkg::Gettext;

use Carp;
use POSIX qw(:errno_h);

use parent qw(Dpkg::Interface::Storable);

my $maxsubsts = 50;

=encoding utf8

=head1 NAME

Dpkg::Substvars - handle variable substitution in strings

=head1 DESCRIPTION

It provides some an object which is able to substitute variables in
strings.

=head1 METHODS

=over 8

=item my $s = Dpkg::Substvars-&gt;new($file)

Create a new object that can do substitutions. By default it contains
generic substitutions like ${Newline}, ${Space}, ${Tab}, ${dpkg:Version}
and ${dpkg:Upstream-Version}.

Additional substitutions will be read from the $file passed as parameter.

It keeps track of which substitutions were actually used (only counting
substvars(), not get()), and warns about unused substvars when asked to. The
substitutions that are always present are not included in these warnings.

=cut

sub new {
    my ($this, $arg) = @_;
    my $class = ref($this) || $this;
    my $self = {
        vars =&gt; {
            'Newline' =&gt; "\n",
            'Space' =&gt; ' ',
            'Tab' =&gt; "\t",
            'dpkg:Version' =&gt; $Dpkg::PROGVERSION,
            'dpkg:Upstream-Version' =&gt; $Dpkg::PROGVERSION,
            },
        used =&gt; {},
	msg_prefix =&gt; '',
    };
    $self-&gt;{vars}{'dpkg:Upstream-Version'} =~ s/-[^-]+$//;
    bless $self, $class;
    $self-&gt;mark_as_used($_) foreach keys %{$self-&gt;{vars}};
    if ($arg) {
        $self-&gt;load($arg) if -e $arg;
    }
    return $self;
}

=item $s-&gt;set($key, $value)

Add/replace a substitution.

=cut

sub set {
    my ($self, $key, $value) = @_;
    $self-&gt;{vars}{$key} = $value;
}

=item $s-&gt;set_as_used($key, $value)

Add/replace a substitution and mark it as used (no warnings will be produced
even if unused).

=cut

sub set_as_used {
    my ($self, $key, $value) = @_;
    $self-&gt;set($key, $value);
    $self-&gt;mark_as_used($key);
}

=item $s-&gt;get($key)

Get the value of a given substitution.

=cut

sub get {
    my ($self, $key) = @_;
    return $self-&gt;{vars}{$key};
}

=item $s-&gt;delete($key)

Remove a given substitution.

=cut

sub delete {
    my ($self, $key) = @_;
    delete $self-&gt;{used}{$key};
    return delete $self-&gt;{vars}{$key};
}

=item $s-&gt;mark_as_used($key)

Prevents warnings about a unused substitution, for example if it is provided by
default.

=cut

sub mark_as_used {
    my ($self, $key) = @_;
    $self-&gt;{used}{$key}++;
}

=item $s-&gt;no_warn($key)

Obsolete function, use mark_as_used() instead.

=cut

sub no_warn {
    my ($self, $key) = @_;
    carp 'obsolete no_warn() function, use mark_as_used() instead';
    $self-&gt;mark_as_used($key);
}

=item $s-&gt;load($file)

Add new substitutions read from $file.

=item $s-&gt;parse($fh, $desc)

Add new substitutions read from the filehandle. $desc is used to identify
the filehandle in error messages.

=cut

sub parse {
    my ($self, $fh, $varlistfile) = @_;
    binmode($fh);
    while (&lt;$fh&gt;) {
	next if m/^\s*\#/ || !m/\S/;
	s/\s*\n$//;
	if (! m/^(\w[-:0-9A-Za-z]*)\=(.*)$/) {
	    error(_g('bad line in substvars file %s at line %d'),
		  $varlistfile, $.);
	}
	$self-&gt;{vars}{$1} = $2;
    }
}

=item $s-&gt;set_version_substvars($sourceversion, $binaryversion)

Defines ${binary:Version}, ${source:Version} and
${source:Upstream-Version} based on the given version strings.

These will never be warned about when unused.

=cut

sub set_version_substvars {
    my ($self, $sourceversion, $binaryversion) = @_;

    # Handle old function signature taking only one argument.
    $binaryversion ||= $sourceversion;

    # For backwards compatibility on binNMUs that do not use the Binary-Only
    # field on the changelog, always fix up the source version.
    $sourceversion =~ s/\+b[0-9]+$//;

    $self-&gt;{vars}{'binary:Version'} = $binaryversion;
    $self-&gt;{vars}{'source:Version'} = $sourceversion;
    $self-&gt;{vars}{'source:Upstream-Version'} = $sourceversion;
    $self-&gt;{vars}{'source:Upstream-Version'} =~ s/-[^-]*$//;

    # XXX: Source-Version is now deprecated, remove in the future.
    $self-&gt;{vars}{'Source-Version'} = $binaryversion;

    $self-&gt;mark_as_used($_) foreach qw/binary:Version source:Version source:Upstream-Version Source-Version/;
}

=item $s-&gt;set_arch_substvars()

Defines architecture variables: ${Arch}.

This will never be warned about when unused.

=cut

sub set_arch_substvars {
    my ($self) = @_;

    $self-&gt;set_as_used('Arch', get_host_arch());
}

=item $newstring = $s-&gt;substvars($string)

Substitutes variables in $string and return the result in $newstring.

=cut

sub substvars {
    my ($self, $v, %opts) = @_;
    my $lhs;
    my $vn;
    my $rhs = '';
    my $count = 0;
    $opts{msg_prefix} = $self-&gt;{msg_prefix} unless exists $opts{msg_prefix};
    $opts{no_warn} = 0 unless exists $opts{no_warn};

    while ($v =~ m/^(.*?)\$\{([-:0-9a-z]+)\}(.*)$/si) {
        # If we have consumed more from the leftover data, then
        # reset the recursive counter.
        $count = 0 if (length($3) &lt; length($rhs));

        if ($count &gt;= $maxsubsts) {
            error($opts{msg_prefix} .
	          _g("too many substitutions - recursive ? - in \`%s'"), $v);
        }
        $lhs = $1; $vn = $2; $rhs = $3;
        if (defined($self-&gt;{vars}{$vn})) {
            $v = $lhs . $self-&gt;{vars}{$vn} . $rhs;
            $self-&gt;mark_as_used($vn);
            $count++;
        } else {
            warning($opts{msg_prefix} . _g('unknown substitution variable ${%s}'),
	            $vn) unless $opts{no_warn};
            $v = $lhs . $rhs;
        }
    }
    return $v;
}

=item $s-&gt;warn_about_unused()

Issues warning about any variables that were set, but not used

=cut

sub warn_about_unused {
    my ($self, %opts) = @_;
    $opts{msg_prefix} = $self-&gt;{msg_prefix} unless exists $opts{msg_prefix};

    foreach my $vn (keys %{$self-&gt;{vars}}) {
        next if $self-&gt;{used}{$vn};
        # Empty substitutions variables are ignored on the basis
        # that they are not required in the current situation
        # (example: debhelper's misc:Depends in many cases)
        next if $self-&gt;{vars}{$vn} eq '';
        warning($opts{msg_prefix} . _g('unused substitution variable ${%s}'),
                $vn);
    }
}

=item $s-&gt;set_msg_prefix($prefix)

Define a prefix displayed before all warnings/error messages output
by the module.

=cut

sub set_msg_prefix {
    my ($self, $prefix) = @_;
    $self-&gt;{msg_prefix} = $prefix;
}

=item $s-&gt;save($file)

Store all substitutions variables except the automatic ones in the
indicated file.

=item "$s"

Return a string representation of all substitutions variables except the
automatic ones.

=item $str = $s-&gt;output($fh)

Print all substitutions variables except the automatic ones in the
filehandle and return the content written.

=cut

sub output {
    my ($self, $fh) = @_;
    my $str = '';
    # Store all non-automatic substitutions only
    foreach my $vn (sort keys %{$self-&gt;{vars}}) {
	next if /^(?:(?:dpkg|source|binary):(?:Source-)?Version|Space|Tab|Newline|Arch|Source-Version|F:.+)$/;
	my $line = "$vn=" . $self-&gt;{vars}{$vn} . "\n";
	print { $fh } $line if defined $fh;
	$str .= $line;
    }
    return $str;
}

=back

=head1 AUTHOR

RaphaÃ«l Hertzog &lt;hertzog@debian.org&gt;.

=cut

1;
</pre></body></html>