<html><head><meta name="color-scheme" content="light dark"></head><body><pre style="word-wrap: break-word; white-space: pre-wrap;">package WWW::Mechanize;

=head1 NAME

WWW::Mechanize - Handy web browsing in a Perl object

=head1 VERSION

Version 1.73

=cut

our $VERSION = '1.73';

=head1 SYNOPSIS

C&lt;WWW::Mechanize&gt;, or Mech for short, is a Perl module for stateful
programmatic web browsing, used for automating interaction with
websites.

Features include:

=over 4

=item * All HTTP methods

=item * High-level hyperlink and HTML form support, without having to parse HTML yourself

=item * SSL support

=item * Automatic cookies

=item * Custom HTTP headers

=item * Automatic handling of redirections

=item * Proxies

=item * HTTP authentication

=back

Mech supports performing a sequence of page fetches including
following links and submitting forms. Each fetched page is parsed
and its links and forms are extracted. A link or a form can be
selected, form fields can be filled and the next page can be fetched.
Mech also stores a history of the URLs you've visited, which can
be queried and revisited.

    use WWW::Mechanize;
    my $mech = WWW::Mechanize-&gt;new();

    $mech-&gt;get( $url );

    $mech-&gt;follow_link( n =&gt; 3 );
    $mech-&gt;follow_link( text_regex =&gt; qr/download this/i );
    $mech-&gt;follow_link( url =&gt; 'http://host.com/index.html' );

    $mech-&gt;submit_form(
        form_number =&gt; 3,
        fields      =&gt; {
            username    =&gt; 'mungo',
            password    =&gt; 'lost-and-alone',
        }
    );

    $mech-&gt;submit_form(
        form_name =&gt; 'search',
        fields    =&gt; { query  =&gt; 'pot of gold', },
        button    =&gt; 'Search Now'
    );


Mech is well suited for use in testing web applications.  If you use
one of the Test::*, like L&lt;Test::HTML::Lint&gt; modules, you can check the
fetched content and use that as input to a test call.

    use Test::More;
    like( $mech-&gt;content(), qr/$expected/, "Got expected content" );

Each page fetch stores its URL in a history stack which you can
traverse.

    $mech-&gt;back();

If you want finer control over your page fetching, you can use
these methods. C&lt;follow_link&gt; and C&lt;submit_form&gt; are just high
level wrappers around them.

    $mech-&gt;find_link( n =&gt; $number );
    $mech-&gt;form_number( $number );
    $mech-&gt;form_name( $name );
    $mech-&gt;field( $name, $value );
    $mech-&gt;set_fields( %field_values );
    $mech-&gt;set_visible( @criteria );
    $mech-&gt;click( $button );

L&lt;WWW::Mechanize&gt; is a proper subclass of L&lt;LWP::UserAgent&gt; and
you can also use any of L&lt;LWP::UserAgent&gt;'s methods.

    $mech-&gt;add_header($name =&gt; $value);

Please note that Mech does NOT support JavaScript, you need additional software
for that. Please check L&lt;WWW::Mechanize::FAQ/"JavaScript"&gt; for more.

=head1 IMPORTANT LINKS

=over 4

=item * L&lt;http://code.google.com/p/www-mechanize/issues/list&gt;

The queue for bugs &amp; enhancements in WWW::Mechanize and
Test::WWW::Mechanize.  Please note that the queue at L&lt;http://rt.cpan.org&gt;
is no longer maintained.

=item * L&lt;http://search.cpan.org/dist/WWW-Mechanize/&gt;

The CPAN documentation page for Mechanize.

=item * L&lt;http://search.cpan.org/dist/WWW-Mechanize/lib/WWW/Mechanize/FAQ.pod&gt;

Frequently asked questions.  Make sure you read here FIRST.

=back

=cut

use strict;
use warnings;

use HTTP::Request 1.30;
use LWP::UserAgent 5.827;
use HTML::Form 1.00;
use HTML::TokeParser;

use base 'LWP::UserAgent';

our $HAS_ZLIB;
BEGIN {
    $HAS_ZLIB = eval 'use Compress::Zlib (); 1;';
}

=head1 CONSTRUCTOR AND STARTUP

=head2 new()

Creates and returns a new WWW::Mechanize object, hereafter referred to as
the "agent".

    my $mech = WWW::Mechanize-&gt;new()

The constructor for WWW::Mechanize overrides two of the parms to the
LWP::UserAgent constructor:

    agent =&gt; 'WWW-Mechanize/#.##'
    cookie_jar =&gt; {}    # an empty, memory-only HTTP::Cookies object

You can override these overrides by passing parms to the constructor,
as in:

    my $mech = WWW::Mechanize-&gt;new( agent =&gt; 'wonderbot 1.01' );

If you want none of the overhead of a cookie jar, or don't want your
bot accepting cookies, you have to explicitly disallow it, like so:

    my $mech = WWW::Mechanize-&gt;new( cookie_jar =&gt; undef );

Here are the parms that WWW::Mechanize recognizes.  These do not include
parms that L&lt;LWP::UserAgent&gt; recognizes.

=over 4

=item * C&lt;&lt; autocheck =&gt; [0|1] &gt;&gt;

Checks each request made to see if it was successful.  This saves
you the trouble of manually checking yourself.  Any errors found
are errors, not warnings.

The default value is ON, unless it's being subclassed, in which
case it is OFF.  This means that standalone L&lt;WWW::Mechanize&gt;instances
have autocheck turned on, which is protective for the vast majority
of Mech users who don't bother checking the return value of get()
and post() and can't figure why their code fails. However, if
L&lt;WWW::Mechanize&gt; is subclassed, such as for L&lt;Test::WWW::Mechanize&gt;
or L&lt;Test::WWW::Mechanize::Catalyst&gt;, this may not be an appropriate
default, so it's off.

=item * C&lt;&lt; noproxy =&gt; [0|1] &gt;&gt;

Turn off the automatic call to the L&lt;LWP::UserAgent&gt; C&lt;env_proxy&gt; function.

This needs to be explicitly turned off if you're using L&lt;Crypt::SSLeay&gt; to
access a https site via a proxy server.  Note: you still need to set your
HTTPS_PROXY environment variable as appropriate.

=item * C&lt;&lt; onwarn =&gt; \&amp;func &gt;&gt;

Reference to a C&lt;warn&gt;-compatible function, such as C&lt;&lt; L&lt;Carp&gt;::carp &gt;&gt;,
that is called when a warning needs to be shown.

If this is set to C&lt;undef&gt;, no warnings will ever be shown.  However,
it's probably better to use the C&lt;quiet&gt; method to control that behavior.

If this value is not passed, Mech uses C&lt;Carp::carp&gt; if L&lt;Carp&gt; is
installed, or C&lt;CORE::warn&gt; if not.

=item * C&lt;&lt; onerror =&gt; \&amp;func &gt;&gt;

Reference to a C&lt;die&gt;-compatible function, such as C&lt;&lt; L&lt;Carp&gt;::croak &gt;&gt;,
that is called when there's a fatal error.

If this is set to C&lt;undef&gt;, no errors will ever be shown.

If this value is not passed, Mech uses C&lt;Carp::croak&gt; if L&lt;Carp&gt; is
installed, or C&lt;CORE::die&gt; if not.

=item * C&lt;&lt; quiet =&gt; [0|1] &gt;&gt;

Don't complain on warnings.  Setting C&lt;&lt; quiet =&gt; 1 &gt;&gt; is the same as
calling C&lt;&lt; $mech-&gt;quiet(1) &gt;&gt;.  Default is off.

=item * C&lt;&lt; stack_depth =&gt; $value &gt;&gt;

Sets the depth of the page stack that keeps track of all the
downloaded pages. Default is effectively infinite stack size.  If
the stack is eating up your memory, then set this to a smaller
number, say 5 or 10.  Setting this to zero means Mech will keep no
history.

=back

To support forms, WWW::Mechanize's constructor pushes POST
on to the agent's C&lt;requests_redirectable&gt; list (see also
L&lt;LWP::UserAgent&gt;.)

=cut

sub new {
    my $class = shift;

    my %parent_parms = (
        agent       =&gt; "WWW-Mechanize/$VERSION",
        cookie_jar  =&gt; {},
    );

    my %mech_parms = (
        autocheck   =&gt; ($class eq 'WWW::Mechanize' ? 1 : 0),
        onwarn      =&gt; \&amp;WWW::Mechanize::_warn,
        onerror     =&gt; \&amp;WWW::Mechanize::_die,
        quiet       =&gt; 0,
        stack_depth =&gt; 8675309,     # Arbitrarily humongous stack
        headers     =&gt; {},
        noproxy     =&gt; 0,
    );

    my %passed_parms = @_;

    # Keep the mech-specific parms before creating the object.
    while ( my($key,$value) = each %passed_parms ) {
        if ( exists $mech_parms{$key} ) {
            $mech_parms{$key} = $value;
        }
        else {
            $parent_parms{$key} = $value;
        }
    }

    my $self = $class-&gt;SUPER::new( %parent_parms );
    bless $self, $class;

    # Use the mech parms now that we have a mech object.
    for my $parm ( keys %mech_parms ) {
        $self-&gt;{$parm} = $mech_parms{$parm};
    }
    $self-&gt;{page_stack} = [];
    $self-&gt;env_proxy() unless $mech_parms{noproxy};

    # libwww-perl 5.800 (and before, I assume) has a problem where
    # $ua-&gt;{proxy} can be undef and clone() doesn't handle it.
    $self-&gt;{proxy} = {} unless defined $self-&gt;{proxy};
    push( @{$self-&gt;requests_redirectable}, 'POST' );

    $self-&gt;_reset_page();

    return $self;
}

=head2 $mech-&gt;agent_alias( $alias )

Sets the user agent string to the expanded version from a table of actual user strings.
I&lt;$alias&gt; can be one of the following:

=over 4

=item * Windows IE 6

=item * Windows Mozilla

=item * Mac Safari

=item * Mac Mozilla

=item * Linux Mozilla

=item * Linux Konqueror

=back

then it will be replaced with a more interesting one.  For instance,

    $mech-&gt;agent_alias( 'Windows IE 6' );

sets your User-Agent to

    Mozilla/4.0 (compatible; MSIE 6.0; Windows NT 5.1)

The list of valid aliases can be returned from C&lt;known_agent_aliases()&gt;.  The current list is:

=over

=item * Windows IE 6

=item * Windows Mozilla

=item * Mac Safari

=item * Mac Mozilla

=item * Linux Mozilla

=item * Linux Konqueror

=back

=cut

my %known_agents = (
    'Windows IE 6'      =&gt; 'Mozilla/4.0 (compatible; MSIE 6.0; Windows NT 5.1)',
    'Windows Mozilla'   =&gt; 'Mozilla/5.0 (Windows; U; Windows NT 5.0; en-US; rv:1.4b) Gecko/20030516 Mozilla Firebird/0.6',
    'Mac Safari'        =&gt; 'Mozilla/5.0 (Macintosh; U; PPC Mac OS X; en-us) AppleWebKit/85 (KHTML, like Gecko) Safari/85',
    'Mac Mozilla'       =&gt; 'Mozilla/5.0 (Macintosh; U; PPC Mac OS X Mach-O; en-US; rv:1.4a) Gecko/20030401',
    'Linux Mozilla'     =&gt; 'Mozilla/5.0 (X11; U; Linux i686; en-US; rv:1.4) Gecko/20030624',
    'Linux Konqueror'   =&gt; 'Mozilla/5.0 (compatible; Konqueror/3; Linux)',
);

sub agent_alias {
    my $self = shift;
    my $alias = shift;

    if ( defined $known_agents{$alias} ) {
        return $self-&gt;agent( $known_agents{$alias} );
    }
    else {
        $self-&gt;warn( qq{Unknown agent alias "$alias"} );
        return $self-&gt;agent();
    }
}

=head2 known_agent_aliases()

Returns a list of all the agent aliases that Mech knows about.

=cut

sub known_agent_aliases {
    return sort keys %known_agents;
}

=head1 PAGE-FETCHING METHODS

=head2 $mech-&gt;get( $uri )

Given a URL/URI, fetches it.  Returns an L&lt;HTTP::Response&gt; object.
I&lt;$uri&gt; can be a well-formed URL string, a L&lt;URI&gt; object, or a
L&lt;WWW::Mechanize::Link&gt; object.

The results are stored internally in the agent object, but you don't
know that.  Just use the accessors listed below.  Poking at the
internals is deprecated and subject to change in the future.

C&lt;get()&gt; is a well-behaved overloaded version of the method in
L&lt;LWP::UserAgent&gt;.  This lets you do things like

    $mech-&gt;get( $uri, ':content_file' =&gt; $tempfile );

and you can rest assured that the parms will get filtered down
appropriately.

B&lt;NOTE:&gt; Because C&lt;:content_file&gt; causes the page contents to be
stored in a file instead of the response object, some Mech functions
that expect it to be there won't work as expected. Use with caution.

=cut

sub get {
    my $self = shift;
    my $uri = shift;

    $uri = $uri-&gt;url if ref($uri) eq 'WWW::Mechanize::Link';

    $uri = $self-&gt;base
            ? URI-&gt;new_abs( $uri, $self-&gt;base )
            : URI-&gt;new( $uri );

    # It appears we are returning a super-class method,
    # but it in turn calls the request() method here in Mechanize
    return $self-&gt;SUPER::get( $uri-&gt;as_string, @_ );
}

=head2 $mech-&gt;put( $uri, content =&gt; $content )

PUTs I&lt;$content&gt; to $uri.  Returns an L&lt;HTTP::Response&gt; object.
I&lt;$uri&gt; can be a well-formed URI string, a L&lt;URI&gt; object, or a
L&lt;WWW::Mechanize::Link&gt; object.

=cut

sub put {
    my $self = shift;
    my $uri = shift;

    $uri = $uri-&gt;url if ref($uri) eq 'WWW::Mechanize::Link';

    $uri = $self-&gt;base
            ? URI-&gt;new_abs( $uri, $self-&gt;base )
            : URI-&gt;new( $uri );

    # It appears we are returning a super-class method,
    # but it in turn calls the request() method here in Mechanize
    return $self-&gt;_SUPER_put( $uri-&gt;as_string, @_ );
}


# Added until LWP::UserAgent has it.
sub _SUPER_put {
    require HTTP::Request::Common;
    my($self, @parameters) = @_;
    my @suff = $self-&gt;_process_colonic_headers(\@parameters,1);
    return $self-&gt;request( HTTP::Request::Common::PUT( @parameters ), @suff );
}

=head2 $mech-&gt;reload()

Acts like the reload button in a browser: repeats the current
request. The history (as per the L&lt;/back&gt; method) is not altered.

Returns the L&lt;HTTP::Response&gt; object from the reload, or C&lt;undef&gt;
if there's no current request.

=cut

sub reload {
    my $self = shift;

    return unless my $req = $self-&gt;{req};

    return $self-&gt;_update_page( $req, $self-&gt;_make_request( $req, @_ ) );
}

=head2 $mech-&gt;back()

The equivalent of hitting the "back" button in a browser.  Returns to
the previous page.  Won't go back past the first page. (Really, what
would it do if it could?)

Returns true if it could go back, or false if not.

=cut

sub back {
    my $self = shift;

    my $stack = $self-&gt;{page_stack};
    return unless $stack &amp;&amp; @{$stack};

    my $popped = pop @{$self-&gt;{page_stack}};
    my $req    = $popped-&gt;{req};
    my $res    = $popped-&gt;{res};

    $self-&gt;_update_page( $req, $res );

    return 1;
}

=head1 STATUS METHODS

=head2 $mech-&gt;success()

Returns a boolean telling whether the last request was successful.
If there hasn't been an operation yet, returns false.

This is a convenience function that wraps C&lt;&lt; $mech-&gt;res-&gt;is_success &gt;&gt;.

=cut

sub success {
    my $self = shift;

    return $self-&gt;res &amp;&amp; $self-&gt;res-&gt;is_success;
}


=head2 $mech-&gt;uri()

Returns the current URI as a L&lt;URI&gt; object. This object stringifies
to the URI itself.

=head2 $mech-&gt;response() / $mech-&gt;res()

Return the current response as an L&lt;HTTP::Response&gt; object.

Synonym for C&lt;&lt; $mech-&gt;response() &gt;&gt;

=head2 $mech-&gt;status()

Returns the HTTP status code of the response.  This is a 3-digit
number like 200 for OK, 404 for not found, and so on.

=head2 $mech-&gt;ct() / $mech-&gt;content_type()

Returns the content type of the response.

=head2 $mech-&gt;base()

Returns the base URI for the current response

=head2 $mech-&gt;forms()

When called in a list context, returns a list of the forms found in
the last fetched page. In a scalar context, returns a reference to
an array with those forms. The forms returned are all L&lt;HTML::Form&gt;
objects.

=head2 $mech-&gt;current_form()

Returns the current form as an L&lt;HTML::Form&gt; object.

=head2 $mech-&gt;links()

When called in a list context, returns a list of the links found in the
last fetched page.  In a scalar context it returns a reference to an array
with those links.  Each link is a L&lt;WWW::Mechanize::Link&gt; object.

=head2 $mech-&gt;is_html()

Returns true/false on whether our content is HTML, according to the
HTTP headers.

=cut

sub uri {
    my $self = shift;
    return $self-&gt;response-&gt;request-&gt;uri;
}

sub res {           my $self = shift; return $self-&gt;{res}; }
sub response {      my $self = shift; return $self-&gt;{res}; }
sub status {        my $self = shift; return $self-&gt;{status}; }
sub ct {            my $self = shift; return $self-&gt;{ct}; }
sub content_type {  my $self = shift; return $self-&gt;{ct}; }
sub base {          my $self = shift; return $self-&gt;{base}; }
sub is_html {
    my $self = shift;
    return defined $self-&gt;ct &amp;&amp;
        ($self-&gt;ct eq 'text/html' || $self-&gt;ct eq 'application/xhtml+xml');
}

=head2 $mech-&gt;title()

Returns the contents of the C&lt;&lt; &lt;TITLE&gt; &gt;&gt; tag, as parsed by
L&lt;HTML::HeadParser&gt;.  Returns undef if the content is not HTML.

=cut

sub title {
    my $self = shift;

    return unless $self-&gt;is_html;

    if ( not defined $self-&gt;{title} ) {
        require HTML::HeadParser;
        my $p = HTML::HeadParser-&gt;new;
        $p-&gt;parse($self-&gt;content);
        $self-&gt;{title} = $p-&gt;header('Title');
    }
    return $self-&gt;{title};
}

=head1 CONTENT-HANDLING METHODS

=head2 $mech-&gt;content(...)

Returns the content that the mech uses internally for the last page
fetched. Ordinarily this is the same as
C&lt;&lt; $mech-&gt;response()-&gt;decoded_content() &gt;&gt;,
but this may differ for HTML documents if L&lt;/update_html&gt; is
overloaded (in which case the value passed to the base-class
implementation of same will be returned), and/or extra named arguments
are passed to I&lt;content()&gt;:

=over 2

=item I&lt;&lt; $mech-&gt;content( format =&gt; 'text' ) &gt;&gt;

Returns a text-only version of the page, with all HTML markup
stripped. This feature requires I&lt;HTML::TreeBuilder&gt; to be installed,
or a fatal error will be thrown. This works only if the contents are
HTML.

=item I&lt;&lt; $mech-&gt;content( base_href =&gt; [$base_href|undef] ) &gt;&gt;

Returns the HTML document, modified to contain a
C&lt;&lt; &lt;base href="$base_href"&gt; &gt;&gt; mark-up in the header.
I&lt;$base_href&gt; is C&lt;&lt; $mech-&gt;base() &gt;&gt; if not specified. This is
handy to pass the HTML to e.g. L&lt;HTML::Display&gt;. This works only if
the contents are HTML.


=item I&lt;&lt; $mech-&gt;content( raw =&gt; 1 ) &gt;&gt;

Returns C&lt;&lt; $self-&gt;response()-&gt;content() &gt;&gt;, i.e. the raw contents from the
response.

=item I&lt;&lt; $mech-&gt;content( decoded_by_headers =&gt; 1 ) &gt;&gt;

Returns the content after applying all C&lt;Content-Encoding&gt; headers but
with not additional mangling.

=item I&lt;&lt; $mech-&gt;content( charset =&gt; $charset ) &gt;&gt;

Returns C&lt;&lt; $self-&gt;response()-&gt;decoded_content(charset =&gt; $charset) &gt;&gt;
(see L&lt;HTTP::Response&gt; for details).

=back

To preserve backwards compatibility, additional parameters will be
ignored unless none of C&lt;&lt; raw | decoded_by_headers | charset &gt;&gt; is
specified and the text is HTML, in which case an error will be triggered.

=cut

sub content {
    my $self = shift;
    my %parms = @_;

    my $content = $self-&gt;{content};
    if (delete $parms{raw}) {
        $content = $self-&gt;response()-&gt;content();
    }
    elsif (delete $parms{decoded_by_headers}) {
        $content = $self-&gt;response()-&gt;decoded_content(charset =&gt; 'none');
    }
    elsif (my $charset = delete $parms{charset}) {
        $content = $self-&gt;response()-&gt;decoded_content(charset =&gt; $charset);
    }
    elsif ( $self-&gt;is_html ) {
        if ( exists $parms{base_href} ) {
            my $base_href = (delete $parms{base_href}) || $self-&gt;base;
            $content=~s/&lt;head&gt;/&lt;head&gt;\n&lt;base href="$base_href"&gt;/i;
        }

        if ( my $format = delete $parms{format} ) {
            if ( $format eq 'text' ) {
                $content = $self-&gt;text;
            }
            else {
                $self-&gt;die( qq{Unknown "format" parameter "$format"} );
            }
        }

        $self-&gt;_check_unhandled_parms( %parms );
    }

    return $content;
}

=head2 $mech-&gt;text()

Returns the text of the current HTML content.  If the content isn't
HTML, $mech will die.

The text is extracted by parsing the content, and then the extracted
text is cached, so don't worry about performance of calling this
repeatedly.

=cut

sub text {
    my $self = shift;

    if ( not defined $self-&gt;{text} ) {
        require HTML::TreeBuilder;
        my $tree = HTML::TreeBuilder-&gt;new();
        $tree-&gt;parse( $self-&gt;content );
        $tree-&gt;eof();
        $tree-&gt;elementify(); # just for safety
        $self-&gt;{text} = $tree-&gt;as_text();
        $tree-&gt;delete;
    }

    return $self-&gt;{text};
}

sub _check_unhandled_parms {
    my $self  = shift;
    my %parms = @_;

    for my $cmd ( sort keys %parms ) {
        $self-&gt;die( qq{Unknown named argument "$cmd"} );
    }
}

=head1 LINK METHODS

=head2 $mech-&gt;links()

Lists all the links on the current page.  Each link is a
WWW::Mechanize::Link object. In list context, returns a list of all
links.  In scalar context, returns an array reference of all links.

=cut

sub links {
    my $self = shift;

    $self-&gt;_extract_links() unless $self-&gt;{links};

    return @{$self-&gt;{links}} if wantarray;
    return $self-&gt;{links};
}

=head2 $mech-&gt;follow_link(...)

Follows a specified link on the page.  You specify the match to be
found using the same parms that C&lt;L&lt;find_link()&gt;&gt; uses.

Here some examples:

=over 4

=item * 3rd link called "download"

    $mech-&gt;follow_link( text =&gt; 'download', n =&gt; 3 );

=item * first link where the URL has "download" in it, regardless of case:

    $mech-&gt;follow_link( url_regex =&gt; qr/download/i );

or

    $mech-&gt;follow_link( url_regex =&gt; qr/(?i:download)/ );

=item * 3rd link on the page

    $mech-&gt;follow_link( n =&gt; 3 );

=item * the link with the url

    $mech-&gt;follow_link( url =&gt; '/other/page' );

or

    $mech-&gt;follow_link( url =&gt; 'http://example.com/page' );

=back

Returns the result of the GET method (an HTTP::Response object) if
a link was found. If the page has no links, or the specified link
couldn't be found, returns undef.

=cut

sub follow_link {
    my $self = shift;
    $self-&gt;die( qq{Needs to get key-value pairs of parameters.} ) if @_ % 2;
    my %parms = ( n=&gt;1, @_ );

    if ( $parms{n} eq 'all' ) {
        delete $parms{n};
        $self-&gt;warn( q{follow_link(n=&gt;"all") is not valid} );
    }

    my $link = $self-&gt;find_link(%parms);
    if ( $link ) {
        return $self-&gt;get( $link-&gt;url );
    }

    if ( $self-&gt;{autocheck} ) {
        $self-&gt;die( 'Link not found' );
    }

    return;
}

=head2 $mech-&gt;find_link( ... )

Finds a link in the currently fetched page. It returns a
L&lt;WWW::Mechanize::Link&gt; object which describes the link.  (You'll
probably be most interested in the C&lt;url()&gt; property.)  If it fails
to find a link it returns undef.

You can take the URL part and pass it to the C&lt;get()&gt; method.  If
that's your plan, you might as well use the C&lt;follow_link()&gt; method
directly, since it does the C&lt;get()&gt; for you automatically.

Note that C&lt;&lt; &lt;FRAME SRC="..."&gt; &gt;&gt; tags are parsed out of the the HTML
and treated as links so this method works with them.

You can select which link to find by passing in one or more of these
key/value pairs:

=over 4

=item * C&lt;&lt; text =&gt; 'string', &gt;&gt; and C&lt;&lt; text_regex =&gt; qr/regex/, &gt;&gt;

C&lt;text&gt; matches the text of the link against I&lt;string&gt;, which must be an
exact match.  To select a link with text that is exactly "download", use

    $mech-&gt;find_link( text =&gt; 'download' );

C&lt;text_regex&gt; matches the text of the link against I&lt;regex&gt;.  To select a
link with text that has "download" anywhere in it, regardless of case, use

    $mech-&gt;find_link( text_regex =&gt; qr/download/i );

Note that the text extracted from the page's links are trimmed.  For
example, C&lt;&lt; &lt;a&gt; foo &lt;/a&gt; &gt;&gt; is stored as 'foo', and searching for
leading or trailing spaces will fail.

=item * C&lt;&lt; url =&gt; 'string', &gt;&gt; and C&lt;&lt; url_regex =&gt; qr/regex/, &gt;&gt;

Matches the URL of the link against I&lt;string&gt; or I&lt;regex&gt;, as appropriate.
The URL may be a relative URL, like F&lt;foo/bar.html&gt;, depending on how
it's coded on the page.

=item * C&lt;&lt; url_abs =&gt; string &gt;&gt; and C&lt;&lt; url_abs_regex =&gt; regex &gt;&gt;

Matches the absolute URL of the link against I&lt;string&gt; or I&lt;regex&gt;,
as appropriate.  The URL will be an absolute URL, even if it's relative
in the page.

=item * C&lt;&lt; name =&gt; string &gt;&gt; and C&lt;&lt; name_regex =&gt; regex &gt;&gt;

Matches the name of the link against I&lt;string&gt; or I&lt;regex&gt;, as appropriate.

=item * C&lt;&lt; id =&gt; string &gt;&gt; and C&lt;&lt; id_regex =&gt; regex &gt;&gt;

Matches the attribute 'id' of the link against I&lt;string&gt; or
I&lt;regex&gt;, as appropriate.

=item * C&lt;&lt; class =&gt; string &gt;&gt; and C&lt;&lt; class_regex =&gt; regex &gt;&gt;

Matches the attribute 'class' of the link against I&lt;string&gt; or
I&lt;regex&gt;, as appropriate.

=item * C&lt;&lt; tag =&gt; string &gt;&gt; and C&lt;&lt; tag_regex =&gt; regex &gt;&gt;

Matches the tag that the link came from against I&lt;string&gt; or I&lt;regex&gt;,
as appropriate.  The C&lt;tag_regex&gt; is probably most useful to check for
more than one tag, as in:

    $mech-&gt;find_link( tag_regex =&gt; qr/^(a|frame)$/ );

The tags and attributes looked at are defined below, at
L&lt;&lt; $mech-&gt;find_link() : link format &gt;&gt;.

=back

If C&lt;n&gt; is not specified, it defaults to 1.  Therefore, if you don't
specify any parms, this method defaults to finding the first link on the
page.

Note that you can specify multiple text or URL parameters, which
will be ANDed together.  For example, to find the first link with
text of "News" and with "cnn.com" in the URL, use:

    $mech-&gt;find_link( text =&gt; 'News', url_regex =&gt; qr/cnn\.com/ );

The return value is a reference to an array containing a
L&lt;WWW::Mechanize::Link&gt; object for every link in C&lt;&lt; $self-&gt;content &gt;&gt;.

The links come from the following:

=over 4

=item C&lt;&lt; &lt;a href=...&gt; &gt;&gt;

=item C&lt;&lt; &lt;area href=...&gt; &gt;&gt;

=item C&lt;&lt; &lt;frame src=...&gt; &gt;&gt;

=item C&lt;&lt; &lt;iframe src=...&gt; &gt;&gt;

=item C&lt;&lt; &lt;link href=...&gt; &gt;&gt;

=item C&lt;&lt; &lt;meta content=...&gt; &gt;&gt;

=back

=cut

sub find_link {
    my $self = shift;
    my %parms = ( n=&gt;1, @_ );

    my $wantall = ( $parms{n} eq 'all' );

    $self-&gt;_clean_keys( \%parms, qr/^(n|(text|url|url_abs|name|tag|id|class)(_regex)?)$/ );

    my @links = $self-&gt;links or return;

    my $nmatches = 0;
    my @matches;
    for my $link ( @links ) {
        if ( _match_any_link_parms($link,\%parms) ) {
            if ( $wantall ) {
                push( @matches, $link );
            }
            else {
                ++$nmatches;
                return $link if $nmatches &gt;= $parms{n};
            }
        }
    } # for @links

    if ( $wantall ) {
        return @matches if wantarray;
        return \@matches;
    }

    return;
} # find_link

# Used by find_links to check for matches
# The logic is such that ALL parm criteria that are given must match
sub _match_any_link_parms {
    my $link = shift;
    my $p = shift;

    # No conditions, anything matches
    return 1 unless keys %$p;

    return if defined $p-&gt;{url}           &amp;&amp; !($link-&gt;url eq $p-&gt;{url} );
    return if defined $p-&gt;{url_regex}     &amp;&amp; !($link-&gt;url =~ $p-&gt;{url_regex} );
    return if defined $p-&gt;{url_abs}       &amp;&amp; !($link-&gt;url_abs eq $p-&gt;{url_abs} );
    return if defined $p-&gt;{url_abs_regex} &amp;&amp; !($link-&gt;url_abs =~ $p-&gt;{url_abs_regex} );
    return if defined $p-&gt;{text}          &amp;&amp; !(defined($link-&gt;text) &amp;&amp; $link-&gt;text eq $p-&gt;{text} );
    return if defined $p-&gt;{text_regex}    &amp;&amp; !(defined($link-&gt;text) &amp;&amp; $link-&gt;text =~ $p-&gt;{text_regex} );
    return if defined $p-&gt;{name}          &amp;&amp; !(defined($link-&gt;name) &amp;&amp; $link-&gt;name eq $p-&gt;{name} );
    return if defined $p-&gt;{name_regex}    &amp;&amp; !(defined($link-&gt;name) &amp;&amp; $link-&gt;name =~ $p-&gt;{name_regex} );
    return if defined $p-&gt;{tag}           &amp;&amp; !($link-&gt;tag &amp;&amp; $link-&gt;tag eq $p-&gt;{tag} );
    return if defined $p-&gt;{tag_regex}     &amp;&amp; !($link-&gt;tag &amp;&amp; $link-&gt;tag =~ $p-&gt;{tag_regex} );

    return if defined $p-&gt;{id}            &amp;&amp; !($link-&gt;attrs-&gt;{id} &amp;&amp; $link-&gt;attrs-&gt;{id} eq $p-&gt;{id} );
    return if defined $p-&gt;{id_regex}      &amp;&amp; !($link-&gt;attrs-&gt;{id} &amp;&amp; $link-&gt;attrs-&gt;{id} =~ $p-&gt;{id_regex} );
    return if defined $p-&gt;{class}         &amp;&amp; !($link-&gt;attrs-&gt;{class} &amp;&amp; $link-&gt;attrs-&gt;{class} eq $p-&gt;{class} );
    return if defined $p-&gt;{class_regex}   &amp;&amp; !($link-&gt;attrs-&gt;{class} &amp;&amp; $link-&gt;attrs-&gt;{class} =~ $p-&gt;{class_regex} );

    # Success: everything that was defined passed.
    return 1;

}

# Cleans the %parms parameter for the find_link and find_image methods.
sub _clean_keys {
    my $self = shift;
    my $parms = shift;
    my $rx_keyname = shift;

    for my $key ( keys %$parms ) {
        my $val = $parms-&gt;{$key};
        if ( $key !~ qr/$rx_keyname/ ) {
            $self-&gt;warn( qq{Unknown link-finding parameter "$key"} );
            delete $parms-&gt;{$key};
            next;
        }

        my $key_regex = ( $key =~ /_regex$/ );
        my $val_regex = ( ref($val) eq 'Regexp' );

        if ( $key_regex ) {
            if ( !$val_regex ) {
                $self-&gt;warn( qq{$val passed as $key is not a regex} );
                delete $parms-&gt;{$key};
                next;
            }
        }
        else {
            if ( $val_regex ) {
                $self-&gt;warn( qq{$val passed as '$key' is a regex} );
                delete $parms-&gt;{$key};
                next;
            }
            if ( $val =~ /^\s|\s$/ ) {
                $self-&gt;warn( qq{'$val' is space-padded and cannot succeed} );
                delete $parms-&gt;{$key};
                next;
            }
        }
    } # for keys %parms

    return;
} # _clean_keys()


=head2 $mech-&gt;find_all_links( ... )

Returns all the links on the current page that match the criteria.  The
method for specifying link criteria is the same as in C&lt;L&lt;/find_link()&gt;&gt;.
Each of the links returned is a L&lt;WWW::Mechanize::Link&gt; object.

In list context, C&lt;find_all_links()&gt; returns a list of the links.
Otherwise, it returns a reference to the list of links.

C&lt;find_all_links()&gt; with no parameters returns all links in the
page.

=cut

sub find_all_links {
    my $self = shift;
    return $self-&gt;find_link( @_, n=&gt;'all' );
}

=head2 $mech-&gt;find_all_inputs( ... criteria ... )

find_all_inputs() returns an array of all the input controls in the
current form whose properties match all of the regexes passed in.
The controls returned are all descended from HTML::Form::Input.

If no criteria are passed, all inputs will be returned.

If there is no current page, there is no form on the current
page, or there are no submit controls in the current form
then the return will be an empty array.

You may use a regex or a literal string:

    # get all textarea controls whose names begin with "customer"
    my @customer_text_inputs = $mech-&gt;find_all_inputs(
        type       =&gt; 'textarea',
        name_regex =&gt; qr/^customer/,
    );

    # get all text or textarea controls called "customer"
    my @customer_text_inputs = $mech-&gt;find_all_inputs(
        type_regex =&gt; qr/^(text|textarea)$/,
        name       =&gt; 'customer',
    );

=cut

sub find_all_inputs {
    my $self = shift;
    my %criteria = @_;

    my $form = $self-&gt;current_form() or return;

    my @found;
    foreach my $input ( $form-&gt;inputs ) { # check every pattern for a match on the current hash
        my $matched = 1;
        foreach my $criterion ( sort keys %criteria ) { # Sort so we're deterministic
            my $field = $criterion;
            my $is_regex = ( $field =~ s/(?:_regex)$// );
            my $what = $input-&gt;{$field};
            $matched = defined($what) &amp;&amp; (
                $is_regex
                    ? ( $what =~ $criteria{$criterion} )
                    : ( $what eq $criteria{$criterion} )
                );
            last if !$matched;
        }
        push @found, $input if $matched;
    }
    return @found;
}

=head2 $mech-&gt;find_all_submits( ... criteria ... )

C&lt;find_all_submits()&gt; does the same thing as C&lt;find_all_inputs()&gt;
except that it only returns controls that are submit controls,
ignoring other types of input controls like text and checkboxes.

=cut

sub find_all_submits {
    my $self = shift;

    return $self-&gt;find_all_inputs( @_, type_regex =&gt; qr/^(submit|image)$/ );
}


=head1 IMAGE METHODS

=head2 $mech-&gt;images

Lists all the images on the current page.  Each image is a
WWW::Mechanize::Image object. In list context, returns a list of all
images.  In scalar context, returns an array reference of all images.

=cut

sub images {
    my $self = shift;

    $self-&gt;_extract_images() unless $self-&gt;{images};

    return @{$self-&gt;{images}} if wantarray;
    return $self-&gt;{images};
}

=head2 $mech-&gt;find_image()

Finds an image in the current page. It returns a
L&lt;WWW::Mechanize::Image&gt; object which describes the image.  If it fails
to find an image it returns undef.

You can select which image to find by passing in one or more of these
key/value pairs:

=over 4

=item * C&lt;&lt; alt =&gt; 'string' &gt;&gt; and C&lt;&lt; alt_regex =&gt; qr/regex/, &gt;&gt;

C&lt;alt&gt; matches the ALT attribute of the image against I&lt;string&gt;, which must be an
exact match. To select a image with an ALT tag that is exactly "download", use

    $mech-&gt;find_image( alt =&gt; 'download' );

C&lt;alt_regex&gt; matches the ALT attribute of the image  against a regular
expression.  To select an image with an ALT attribute that has "download"
anywhere in it, regardless of case, use

    $mech-&gt;find_image( alt_regex =&gt; qr/download/i );

=item * C&lt;&lt; url =&gt; 'string', &gt;&gt; and C&lt;&lt; url_regex =&gt; qr/regex/, &gt;&gt;

Matches the URL of the image against I&lt;string&gt; or I&lt;regex&gt;, as appropriate.
The URL may be a relative URL, like F&lt;foo/bar.html&gt;, depending on how
it's coded on the page.

=item * C&lt;&lt; url_abs =&gt; string &gt;&gt; and C&lt;&lt; url_abs_regex =&gt; regex &gt;&gt;

Matches the absolute URL of the image against I&lt;string&gt; or I&lt;regex&gt;,
as appropriate.  The URL will be an absolute URL, even if it's relative
in the page.

=item * C&lt;&lt; tag =&gt; string &gt;&gt; and C&lt;&lt; tag_regex =&gt; regex &gt;&gt;

Matches the tag that the image came from against I&lt;string&gt; or I&lt;regex&gt;,
as appropriate.  The C&lt;tag_regex&gt; is probably most useful to check for
more than one tag, as in:

    $mech-&gt;find_image( tag_regex =&gt; qr/^(img|input)$/ );

The tags supported are C&lt;&lt; &lt;img&gt; &gt;&gt; and C&lt;&lt; &lt;input&gt; &gt;&gt;.

=back

If C&lt;n&gt; is not specified, it defaults to 1.  Therefore, if you don't
specify any parms, this method defaults to finding the first image on the
page.

Note that you can specify multiple ALT or URL parameters, which
will be ANDed together.  For example, to find the first image with
ALT text of "News" and with "cnn.com" in the URL, use:

    $mech-&gt;find_image( image =&gt; 'News', url_regex =&gt; qr/cnn\.com/ );

The return value is a reference to an array containing a
L&lt;WWW::Mechanize::Image&gt; object for every image in C&lt;&lt; $self-&gt;content &gt;&gt;.

=cut

sub find_image {
    my $self = shift;
    my %parms = ( n=&gt;1, @_ );

    my $wantall = ( $parms{n} eq 'all' );

    $self-&gt;_clean_keys( \%parms, qr/^(n|(alt|url|url_abs|tag)(_regex)?)$/ );

    my @images = $self-&gt;images or return;

    my $nmatches = 0;
    my @matches;
    for my $image ( @images ) {
        if ( _match_any_image_parms($image,\%parms) ) {
            if ( $wantall ) {
                push( @matches, $image );
            }
            else {
                ++$nmatches;
                return $image if $nmatches &gt;= $parms{n};
            }
        }
    } # for @images

    if ( $wantall ) {
        return @matches if wantarray;
        return \@matches;
    }

    return;
}

# Used by find_images to check for matches
# The logic is such that ALL parm criteria that are given must match
sub _match_any_image_parms {
    my $image = shift;
    my $p = shift;

    # No conditions, anything matches
    return 1 unless keys %$p;

    return if defined $p-&gt;{url}           &amp;&amp; !($image-&gt;url eq $p-&gt;{url} );
    return if defined $p-&gt;{url_regex}     &amp;&amp; !($image-&gt;url =~ $p-&gt;{url_regex} );
    return if defined $p-&gt;{url_abs}       &amp;&amp; !($image-&gt;url_abs eq $p-&gt;{url_abs} );
    return if defined $p-&gt;{url_abs_regex} &amp;&amp; !($image-&gt;url_abs =~ $p-&gt;{url_abs_regex} );
    return if defined $p-&gt;{alt}           &amp;&amp; !(defined($image-&gt;alt) &amp;&amp; $image-&gt;alt eq $p-&gt;{alt} );
    return if defined $p-&gt;{alt_regex}     &amp;&amp; !(defined($image-&gt;alt) &amp;&amp; $image-&gt;alt =~ $p-&gt;{alt_regex} );
    return if defined $p-&gt;{tag}           &amp;&amp; !($image-&gt;tag &amp;&amp; $image-&gt;tag eq $p-&gt;{tag} );
    return if defined $p-&gt;{tag_regex}     &amp;&amp; !($image-&gt;tag &amp;&amp; $image-&gt;tag =~ $p-&gt;{tag_regex} );

    # Success: everything that was defined passed.
    return 1;
}


=head2 $mech-&gt;find_all_images( ... )

Returns all the images on the current page that match the criteria.  The
method for specifying image criteria is the same as in C&lt;L&lt;/find_image()&gt;&gt;.
Each of the images returned is a L&lt;WWW::Mechanize::Image&gt; object.

In list context, C&lt;find_all_images()&gt; returns a list of the images.
Otherwise, it returns a reference to the list of images.

C&lt;find_all_images()&gt; with no parameters returns all images in the page.

=cut

sub find_all_images {
    my $self = shift;
    return $self-&gt;find_image( @_, n=&gt;'all' );
}

=head1 FORM METHODS

These methods let you work with the forms on a page.  The idea is
to choose a form that you'll later work with using the field methods
below.

=head2 $mech-&gt;forms

Lists all the forms on the current page.  Each form is an L&lt;HTML::Form&gt;
object.  In list context, returns a list of all forms.  In scalar
context, returns an array reference of all forms.

=cut

sub forms {
    my $self = shift;

    $self-&gt;_extract_forms() unless $self-&gt;{forms};

    return @{$self-&gt;{forms}} if wantarray;
    return $self-&gt;{forms};
}

sub current_form {
    my $self = shift;

    if ( !$self-&gt;{current_form} ) {
        $self-&gt;form_number(1);
    }

    return $self-&gt;{current_form};
}

=head2 $mech-&gt;form_number($number)

Selects the I&lt;number&gt;th form on the page as the target for subsequent
calls to C&lt;L&lt;/field()&gt;&gt; and C&lt;L&lt;/click()&gt;&gt;.  Also returns the form that was
selected.

If it is found, the form is returned as an L&lt;HTML::Form&gt; object and set internally
for later use with Mech's form methods such as C&lt;L&lt;/field()&gt;&gt; and C&lt;L&lt;/click()&gt;&gt;.

Emits a warning and returns undef if no form is found.

The first form is number 1, not zero.

=cut

sub form_number {
    my ($self, $form) = @_;
    # XXX Should we die if no $form is defined? Same question for form_name()

    my $forms = $self-&gt;forms;
    if ( $forms-&gt;[$form-1] ) {
        $self-&gt;{current_form} = $forms-&gt;[$form-1];
        return $self-&gt;{current_form};
    }

    return;
}

=head2 $mech-&gt;form_name( $name )

Selects a form by name.  If there is more than one form on the page
with that name, then the first one is used, and a warning is
generated.

If it is found, the form is returned as an L&lt;HTML::Form&gt; object and
set internally for later use with Mech's form methods such as
C&lt;L&lt;/field()&gt;&gt; and C&lt;L&lt;/click()&gt;&gt;.

Returns undef if no form is found.

=cut

sub form_name {
    my ($self, $form) = @_;

    my $temp;
    my @matches = grep {defined($temp = $_-&gt;attr('name')) and ($temp eq $form) } $self-&gt;forms;

    my $nmatches = @matches;
    if ( $nmatches &gt; 0 ) {
        if ( $nmatches &gt; 1 ) {
            $self-&gt;warn( "There are $nmatches forms named $form.  The first one was used." )
        }
        return $self-&gt;{current_form} = $matches[0];
    }

    return;
}

=head2 $mech-&gt;form_id( $name )

Selects a form by ID.  If there is more than one form on the page
with that ID, then the first one is used, and a warning is generated.

If it is found, the form is returned as an L&lt;HTML::Form&gt; object and
set internally for later use with Mech's form methods such as
C&lt;L&lt;/field()&gt;&gt; and C&lt;L&lt;/click()&gt;&gt;.

Returns undef if no form is found.

=cut

sub form_id {
    my ($self, $formid) = @_;

    my $temp;
    my @matches = grep { defined($temp = $_-&gt;attr('id')) and ($temp eq $formid) } $self-&gt;forms;
    if ( @matches ) {
        $self-&gt;warn( 'There are ', scalar @matches, " forms with ID $formid.  The first one was used." )
            if @matches &gt; 1;
        return $self-&gt;{current_form} = $matches[0];
    }
    else {
        $self-&gt;warn( qq{ There is no form with ID "$formid"} );
        return undef;
    }
}


=head2 $mech-&gt;form_with_fields( @fields )

Selects a form by passing in a list of field names it must contain.  If there
is more than one form on the page with that matches, then the first one is used,
and a warning is generated.

If it is found, the form is returned as an L&lt;HTML::Form&gt; object and set internally
for later used with Mech's form methods such as C&lt;L&lt;/field()&gt;&gt; and C&lt;L&lt;/click()&gt;&gt;.

Returns undef if no form is found.

Note that this functionality requires libwww-perl 5.69 or higher.

=cut

sub form_with_fields {
    my ($self, @fields) = @_;
    die 'no fields provided' unless scalar @fields;

    my @matches;
    FORMS: for my $form (@{ $self-&gt;forms }) {
        my @fields_in_form = $form-&gt;param();
        for my $field (@fields) {
            next FORMS unless grep { $_ eq $field } @fields_in_form;
        }
        push @matches, $form;
    }

    my $nmatches = @matches;
    if ( $nmatches &gt; 0 ) {
        if ( $nmatches &gt; 1 ) {
            $self-&gt;warn( "There are $nmatches forms with the named fields.  The first one was used." )
        }
        return $self-&gt;{current_form} = $matches[0];
    }
    else {
        $self-&gt;warn( qq{There is no form with the requested fields} );
        return undef;
    }
}

=head1 FIELD METHODS

These methods allow you to set the values of fields in a given form.

=head2 $mech-&gt;field( $name, $value, $number )

=head2 $mech-&gt;field( $name, \@values, $number )

Given the name of a field, set its value to the value specified.
This applies to the current form (as set by the L&lt;/form_name()&gt; or
L&lt;/form_number()&gt; method or defaulting to the first form on the
page).

The optional I&lt;$number&gt; parameter is used to distinguish between two fields
with the same name.  The fields are numbered from 1.

=cut

sub field {
    my ($self, $name, $value, $number) = @_;
    $number ||= 1;

    my $form = $self-&gt;current_form();
    if ($number &gt; 1) {
        $form-&gt;find_input($name, undef, $number)-&gt;value($value);
    }
    else {
        if ( ref($value) eq 'ARRAY' ) {
            $form-&gt;param($name, $value);
        }
        else {
            $form-&gt;value($name =&gt; $value);
        }
    }
}

=head2 $mech-&gt;select($name, $value)

=head2 $mech-&gt;select($name, \@values)

Given the name of a C&lt;select&gt; field, set its value to the value
specified.  If the field is not C&lt;&lt; &lt;select multiple&gt; &gt;&gt; and the
C&lt;$value&gt; is an array, only the B&lt;first&gt; value will be set.  [Note:
the documentation previously claimed that only the last value would
be set, but this was incorrect.]  Passing C&lt;$value&gt; as a hash with
an C&lt;n&gt; key selects an item by number (e.g.
C&lt;&lt; {n =&gt; 3} &gt;&gt; or C&lt;&lt; {n =&gt; [2,4]} &gt;&gt;).
The numbering starts at 1.  This applies to the current form.

If you have a field with C&lt;&lt; &lt;select multiple&gt; &gt;&gt; and you pass a single
C&lt;$value&gt;, then C&lt;$value&gt; will be added to the list of fields selected,
without clearing the others.  However, if you pass an array reference,
then all previously selected values will be cleared.

Returns true on successfully setting the value. On failure, returns
false and calls C&lt;&lt; $self&gt;warn() &gt;&gt; with an error message.

=cut

sub select {
    my ($self, $name, $value) = @_;

    my $form = $self-&gt;current_form();

    my $input = $form-&gt;find_input($name);
    if (!$input) {
        $self-&gt;warn( qq{Input "$name" not found} );
        return;
    }

    if ($input-&gt;type ne 'option') {
        $self-&gt;warn( qq{Input "$name" is not type "select"} );
        return;
    }

    # For $mech-&gt;select($name, {n =&gt; 3}) or $mech-&gt;select($name, {n =&gt; [2,4]}),
    # transform the 'n' number(s) into value(s) and put it in $value.
    if (ref($value) eq 'HASH') {
        for (keys %$value) {
            $self-&gt;warn(qq{Unknown select value parameter "$_"})
              unless $_ eq 'n';
        }

        if (defined($value-&gt;{n})) {
            my @inputs = $form-&gt;find_input($name, 'option');
            my @values = ();
            # distinguish between multiple and non-multiple selects
            # (see INPUTS section of `perldoc HTML::Form`)
            if (@inputs == 1) {
                @values = $inputs[0]-&gt;possible_values();
            }
            else {
                foreach my $input (@inputs) {
                    my @possible = $input-&gt;possible_values();
                    push @values, pop @possible;
                }
            }

            my $n = $value-&gt;{n};
            if (ref($n) eq 'ARRAY') {
                $value = [];
                for (@$n) {
                    unless (/^\d+$/) {
                        $self-&gt;warn(qq{"n" value "$_" is not a positive integer});
                        return;
                    }
                    push @$value, $values[$_ - 1];  # might be undef
                }
            }
            elsif (!ref($n) &amp;&amp; $n =~ /^\d+$/) {
                $value = $values[$n - 1];           # might be undef
            }
            else {
                $self-&gt;warn('"n" value is not a positive integer or an array ref');
                return;
            }
        }
        else {
            $self-&gt;warn('Hash value is invalid');
            return;
        }
    } # hashref

    if (ref($value) eq 'ARRAY') {
        $form-&gt;param($name, $value);
        return 1;
    }

    $form-&gt;value($name =&gt; $value);
    return 1;
}

=head2 $mech-&gt;set_fields( $name =&gt; $value ... )

This method sets multiple fields of the current form. It takes a list
of field name and value pairs. If there is more than one field with
the same name, the first one found is set. If you want to select which
of the duplicate field to set, use a value which is an anonymous array
which has the field value and its number as the 2 elements.

        # set the second foo field
        $mech-&gt;set_fields( $name =&gt; [ 'foo', 2 ] );

The fields are numbered from 1.

This applies to the current form.

=cut

sub set_fields {
    my $self = shift;
    my %fields = @_;

    my $form = $self-&gt;current_form or $self-&gt;die( 'No form defined' );

    while ( my ( $field, $value ) = each %fields ) {
        if ( ref $value eq 'ARRAY' ) {
            $form-&gt;find_input( $field, undef,
                         $value-&gt;[1])-&gt;value($value-&gt;[0] );
        }
        else {
            $form-&gt;value($field =&gt; $value);
        }
    } # while
} # set_fields()

=head2 $mech-&gt;set_visible( @criteria )

This method sets fields of the current form without having to know
their names.  So if you have a login screen that wants a username and
password, you do not have to fetch the form and inspect the source (or
use the F&lt;mech-dump&gt; utility, installed with WWW::Mechanize) to see
what the field names are; you can just say

    $mech-&gt;set_visible( $username, $password );

and the first and second fields will be set accordingly.  The method
is called set_I&lt;visible&gt; because it acts only on visible fields;
hidden form inputs are not considered.  The order of the fields is
the order in which they appear in the HTML source which is nearly
always the order anyone viewing the page would think they are in,
but some creative work with tables could change that; caveat user.

Each element in C&lt;@criteria&gt; is either a field value or a field
specifier.  A field value is a scalar.  A field specifier allows
you to specify the I&lt;type&gt; of input field you want to set and is
denoted with an arrayref containing two elements.  So you could
specify the first radio button with

    $mech-&gt;set_visible( [ radio =&gt; 'KCRW' ] );

Field values and specifiers can be intermixed, hence

    $mech-&gt;set_visible( 'fred', 'secret', [ option =&gt; 'Checking' ] );

would set the first two fields to "fred" and "secret", and the I&lt;next&gt;
C&lt;OPTION&gt; menu field to "Checking".

The possible field specifier types are: "text", "password", "hidden",
"textarea", "file", "image", "submit", "radio", "checkbox" and "option".

C&lt;set_visible&gt; returns the number of values set.

=cut

sub set_visible {
    my $self = shift;

    my $form = $self-&gt;current_form;
    my @inputs = $form-&gt;inputs;

    my $num_set = 0;
    for my $value ( @_ ) {
        # Handle type/value pairs an arrayref
        if ( ref $value eq 'ARRAY' ) {
            my ( $type, $value ) = @$value;
            while ( my $input = shift @inputs ) {
                next if $input-&gt;type eq 'hidden';
                if ( $input-&gt;type eq $type ) {
                    $input-&gt;value( $value );
                    $num_set++;
                    last;
                }
            } # while
        }
        # by default, it's a value
        else {
            while ( my $input = shift @inputs ) {
                next if $input-&gt;type eq 'hidden';
                $input-&gt;value( $value );
                $num_set++;
                last;
            } # while
        }
    } # for

    return $num_set;
} # set_visible()

=head2 $mech-&gt;tick( $name, $value [, $set] )

"Ticks" the first checkbox that has both the name and value associated
with it on the current form.  Dies if there is no named check box for
that value.  Passing in a false value as the third optional argument
will cause the checkbox to be unticked.

=cut

sub tick {
    my $self = shift;
    my $name = shift;
    my $value = shift;
    my $set = @_ ? shift : 1;  # default to 1 if not passed

    # loop though all the inputs
    my $index = 0;
    while ( my $input = $self-&gt;current_form-&gt;find_input( $name, 'checkbox', $index ) ) {
        # Can't guarantee that the first element will be undef and the second
        # element will be the right name
        foreach my $val ($input-&gt;possible_values()) {
            next unless defined $val;
            if ($val eq $value) {
                $input-&gt;value($set ? $value : undef);
                return;
            }
        }

        # move onto the next input
        $index++;
    } # while

    # got self far?  Didn't find anything
    $self-&gt;warn( qq{No checkbox "$name" for value "$value" in form} );
} # tick()

=head2 $mech-&gt;untick($name, $value)

Causes the checkbox to be unticked.  Shorthand for
C&lt;tick($name,$value,undef)&gt;

=cut

sub untick {
    shift-&gt;tick(shift,shift,undef);
}

=head2 $mech-&gt;value( $name [, $number] )

Given the name of a field, return its value. This applies to the current
form.

The optional I&lt;$number&gt; parameter is used to distinguish between two fields
with the same name.  The fields are numbered from 1.

If the field is of type file (file upload field), the value is always
cleared to prevent remote sites from downloading your local files.
To upload a file, specify its file name explicitly.

=cut

sub value {
    my $self = shift;
    my $name = shift;
    my $number = shift || 1;

    my $form = $self-&gt;current_form;
    if ( $number &gt; 1 ) {
        return $form-&gt;find_input( $name, undef, $number )-&gt;value();
    }
    else {
        return $form-&gt;value( $name );
    }
} # value

=head2 $mech-&gt;click( $button [, $x, $y] )

Has the effect of clicking a button on the current form.  The first
argument is the name of the button to be clicked.  The second and
third arguments (optional) allow you to specify the (x,y) coordinates
of the click.

If there is only one button on the form, C&lt;&lt; $mech-&gt;click() &gt;&gt; with
no arguments simply clicks that one button.

Returns an L&lt;HTTP::Response&gt; object.

=cut

sub click {
    my ($self, $button, $x, $y) = @_;
    for ($x, $y) { $_ = 1 unless defined; }
    my $request = $self-&gt;current_form-&gt;click($button, $x, $y);
    return $self-&gt;request( $request );
}

=head2 $mech-&gt;click_button( ... )

Has the effect of clicking a button on the current form by specifying
its name, value, or index.  Its arguments are a list of key/value
pairs.  Only one of name, number, input or value must be specified in
the keys.

=over 4

=item * C&lt;&lt; name =&gt; name &gt;&gt;

Clicks the button named I&lt;name&gt; in the current form.

=item * C&lt;&lt; number =&gt; n &gt;&gt;

Clicks the I&lt;n&gt;th button in the current form. Numbering starts at 1.

=item * C&lt;&lt; value =&gt; value &gt;&gt;

Clicks the button with the value I&lt;value&gt; in the current form.

=item * C&lt;&lt; input =&gt; $inputobject &gt;&gt;

Clicks on the button referenced by $inputobject, an instance of
L&lt;HTML::Form::SubmitInput&gt; obtained e.g. from

    $mech-&gt;current_form()-&gt;find_input( undef, 'submit' )

$inputobject must belong to the current form.

=item * C&lt;&lt; x =&gt; x &gt;&gt;

=item * C&lt;&lt; y =&gt; y &gt;&gt;

These arguments (optional) allow you to specify the (x,y) coordinates
of the click.

=back

=cut

sub click_button {
    my $self = shift;
    my %args = @_;

    for ( keys %args ) {
        if ( !/^(number|name|value|input|x|y)$/ ) {
            $self-&gt;warn( qq{Unknown click_button parameter "$_"} );
        }
    }

    for ($args{x}, $args{y}) {
        $_ = 1 unless defined;
    }

    my $form = $self-&gt;current_form or $self-&gt;die( 'click_button: No form has been selected' );

    my $request;
    if ( $args{name} ) {
        $request = $form-&gt;click( $args{name}, $args{x}, $args{y} );
    }
    elsif ( $args{number} ) {
        my $input = $form-&gt;find_input( undef, 'submit', $args{number} );
        $request = $input-&gt;click( $form, $args{x}, $args{y} );
    }
    elsif ( $args{input} ) {
        $request = $args{input}-&gt;click( $form, $args{x}, $args{y} );
    }
    elsif ( $args{value} ) {
        my $i = 1;
        while ( my $input = $form-&gt;find_input(undef, 'submit', $i) ) {
            if ( $args{value} &amp;&amp; ($args{value} eq $input-&gt;value) ) {
                $request = $input-&gt;click( $form, $args{x}, $args{y} );
                last;
            }
            $i++;
        } # while
    } # $args{value}

    return $self-&gt;request( $request );
}

=head2 $mech-&gt;submit()

Submits the page, without specifying a button to click.  Actually,
no button is clicked at all.

Returns an L&lt;HTTP::Response&gt; object.

This used to be a synonym for C&lt;&lt; $mech-&gt;click( 'submit' ) &gt;&gt;, but is no
longer so.

=cut

sub submit {
    my $self = shift;

    my $request = $self-&gt;current_form-&gt;make_request;
    return $self-&gt;request( $request );
}

=head2 $mech-&gt;submit_form( ... )

This method lets you select a form from the previously fetched page,
fill in its fields, and submit it. It combines the form_number/form_name,
set_fields and click methods into one higher level call. Its arguments
are a list of key/value pairs, all of which are optional.

=over 4

=item * C&lt;&lt; fields =&gt; \%fields &gt;&gt;

Specifies the fields to be filled in the current form.

=item * C&lt;&lt; with_fields =&gt; \%fields &gt;&gt;

Probably all you need for the common case. It combines a smart form selector
and data setting in one operation. It selects the first form that contains all
fields mentioned in C&lt;\%fields&gt;.  This is nice because you don't need to know
the name or number of the form to do this.

(calls C&lt;L&lt;/form_with_fields()&gt;&gt; and C&lt;L&lt;/set_fields()&gt;&gt;).

If you choose this, the form_number, form_name, form_id and fields options will be ignored.

=item * C&lt;&lt; form_number =&gt; n &gt;&gt;

Selects the I&lt;n&gt;th form (calls C&lt;L&lt;/form_number()&gt;&gt;).  If this parm is not
specified, the currently-selected form is used.

=item * C&lt;&lt; form_name =&gt; name &gt;&gt;

Selects the form named I&lt;name&gt; (calls C&lt;L&lt;/form_name()&gt;&gt;)

=item * C&lt;&lt; form_id =&gt; ID &gt;&gt;

Selects the form with ID I&lt;ID&gt; (calls C&lt;L&lt;/form_id()&gt;&gt;)

=item * C&lt;&lt; button =&gt; button &gt;&gt;

Clicks on button I&lt;button&gt; (calls C&lt;L&lt;/click()&gt;&gt;)

=item * C&lt;&lt; x =&gt; x, y =&gt; y &gt;&gt;

Sets the x or y values for C&lt;L&lt;/click()&gt;&gt;

=back

If no form is selected, the first form found is used.

If I&lt;button&gt; is not passed, then the C&lt;L&lt;/submit()&gt;&gt; method is used instead.

If you want to submit a file and get its content from a scalar rather
than a file in the filesystem, you can use:

    $mech-&gt;submit_form(with_fields =&gt; { logfile =&gt; [ [ undef, 'whatever', Content =&gt; $content ], 1 ] } );

Returns an L&lt;HTTP::Response&gt; object.

=cut

sub submit_form {
    my( $self, %args ) = @_;

    for ( keys %args ) {
        if ( !/^(form_(number|name|fields|id)|(with_)?fields|button|x|y)$/ ) {
            # XXX Why not die here?
            $self-&gt;warn( qq{Unknown submit_form parameter "$_"} );
        }
    }

    my $fields;
    for (qw/with_fields fields/) {
        if ($args{$_}) {
            if ( ref $args{$_} eq 'HASH' ) {
                $fields = $args{$_};
            }
            else {
                die "$_ arg to submit_form must be a hashref";
            }
            last;
        }
    }

    if ( $args{with_fields} ) {
        $fields || die q{must submit some 'fields' with with_fields};
        $self-&gt;form_with_fields(keys %{$fields}) or die "There is no form with the requested fields";
    }
    elsif ( my $form_number = $args{form_number} ) {
        $self-&gt;form_number( $form_number ) or die "There is no form numbered $form_number";
    }
    elsif ( my $form_name = $args{form_name} ) {
        $self-&gt;form_name( $form_name ) or die qq{There is no form named "$form_name"};
    }
    elsif ( my $form_id = $args{form_id} ) {
        $self-&gt;form_id( $form_id ) or die qq{There is no form with ID "$form_id"};
    }
    else {
        # No form selector was used.
        # Maybe a form was set separately, or we'll default to the first form.
    }

    $self-&gt;set_fields( %{$fields} ) if $fields;

    my $response;
    if ( $args{button} ) {
        $response = $self-&gt;click( $args{button}, $args{x} || 0, $args{y} || 0 );
    }
    else {
        $response = $self-&gt;submit();
    }

    return $response;
}

=head1 MISCELLANEOUS METHODS

=head2 $mech-&gt;add_header( name =&gt; $value [, name =&gt; $value... ] )

Sets HTTP headers for the agent to add or remove from the HTTP request.

    $mech-&gt;add_header( Encoding =&gt; 'text/klingon' );

If a I&lt;value&gt; is C&lt;undef&gt;, then that header will be removed from any
future requests.  For example, to never send a Referer header:

    $mech-&gt;add_header( Referer =&gt; undef );

If you want to delete a header, use C&lt;delete_header&gt;.

Returns the number of name/value pairs added.

B&lt;NOTE&gt;: This method was very different in WWW::Mechanize before 1.00.
Back then, the headers were stored in a package hash, not as a member of
the object instance.  Calling C&lt;add_header()&gt; would modify the headers
for every WWW::Mechanize object, even after your object no longer existed.

=cut

sub add_header {
    my $self = shift;
    my $npairs = 0;

    while ( @_ ) {
        my $key = shift;
        my $value = shift;
        ++$npairs;

        $self-&gt;{headers}{$key} = $value;
    }

    return $npairs;
}

=head2 $mech-&gt;delete_header( name [, name ... ] )

Removes HTTP headers from the agent's list of special headers.  For
instance, you might need to do something like:

    # Don't send a Referer for this URL
    $mech-&gt;add_header( Referer =&gt; undef );

    # Get the URL
    $mech-&gt;get( $url );

    # Back to the default behavior
    $mech-&gt;delete_header( 'Referer' );

=cut

sub delete_header {
    my $self = shift;

    while ( @_ ) {
        my $key = shift;

        delete $self-&gt;{headers}{$key};
    }

    return;
}


=head2 $mech-&gt;quiet(true/false)

Allows you to suppress warnings to the screen.

    $mech-&gt;quiet(0); # turns on warnings (the default)
    $mech-&gt;quiet(1); # turns off warnings
    $mech-&gt;quiet();  # returns the current quietness status

=cut

sub quiet {
    my $self = shift;

    $self-&gt;{quiet} = $_[0] if @_;

    return $self-&gt;{quiet};
}

=head2 $mech-&gt;stack_depth( $max_depth )

Get or set the page stack depth. Use this if you're doing a lot of page
scraping and running out of memory.

A value of 0 means "no history at all."  By default, the max stack depth
is humongously large, effectively keeping all history.

=cut

sub stack_depth {
    my $self = shift;
    $self-&gt;{stack_depth} = shift if @_;
    return $self-&gt;{stack_depth};
}

=head2 $mech-&gt;save_content( $filename, %opts )

Dumps the contents of C&lt;&lt; $mech-&gt;content &gt;&gt; into I&lt;$filename&gt;.
I&lt;$filename&gt; will be overwritten.  Dies if there are any errors.

If the content type does not begin with "text/", then the content
is saved in binary mode (i.e. C&lt;binmode()&gt; is set on the output
filehandle).

Additional arguments can be passed as I&lt;key&gt;/I&lt;value&gt; pairs:

=over

=item I&lt;&lt; $mech-&gt;save_content( $filename, binary =&gt; 1 ) &gt;&gt;

Filehandle is set with C&lt;binmode&gt; to C&lt;:raw&gt; and contents are taken
calling C&lt;&lt; $self-&gt;content(decoded_by_headers =&gt; 1) &gt;&gt;. Same as calling:

    $mech-&gt;save_content( $filename, binmode =&gt; ':raw',
                         decoded_by_headers =&gt; 1 );

This I&lt;should&gt; be the safest way to save contents verbatim.

=item I&lt;&lt; $mech-&gt;save_content( $filename, binmode =&gt; $binmode ) &gt;&gt;

Filehandle is set to binary mode. If C&lt;$binmode&gt; begins with ':', it is
passed as a parameter to C&lt;binmode&gt;:

    binmode $fh, $binmode;

otherwise the filehandle is set to binary mode if C&lt;$binmode&gt; is true:

    binmode $fh;

=item I&lt;all other arguments&gt;

are passed as-is to C&lt;&lt; $mech-&gt;content(%opts) &gt;&gt;. In particular,
C&lt;decoded_by_headers&gt; might come handy if you want to revert the effect
of line compression performed by the web server but without further
interpreting the contents (e.g. decoding it according to the charset).

=back

=cut

sub save_content {
    my $self = shift;
    my $filename = shift;
    my %opts = @_;
    if (delete $opts{binary}) {
        $opts{binmode} = ':raw';
        $opts{decoded_by_headers} = 1;
    }

    open( my $fh, '&gt;', $filename ) or $self-&gt;die( "Unable to create $filename: $!" );
    if ((my $binmode = delete($opts{binmode}) || '') || ($self-&gt;content_type() !~ m{^text/})) {
        if (length($binmode) &amp;&amp; (substr($binmode, 0, 1) eq ':')) {
            binmode $fh, $binmode;
        }
        else {
            binmode $fh;
        }
    }
    print {$fh} $self-&gt;content(%opts) or $self-&gt;die( "Unable to write to $filename: $!" );
    close $fh or $self-&gt;die( "Unable to close $filename: $!" );

    return;
}


=head2 $mech-&gt;dump_headers( [$fh] )

Prints a dump of the HTTP response headers for the most recent
response.  If I&lt;$fh&gt; is not specified or is undef, it dumps to
STDOUT.

Unlike the rest of the dump_* methods, $fh can be a scalar. It
will be used as a file name.

=cut

sub _get_fh_default_stdout {
    my $self = shift;
    my $p = shift || '';
    if ( !$p ) {
        return \*STDOUT;
    } elsif ( !ref($p) ) {
        open my $fh, '&gt;', $p or $self-&gt;die( "Unable to write to $p: $!" );;
        return $fh;
    } else {
        return $p;
    }
}

sub dump_headers {
    my $self = shift;
    my $fh   = $self-&gt;_get_fh_default_stdout(shift);

    print {$fh} $self-&gt;response-&gt;headers_as_string;

    return;
}


=head2 $mech-&gt;dump_links( [[$fh], $absolute] )

Prints a dump of the links on the current page to I&lt;$fh&gt;.  If I&lt;$fh&gt;
is not specified or is undef, it dumps to STDOUT.

If I&lt;$absolute&gt; is true, links displayed are absolute, not relative.

=cut

sub dump_links {
    my $self = shift;
    my $fh = shift || \*STDOUT;
    my $absolute = shift;

    for my $link ( $self-&gt;links ) {
        my $url = $absolute ? $link-&gt;url_abs : $link-&gt;url;
        $url = '' if not defined $url;
        print {$fh} $url, "\n";
    }
    return;
}

=head2 $mech-&gt;dump_images( [[$fh], $absolute] )

Prints a dump of the images on the current page to I&lt;$fh&gt;.  If I&lt;$fh&gt;
is not specified or is undef, it dumps to STDOUT.

If I&lt;$absolute&gt; is true, links displayed are absolute, not relative.

=cut

sub dump_images {
    my $self = shift;
    my $fh = shift || \*STDOUT;
    my $absolute = shift;

    for my $image ( $self-&gt;images ) {
        my $url = $absolute ? $image-&gt;url_abs : $image-&gt;url;
        $url = '' if not defined $url;
        print {$fh} $url, "\n";
    }
    return;
}

=head2 $mech-&gt;dump_forms( [$fh] )

Prints a dump of the forms on the current page to I&lt;$fh&gt;.  If I&lt;$fh&gt;
is not specified or is undef, it dumps to STDOUT.

=cut

sub dump_forms {
    my $self = shift;
    my $fh = shift || \*STDOUT;

    for my $form ( $self-&gt;forms ) {
        print {$fh} $form-&gt;dump, "\n";
    }
    return;
}

=head2 $mech-&gt;dump_text( [$fh] )

Prints a dump of the text on the current page to I&lt;$fh&gt;.  If I&lt;$fh&gt;
is not specified or is undef, it dumps to STDOUT.

=cut

sub dump_text {
    my $self = shift;
    my $fh = shift || \*STDOUT;
    my $absolute = shift;

    print {$fh} $self-&gt;text, "\n";

    return;
}


=head1 OVERRIDDEN LWP::UserAgent METHODS

=head2 $mech-&gt;clone()

Clone the mech object.  The clone will be using the same cookie jar
as the original mech.

=cut

sub clone {
    my $self  = shift;
    my $clone = $self-&gt;SUPER::clone();

    $clone-&gt;cookie_jar( $self-&gt;cookie_jar );

    return $clone;
}


=head2 $mech-&gt;redirect_ok()

An overloaded version of C&lt;redirect_ok()&gt; in L&lt;LWP::UserAgent&gt;.
This method is used to determine whether a redirection in the request
should be followed.

Note that WWW::Mechanize's constructor pushes POST on to the agent's
C&lt;requests_redirectable&gt; list.

=cut

sub redirect_ok {
    my $self = shift;
    my $prospective_request = shift;
    my $response = shift;

    my $ok = $self-&gt;SUPER::redirect_ok( $prospective_request, $response );
    if ( $ok ) {
        $self-&gt;{redirected_uri} = $prospective_request-&gt;uri;
    }

    return $ok;
}


=head2 $mech-&gt;request( $request [, $arg [, $size]])

Overloaded version of C&lt;request()&gt; in L&lt;LWP::UserAgent&gt;.  Performs
the actual request.  Normally, if you're using WWW::Mechanize, it's
because you don't want to deal with this level of stuff anyway.

Note that C&lt;$request&gt; will be modified.

Returns an L&lt;HTTP::Response&gt; object.

=cut

sub request {
    my $self = shift;
    my $request = shift;

    $request = $self-&gt;_modify_request( $request );

    if ( $request-&gt;method eq 'GET' || $request-&gt;method eq 'POST' ) {
        $self-&gt;_push_page_stack();
    }

    return $self-&gt;_update_page($request, $self-&gt;_make_request( $request, @_ ));
}

=head2 $mech-&gt;update_html( $html )

Allows you to replace the HTML that the mech has found.  Updates the
forms and links parse-trees that the mech uses internally.

Say you have a page that you know has malformed output, and you want to
update it so the links come out correctly:

    my $html = $mech-&gt;content;
    $html =~ s[&lt;/option&gt;.{0,3}&lt;/td&gt;][&lt;/option&gt;&lt;/select&gt;&lt;/td&gt;]isg;
    $mech-&gt;update_html( $html );

This method is also used internally by the mech itself to update its
own HTML content when loading a page. This means that if you would
like to I&lt;systematically&gt; perform the above HTML substitution, you
would overload I&lt;update_html&gt; in a subclass thusly:

   package MyMech;
   use base 'WWW::Mechanize';

   sub update_html {
       my ($self, $html) = @_;
       $html =~ s[&lt;/option&gt;.{0,3}&lt;/td&gt;][&lt;/option&gt;&lt;/select&gt;&lt;/td&gt;]isg;
       $self-&gt;WWW::Mechanize::update_html( $html );
   }

If you do this, then the mech will use the tidied-up HTML instead of
the original both when parsing for its own needs, and for returning to
you through L&lt;/content&gt;.

Overloading this method is also the recommended way of implementing
extra validation steps (e.g. link checkers) for every HTML page
received.  L&lt;/warn&gt; and L&lt;/die&gt; would then come in handy to signal
validation errors.

=cut

sub update_html {
    my $self = shift;
    my $html = shift;

    $self-&gt;_reset_page;
    $self-&gt;{ct} = 'text/html';
    $self-&gt;{content} = $html;

    return;
}

=head2 $mech-&gt;credentials( $username, $password )

Provide credentials to be used for HTTP Basic authentication for
all sites and realms until further notice.

The four argument form described in L&lt;LWP::UserAgent&gt; is still
supported.

=cut

sub credentials {
    my $self = shift;

    # The latest LWP::UserAgent also supports 2 arguments,
    # in which case the first is host:port
    if (@_ == 4 || (@_ == 2 &amp;&amp; $_[0] =~ /:\d+$/)) {
        return $self-&gt;SUPER::credentials(@_);
    }

    @_ == 2
        or $self-&gt;die( 'Invalid # of args for overridden credentials()' );

    return @$self{qw( __username __password )} = @_;
}

=head2 $mech-&gt;get_basic_credentials( $realm, $uri, $isproxy )

Returns the credentials for the realm and URI.

=cut

sub get_basic_credentials {
    my $self = shift;
    my @cred = grep { defined } @$self{qw( __username __password )};
    return @cred if @cred == 2;
    return $self-&gt;SUPER::get_basic_credentials(@_);
}

=head2 $mech-&gt;clear_credentials()

Remove any credentials set up with C&lt;credentials()&gt;.

=cut

sub clear_credentials {
    my $self = shift;
    delete @$self{qw( __username __password )};
}

=head1 INHERITED UNCHANGED LWP::UserAgent METHODS

As a subclass of L&lt;LWP::UserAgent&gt;, WWW::Mechanize inherits all of
L&lt;LWP::UserAgent&gt;'s methods.  Many of which are overridden or
extended. The following methods are inherited unchanged. View the
L&lt;LWP::UserAgent&gt; documentation for their implementation descriptions.

This is not meant to be an inclusive list.  LWP::UA may have added
others.

=head2 $mech-&gt;head()

Inherited from L&lt;LWP::UserAgent&gt;.

=head2 $mech-&gt;post()

Inherited from L&lt;LWP::UserAgent&gt;.

=head2 $mech-&gt;mirror()

Inherited from L&lt;LWP::UserAgent&gt;.

=head2 $mech-&gt;simple_request()

Inherited from L&lt;LWP::UserAgent&gt;.

=head2 $mech-&gt;is_protocol_supported()

Inherited from L&lt;LWP::UserAgent&gt;.

=head2 $mech-&gt;prepare_request()

Inherited from L&lt;LWP::UserAgent&gt;.

=head2 $mech-&gt;progress()

Inherited from L&lt;LWP::UserAgent&gt;.

=head1 INTERNAL-ONLY METHODS

These methods are only used internally.  You probably don't need to
know about them.

=head2 $mech-&gt;_update_page($request, $response)

Updates all internal variables in $mech as if $request was just
performed, and returns $response. The page stack is B&lt;not&gt; altered by
this method, it is up to caller (e.g. L&lt;/request&gt;) to do that.

=cut

sub _update_page {
    my ($self, $request, $res) = @_;

    $self-&gt;{req} = $request;
    $self-&gt;{redirected_uri} = $request-&gt;uri-&gt;as_string;

    $self-&gt;{res} = $res;

    $self-&gt;{status}  = $res-&gt;code;
    $self-&gt;{base}    = $res-&gt;base;
    $self-&gt;{ct}      = $res-&gt;content_type || '';

    if ( $res-&gt;is_success ) {
        $self-&gt;{uri} = $self-&gt;{redirected_uri};
        $self-&gt;{last_uri} = $self-&gt;{uri};
    }

    if ( $res-&gt;is_error ) {
        if ( $self-&gt;{autocheck} ) {
            $self-&gt;die( 'Error ', $request-&gt;method, 'ing ', $request-&gt;uri, ': ', $res-&gt;message );
        }
    }

    $self-&gt;_reset_page;

    # Try to decode the content. Undef will be returned if there's nothing to decompress.
    # See docs in HTTP::Message for details. Do we need to expose the options there?
    my $content = $res-&gt;decoded_content();
    $content = $res-&gt;content if (not defined $content);

    $content .= _taintedness();

    if ($self-&gt;is_html) {
        $self-&gt;update_html($content);
    }
    else {
        $self-&gt;{content} = $content;
    }

    return $res;
} # _update_page

our $_taintbrush;

# This is lifted wholesale from Test::Taint
sub _taintedness {
    return $_taintbrush if defined $_taintbrush;

    # Somehow we need to get some taintedness into our $_taintbrush.
    # Let's try the easy way first. Either of these should be
    # tainted, unless somebody has untainted them, so this
    # will almost always work on the first try.
    # (Unless, of course, taint checking has been turned off!)
    $_taintbrush = substr("$0$^X", 0, 0);
    return $_taintbrush if _is_tainted( $_taintbrush );

    # Let's try again. Maybe somebody cleaned those.
    $_taintbrush = substr(join('', grep { defined } @ARGV, %ENV), 0, 0);
    return $_taintbrush if _is_tainted( $_taintbrush );

    # If those don't work, go try to open some file from some unsafe
    # source and get data from them.  That data is tainted.
    # (Yes, even reading from /dev/null works!)
    for my $filename ( qw(/dev/null / . ..), values %INC, $0, $^X ) {
        if ( open my $fh, '&lt;', $filename ) {
            my $data;
            if ( defined sysread $fh, $data, 1 ) {
                $_taintbrush = substr( $data, 0, 0 );
                last if _is_tainted( $_taintbrush );
            }
        }
    }

    # Sanity check
    die "Our taintbrush should have zero length!" if length $_taintbrush;

    return $_taintbrush;
}

sub _is_tainted {
    no warnings qw(void uninitialized);

    return !eval { join('', shift), kill 0; 1 };
} # _is_tainted


=head2 $mech-&gt;_modify_request( $req )

Modifies a L&lt;HTTP::Request&gt; before the request is sent out,
for both GET and POST requests.

We add a C&lt;Referer&gt; header, as well as header to note that we can accept gzip
encoded content, if L&lt;Compress::Zlib&gt; is installed.

=cut

sub _modify_request {
    my $self = shift;
    my $req = shift;

    # add correct Accept-Encoding header to restore compliance with
    # http://www.freesoft.org/CIE/RFC/2068/158.htm
    # http://use.perl.org/~rhesa/journal/25952
    if (not $req-&gt;header( 'Accept-Encoding' ) ) {
        # "identity" means "please! unencoded content only!"
        $req-&gt;header( 'Accept-Encoding', $HAS_ZLIB ? 'gzip' : 'identity' );
    }

    my $last = $self-&gt;{last_uri};
    if ( $last ) {
        $last = $last-&gt;as_string if ref($last);
        $req-&gt;header( Referer =&gt; $last );
    }
    while ( my($key,$value) = each %{$self-&gt;{headers}} ) {
        if ( defined $value ) {
            $req-&gt;header( $key =&gt; $value );
        }
        else {
            $req-&gt;remove_header( $key );
        }
    }

    return $req;
}


=head2 $mech-&gt;_make_request()

Convenience method to make it easier for subclasses like
L&lt;WWW::Mechanize::Cached&gt; to intercept the request.

=cut

sub _make_request {
    my $self = shift;
    return $self-&gt;SUPER::request(@_);
}

=head2 $mech-&gt;_reset_page()

Resets the internal fields that track page parsed stuff.

=cut

sub _reset_page {
    my $self = shift;

    $self-&gt;{links}        = undef;
    $self-&gt;{images}       = undef;
    $self-&gt;{forms}        = undef;
    $self-&gt;{current_form} = undef;
    $self-&gt;{title}        = undef;
    $self-&gt;{text}         = undef;

    return;
}

=head2 $mech-&gt;_extract_links()

Extracts links from the content of a webpage, and populates the C&lt;{links}&gt;
property with L&lt;WWW::Mechanize::Link&gt; objects.

=cut

my %link_tags = (
    a      =&gt; 'href',
    area   =&gt; 'href',
    frame  =&gt; 'src',
    iframe =&gt; 'src',
    link   =&gt; 'href',
    meta   =&gt; 'content',
);

sub _extract_links {
    my $self = shift;


    $self-&gt;{links} = [];
    if ( defined $self-&gt;{content} ) {
        my $parser = HTML::TokeParser-&gt;new(\$self-&gt;{content});
        while ( my $token = $parser-&gt;get_tag( keys %link_tags ) ) {
            my $link = $self-&gt;_link_from_token( $token, $parser );
            push( @{$self-&gt;{links}}, $link ) if $link;
        } # while
    }

    return;
}


my %image_tags = (
    img   =&gt; 'src',
    input =&gt; 'src',
);

sub _extract_images {
    my $self = shift;

    $self-&gt;{images} = [];

    if ( defined $self-&gt;{content} ) {
        my $parser = HTML::TokeParser-&gt;new(\$self-&gt;{content});
        while ( my $token = $parser-&gt;get_tag( keys %image_tags ) ) {
            my $image = $self-&gt;_image_from_token( $token, $parser );
            push( @{$self-&gt;{images}}, $image ) if $image;
        } # while
    }

    return;
}

sub _image_from_token {
    my $self = shift;
    my $token = shift;
    my $parser = shift;

    my $tag = $token-&gt;[0];
    my $attrs = $token-&gt;[1];

    if ( $tag eq 'input' ) {
        my $type = $attrs-&gt;{type} or return;
        return unless $type eq 'image';
    }

    require WWW::Mechanize::Image;
    return
        WWW::Mechanize::Image-&gt;new({
            tag     =&gt; $tag,
            base    =&gt; $self-&gt;base,
            url     =&gt; $attrs-&gt;{src},
            name    =&gt; $attrs-&gt;{name},
            height  =&gt; $attrs-&gt;{height},
            width   =&gt; $attrs-&gt;{width},
            alt     =&gt; $attrs-&gt;{alt},
        });
}

sub _link_from_token {
    my $self = shift;
    my $token = shift;
    my $parser = shift;

    my $tag = $token-&gt;[0];
    my $attrs = $token-&gt;[1];
    my $url = $attrs-&gt;{$link_tags{$tag}};

    my $text;
    my $name;
    if ( $tag eq 'a' ) {
        $text = $parser-&gt;get_trimmed_text("/$tag");
        $text = '' unless defined $text;

        my $onClick = $attrs-&gt;{onclick};
        if ( $onClick &amp;&amp; ($onClick =~ /^window\.open\(\s*'([^']+)'/) ) {
            $url = $1;
        }
    } # a

    # Of the tags we extract from, only 'AREA' has an alt tag
    # The rest should have a 'name' attribute.
    # ... but we don't do anything with that bit of wisdom now.

    $name = $attrs-&gt;{name};

    if ( $tag eq 'meta' ) {
        my $equiv = $attrs-&gt;{'http-equiv'};
        my $content = $attrs-&gt;{'content'};
        return unless $equiv &amp;&amp; (lc $equiv eq 'refresh') &amp;&amp; defined $content;

        if ( $content =~ /^\d+\s*;\s*url\s*=\s*(\S+)/i ) {
            $url = $1;
            $url =~ s/^"(.+)"$/$1/ or $url =~ s/^'(.+)'$/$1/;
        }
        else {
            undef $url;
        }
    } # meta

    return unless defined $url;   # probably just a name link or &lt;AREA NOHREF...&gt;

    require WWW::Mechanize::Link;
    return
        WWW::Mechanize::Link-&gt;new({
            url  =&gt; $url,
            text =&gt; $text,
            name =&gt; $name,
            tag  =&gt; $tag,
            base =&gt; $self-&gt;base,
            attrs =&gt; $attrs,
        });
} # _link_from_token


sub _extract_forms {
    my $self = shift;

    my @forms = HTML::Form-&gt;parse( $self-&gt;content, $self-&gt;base );
    $self-&gt;{forms} = \@forms;
    for my $form ( @forms ) {
        for my $input ($form-&gt;inputs) {
             if ($input-&gt;type eq 'file') {
                 $input-&gt;value( undef );
             }
        }
    }

    return;
}

=head2 $mech-&gt;_push_page_stack()

The agent keeps a stack of visited pages, which it can pop when it needs
to go BACK and so on.

The current page needs to be pushed onto the stack before we get a new
page, and the stack needs to be popped when BACK occurs.

Neither of these take any arguments, they just operate on the $mech
object.

=cut

sub _push_page_stack {
    my $self = shift;

    my $req = $self-&gt;{req};
    my $res = $self-&gt;{res};

    return unless $req &amp;&amp; $res &amp;&amp; $self-&gt;stack_depth;

    # Don't push anything if it's a virgin object
    my $stack = $self-&gt;{page_stack} ||= [];
    if ( @{$stack} &gt;= $self-&gt;stack_depth ) {
        shift @{$stack};
    }
    push( @{$stack}, { req =&gt; $req, res =&gt; $res } );

    return 1;
}

=head2 warn( @messages )

Centralized warning method, for diagnostics and non-fatal problems.
Defaults to calling C&lt;CORE::warn&gt;, but may be overridden by setting
C&lt;onwarn&gt; in the constructor.

=cut

sub warn {
    my $self = shift;

    return unless my $handler = $self-&gt;{onwarn};

    return if $self-&gt;quiet;

    return $handler-&gt;(@_);
}

=head2 die( @messages )

Centralized error method.  Defaults to calling C&lt;CORE::die&gt;, but
may be overridden by setting C&lt;onerror&gt; in the constructor.

=cut

sub die {
    my $self = shift;

    return unless my $handler = $self-&gt;{onerror};

    return $handler-&gt;(@_);
}


# NOT an object method!
sub _warn {
    require Carp;
    return &amp;Carp::carp; ## no critic
}

# NOT an object method!
sub _die {
    require Carp;
    return &amp;Carp::croak; ## no critic
}

1; # End of module

__END__

=head1 WWW::MECHANIZE'S GIT REPOSITORY

WWW::Mechanize is hosted at GitHub, though the bug tracker still
lives at Google Code.

Repository: L&lt;https://github.com/libwww-perl/WWW-Mechanize&gt;.
Bugs: L&lt;http://code.google.com/p/www-mechanize/issues&gt;.

=head1 OTHER DOCUMENTATION

=head2 I&lt;Spidering Hacks&gt;, by Kevin Hemenway and Tara Calishain

I&lt;Spidering Hacks&gt; from O'Reilly
(L&lt;http://www.oreilly.com/catalog/spiderhks/&gt;) is a great book for anyone
wanting to know more about screen-scraping and spidering.

There are six hacks that use Mech or a Mech derivative:

=over 4

=item #21 WWW::Mechanize 101

=item #22 Scraping with WWW::Mechanize

=item #36 Downloading Images from Webshots

=item #44 Archiving Yahoo! Groups Messages with WWW::Yahoo::Groups

=item #64 Super Author Searching

=item #73 Scraping TV Listings

=back

The book was also positively reviewed on Slashdot:
L&lt;http://books.slashdot.org/article.pl?sid=03/12/11/2126256&gt;

=head1 ONLINE RESOURCES AND SUPPORT

=over 4

=item * WWW::Mechanize mailing list

The Mech mailing list is at
L&lt;http://groups.google.com/group/www-mechanize-users&gt; and is specific
to Mechanize, unlike the LWP mailing list below.  Although it is a
users list, all development discussion takes place here, too.

=item * LWP mailing list

The LWP mailing list is at
L&lt;http://lists.perl.org/showlist.cgi?name=libwww&gt;, and is more
user-oriented and well-populated than the WWW::Mechanize list.

=item * Perlmonks

L&lt;http://perlmonks.org&gt; is an excellent community of support, and
many questions about Mech have already been answered there.

=item * L&lt;WWW::Mechanize::Examples&gt;

A random array of examples submitted by users, included with the
Mechanize distribution.

=back

=head1 ARTICLES ABOUT WWW::MECHANIZE

=over 4

=item * L&lt;http://www-128.ibm.com/developerworks/linux/library/wa-perlsecure.html&gt;

IBM article "Secure Web site access with Perl"

=item * L&lt;http://www.oreilly.com/catalog/googlehks2/chapter/hack84.pdf&gt;

Leland Johnson's hack #84 in I&lt;Google Hacks, 2nd Edition&gt; is
an example of a production script that uses WWW::Mechanize and
HTML::TableContentParser. It takes in keywords and returns the estimated
price of these keywords on Google's AdWords program.

=item * L&lt;http://www.perl.com/pub/a/2004/06/04/recorder.html&gt;

Linda Julien writes about using HTTP::Recorder to create WWW::Mechanize
scripts.

=item * L&lt;http://www.developer.com/lang/other/article.php/3454041&gt;

Jason Gilmore's article on using WWW::Mechanize for scraping sales
information from Amazon and eBay.

=item * L&lt;http://www.perl.com/pub/a/2003/01/22/mechanize.html&gt;

Chris Ball's article about using WWW::Mechanize for scraping TV
listings.

=item * L&lt;http://www.stonehenge.com/merlyn/LinuxMag/col47.html&gt;

Randal Schwartz's article on scraping Yahoo News for images.  It's
already out of date: He manually walks the list of links hunting
for matches, which wouldn't have been necessary if the C&lt;find_link()&gt;
method existed at press time.

=item * L&lt;http://www.perladvent.org/2002/16th/&gt;

WWW::Mechanize on the Perl Advent Calendar, by Mark Fowler.

=item * L&lt;http://www.linux-magazin.de/Artikel/ausgabe/2004/03/perl/perl.html&gt;

Michael Schilli's article on Mech and L&lt;WWW::Mechanize::Shell&gt; for the
German magazine I&lt;Linux Magazin&gt;.

=back

=head2 Other modules that use Mechanize

Here are modules that use or subclass Mechanize.  Let me know of any others:

=over 4

=item * L&lt;Finance::Bank::LloydsTSB&gt;

=item * L&lt;HTTP::Recorder&gt;

Acts as a proxy for web interaction, and then generates WWW::Mechanize scripts.

=item * L&lt;Win32::IE::Mechanize&gt;

Just like Mech, but using Microsoft Internet Explorer to do the work.

=item * L&lt;WWW::Bugzilla&gt;

=item * L&lt;WWW::CheckSite&gt;

=item * L&lt;WWW::Google::Groups&gt;

=item * L&lt;WWW::Hotmail&gt;

=item * L&lt;WWW::Mechanize::Cached&gt;

=item * L&lt;WWW::Mechanize::FormFiller&gt;

=item * L&lt;WWW::Mechanize::Shell&gt;

=item * L&lt;WWW::Mechanize::Sleepy&gt;

=item * L&lt;WWW::Mechanize::SpamCop&gt;

=item * L&lt;WWW::Mechanize::Timed&gt;

=item * L&lt;WWW::SourceForge&gt;

=item * L&lt;WWW::Yahoo::Groups&gt;

=item * L&lt;WWW::Scripter&gt;

=back

=head1 ACKNOWLEDGEMENTS

Thanks to the numerous people who have helped out on WWW::Mechanize in
one way or another, including
Kirrily Robert for the original C&lt;WWW::Automate&gt;,
Lyle Hopkins,
Damien Clark,
Ansgar Burchardt,
Gisle Aas,
Jeremy Ary,
Hilary Holz,
Rafael Kitover,
Norbert Buchmuller,
Dave Page,
David Sainty,
H.Merijn Brand,
Matt Lawrence,
Michael Schwern,
Adriano Ferreira,
Miyagawa,
Peteris Krumins,
Rafael Kitover,
David Steinbrunner,
Kevin Falcone,
Mike O'Regan,
Mark Stosberg,
Uri Guttman,
Peter Scott,
Phillipe Bruhat,
Ian Langworth,
John Beppu,
Gavin Estey,
Jim Brandt,
Ask Bjoern Hansen,
Greg Davies,
Ed Silva,
Mark-Jason Dominus,
Autrijus Tang,
Mark Fowler,
Stuart Children,
Max Maischein,
Meng Wong,
Prakash Kailasa,
Abigail,
Jan Pazdziora,
Dominique Quatravaux,
Scott Lanning,
Rob Casey,
Leland Johnson,
Joshua Gatcomb,
Julien Beasley,
Abe Timmerman,
Peter Stevens,
Pete Krawczyk,
Tad McClellan,
and the late great Iain Truskett.

=head1 COPYRIGHT

Copyright (c) 2005-2010 Andy Lester. All rights reserved. This program is
free software; you can redistribute it and/or modify it under the same
terms as Perl itself.

=cut
</pre></body></html>