<html><head><meta name="color-scheme" content="light dark"></head><body><pre style="word-wrap: break-word; white-space: pre-wrap;">package Term::UI;

use if $] &gt; 5.017, 'deprecate';

use Carp;
use Params::Check qw[check allow];
use Term::ReadLine;
use Locale::Maketext::Simple Style =&gt; 'gettext';
use Term::UI::History;

use strict;

BEGIN {
    use vars        qw[$VERSION $AUTOREPLY $VERBOSE $INVALID];
    $VERBOSE    =   1;
    $VERSION    =   '0.42';
    $INVALID    =   loc('Invalid selection, please try again: ');
}

push @Term::ReadLine::Stub::ISA, __PACKAGE__
        unless grep { $_ eq __PACKAGE__ } @Term::ReadLine::Stub::ISA;


=pod

=head1 NAME

Term::UI - Term::ReadLine UI made easy

=head1 SYNOPSIS

    use Term::UI;
    use Term::ReadLine;

    my $term = Term::ReadLine-&gt;new('brand');

    my $reply = $term-&gt;get_reply(
                    prompt =&gt; 'What is your favourite colour?',
                    choices =&gt; [qw|blue red green|],
                    default =&gt; 'blue',
    );

    my $bool = $term-&gt;ask_yn(
                        prompt =&gt; 'Do you like cookies?',
                        default =&gt; 'y',
                );


    my $string = q[some_command -option --no-foo --quux='this thing'];

    my ($options,$munged_input) = $term-&gt;parse_options($string);


    ### don't have Term::UI issue warnings -- default is '1'
    $Term::UI::VERBOSE = 0;

    ### always pick the default (good for non-interactive terms)
    ### -- default is '0'
    $Term::UI::AUTOREPLY = 1;

    ### Retrieve the entire session as a printable string:
    $hist = Term::UI::History-&gt;history_as_string;
    $hist = $term-&gt;history_as_string;

=head1 DESCRIPTION

C&lt;Term::UI&gt; is a transparent way of eliminating the overhead of having
to format a question and then validate the reply, informing the user
if the answer was not proper and re-issuing the question.

Simply give it the question you want to ask, optionally with choices
the user can pick from and a default and C&lt;Term::UI&gt; will DWYM.

For asking a yes or no question, there's even a shortcut.

=head1 HOW IT WORKS

C&lt;Term::UI&gt; places itself at the back of the C&lt;Term::ReadLine&gt;
C&lt;@ISA&gt; array, so you can call its functions through your term object.

C&lt;Term::UI&gt; uses C&lt;Term::UI::History&gt; to record all interactions
with the commandline. You can retrieve this history, or alter
the filehandle the interaction is printed to. See the
C&lt;Term::UI::History&gt; manpage or the C&lt;SYNOPSIS&gt; for details.

=head1 METHODS

=head2 $reply = $term-&gt;get_reply( prompt =&gt; 'question?', [choices =&gt; \@list, default =&gt; $list[0], multi =&gt; BOOL, print_me =&gt; "extra text to print &amp; record", allow =&gt; $ref] );

C&lt;get_reply&gt; asks a user a question, and then returns the reply to the
caller. If the answer is invalid (more on that below), the question will
be reposed, until a satisfactory answer has been entered.

You have the option of providing a list of choices the user can pick from
using the C&lt;choices&gt; argument. If the answer is not in the list of choices
presented, the question will be reposed.

If you provide a C&lt;default&gt;  answer, this will be returned when either
C&lt;$AUTOREPLY&gt; is set to true, (see the C&lt;GLOBAL VARIABLES&gt; section further
below), or when the user just hits C&lt;enter&gt;.

You can indicate that the user is allowed to enter multiple answers by
toggling the C&lt;multi&gt; flag. Note that a list of answers will then be
returned to you, rather than a simple string.

By specifying an C&lt;allow&gt; handler, you can yourself validate the answer
a user gives. This can be any of the types that the Params::Check C&lt;allow&gt;
function allows, so please refer to that manpage for details.

Finally, you have the option of adding a C&lt;print_me&gt; argument, which is
simply printed before the prompt. It's printed to the same file handle
as the rest of the questions, so you can use this to keep track of a
full session of Q&amp;A with the user, and retrieve it later using the
C&lt;&lt; Term::UI-&gt;history_as_string &gt;&gt; function.

See the C&lt;EXAMPLES&gt; section for samples of how to use this function.

=cut

sub get_reply {
    my $term = shift;
    my %hash = @_;

    my $tmpl = {
        default     =&gt; { default =&gt; undef,  strict_type =&gt; 0 },
        prompt      =&gt; { default =&gt; '',     strict_type =&gt; 1, required =&gt; 1 },
        choices     =&gt; { default =&gt; [],     strict_type =&gt; 1 },
        multi       =&gt; { default =&gt; 0,      allow =&gt; [0, 1] },
        allow       =&gt; { default =&gt; qr/.*/ },
        print_me    =&gt; { default =&gt; '',     strict_type =&gt; 1 },
    };

    my $args = check( $tmpl, \%hash, $VERBOSE )
                or ( carp( loc(q[Could not parse arguments]) ), return );

    # Check for legacy default on multi=1
    if ($args-&gt;{multi} and ref($args-&gt;{default}) ne "ARRAY") {
        $args-&gt;{default} = [ $args-&gt;{default} ];
    }

    ### add this to the prompt to indicate the default
    ### answer to the question if there is one.
    my $prompt_add;

    ### if you supplied several choices to pick from,
    ### we'll print them separately before the prompt
    if( @{$args-&gt;{choices}} ) {
        my $i;

        for my $choice ( @{$args-&gt;{choices}} ) {
            $i++;   # the answer counter -- but humans start counting
                    # at 1 :D

            ### so this choice is the default? add it to 'prompt_add'
            ### so we can construct a "foo? [DIGIT]" type prompt
            if (defined $args-&gt;{default}) {
                if ($args-&gt;{multi}) {
                    push @$prompt_add, $i if (scalar(grep { m/^$choice$/ } @{$args-&gt;{default}}));
                }
                else {
                    $prompt_add = $i if ($choice eq $args-&gt;{default});
                }
            }

            ### create a "DIGIT&gt; choice" type line
            $args-&gt;{print_me} .= sprintf "\n%3s&gt; %-s", $i, $choice;
        }

        $prompt_add = join(" ", @$prompt_add) if ($args-&gt;{multi});

        ### we listed some choices -- add another newline for
        ### pretty printing
        $args-&gt;{print_me} .= "\n" if $i;

        ### allowable answers are now equal to the choices listed
        $args-&gt;{allow} = $args-&gt;{choices};

    ### no choices, but a default? set 'prompt_add' to the default
    ### to construct a 'foo? [DEFAULT]' type prompt
    } elsif ( defined $args-&gt;{default} ) {
        if ($args-&gt;{multi} and ref($args-&gt;{default}) eq "ARRAY") {
            $prompt_add = join(" ", @{$args-&gt;{default}});
        }
        else {
            $prompt_add = $args-&gt;{default};
        }
    }

    ### we set up the defaults, prompts etc, dispatch to the readline call
    return $term-&gt;_tt_readline( %$args, prompt_add =&gt; $prompt_add );

}

=head2 $bool = $term-&gt;ask_yn( prompt =&gt; "your question", [default =&gt; (y|1,n|0), print_me =&gt; "extra text to print &amp; record"] )

Asks a simple C&lt;yes&gt; or C&lt;no&gt; question to the user, returning a boolean
indicating C&lt;true&gt; or C&lt;false&gt; to the caller.

The C&lt;default&gt; answer will automatically returned, if the user hits
C&lt;enter&gt; or if C&lt;$AUTOREPLY&gt; is set to true. See the C&lt;GLOBAL VARIABLES&gt;
section further below.

Also, you have the option of adding a C&lt;print_me&gt; argument, which is
simply printed before the prompt. It's printed to the same file handle
as the rest of the questions, so you can use this to keep track of a
full session of Q&amp;A with the user, and retrieve it later using the
C&lt;&lt; Term::UI-&gt;history_as_string &gt;&gt; function.


See the C&lt;EXAMPLES&gt; section for samples of how to use this function.

=cut

sub ask_yn {
    my $term = shift;
    my %hash = @_;

    my $tmpl = {
        default     =&gt; { default =&gt; undef, allow =&gt; [qw|0 1 y n|],
                                                            strict_type =&gt; 1 },
        prompt      =&gt; { default =&gt; '', required =&gt; 1,      strict_type =&gt; 1 },
        print_me    =&gt; { default =&gt; '',                     strict_type =&gt; 1 },
        multi       =&gt; { default =&gt; 0,                      no_override =&gt; 1 },
        choices     =&gt; { default =&gt; [qw|y n|],              no_override =&gt; 1 },
        allow       =&gt; { default =&gt; [qr/^y(?:es)?$/i, qr/^n(?:o)?$/i],
                         no_override =&gt; 1
                       },
    };

    my $args = check( $tmpl, \%hash, $VERBOSE ) or return undef;

    ### uppercase the default choice, if there is one, to be added
    ### to the prompt in a 'foo? [Y/n]' type style.
    my $prompt_add;
    {   my @list = @{$args-&gt;{choices}};
        if( defined $args-&gt;{default} ) {

            ### if you supplied the default as a boolean, rather than y/n
            ### transform it to a y/n now
            $args-&gt;{default} = $args-&gt;{default} =~ /\d/
                                ? { 0 =&gt; 'n', 1 =&gt; 'y' }-&gt;{ $args-&gt;{default} }
                                : $args-&gt;{default};

            @list = map { lc $args-&gt;{default} eq lc $_
                                ? uc $args-&gt;{default}
                                : $_
                    } @list;
        }

        $prompt_add .= join("/", @list);
    }

    my $rv = $term-&gt;_tt_readline( %$args, prompt_add =&gt; $prompt_add );

    return $rv =~ /^y/i ? 1 : 0;
}



sub _tt_readline {
    my $term = shift;
    my %hash = @_;

    local $Params::Check::VERBOSE = 0;  # why is this?
    local $| = 1;                       # print ASAP


    my ($default, $prompt, $choices, $multi, $allow, $prompt_add, $print_me);
    my $tmpl = {
        default     =&gt; { default =&gt; undef,  strict_type =&gt; 0,
                            store =&gt; \$default },
        prompt      =&gt; { default =&gt; '',     strict_type =&gt; 1, required =&gt; 1,
                            store =&gt; \$prompt },
        choices     =&gt; { default =&gt; [],     strict_type =&gt; 1,
                            store =&gt; \$choices },
        multi       =&gt; { default =&gt; 0,      allow =&gt; [0, 1], store =&gt; \$multi },
        allow       =&gt; { default =&gt; qr/.*/, store =&gt; \$allow, },
        prompt_add  =&gt; { default =&gt; '',     store =&gt; \$prompt_add, strict_type =&gt; 1 },
        print_me    =&gt; { default =&gt; '',     store =&gt; \$print_me },
    };

    check( $tmpl, \%hash, $VERBOSE ) or return;

    ### prompts for Term::ReadLine can't be longer than one line, or
    ### it can display wonky on some terminals.
    history( $print_me ) if $print_me;


    if ($prompt_add) {
        ### we might have to add a default value to the prompt, to
        ### show the user what will be picked by default:
        $prompt .= " [$prompt_add]: " ;
    }
    else {
        $prompt .= " : ";
    }


    ### are we in autoreply mode?
    if ($AUTOREPLY) {

        ### you used autoreply, but didn't provide a default!
        carp loc(
            q[You have '%1' set to true, but did not provide a default!],
            '$AUTOREPLY'
        ) if( !defined $default &amp;&amp; $VERBOSE);

        ### print it out for visual feedback
        if ($multi and defined($default)) {
            history( join ' ', grep { defined } $prompt, @$default );
            ### and return the default
            return @$default;
        }
        else {
            history( join ' ', grep { defined } $prompt, $default );
            ### and return the default
            return $default;
        }

    }

    if ($multi and defined($default)) {
        $default = join(' ', @$default);
    }

    ### so, no AUTOREPLY, let's see what the user will answer
    LOOP: {

        ### annoying bug in T::R::Perl that mucks up lines with a \n
        ### in them; So split by \n, save the last line as the prompt
        ### and just print the rest
        {   my @lines   = split "\n", $prompt;
            $prompt     = pop @lines;

            history( "$_\n" ) for @lines;
        }

        ### pose the question
        my $answer  = $term-&gt;readline($prompt);
        $answer     = $default unless length $answer;

        $term-&gt;addhistory( $answer ) if length $answer;

        ### add both prompt and answer to the history
        history( "$prompt $answer", 0 );

        ### if we're allowed to give multiple answers, split
        ### the answer on whitespace
        my @answers = $multi ? split(/\s+/, $answer) : $answer;

        ### the return value list
        my @rv;

        if( @$choices ) {

            for my $answer (@answers) {

                ### a digit implies a multiple choice question,
                ### a non-digit is an open answer
                if( $answer =~ /\D/ ) {
                    push @rv, $answer if allow( $answer, $allow );
                } else {

                    ### remember, the answer digits are +1 compared to
                    ### the choices, because humans want to start counting
                    ### at 1, not at 0
                    push @rv, $choices-&gt;[ $answer - 1 ]
                        if $answer &gt; 0 &amp;&amp; defined $choices-&gt;[ $answer - 1 ];
                }
            }

        ### no fixed list of choices.. just check if the answers
        ### (or otherwise the default!) pass the allow handler
        } else {
            push @rv, grep { allow( $_, $allow ) } @answers;
        }

        ### if not all the answers made it to the return value list,
        ### at least one of them was an invalid answer -- make the
        ### user do it again
        if( (@rv != @answers) or
            (scalar(@$choices) and not scalar(@answers))
        ) {
            $prompt = $INVALID;
            $prompt .= "[$prompt_add] " if $prompt_add;
            redo LOOP;

        ### otherwise just return the answer, or answers, depending
        ### on the multi setting
        } else {
            return $multi ? @rv : $rv[0];
        }
    }
}

=head2 ($opts, $munged) = $term-&gt;parse_options( STRING );

C&lt;parse_options&gt; will convert all options given from an input string
to a hash reference. If called in list context it will also return
the part of the input string that it found no options in.

Consider this example:

    my $str =   q[command --no-foo --baz --bar=0 --quux=bleh ] .
                q[--option="some'thing" -one-dash -single=blah' arg];

    my ($options,$munged) =  $term-&gt;parse_options($str);

    ### $options would contain: ###
    $options = {
                'foo'       =&gt; 0,
                'bar'       =&gt; 0,
                'one-dash'  =&gt; 1,
                'baz'       =&gt; 1,
                'quux'      =&gt; 'bleh',
                'single'    =&gt; 'blah\'',
                'option'    =&gt; 'some\'thing'
    };

    ### and this is the munged version of the input string,
    ### ie what's left of the input minus the options
    $munged = 'command arg';

As you can see, you can either use a single or a double C&lt;-&gt; to
indicate an option.
If you prefix an option with C&lt;no-&gt; and do not give it a value, it
will be set to 0.
If it has no prefix and no value, it will be set to 1.
Otherwise, it will be set to its value. Note also that it can deal
fine with single/double quoting issues.

=cut

sub parse_options {
    my $term    = shift;
    my $input   = shift;

    my $return = {};

    ### there's probably a more elegant way to do this... ###
    while ( $input =~ s/(?:^|\s+)--?([-\w]+=("|').+?\2)(?=\Z|\s+)//  or
            $input =~ s/(?:^|\s+)--?([-\w]+=\S+)(?=\Z|\s+)//         or
            $input =~ s/(?:^|\s+)--?([-\w]+)(?=\Z|\s+)//
    ) {
        my $match = $1;

        if( $match =~ /^([-\w]+)=("|')(.+?)\2$/ ) {
            $return-&gt;{$1} = $3;

        } elsif( $match =~ /^([-\w]+)=(\S+)$/ ) {
            $return-&gt;{$1} = $2;

        } elsif( $match =~ /^no-?([-\w]+)$/i ) {
            $return-&gt;{$1} = 0;

        } elsif ( $match =~ /^([-\w]+)$/ ) {
            $return-&gt;{$1} = 1;

        } else {
            carp(loc(q[I do not understand option "%1"\n], $match)) if $VERBOSE;
        }
    }

    return wantarray ? ($return,$input) : $return;
}

=head2 $str = $term-&gt;history_as_string

Convenience wrapper around C&lt;&lt; Term::UI::History-&gt;history_as_string &gt;&gt;.

Consult the C&lt;Term::UI::History&gt; man page for details.

=cut

sub history_as_string { return Term::UI::History-&gt;history_as_string };

1;

=head1 GLOBAL VARIABLES

The behaviour of Term::UI can be altered by changing the following
global variables:

=head2 $Term::UI::VERBOSE

This controls whether Term::UI will issue warnings and explanations
as to why certain things may have failed. If you set it to 0,
Term::UI will not output any warnings.
The default is 1;

=head2 $Term::UI::AUTOREPLY

This will make every question be answered by the default, and warn if
there was no default provided. This is particularly useful if your
program is run in non-interactive mode.
The default is 0;

=head2 $Term::UI::INVALID

This holds the string that will be printed when the user makes an
invalid choice.
You can override this string from your program if you, for example,
wish to do localization.
The default is C&lt;Invalid selection, please try again: &gt;

=head2 $Term::UI::History::HISTORY_FH

This is the filehandle all the print statements from this module
are being sent to. Please consult the C&lt;Term::UI::History&gt; manpage
for details.

This defaults to C&lt;*STDOUT&gt;.

=head1 EXAMPLES

=head2 Basic get_reply sample

    ### ask a user (with an open question) for their favourite colour
    $reply = $term-&gt;get_reply( prompt =&gt; 'Your favourite colour? );

which would look like:

    Your favourite colour?

and C&lt;$reply&gt; would hold the text the user typed.

=head2 get_reply with choices

    ### now provide a list of choices, so the user has to pick one
    $reply = $term-&gt;get_reply(
                prompt  =&gt; 'Your favourite colour?',
                choices =&gt; [qw|red green blue|] );

which would look like:

      1&gt; red
      2&gt; green
      3&gt; blue

    Your favourite colour?

C&lt;$reply&gt; will hold one of the choices presented. C&lt;Term::UI&gt; will repose
the question if the user attempts to enter an answer that's not in the
list of choices. The string presented is held in the C&lt;$Term::UI::INVALID&gt;
variable (see the C&lt;GLOBAL VARIABLES&gt; section for details.

=head2 get_reply with choices and default

    ### provide a sensible default option -- everyone loves blue!
    $reply = $term-&gt;get_reply(
                prompt  =&gt; 'Your favourite colour?',
                choices =&gt; [qw|red green blue|],
                default =&gt; 'blue' );

which would look like:

      1&gt; red
      2&gt; green
      3&gt; blue

    Your favourite colour? [3]:

Note the default answer after the prompt. A user can now just hit C&lt;enter&gt;
(or set C&lt;$Term::UI::AUTOREPLY&gt; -- see the C&lt;GLOBAL VARIABLES&gt; section) and
the sensible answer 'blue' will be returned.

=head2 get_reply using print_me &amp; multi

    ### allow the user to pick more than one colour and add an
    ### introduction text
    @reply = $term-&gt;get_reply(
                print_me    =&gt; 'Tell us what colours you like',
                prompt      =&gt; 'Your favourite colours?',
                choices     =&gt; [qw|red green blue|],
                multi       =&gt; 1 );

which would look like:

    Tell us what colours you like
      1&gt; red
      2&gt; green
      3&gt; blue

    Your favourite colours?

An answer of C&lt;3 2 1&gt; would fill C&lt;@reply&gt; with C&lt;blue green red&gt;

=head2 get_reply &amp; allow

    ### pose an open question, but do a custom verification on
    ### the answer, which will only exit the question loop, if
    ### the answer matches the allow handler.
    $reply = $term-&gt;get_reply(
                prompt  =&gt; "What is the magic number?",
                allow   =&gt; 42 );

Unless the user now enters C&lt;42&gt;, the question will be reposed over
and over again. You can use more sophisticated C&lt;allow&gt; handlers (even
subroutines can be used). The C&lt;allow&gt; handler is implemented using
C&lt;Params::Check&gt;'s C&lt;allow&gt; function. Check its manpage for details.

=head2 an elaborate ask_yn sample

    ### ask a user if he likes cookies. Default to a sensible 'yes'
    ### and inform him first what cookies are.
    $bool = $term-&gt;ask_yn( prompt   =&gt; 'Do you like cookies?',
                           default  =&gt; 'y',
                           print_me =&gt; 'Cookies are LOVELY!!!' );

would print:

    Cookies are LOVELY!!!
    Do you like cookies? [Y/n]:

If a user then simply hits C&lt;enter&gt;, agreeing with the default,
C&lt;$bool&gt; would be set to C&lt;true&gt;. (Simply hitting 'y' would also
return C&lt;true&gt;. Hitting 'n' would return C&lt;false&gt;)

We could later retrieve this interaction by printing out the Q&amp;A
history as follows:

    print $term-&gt;history_as_string;

which would then print:

    Cookies are LOVELY!!!
    Do you like cookies? [Y/n]:  y

There's a chance we're doing this non-interactively, because a console
is missing, the user indicated he just wanted the defaults, etc.

In this case, simply setting C&lt;$Term::UI::AUTOREPLY&gt; to true, will
return from every question with the default answer set for the question.
Do note that if C&lt;AUTOREPLY&gt; is true, and no default is set, C&lt;Term::UI&gt;
will warn about this and return C&lt;undef&gt;.

=head1 See Also

C&lt;Params::Check&gt;, C&lt;Term::ReadLine&gt;, C&lt;Term::UI::History&gt;

=head1 BUG REPORTS

Please report bugs or other issues to E&lt;lt&gt;bug-term-ui@rt.cpan.org&lt;gt&gt;.

=head1 AUTHOR

This module by Jos Boumans E&lt;lt&gt;kane@cpan.orgE&lt;gt&gt;.

=head1 COPYRIGHT

This library is free software; you may redistribute and/or modify it
under the same terms as Perl itself.

=cut
</pre></body></html>