<html><head><meta name="color-scheme" content="light dark"></head><body><pre style="word-wrap: break-word; white-space: pre-wrap;">use strict;
use warnings;
package YAML::Node;

our $VERSION = '0.84';

use YAML::Tag;
require YAML::Mo;

use Exporter;
our @ISA     = qw(Exporter YAML::Mo::Object);
our @EXPORT  = qw(ynode);

sub ynode {
    my $self;
    if (ref($_[0]) eq 'HASH') {
	$self = tied(%{$_[0]});
    }
    elsif (ref($_[0]) eq 'ARRAY') {
	$self = tied(@{$_[0]});
    }
    elsif (ref(\$_[0]) eq 'GLOB') {
	$self = tied(*{$_[0]});
    }
    else {
	$self = tied($_[0]);
    }
    return (ref($self) =~ /^yaml_/) ? $self : undef;
}

sub new {
    my ($class, $node, $tag) = @_;
    my $self;
    $self-&gt;{NODE} = $node;
    my (undef, $type) = YAML::Mo::Object-&gt;node_info($node);
    $self-&gt;{KIND} = (not defined $type) ? 'scalar' :
                    ($type eq 'ARRAY') ? 'sequence' :
		    ($type eq 'HASH') ? 'mapping' :
		    $class-&gt;die("Can't create YAML::Node from '$type'");
    tag($self, ($tag || ''));
    if ($self-&gt;{KIND} eq 'scalar') {
	yaml_scalar-&gt;new($self, $_[1]);
	return \ $_[1];
    }
    my $package = "yaml_" . $self-&gt;{KIND};    
    $package-&gt;new($self)
}

sub node { $_-&gt;{NODE} }
sub kind { $_-&gt;{KIND} }
sub tag {
    my ($self, $value) = @_;
    if (defined $value) {
       	$self-&gt;{TAG} = YAML::Tag-&gt;new($value);
	return $self;
    }
    else {
       return $self-&gt;{TAG};
    }
}
sub keys {
    my ($self, $value) = @_;
    if (defined $value) {
       	$self-&gt;{KEYS} = $value;
	return $self;
    }
    else {
       return $self-&gt;{KEYS};
    }
}

#==============================================================================
package yaml_scalar;

@yaml_scalar::ISA = qw(YAML::Node);

sub new {
    my ($class, $self) = @_;
    tie $_[2], $class, $self;
}

sub TIESCALAR {
    my ($class, $self) = @_;
    bless $self, $class;
    $self
}

sub FETCH {
    my ($self) = @_;
    $self-&gt;{NODE}
}

sub STORE {
    my ($self, $value) = @_;
    $self-&gt;{NODE} = $value
}

#==============================================================================
package yaml_sequence;

@yaml_sequence::ISA = qw(YAML::Node);

sub new {
    my ($class, $self) = @_;
    my $new;
    tie @$new, $class, $self;
    $new
}

sub TIEARRAY {
    my ($class, $self) = @_;
    bless $self, $class
}

sub FETCHSIZE {
    my ($self) = @_;
    scalar @{$self-&gt;{NODE}};
}

sub FETCH {
    my ($self, $index) = @_;
    $self-&gt;{NODE}[$index]
}

sub STORE {
    my ($self, $index, $value) = @_;
    $self-&gt;{NODE}[$index] = $value
}

sub undone {
    die "Not implemented yet"; # XXX
}

*STORESIZE = *POP = *PUSH = *SHIFT = *UNSHIFT = *SPLICE = *DELETE = *EXISTS = 
*STORESIZE = *POP = *PUSH = *SHIFT = *UNSHIFT = *SPLICE = *DELETE = *EXISTS = 
*undone; # XXX Must implement before release

#==============================================================================
package yaml_mapping;

@yaml_mapping::ISA = qw(YAML::Node);

sub new {
    my ($class, $self) = @_;
    @{$self-&gt;{KEYS}} = sort keys %{$self-&gt;{NODE}}; 
    my $new;
    tie %$new, $class, $self;
    $new
}

sub TIEHASH {
    my ($class, $self) = @_;
    bless $self, $class
}

sub FETCH {
    my ($self, $key) = @_;
    if (exists $self-&gt;{NODE}{$key}) {
	return (grep {$_ eq $key} @{$self-&gt;{KEYS}}) 
	       ? $self-&gt;{NODE}{$key} : undef;
    }
    return $self-&gt;{HASH}{$key};
}

sub STORE {
    my ($self, $key, $value) = @_;
    if (exists $self-&gt;{NODE}{$key}) {
	$self-&gt;{NODE}{$key} = $value;
    }
    elsif (exists $self-&gt;{HASH}{$key}) {
	$self-&gt;{HASH}{$key} = $value;
    }
    else {
	if (not grep {$_ eq $key} @{$self-&gt;{KEYS}}) {
	    push(@{$self-&gt;{KEYS}}, $key);
	}
	$self-&gt;{HASH}{$key} = $value;
    }
    $value
}

sub DELETE {
    my ($self, $key) = @_;
    my $return;
    if (exists $self-&gt;{NODE}{$key}) {
	$return = $self-&gt;{NODE}{$key};
    }
    elsif (exists $self-&gt;{HASH}{$key}) {
	$return = delete $self-&gt;{NODE}{$key};
    }
    for (my $i = 0; $i &lt; @{$self-&gt;{KEYS}}; $i++) {
	if ($self-&gt;{KEYS}[$i] eq $key) {
	    splice(@{$self-&gt;{KEYS}}, $i, 1);
	}
    }
    return $return;
}

sub CLEAR {
    my ($self) = @_;
    @{$self-&gt;{KEYS}} = ();
    %{$self-&gt;{HASH}} = ();
}

sub FIRSTKEY {
    my ($self) = @_;
    $self-&gt;{ITER} = 0;
    $self-&gt;{KEYS}[0]
}

sub NEXTKEY {
    my ($self) = @_;
    $self-&gt;{KEYS}[++$self-&gt;{ITER}]
}

sub EXISTS {
    my ($self, $key) = @_;
    exists $self-&gt;{NODE}{$key}
}

1;

__END__

=head1 NAME

YAML::Node - A generic data node that encapsulates YAML information

=head1 SYNOPSIS

    use YAML;
    use YAML::Node;
    
    my $ynode = YAML::Node-&gt;new({}, 'ingerson.com/fruit');
    %$ynode = qw(orange orange apple red grape green);
    print Dump $ynode;

yields:

    --- !ingerson.com/fruit
    orange: orange
    apple: red
    grape: green

=head1 DESCRIPTION

A generic node in YAML is similar to a plain hash, array, or scalar node
in Perl except that it must also keep track of its type. The type is a
URI called the YAML type tag.

YAML::Node is a class for generating and manipulating these containers.
A YAML node (or ynode) is a tied hash, array or scalar. In most ways it
behaves just like the plain thing. But you can assign and retrieve and
YAML type tag URI to it. For the hash flavor, you can also assign the
order that the keys will be retrieved in. By default a ynode will offer
its keys in the same order that they were assigned.

YAML::Node has a class method call new() that will return a ynode. You
pass it a regular node and an optional type tag. After that you can
use it like a normal Perl node, but when you YAML::Dump it, the magical
properties will be honored.

This is how you can control the sort order of hash keys during a YAML
serialization. By default, YAML sorts keys alphabetically. But notice
in the above example that the keys were Dumped in the same order they
were assigned.

YAML::Node exports a function called ynode(). This function returns the tied object so that you can call special methods on it like -&gt;keys().

keys() works like this:

    use YAML;
    use YAML::Node;
    
    %$node = qw(orange orange apple red grape green);
    $ynode = YAML::Node-&gt;new($node);
    ynode($ynode)-&gt;keys(['grape', 'apple']);
    print Dump $ynode;

produces:

    ---
    grape: green
    apple: red

It tells the ynode which keys and what order to use.

ynodes will play a very important role in how programs use YAML. They
are the foundation of how a Perl class can marshall the Loading and
Dumping of its objects.

The upcoming versions of YAML.pm will have much more information on this.

=head1 AUTHOR

Ingy dÃ¶t Net &lt;ingy@cpan.org&gt;

=head1 COPYRIGHT

Copyright (c) 2006, 2011-2012. Ingy dÃ¶t Net. All rights reserved.

Copyright (c) 2002. Brian Ingerson. All rights reserved.

This program is free software; you can redistribute it and/or modify it
under the same terms as Perl itself.

See L&lt;http://www.perl.com/perl/misc/Artistic.html&gt;

=cut
</pre></body></html>