if ($?verbose_login) echo "Loading: aliases[basic]"

alias ilock /afs/sipb/project/www/bin/lock
alias plock '/afs/sipb/project/www/bin/lock `pick \!:*' \
	'+/afs/sipb/user/nocturne/mh-sucks/inbox`'
alias ulock /afs/sipb/project/www/bin/unlock
alias mq  'more /afs/sipb/user/nocturne/mh-sucks/queue/\!:1'
alias fpi 'folder -pack +/afs/sipb/user/nocturne/mh-sucks/inbox'
alias si  'scan +/afs/sipb/user/nocturne/mh-sucks/inbox'
alias sq  'scan +/afs/sipb/user/nocturne/mh-sucks/queue'
alias aq  'add-home /afs/sipb/user/nocturne/mh-sucks/queue/\!:1'
alias rq  '/afs/sipb/project/www/bin/requeue \!:*'

alias pickto 'pick -to \!:1 -or -cc \!:1'
alias repickto 'refile +\!:1 `pick -to \!:2 -or -cc \!:2`'
# savoyards, theater, acapella, music-ec, music, music-hackers
alias artsto   'refile +\!:1 `pick '\
                  '-to savoyards@mit.edu -or -cc savoyards@mit.edu -or '\
                  '-to theater@mit.edu -or -cc theater@mit.edu -or '\
                  '-to acapella@mit.edu -or -cc acapella@mit.edu -or '\
                  '-to music@mit.edu -or -cc music@mit.edu -or '\
                  '-to music-ec@mit.edu -or -cc music-ec@mit.edu -or '\
                  '-to mop@media.mit.edu -or -cc mop@media.mit.edu`'

alias websource 'lynx -source \!:*'
alias webshow   'lynx -dump   \!:*'

alias oweboed    'lynx http://bion.mit.edu:8000/patbin/oed-kwic\?query=`echo \!:* | sed -e '"'"'s/ /%20/g'"'"'`\&type-Lookup\&size=1-100'

alias weboed	'lynx -cookies http://dictionary.oed.com/cgi/search_main\?query_type=fulltext\&queryword=`echo \!:* | sed -e '"'"'s/ /%20/g'"'"'`\&sort_type=alpha\&edition=2e\&first=1\&max_to_show=1000\&search_spec=def'

alias webeb     'lynx http://www.eb.com:180/cgi-bin/g\?keywords=`echo \!:* | sed -e '"'"'s/ /%20/g'"'"'`\&DBase=Articles\&hits=100\&context=all'
alias webav     'lynx http://www.altavista.digital.com/cgi-bin/query\?pg=q\&what=the%20Web\&fmt=in%20Standard%20Form\&q=`echo \!:* | sed -e '"'"'s/ /%20/g'"'"'`'


alias	d2hex	perl -e "'"' printf("%lx\n",     ("\!:1")) '"'"
alias	hex2d	perl -e "'"' printf("%ld\n", hex ("\!:1")) '"'"
alias	d2oct	perl -e "'"' printf("%lo\n",     ("\!:1")) '"'"
alias	oct2d	perl -e "'"' printf("%ld\n", oct ("\!:1")) '"'"

# Attach is necessary because 'multips' depends on /mit/postscript...
alias 4enscript 'attach -q -h postscript; \
                 foreach j (\!:*) \
 echo 4up-enscripting $j ... ; enscript -2Gr -p- $j | /mit/postscript/genericbin/multips | lpr -P${PRINTER}2 \
		end'

alias pvi 'cat > /tmp/.pvi.$$ && (vi /tmp/.pvi.$$ > `tty` && cat /tmp/.pvi.$$; rm -f /tmp/.pvi.$$)'

alias howrun 'echo add `where \!:* | ' \
                       'sed -e '\''s/^\/mit\/\([^\/][^\/]*\)\/.*$/\1/'\''`'\
	          '\"man \!:* | tr \" \\012'

alias tvt 'setenv TERM vt100; resize'
alias popmore 'pop -request c -request "retr \!:1" -request quit | more'
alias popcp 'pop -request c -request "retr \!:1" -request quit > \!:2'


alias cv cview printers \| gawk \
  \''NR > 3 {if ($3=="up") printf("%-11s%8s%3s   \n",$1,$2,$4); \\\
     if ($7=="up") printf("%-11s%8s%3s   \n",$5,$6,$8)}'\' \| \
  gsort -fb +1n -2 +1 -2 +0 -1 \| rs -e -t 0 3

# alias akall '/bin/athena/aklog athena.mit.edu sipb.mit.edu dev.mit.edu'
alias akall '/usr/athena/bin/aklog athena.mit.edu sipb.mit.edu'

alias zhosts  'zlocate \!:1 | awk '\''{print $1}'\'''
alias zf      'foreach j ( `zhosts \!:1` )\
		echo $j ; finger @$j | grep \!:1 \
		end'

alias zhi     'hostinfo `zhosts \!:1`'
alias zfrom   'foreach j ( `zhosts \!:1` )\
		echo $j ; finger \!:1@$j | grep "On since" \
		end'
alias ttop    'top -d1 | cat'
alias tfree   'top -d1 | head -3'
# alias linux   'cd `attach -n -e tsx-11:/u1/ftp/pub/`'
alias redhat 'cd `attach -p -r -h -n -e small-gods:/redhat`'
alias wuarchive 'cd `attach -p -r -h -n -e wuarchive.wustl.edu:/archive`'
alias lsc     'finger -l lsc@zurich.ai.mit.edu | more'
alias repl    'repl -filter /mit/nocturne/dotfiles/reply-filter -cc all \!:*'
alias dscchk  'discuss -rq ckm -quit'
alias sink    'cat >>/dev/null'
# alias zone    'finger @weyr @ninja @hal @monk @soup @goon @achates @isla'\
#               '@elric @akom @tla @zaphod @gevalt' 
alias mtcsh   'man -M /afs/sipb/project/tcsh/man tcsh'
alias hi       /afs/net/tools/@sys/hostinfo
# alias consult 'finger @atc @sonny @navigator @momoney @tailgunner @copilot'\
#               '@fountain'
#alias sipb 'finger @oliver @dt @podge @hodge @milq @bill @binkley @snork'\
#           '@steve @milo @rosebud @enterpoop @bed @picayune @ronald-ann'\
#           '@charon @ronald-ann @charon @beacon @cutter'
# alias esg     'finger @lock @torque @bander @l-slide'
alias map     'more /mit/nocturne/randomtext/w20map'
alias val 'telnet betterbox.net 5454'
# alias val 'telnet hal-alt.hal.com 2444'
# alias oldval     'telnet 192.187.153.1 2444'
# alias olderval 'telnet wiretap.spies.com 2444'
alias info    'finger \!:1@mitdir | tail -n +12'
# alias ainfo   'finger \!:1@athena'
alias ainfo   'finger \!:1@monk | head -14 | tail -9'
alias bkg     'xv -root -rmode 5 -maxpect -quit \!:* &'
alias tilebkg 'xv -root -rmode 0 -quit \!:* &'
alias dir     'ls -l \!:* | more'

#eit mods
alias zeit    'zwrite -i eit -s "albert st.john-smythe"'

#zephyr-related things
alias class 'foreach j ( \!:*  ) \
		zctl sub $j \* \* \
		end'
alias unclass 'foreach j ( \!:*  ) \
		zctl unsub $j \* \* \
		end'
alias uninst  'foreach j ( \!:*  ) \
		zpunt $j\
		end'
alias zn       znol
alias zl       zlocate
alias npunt   'znol off -u \!:*'
alias nperson 'echo \!:*|tr " " \\012|znol -f -'
# alias z       'set parms = (-r) ;' \
#               'if ("\!*" != "") set parms = (\!*) ;' \
#               'zw -r $parms ;' \
#               'unset parms'
alias zaway   'zaway /mit/nocturne/.d/away'
alias zme     'z -n nocturne'
alias xznol   '/afs/sipb/project/xznol/build/xznol.sh'
alias wnol    'znol | zwrite -n -i znol nocturne > /dev/null &'

alias generic_log 'set g_log_lines = "-25";'\
	      'set g_log_file = \!:1;'\
              'if ("\!:*" != "\!:1") set g_log_lines = -\!:$ ;'\
              'tail $g_log_lines $g_log_file | more ;'\
              'unset g_log_lines g_log_file'

alias omlog    'generic_log /tmp/z-log.nocturne.m'
alias oplog    'generic_log /tmp/z-log.nocturne.p'
alias ollog    'generic_log /tmp/z-log.nocturne.l'
alias ojlog    'generic_log /tmp/z-log.nocturne.j'
alias omylog   'generic_log /tmp/z-log.nocturne'

alias mlog    'logparse medium' 
alias plog    'logparse personal'
alias llog    'logparse inout'
alias jlog    'logparse johanna'
alias ilog    'logparse r'
alias mylog   'logparse low'

#alias iftest 'if ("" != "") then\
#               echo A ;' \
#             'else\
#              echo B ; \
#              if ("" == "") then\
# echo C ; endif ; \
#             endif ;'
#
#alias zlog 'set zlog_inst = "" zlog_lines = 25;' \
#           'if ("\!:*" == "") then\
#               echo You must specify an instance-name as an argument. ; \
#             else\
#               if ("\!:*" != "")     then\
#                  set zlog_inst  = \!:$ ; endif ; \
#               if ("\!:*" != "\!:1") then\
#                  set zlog_lines = \!:1 ; endif ; \
#            endif;' \
#            'unset zlog_inst zlog_lines'
#
#alias asdfasdf ' \
#               if ("$zlog_lines" == "") then\
#                  echo You must specify an instance-name as an argument. ; \
#                else\
#                 set zlog_inst = /mit/bitbucket/zephyr-log/$zlog_inst ; \
#                 if ( -r $zlog_inst ) then\
#        	    generic_log $zlog_inst $zlog_lines ; \
#                  else\
#                    echo No log file. ; \
#                  endif; \
#               endif; \
#'

#alias zlog    'set zlog_inst = "" zlog_lines = "";'\
#              'if ("\!:*" != "")     set zlog_inst  = \!:$ ;' \
#	      'if ("\!:*" != "\!:1") set zlog_lines = \!:1 ;' \
#	      'generic_log /mit/bitbucket/zephyr-log/$zlog_inst $zlog_lines ;'\
#              'unset zlog_inst zlog_lines'

alias zlog    'set zlog_inst = "" zlog_lines = "";'\
              'if ("\!:*" != "")     set zlog_inst  = \!:$ ;' \
	      'if ("\!:*" != "\!:1") set zlog_lines = \!:1 ;' \
	      'generic_log /mit/zlog/$zlog_inst $zlog_lines ;'\
              'unset zlog_inst zlog_lines'

alias sipbrw 'detach /mit/sipb; attach -m /mit/sipb -t afs -e /afs/.sipb.mit.edu/project/sipb'
alias sipbro 'detach /mit/sipb; attach -h -n sipb'
#things i don't use that i might in the future...
#alias z6    'znol -l -f /mit/nocturne/.d/anyone.6.170'
#alias one 'PCLU -debug  /mit/6.170/lib/ps1-library.lib -create ps1.lib ps1.code.clu'
#alias two 'PCLU -debug /mit/6.170/lib/ps1-library.lib ps1.lib ps1.code.clu'
#alias three 'PCLU -debug -link ps1 /mit/6.170/lib/ps1-library.o ps1.o'

# alias mdo 'mformat -h a: < /tmp/form ; echo ; mcopy \!:*/* a:'

alias zlog-age 'ghead -c 4 \!:* | perl -ne '\''require "ctime.pl"; print &ctime(0x7fffffff & unpack("N1",$_));'\'

alias dcmd 'set _dcmd = ( \!* ); set _gdiffargs = "";  \
     if ( $#_dcmd == 3 ) set _gdiffargs = "$_dcmd[3]"; \
     eval $_dcmd[1] >\! /tmp/dcmd && \
     eval $_dcmd[2] | gdiff $_gdiffargs /tmp/dcmd - '
alias pernmush telnet jhereg 4201
alias rot13 'tr "A-Za-z" "N-ZA-Mn-za-m"'
alias rot12 'tr "A-Za-z" "M-ZA-Lm-za-l"'
alias rot14 'tr "M-ZA-Lm-za-l" "A-Za-z"'
alias subhelp 'zctl sub message help \* ; zctl sub message help.d \*'
alias unsubhelp 'zctl unsub message help \* ; zctl unsub message help.d \*'

alias loggit "/mit/nocturne/home/lib/tcl/loggit -geometry -300+5&"
alias rn "rmm ; next"

alias lprmp3 "lpr -b -Psipbmp3 \!:*"
alias lpqmp3 "lpq -Psipbmp3"

alias scanspam 'scan `pick cur-last --x-spam-flag yes`'
alias rmmspam 'rmm `pick cur-last --x-spam-flag yes`'

alias scan "scan -form ~/.d/scan.spam"
# alias inc  "inc -form ~/.d/scan.spam && rmmspam"
alias inc  'echo "you really didn'"'"'t mean to run inc"'

alias eli 'emacs -f run-alisp \!:* &'
alias alpine "klist -s && /usr/athena/bin/aklog athena sipb && /usr/athena/bin/alpine || echo 'try again with tickets'"